chiark - git - mdw - disorder/blob - scripts/protocol

   1 #! /usr/bin/perl -w
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2010-11 Richard Kettlewell
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 use strict;
  20
  21 # This file contains the definition of the disorder protocol, plus
  22 # code to generates stubs for it in the various supported languages.
  23 #
  24 # At the time of writing it is a work in progress!
  25
  26 #
  27 # Types:
  28 #
  29 #    string         A (Unicode) string.
  30 #    string-raw     A string that is not subject to de-quoting (return only)
  31 #    integer        An integer.  Decimal on the wire.
  32 #    time           A timestamp.  Decimal on the wire.
  33 #    boolean        True or false.  "yes" or "no" on the wire.
  34 #    list           In commands: a list of strings in the command.
  35 #                   In returns: a list of lines in the response.
  36 #    pair-list      In returns: a list of key-value pairs in a response body.
  37 #    body           In commands: a list of strings as a command body.
  38 #                   In returns: a list of strings as a response body.
  39 #    queue          In returns: a list of queue entries in a response body.
  40 #    queue-one      In returns: a queue entry in the response.
  41 #    literal        Constant string sent in sequence
  42 #
  43
  44 # Variables and utilities -----------------------------------------------------
  45
  46 our @h = ();
  47 our @c = ();
  48
  49 # Write(PATH, LINES)
  50 #
  51 # Write array ref LINES to file PATH.
  52 sub Write {
  53     my $path = shift;
  54     my $lines = shift;
  55
  56     (open(F, ">$path")
  57      and print F @$lines
  58      and close F)
  59         or die "$0: $path: $!\n";
  60 }
  61
  62 # Command classes -------------------------------------------------------------
  63
  64 # c_in_decl([TYPE, NAME])
  65 #
  66 # Return the C declaration for an input parameter of type TYPE with
  67 # name NAME.
  68 sub c_in_decl {
  69     my $arg = shift;
  70
  71     my $type = $arg->[0];
  72     my $name = $arg->[1];
  73     if($type eq 'string') {
  74         return "const char *$name";
  75     } elsif($type eq 'integer') {
  76         return "long $name";
  77     } elsif($type eq 'time') {
  78         return "time_t $name";
  79     } elsif($type eq 'list' or $type eq 'body') {
  80         return ("char **$name",
  81                 "int n$name");
  82     } elsif($type eq 'literal') {
  83         return ();
  84     } else {
  85         die "$0: c_in_decl: unknown type '$type'\n";
  86     }
  87 }
  88
  89 # c_out_decl([TYPE, NAME])
  90 #
  91 # Return the C declaration for an output (reference) parameter of type
  92 # TYPE with name NAME.
  93 sub c_out_decl {
  94     my $arg = shift;
  95
  96     return () unless defined $arg;
  97     my $type = $arg->[0];
  98     my $name = $arg->[1];
  99     if($type eq 'string' or $type eq 'string-raw') {
 100         return ("char **${name}p");
 101     } elsif($type eq 'integer') {
 102         return ("long *${name}p");
 103     } elsif($type eq 'time') {
 104         return ("time_t *${name}p");
 105     } elsif($type eq 'boolean') {
 106         return ("int *${name}p");
 107     } elsif($type eq 'list' or $type eq 'body') {
 108         return ("char ***${name}p",
 109                 "int *n${name}p");
 110     } elsif($type eq 'pair-list') {
 111         return ("struct kvp **${name}p");
 112     } elsif($type eq 'queue' or $type eq 'queue-one') {
 113         return ("struct queue_entry **${name}p");
 114     } elsif($type eq 'user') {
 115         return ();
 116     } else {
 117         die "$0: c_out_decl: unknown type '$type'\n";
 118     }
 119 }
 120
 121 # c_param_docs([TYPE, NAME})
 122 #
 123 # Return the doc string for a C input parameter.
 124 sub c_param_docs {
 125     my $args = shift;
 126     my @d = ();
 127     for my $arg (@$args) {
 128         my $type = $arg->[0];
 129         my $name = $arg->[1];
 130         my $description = $arg->[2];
 131         if($type eq 'body' or $type eq 'list') {
 132             push(@d,
 133                  " * \@param $name $description\n",
 134                  " * \@param n$name Length of $name\n");
 135         } elsif($type ne 'literal') {
 136             push(@d, " * \@param $name $description\n");
 137         }
 138     }
 139     return @d;
 140 }
 141
 142 # c_param_docs([TYPE, NAME})
 143 #
 144 # Return the doc string for a C output parameter.
 145 sub c_return_docs {
 146     my $returns = shift;
 147     return () unless defined $returns;
 148     for my $return (@$returns) {
 149         my $type = $return->[0];
 150         my $name = $return->[1];
 151         my $descr = $return->[2];
 152         if($type eq 'string'
 153            or $type eq 'string-raw'
 154            or $type eq 'integer'
 155            or $type eq 'time'
 156            or $type eq 'boolean') {
 157             return (" * \@param ${name}p $descr\n");
 158         } elsif($type eq 'list' or $type eq 'body') {
 159             return (" * \@param ${name}p $descr\n",
 160                     " * \@param n${name}p Number of elements in ${name}p\n");
 161         } elsif($type eq 'pair-list') {
 162             return (" * \@param ${name}p $descr\n");
 163         } elsif($type eq 'queue' or $type eq 'queue-one') {
 164             return (" * \@param ${name}p $descr\n");
 165         } elsif($type eq 'user') {
 166             return ();
 167         } else {
 168             die "$0: c_return_docs: unknown type '$type'\n";
 169         }
 170     }
 171 }
 172
 173 # simple(CMD, SUMMARY, DETAIL,
 174 #        [[TYPE,NAME,DESCR], [TYPE,NAME,DESCR], ...],
 175 #        [[RETURN-TYPE, RETURN-NAME, RETURN_DESCR]])
 176 #
 177 # CMD is normally just the name of the command, but can
 178 # be [COMMAND,FUNCTION] if the function name should differ
 179 # from the protocol command.
 180 sub simple {
 181     my $cmd = shift;
 182     my $summary = shift;
 183     my $detail = shift;
 184     my $args = shift;
 185     my $returns = shift;
 186
 187     my $cmdc;
 188     if(ref $cmd eq 'ARRAY') {
 189         $cmdc = $$cmd[1];
 190         $cmd = $$cmd[0];
 191     } else {
 192         $cmdc = $cmd;
 193         $cmdc =~ s/-/_/g;
 194     }
 195     print STDERR "Processing $cmd... ";
 196     # Synchronous C API
 197     print STDERR "H ";
 198     push(@h, "/** \@brief $summary\n",
 199          " *\n",
 200          " * $detail\n",
 201          " *\n",
 202          " * \@param c Client\n",
 203          c_param_docs($args),
 204          c_return_docs($returns),
 205          " * \@return 0 on success, non-0 on error\n",
 206          " */\n",
 207          "int disorder_$cmdc(",
 208          join(", ", "disorder_client *c",
 209                     map(c_in_decl($_), @$args),
 210                     map(c_out_decl($_), @$returns)),
 211          ");\n\n");
 212     print STDERR "C ";
 213     push(@c, "int disorder_$cmdc(",
 214          join(", ", "disorder_client *c",
 215                     map(c_in_decl($_), @$args),
 216                     map(c_out_decl($_), @$returns)),
 217          ") {\n");
 218     my @cargs = ();
 219     for my $arg (@$args) {
 220         if($arg->[0] eq 'body' or $arg->[0] eq 'list') {
 221             push(@cargs, "disorder_$arg->[0]", $arg->[1], "n$arg->[1]");
 222         } elsif($arg->[0] eq 'string') {
 223             push(@cargs, $arg->[1]);
 224         } elsif($arg->[0] eq 'integer') {
 225             push(@cargs, "buf_$arg->[1]");
 226             push(@c, "  char buf_$arg->[1]\[16];\n",
 227                  "  byte_snprintf(buf_$arg->[1], sizeof buf_$arg->[1], \"%ld\", $arg->[1]);\n");
 228         } elsif($arg->[0] eq 'time') {
 229             push(@cargs, "buf_$arg->[1]");
 230             push(@c, "  char buf_$arg->[1]\[16];\n",
 231                  "  byte_snprintf(buf_$arg->[1], sizeof buf_$arg->[1], \"%lld\", (long long)$arg->[1]);\n");
 232         } elsif($arg->[0] eq 'literal') {
 233             push(@cargs, "\"$arg->[1]\"");
 234         } else {
 235             die "$0: unsupported arg type '$arg->[0]' for '$cmd'\n";
 236         }
 237     }
 238     if(!defined $returns or scalar @$returns == 0) {
 239         # Simple case
 240         push(@c, "  return disorder_simple(",
 241              join(", ", "c", "NULL", "\"$cmd\"", @cargs, "(char *)NULL"),
 242              ");\n");
 243     } elsif(scalar @$returns == 1
 244             and $returns->[0]->[0] eq 'queue-one') {
 245         # Special case
 246         my $return = $$returns[0];
 247         push(@c, "  return onequeue(c, \"$cmd\", $return->[1]p);\n");
 248     } elsif(scalar @$returns == 1
 249             and $returns->[0]->[0] eq 'string-raw') {
 250         # Special case
 251         my $return = $$returns[0];
 252         push(@c, "  return disorder_simple(",
 253              join(", ", "c", "$return->[1]p", "\"$cmd\"", @cargs, "(char *)NULL"),
 254              ");\n");
 255     } elsif(scalar @$returns == 1
 256             and $returns->[0]->[0] eq 'pair-list') {
 257         # Special case
 258         my $return = $$returns[0];
 259         push(@c, "  return pairlist(",
 260              join(", ", "c", "$return->[1]p", "\"$cmd\"",
 261                   @cargs,
 262                   "(char *)NULL"),
 263              ");\n");
 264     } else {
 265         my $split = 0;
 266         for(my $n = 0; $n < scalar @$returns; ++$n) {
 267             my $return = $returns->[$n];
 268             my $type = $return->[0];
 269             my $name = $return->[1];
 270             if($type eq 'string'
 271                or $type eq 'boolean'
 272                or $type eq 'integer'
 273                or $type eq 'time'
 274                or $type eq 'user') {
 275                 $split = 1;
 276             }
 277         }
 278         if($split) {
 279             push(@c, "  char **v, *r;\n",
 280                  "  int nv;\n");
 281         }
 282         push(@c,
 283              "  int rc = disorder_simple(",
 284              join(", ",
 285                   "c",
 286                   $split ? "&r" : "NULL",
 287                   "\"$cmd\"",
 288                   @cargs,
 289                   "(char *)NULL"),
 290              ");\n",
 291              "  if(rc)\n",
 292              "    return rc;\n");
 293         if($split) {
 294             push(@c,
 295                  "  v = split(r, &nv, SPLIT_QUOTES, 0, 0);\n",
 296                  "  if(nv != ", scalar @$returns, ") {\n",
 297                  "    disorder_error(0, \"malformed reply to %s\", \"$cmd\");\n",
 298                  "    return -1;\n",
 299                  "  }\n");
 300         }
 301         for(my $n = 0; $n < scalar @$returns; ++$n) {
 302             my $return = $returns->[$n];
 303             my $type = $return->[0];
 304             my $name = $return->[1];
 305             if($type eq 'string') {
 306                 push(@c,
 307                      "  *${name}p = v[$n];\n");
 308             } elsif($type eq 'boolean') {
 309                 push(@c,
 310                      "  if(boolean(\"$cmd\", v[$n], ${name}p))\n",
 311                      "    return -1;\n");
 312             } elsif($type eq 'integer') {
 313                 push(@c,
 314                      "  *${name}p = atol(v[$n]);\n");
 315             } elsif($type eq 'time') {
 316                 push(@c,
 317                      "  *${name}p = atoll(v[$n]);\n");
 318             } elsif($type eq 'user') {
 319                 push(@c,
 320                      "  c->user = v[$n];\n");
 321             } elsif($type eq 'body') {
 322                 push(@c,
 323                      "  if(readlist(c, ${name}p, n${name}p))\n",
 324                      "    return -1;\n");
 325             } elsif($type eq 'queue') {
 326                 push(@c,
 327                      "  if(readqueue(c, ${name}p))\n",
 328                      "    return -1;\n");
 329             } else {
 330                 die "$0: C API: unknown return type '$type' for '$name'\n";
 331             }
 332         }
 333         push(@c, "  return 0;\n");
 334         # TODO xfree unconsumed split output
 335     }
 336     push(@c, "}\n\n");
 337
 338     # Asynchronous C API
 339     # TODO
 340
 341     # Python API
 342     # TODO
 343
 344     # Java API
 345     # TODO
 346     print STDERR "\n";
 347 }
 348
 349 # TODO other command classes
 350
 351 # Front matter ----------------------------------------------------------------
 352
 353 our @generated = ("/*\n",
 354                   " * Automatically generated file, see scripts/protocol\n",
 355                   " *\n",
 356                   " * DO NOT EDIT.\n",
 357                   " */\n");
 358
 359 our @gpl = ("/*\n",
 360             " * This file is part of DisOrder.\n",
 361             " * Copyright (C) 2010-11 Richard Kettlewell\n",
 362             " *\n",
 363             " * This program is free software: you can redistribute it and/or modify\n",
 364             " * it under the terms of the GNU General Public License as published by\n",
 365             " * the Free Software Foundation, either version 3 of the License, or\n",
 366             " * (at your option) any later version.\n",
 367             " *\n",
 368             " * This program is distributed in the hope that it will be useful,\n",
 369             " * but WITHOUT ANY WARRANTY; without even the implied warranty of\n",
 370             " * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\n",
 371             " * GNU General Public License for more details.\n",
 372             " *\n",
 373             " * You should have received a copy of the GNU General Public License\n",
 374             " * along with this program.  If not, see <http://www.gnu.org/licenses/>.\n",
 375             " */\n");
 376
 377
 378 push(@h, @generated, @gpl,
 379      "#ifndef CLIENT_STUBS_H\n",
 380      "#define CLIENT_STUBS_H\n",
 381      "\n");
 382
 383 push(@c, @generated, @gpl,
 384      "\n");
 385
 386 # The protocol ----------------------------------------------------------------
 387
 388 simple("adopt",
 389        "Adopt a track",
 390        "Makes the calling user owner of a randomly picked track.",
 391        [["string", "id", "Track ID"]]);
 392
 393 simple("adduser",
 394        "Create a user",
 395        "Create a new user.  Requires the 'admin' right.  Email addresses etc must be filled in in separate commands.",
 396        [["string", "user", "New username"],
 397         ["string", "password", "Initial password"],
 398         ["string", "rights", "Initial rights (optional)"]]);
 399
 400 simple("allfiles",
 401        "List files and directories in a directory",
 402        "See 'files' and 'dirs' for more specific lists.",
 403        [["string", "dir", "Directory to list (optional)"],
 404         ["string", "re", "Regexp that results must match (optional)"]],
 405        [["body", "files", "List of matching files and directories"]]);
 406
 407 simple("confirm",
 408        "Confirm registration",
 409        "The confirmation string must have been created with 'register'.  The username is returned so the caller knows who they are.",
 410        [["string", "confirmation", "Confirmation string"]],
 411        [["user"]]);
 412
 413 simple("cookie",
 414        "Log in with a cookie",
 415        "The cookie must have been created with 'make-cookie'.  The username is returned so the caller knows who they are.",
 416        [["string", "cookie", "Cookie string"]],
 417        [["user"]]);
 418
 419 simple("deluser",
 420        "Delete user",
 421        "Requires the 'admin' right.",
 422        [["string", "user", "User to delete"]]);
 423
 424 simple("dirs",
 425        "List directories in a directory",
 426        "",
 427        [["string", "dir", "Directory to list (optional)"],
 428         ["string", "re", "Regexp that results must match (optional)"]],
 429        [["body", "files", "List of matching directories"]]);
 430
 431 simple("disable",
 432        "Disable play",
 433        "Play will stop at the end of the current track, if one is playing.  Requires the 'global prefs' right.",
 434        []);
 435
 436 simple("edituser",
 437        "Set a user property",
 438        "With the 'admin' right you can do anything.  Otherwise you need the 'userinfo' right and can only set 'email' and 'password'.",
 439        [["string", "username", "User to modify"],
 440         ["string", "property", "Property name"],
 441         ["string", "value", "New property value"]]);
 442
 443 simple("enable",
 444        "Enable play",
 445        "Requires the 'global prefs' right.",
 446        []);
 447
 448 simple("enabled",
 449        "Detect whether play is enabled",
 450        "",
 451        [],
 452        [["boolean", "enabled", "1 if play is enabled and 0 otherwise"]]);
 453
 454 simple("exists",
 455        "Test whether a track exists",
 456        "",
 457        [["string", "track", "Track name"]],
 458        [["boolean", "exists", "1 if the track exists and 0 otherwise"]]);
 459
 460 simple("files",
 461        "List files in a directory",
 462        "",
 463        [["string", "dir", "Directory to list (optional)"],
 464         ["string", "re", "Regexp that results must match (optional)"]],
 465        [["body", "files", "List of matching files"]]);
 466
 467 simple("get",
 468        "Get a track preference",
 469        "If the track does not exist that is an error.  If the track exists but the preference does not then a null value is returned.",
 470        [["string", "track", "Track name"],
 471         ["string", "pref", "Preference name"]],
 472        [["string", "value", "Preference value"]]);
 473
 474 simple("get-global",
 475        "Get a global preference",
 476        "If the preference does exist not then a null value is returned.",
 477        [["string", "pref", "Global preference name"]],
 478        [["string", "value", "Preference value"]]);
 479
 480 simple("length",
 481        "Get a track's length",
 482        "If the track does not exist an error is returned.",
 483        [["string", "track", "Track name"]],
 484        [["integer", "length", "Track length in seconds"]]);
 485
 486 # TODO log
 487
 488 simple("make-cookie",
 489        "Create a login cookie for this user",
 490        "The cookie may be redeemed via the 'cookie' command",
 491        [],
 492        [["string", "cookie", "Newly created cookie"]]);
 493
 494 simple("move",
 495        "Move a track",
 496        "Requires one of the 'move mine', 'move random' or 'move any' rights depending on how the track came to be added to the queue.",
 497        [["string", "track", "Track ID or name"],
 498         ["integer", "delta", "How far to move the track towards the head of the queue"]]);
 499
 500 simple("moveafter",
 501        "Move multiple tracks",
 502        "Requires one of the 'move mine', 'move random' or 'move any' rights depending on how the track came to be added to the queue.",
 503        [["string", "target", "Move after this track, or to head if \"\""],
 504         ["list", "ids", "List of tracks to move by ID"]]);
 505
 506 simple(["new", "new_tracks"],
 507        "List recently added tracks",
 508        "",
 509        [["integer", "max", "Maximum tracks to fetch, or 0 for all available"]],
 510        [["body", "tracks", "Recently added tracks"]]);
 511
 512 simple("nop",
 513        "Do nothing",
 514        "Used as a keepalive.  No authentication required.",
 515        []);
 516
 517 simple("part",
 518        "Get a track name part",
 519        "If the name part cannot be constructed an empty string is returned.",
 520        [["string", "track", "Track name"],
 521         ["string", "context", "Context (\"sort\" or \"display\")"],
 522         ["string", "part", "Name part (\"artist\", \"album\" or \"title\")"]],
 523        [["string", "part", "Value of name part"]]);
 524
 525 simple("pause",
 526        "Pause the currently playing track",
 527        "Requires the 'pause' right.",
 528        []);
 529
 530 simple("play",
 531        "Play a track",
 532        "Requires the 'play' right.",
 533        [["string", "track", "Track to play"]],
 534        [["string-raw", "id", "Queue ID of new track"]]);
 535
 536 simple("playafter",
 537        "Play multiple tracks",
 538        "Requires the 'play' right.",
 539        [["string", "target", "Insert into queue after this track, or at head if \"\""],
 540         ["list", "tracks", "List of track names to play"]]);
 541
 542 simple("playing",
 543        "Retrieve the playing track",
 544        "",
 545        [],
 546        [["queue-one", "playing", "Details of the playing track"]]);
 547
 548 simple("playlist-delete",
 549        "Delete a playlist",
 550        "Requires the 'play' right and permission to modify the playlist.",
 551        [["string", "playlist", "Playlist to delete"]]);
 552
 553 simple("playlist-get",
 554        "List the contents of a playlist",
 555        "Requires the 'read' right and oermission to read the playlist.",
 556        [["string", "playlist", "Playlist name"]],
 557        [["body", "tracks", "List of tracks in playlist"]]);
 558
 559 simple("playlist-get-share",
 560        "Get a playlist's sharing status",
 561        "Requires the 'read' right and permission to read the playlist.",
 562        [["string", "playlist", "Playlist to read"]],
 563        [["string-raw", "share", "Sharing status (\"public\", \"private\" or \"shared\")"]]);
 564
 565 simple("playlist-lock",
 566        "Lock a playlist",
 567        "Requires the 'play' right and permission to modify the playlist.  A given connection may lock at most one playlist.",
 568        [["string", "playlist", "Playlist to delete"]]);
 569
 570 simple("playlist-set",
 571        "Set the contents of a playlist",
 572        "Requires the 'play' right and permission to modify the playlist, which must be locked.",
 573        [["string", "playlist", "Playlist to modify"],
 574         ["body", "tracks", "New list of tracks for playlist"]]);
 575
 576 simple("playlist-set-share",
 577        "Set a playlist's sharing status",
 578        "Requires the 'play' right and permission to modify the playlist.",
 579        [["string", "playlist", "Playlist to modify"],
 580         ["string", "share", "New sharing status (\"public\", \"private\" or \"shared\")"]]);
 581
 582 simple("playlist-unlock",
 583        "Unlock the locked playlist playlist",
 584        "The playlist to unlock is implicit in the connection.",
 585        []);
 586
 587 simple("playlists",
 588        "List playlists",
 589        "Requires the 'read' right.  Only playlists that you have permission to read are returned.",
 590        [],
 591        [["body", "playlists", "Playlist names"]]);
 592
 593 simple("prefs",
 594        "Get all the preferences for a track",
 595        "",
 596        [["string", "track", "Track name"]],
 597        [["pair-list", "prefs", "Track preferences"]]);
 598
 599 simple("queue",
 600        "List the queue",
 601        "",
 602        [],
 603        [["queue", "queue", "Current queue contents"]]);
 604
 605 simple("random-disable",
 606        "Disable random play",
 607        "Requires the 'global prefs' right.",
 608        []);
 609
 610 simple("random-enable",
 611        "Enable random play",
 612        "Requires the 'global prefs' right.",
 613        []);
 614
 615 simple("random-enabled",
 616        "Detect whether random play is enabled",
 617        "Random play counts as enabled even if play is disabled.",
 618        [],
 619        [["boolean", "enabled", "1 if random play is enabled and 0 otherwise"]]);
 620
 621 simple("recent",
 622        "List recently played tracks",
 623        "",
 624        [],
 625        [["queue", "recent", "Recently played tracks"]]);
 626
 627 simple("reconfigure",
 628        "Re-read configuraiton file.",
 629        "Requires the 'admin' right.",
 630        []);
 631
 632 simple("register",
 633        "Register a new user",
 634        "Requires the 'register' right which is usually only available to the 'guest' user.  Redeem the confirmation string via 'confirm' to complete registration.",
 635        [["string", "username", "Requested new username"],
 636         ["string", "password", "Requested initial password"],
 637         ["string", "email", "New user's email address"]],
 638        [["string", "confirmation", "Confirmation string"]]);
 639
 640 simple("reminder",
 641        "Send a password reminder.",
 642        "If the user has no valid email address, or no password, or a reminder has been sent too recently, then no reminder will be sent.",
 643        [["string", "username", "User to remind"]]);
 644
 645 simple("remove",
 646        "Remove a track form the queue.",
 647        "Requires one of the 'remove mine', 'remove random' or 'remove any' rights depending on how the track came to be added to the queue.",
 648        [["string", "id", "Track ID"]]);
 649
 650 simple("rescan",
 651        "Rescan all collections for new or obsolete tracks.",
 652        "Requires the 'rescan' right.",
 653        []);     # TODO wait/fresh flags
 654
 655 simple("resolve",
 656        "Resolve a track name",
 657        "Converts aliases to non-alias track names",
 658        [["string", "track", "Track name (might be an alias)"]],
 659        [["string", "resolved", "Resolve track name (definitely not an alias)"]]);
 660
 661 simple("resume",
 662        "Resume the currently playing track",
 663        "Requires the 'pause' right.",
 664        []);
 665
 666 simple("revoke",
 667        "Revoke a cookie.",
 668        "It will not subsequently be possible to log in with the cookie.",
 669        []);
 670
 671 simple("rtp-address",
 672        "Get the server's RTP address information",
 673        "",
 674        [],
 675        [["string", "address", "Where to store hostname or address"],
 676         ["string", "port", "Where to store service name or port number"]]);
 677
 678 simple("scratch",
 679        "Terminate the playing track.",
 680        "Requires one of the 'scratch mine', 'scratch random' or 'scratch any' rights depending on how the track came to be added to the queue.",
 681        [["string", "id", "Track ID (optional)"]]);
 682
 683 simple(["schedule-add", "schedule_add_play"],
 684        "Schedule a track to play in the future",
 685        "",
 686        [["time", "when", "When to play the track"],
 687         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 688         ["literal", "play", ""],
 689         ["string", "track", "Track to play"]]);
 690
 691 simple(["schedule-add", "schedule_add_set_global"],
 692        "Schedule a global setting to be changed in the future",
 693        "",
 694        [["time", "when", "When to change the setting"],
 695         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 696         ["literal", "set-global", ""],
 697         ["string", "pref", "Global preference to set"],
 698         ["string", "value", "New value of global preference"]]);
 699
 700 simple(["schedule-add", "schedule_add_unset_global"],
 701        "Schedule a global setting to be unset in the future",
 702        "",
 703        [["time", "when", "When to change the setting"],
 704         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 705         ["literal", "set-global", ""],
 706         ["string", "pref", "Global preference to set"]]);
 707
 708 simple("schedule-del",
 709        "Delete a scheduled event.",
 710        "Users can always delete their own scheduled events; with the admin right you can delete any event.",
 711        [["string", "event", "ID of event to delete"]]);
 712
 713 simple("schedule-get",
 714        "Get the details of scheduled event",
 715        "",
 716        [["string", "id", "Event ID"]],
 717        [["pair-list", "actiondata", "Details of event"]]);
 718
 719 simple("schedule-list",
 720        "List scheduled events",
 721        "This just lists IDs.  Use 'schedule-get' to retrieve more detail",
 722        [],
 723        [["body", "ids", "List of event IDs"]]);
 724
 725 simple("search",
 726        "Search for tracks",
 727        "Terms are either keywords or tags formatted as 'tag:TAG-NAME'.",
 728        [["string", "terms", "List of search terms"]],
 729        [["body", "tracks", "List of matching tracks"]]);
 730
 731 simple("set",
 732        "Set a track preference",
 733        "Requires the 'prefs' right.",
 734        [["string", "track", "Track name"],
 735         ["string", "pref", "Preference name"],
 736         ["string", "value", "New value"]]);
 737
 738 simple("set-global",
 739        "Set a global preference",
 740        "Requires the 'global prefs' right.",
 741        [["string", "pref", "Preference name"],
 742         ["string", "value", "New value"]]);
 743
 744 simple("shutdown",
 745        "Request server shutdown",
 746        "Requires the 'admin' right.",
 747        []);
 748
 749 simple("stats",
 750        "Get server statistics",
 751        "The details of what the server reports are not really defined.  The returned strings are intended to be printed out one to a line.",
 752        [],
 753        [["body", "stats", "List of server information strings."]]);
 754
 755 simple("tags",
 756        "Get a list of known tags",
 757        "Only tags which apply to at least one track are returned.",
 758        [],
 759        [["body", "tags", "List of tags"]]);
 760
 761 simple("unset",
 762        "Unset a track preference",
 763        "Requires the 'prefs' right.",
 764        [["string", "track", "Track name"],
 765         ["string", "pref", "Preference name"]]);
 766
 767 simple("unset-global",
 768        "Set a global preference",
 769        "Requires the 'global prefs' right.",
 770        [["string", "pref", "Preference name"]]);
 771
 772 # 'user' only used for authentication
 773
 774 simple("userinfo",
 775        "Get a user property.",
 776        "If the user does not exist an error is returned, if the user exists but the property does not then a null value is returned.",
 777        [["string", "username", "User to read"],
 778         ["string", "property", "Property to read"]],
 779        [["string", "value", "Value of property"]]);
 780
 781 simple("users",
 782        "Get a list of users",
 783        "",
 784        [],
 785        [["body", "users", "List of users"]]);
 786
 787 simple("version",
 788        "Get the server version",
 789        "",
 790        [],
 791        [["string", "version", "Server version string"]]);
 792
 793 simple(["volume", "set_volume"],
 794        "Set the volume",
 795        "",
 796        [["integer", "left", "Left channel volume"],
 797         ["integer", "right", "Right channel volume"]]);
 798
 799 simple(["volume", "get_volume"],
 800        "Get the volume",
 801        "",
 802        [],
 803        [["integer", "left", "Left channel volume"],
 804         ["integer", "right", "Right channel volume"]]);
 805
 806 # End matter ------------------------------------------------------------------
 807
 808 push(@h, "#endif\n");
 809
 810 # Write it all out ------------------------------------------------------------
 811
 812 Write("lib/client-stubs.h", \@h);
 813 Write("lib/client-stubs.c", \@c);