chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004-2010 Richard Kettlewell
   5 # Portions copyright (C) 2007 Ross Younger
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 AC_INIT([disorder], [4.3+], [richard+disorder@sfere.greenend.org.uk])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AM_INIT_AUTOMAKE(disorder, [4.3+])
  24 AC_CONFIG_SRCDIR([server/disorderd.c])
  25 AM_CONFIG_HEADER([config.h])
  26
  27 # Find host type
  28 AC_CANONICAL_HOST
  29
  30 # What we want to build
  31 want_gtk=yes
  32 want_python=yes
  33 want_tests=yes
  34 want_server=yes
  35 want_cgi=yes
  36
  37 # APIs we want
  38 want_alsa=yes
  39 want_oss=yes
  40 want_coreaudio=yes
  41
  42 # By default we don't want gtk-osx.  But if you ask for --with-gtk-osx...
  43 #
  44 # Disobedience can be built to a native OS X application.  There are some
  45 # caveats:
  46 #  - you will still need Fink (or something) for other libraries
  47 #  - if you wanted an application bundle you are out of luck
  48 #  - the menu bar is still in the main window (not at the top of the screen)
  49 #
  50 # So it's still rather rough and ready.  But it does work...
  51 #
  52 # See:
  53 #   http://www.gtk-osx.org/
  54 #   http://live.gnome.org/GTK%2B/OSX/Framework
  55 want_gtkosx=no
  56
  57 # Checks for programs.
  58 AC_PROG_CC
  59 AM_PROG_CC_C_O
  60 AC_PROG_AWK
  61 AC_SET_MAKE
  62 if test "x$GCC" = xyes; then
  63   gcc_werror=-Werror
  64   case "$CC" in
  65   *-std=* )
  66     ;;
  67   * )
  68     CC="${CC} -std=gnu99"
  69     ;;
  70   esac
  71 else
  72   AC_MSG_ERROR([GNU C is required to build this program])
  73   gcc_werror=""
  74 fi
  75
  76 AC_ARG_WITH([alsa],
  77             [AS_HELP_STRING([--without-alsa],
  78                             [do not build with ALSA support])],
  79             [want_alsa=$withval])
  80 AC_ARG_WITH([oss],
  81             [AS_HELP_STRING([--without-oss],
  82                             [do not build with OSS support])],
  83             [want_oss=$withval])
  84 AC_ARG_WITH([coreaudio],
  85             [AS_HELP_STRING([--without-coreaudio],
  86                             [do not build with Core Audio support])],
  87             [want_coreaudio=$withval])
  88 AC_ARG_WITH([tests],
  89             [AS_HELP_STRING([--without-tests],
  90                             [do not build test suit])],
  91             [want_tests=$withval])
  92 AC_ARG_WITH([gtk-osx],
  93             [AS_HELP_STRING([--with-gtk-osx],
  94                             [use native GTK+ (OS X only)])],
  95             [want_gtkosx=$withval])
  96
  97 AC_MSG_CHECKING([for a known target platform])
  98 case "$host" in
  99 *empeg* )
 100   AC_MSG_RESULT([empeg car stereo])
 101   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
 102   # work around broken toolchain
 103   AC_CHECK_LIB([gpg-error], [gpg_strerror])
 104   AC_CHECK_LIB([pthread], [pthread_create])
 105   want_server=no
 106   want_cgi=no
 107  ;;
 108 *linux* | *Linux* )
 109   AC_MSG_RESULT([Linux])
 110   ;;
 111 *-apple-darwin* )
 112   AC_MSG_RESULT([Mac OS X])
 113   # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
 114   # so we'll just turn off the warning.
 115   CC="$CC -Wno-deprecated-declarations"
 116   if test $want_coreaudio = yes; then
 117     COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
 118   fi
 119   browser=open
 120   AC_MSG_CHECKING([Mac OS X target version])
 121   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
 122   # behaviour.  But we provide a command line option to override it and
 123   # we default to wide support instead of supporting only the build platform.
 124   #
 125   # Currently if you ask for 10.5 you will get a deprecation warning
 126   # when building the CoreAudio support code.  For the time being the
 127   # answer to this is "don't do that then".  If a good reason to ask
 128   # for a 10.5 deployment target emerges then this will be fixed.
 129   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
 130     MACOSX_DEPLOYMENT_TARGET=10.0
 131   fi
 132   AC_ARG_WITH([deployment-target],
 133               [AS_HELP_STRING([--with-deployment-target=TARGET],
 134                               [set target OS X version])],
 135               [MACOSX_DEPLOYMENT_TARGET=$withval])
 136   # Convert to desired format
 137   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
 138   minver="MAC_OS_X_VERSION_$underscored"
 139   AC_MSG_RESULT([$minver])
 140   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
 141                      [define to minimum version of Mac OS X to support])
 142
 143   if test $want_gtkosx = no; then
 144     # Fink's GTK+ is hopelessly broken
 145     PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
 146     export PKG_CONFIG_PATH
 147   fi
 148
 149   ;;
 150 *-freebsd* )
 151   AC_MSG_RESULT([FreeBSD])
 152   # Ports install to /usr/local but the compiler stupidly doesn't look
 153   # there by default
 154   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 155   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
 156   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
 157   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
 158     rjk_cv_libdb="none"
 159     for db in db43 db44 db45 db46; do
 160       if test -e /usr/local/lib/$db; then
 161         rjk_cv_libdb=$db
 162         break
 163       fi
 164     done
 165   ])
 166   if test $rjk_cv_libdb != none; then
 167     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
 168     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
 169   fi
 170   ;;
 171 * )
 172   AC_MSG_RESULT([unknown, winging it])
 173   ;;
 174 esac
 175 AC_SUBST([COREAUDIO])
 176
 177 AC_ARG_WITH([browser],
 178             [AS_HELP_STRING([--with-browser=BROWSER],
 179                             [use BROWSER to display HTML])],
 180             [browser=$withval])
 181
 182 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
 183   rjk_cv_browser=UNKNOWN
 184   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
 185     if type $candidate >/dev/null 2>&1; then
 186       rjk_cv_browser="$candidate"
 187       break
 188     fi
 189   done
 190 ])
 191 if test -z "$browser"; then
 192   browser="$rjk_cv_browser"
 193 fi
 194 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 195
 196 # Figure out what version of sox is installed
 197 AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
 198   rjk_cv_soxver=UNKNOWN
 199   if sox --version > /dev/null 2>&1; then
 200     rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 201   else
 202     rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 203   fi
 204 ])
 205
 206 # Decide what command line options to use
 207 #
 208 # sox version   endian     bits       deployed
 209 # 12.17.9       -x         -[bwld]    debian etch, ubuntu dapper
 210 # 14.0.0        -x/-[BL]   -[bwld]    ubuntu hardy
 211 # 14.0.1        -x/-[BL]   -[1248]    debian lenny
 212 # 14.2.0        -x/-[BL]   -[1248]    debian sid (at 2008-12)
 213
 214 AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
 215   case $rjk_cv_soxver in
 216   [[0-9]].* | 1[[0123]].* )
 217     rjk_cv_soxgen=0
 218     ;;
 219   * )
 220     rjk_cv_soxgen=1
 221     ;;
 222   esac
 223 ])
 224 AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
 225                    [default sox generation])
 226
 227 AC_ARG_WITH([server],
 228             [AS_HELP_STRING([--without-server],
 229                             [do not build server])],
 230             [want_server=$withval])
 231 AC_ARG_WITH([cgi],
 232             [AS_HELP_STRING([--without-cgi],
 233                             [do not build CGI])],
 234             [want_cgi=$withval])
 235 AC_ARG_WITH([gtk],
 236             [AS_HELP_STRING([--without-gtk],
 237                             [do not build GTK+ client])],
 238             [want_gtk=$withval])
 239 AC_ARG_WITH([python],
 240             [AS_HELP_STRING([--without-python],
 241                             [do not build Python support])],
 242             [want_python=$withval])
 243
 244 if test $want_server = no; then
 245   want_cgi=no
 246 fi
 247
 248 #
 249 # OS          Document Root                  CGI directory
 250 # ==          =============                  =============
 251 # Debian      /var/www                       /usr/lib/cgi-bin
 252 # Ubuntu      /var/www                       /usr/lib/cgi-bin
 253 # Red Hat     /var/www/html                  /var/www/cgi-bin
 254 #      or:    /home/httpd/html/              /home/httpd/cgi-bin
 255 # Slackware   /var/www/htdocs                (unknown)
 256 # SuSE        /srv/www/html                  /srv/www/cgi-bin
 257 # Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
 258 # FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
 259 #      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
 260 # OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
 261 # Apache      /usr/local/apache/htdocs       (none)
 262 #
 263 # Sources:
 264 #   http://wiki.linuxquestions.org/wiki/Apache
 265 #   http://mapserver.gis.umn.edu/docs/howto/suse-linux
 266 #   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
 267 #   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
 268 #   http://httpd.apache.org/docs/
 269 #
 270 if test $want_cgi = yes; then
 271   if test -z "$httpdir"; then
 272     AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
 273       rjk_cv_httpdir="not found"
 274       for dir in /var/www/html \
 275                  /var/www/htdocs \
 276                  /var/www/localhost/htdocs \
 277                  /var/www \
 278                  /home/httpd/html \
 279                  /srv/www/html \
 280                  /usr/local/www/data \
 281                  /usr/local/www/*/data \
 282                  /Library/WebServer/Documents \
 283                  /usr/local/apache/htdocs; do
 284         if test -d "$dir"; then
 285           rjk_cv_httpdir="$dir"
 286         fi
 287       done
 288     ])
 289     if test "$rjk_cv_httpdir" = "not found"; then
 290       AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
 291     fi
 292     httpdir="$rjk_cv_httpdir"
 293   fi
 294   if test ! -z "$cgidir"; then
 295     # This is a bit harsh but should stop any disasters
 296     AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
 297   fi
 298   if test -z "$cgiexecdir"; then
 299     AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
 300       rjk_cv_cgiexecdir="not found"
 301       for dir in /usr/lib/cgi-bin \
 302                  /Library/WebServer/CGI-Executables \
 303                  /srv/www/cgi-bin \
 304                  /var/www/cgi-bin \
 305                  /home/httpd/cgi-bin \
 306                  /var/www/localhost/cgi-bin \
 307                  /usr/local/lib/cgi-bin \
 308                  /usr/local/www/cgi-bin \
 309                  /usr/local/www/*/cgi-bin; do
 310         if test -d "$dir"; then
 311           rjk_cv_cgiexecdir="$dir"
 312           break
 313         fi
 314       done
 315     ])
 316     if test "$rjk_cv_cgiexecdir" = "not found"; then
 317       AC_MSG_ERROR([cannot identify CGI install directory.  Set cgiexecdir on configure command line])
 318     fi
 319     cgiexecdir="$rjk_cv_cgiexecdir"
 320   fi
 321 fi
 322 AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
 323 AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
 324 if test -z "$pkghttpdir"; then
 325   pkghttpdir='$(httpdir)/disorder'
 326 fi
 327 AC_SUBST([pkghttpdir])
 328
 329 if test -z "$dochtmldir"; then
 330   dochtmldir='$(docdir)/html'
 331 fi
 332 AC_SUBST([dochtmldir])
 333
 334 subdirs="scripts lib"
 335 if test $want_tests = yes; then
 336   subdirs="${subdirs} libtests"
 337 fi
 338 subdirs="${subdirs} clients doc examples debian"
 339
 340 if test $want_server = yes; then
 341   subdirs="${subdirs} server plugins driver sounds"
 342 fi
 343 if test $want_cgi = yes; then
 344   subdirs="${subdirs} cgi templates images"
 345 fi
 346 if test $want_gtk = yes; then
 347   subdirs="${subdirs} disobedience"
 348   if test $want_server = no; then
 349     subdirs="${subdirs} images"
 350   fi
 351 fi
 352 if test $want_tests = yes && test $want_python = yes; then
 353   AM_PATH_PYTHON([2.5])
 354   subdirs="${subdirs} python tests"
 355 fi
 356 AC_SUBST([subdirs])
 357
 358 # libtool config
 359 AC_LIBTOOL_DLOPEN
 360 AC_DISABLE_STATIC
 361
 362 AC_PROG_LIBTOOL
 363
 364 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
 365   rjk_cv_gnused="not found"
 366   for candidate in sed gsed; do
 367     if $candidate --version >/dev/null 2>&1; then
 368       rjk_cv_gnused=$candidate
 369     fi
 370   done
 371 ])
 372 GNUSED="${GNUSED:-$rjk_cv_gnused}"
 373 if test "$GNUSED" = "not found"; then
 374   AC_MSG_ERROR([GNU sed is required to build this program])
 375 fi
 376 AC_SUBST([GNUSED])
 377
 378 AC_CHECK_PROGS([GROG],[grog])
 379 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
 380
 381 missing_libraries=""
 382 missing_headers=""
 383 missing_functions=""
 384
 385 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 386
 387 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
 388
 389 # Macs might have libraries under fink's root
 390 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 391 if test "x$FINK" != xnone; then
 392   # Find Fink prefix
 393   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 394     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 395   ])
 396   # Add include and link paths
 397   finkdir="${rjk_cv_finkprefix}"
 398   finkbindir="${rjk_cv_finkprefix}/bin"
 399   CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
 400   if test $want_server = yes; then
 401     CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
 402   fi
 403   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 404   # Distinguish 32- and 64-bit fink
 405   AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
 406     odata=`otool -v -h $finkbindir/dpkg`
 407     case "$odata" in
 408     *X86_64* )
 409       rjk_cv_finkbits=64
 410       ;;
 411     *I386* )
 412       rjk_cv_finkbits=32
 413       ;;
 414     * )
 415       rjk_cv_finkbits=unknown
 416       ;;
 417     esac
 418   ])
 419   # Match Fink so we can use its libraries
 420   case $rjk_cv_finkbits in
 421   32 | 64 )
 422     CC="$CC -m$rjk_cv_finkbits"
 423     ;;
 424   esac
 425 else
 426   finkbindir=""
 427 fi
 428 AC_SUBST([finkdir])
 429 AC_SUBST([finkbindir])
 430
 431 # Checks for libraries.
 432 # We save up a list of missing libraries that we can't do without
 433 # and report them all at once.
 434 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 435             [missing_libraries="$missing_libraries libgc"])
 436 AC_CHECK_LIB(gcrypt, gcry_md_open,
 437              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 438             [missing_libraries="$missing_libraries libgcrypt"])
 439 AC_CHECK_LIB(pcre, pcre_compile,
 440              [AC_SUBST(LIBPCRE,[-lpcre])],
 441              [missing_libraries="$missing_libraries libpcre"])
 442 if test $want_alsa = yes; then
 443   AC_CHECK_LIB([asound], [snd_pcm_open],
 444                [AC_SUBST(LIBASOUND,[-lasound])])
 445 fi
 446 AC_CHECK_LIB([samplerate],[src_new],
 447              [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
 448 if test $want_server = yes; then
 449   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 450                [AC_SUBST(LIBDB,[-ldb])],
 451                [missing_libraries="$missing_libraries libdb"])
 452   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 453                [:],
 454                [missing_libraries="$missing_libraries libvorbis"])
 455   AC_CHECK_LIB(vorbisfile, ov_open,
 456                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 457                [missing_libraries="$missing_libraries libvorbisfile"],
 458                [-lvorbis])
 459   AC_CHECK_LIB(mad, mad_stream_init,
 460                [AC_SUBST(LIBMAD,[-lmad])],
 461                [missing_libraries="$missing_libraries libmad"])
 462   AC_CHECK_LIB([ao], [ao_initialize],
 463                [AC_SUBST(LIBAO,[-lao])],
 464                [missing_libraries="$missing_libraries libao"])
 465   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 466                [AC_SUBST(LIBFLAC,[-lFLAC])],
 467                [missing_libraries="$missing_libraries libFLAC"])
 468 fi
 469 AC_CHECK_LIB([pthread], [pthread_create],
 470              [AC_SUBST(LIBPTHREAD,[-lpthread])],
 471              [missing_libraries="$missing_libraries libpthread"])
 472
 473 if test $want_gtk = yes; then
 474   if test $want_gtkosx = yes; then
 475     GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
 476     GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
 477     GTK_LIBS="-framework Gtk -framework GLib"
 478   else
 479     AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 480     AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 481   fi
 482 fi
 483
 484 # Some platforms have iconv already
 485 AC_CHECK_FUNC(iconv_open, [:],
 486               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 487                             [AC_SUBST(LIBICONV,[-liconv])],
 488                             [missing_functions="$missing_functions iconv_open"])])
 489 AC_CHECK_FUNC([gethostbyname],[:],[
 490   AC_CHECK_LIB(nsl,gethostbyname,
 491                [AC_SUBST(LIBNSL,[-lnsl])],
 492                [missing_functions="$missing_functions gethostbyname"])])
 493 AC_CHECK_FUNC([socket],[:],[
 494   AC_CHECK_LIB(socket,socket,
 495                [AC_SUBST(LIBSOCKET,[-lsocket])],
 496                [missing_functions="$missing_functions socket"])])
 497 AC_CHECK_FUNC([dlopen],[:],[
 498   AC_CHECK_LIB(dl,dlopen,
 499                [AC_SUBST(LIBDL,[-ldl])],
 500                [missing_functions="$missing_functions dlopen"])])
 501
 502 if test ! -z "$missing_libraries"; then
 503   AC_MSG_ERROR([missing libraries:$missing_libraries])
 504 fi
 505
 506 # Checks for header files.
 507 RJK_FIND_GC_H
 508 if test $want_oss = yes; then
 509   AC_CHECK_HEADERS([sys/soundcard.h])
 510 fi
 511 if test $want_alsa = yes; then
 512   AC_CHECK_HEADERS([alsa/asoundlib.h])
 513 fi
 514 if test $want_coreaudio = yes; then
 515   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 516 fi
 517 AC_CHECK_HEADERS([inttypes.h])
 518 # We don't bother checking very standard stuff
 519 # Compilation will fail if any of these headers are missing, so we
 520 # check for them here and fail early.
 521 if test $want_server = yes; then
 522   AC_CHECK_HEADERS([db.h],[:],[
 523     missing_headers="$missing_headers $ac_header"
 524   ])
 525   AC_CHECK_HEADERS([FLAC/file_decoder.h])
 526 fi
 527 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 528                  getopt.h iconv.h langinfo.h \
 529                  pcre.h sys/ioctl.h \
 530                  syslog.h unistd.h],[:],[
 531   missing_headers="$missing_headers $ac_header"
 532 ])
 533 AC_CHECK_HEADERS([samplerate.h])
 534
 535 if test ! -z "$missing_headers"; then
 536   AC_MSG_ERROR([missing headers:$missing_headers])
 537 fi
 538
 539 # We require that libpcre support UTF-8
 540 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 541
 542 # Checks for typedefs, structures, and compiler characteristics.
 543 AC_C_CONST
 544 AC_TYPE_SIZE_T
 545 AC_C_INLINE
 546 AC_C_BIGENDIAN
 547 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 548 #include <netinet/in.h>])
 549
 550 # enable -Werror when we check for certain characteristics:
 551
 552 old_CFLAGS="${CFLAGS}"
 553 CFLAGS="${CFLAGS} $gcc_werror"
 554 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 555
 556 # Some GCC invocations warn for converting function pointers to void *.
 557 # This is fair enough, as it's technically forbidden, but we use dlsym()
 558 # which can pretty much only exist if object and function pointers are
 559 # interconvertable.  So we disable -Werror if need be.
 560 if test ! -z "$gcc_werror"; then
 561   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 562                  [rjk_cv_function_pointer_cast],[
 563     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 564   void somefunction(void);],
 565                       [(void *)somefunction])],
 566                       [rjk_cv_function_pointer_cast=yes],
 567                       [rjk_cv_function_pointer_cast=no])])
 568   if test $rjk_cv_function_pointer_cast = no; then
 569     gcc_werror=""
 570   fi
 571 fi
 572
 573 CFLAGS="${old_CFLAGS}"
 574
 575 # gcrypt maintainers keep changing everything.  Design your interface
 576 # first, then implement it once, rather than getting it wrong three or
 577 # four times and shipping between each attempt.
 578 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 579                [rjk_cv_gcrypt_hash_handle],[
 580   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 581 #include <gcrypt.h>
 582 ],
 583                [gcry_md_hd_t h;])],
 584                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 585     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 586 #include <gcrypt.h>
 587 ],
 588                  [GcryMDHd h;])],
 589                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 590                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 591 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 592                    [libgcrypt hash handle type])
 593
 594 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 595                [rjk_cv_have_gcry_error_t],[
 596   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 597 #include <gcrypt.h>
 598 ],
 599                  [gcry_error_t e;])],
 600                  [rjk_cv_have_gcry_error_t=yes],
 601                  [rjk_cv_have_gcry_error_t=no])])
 602 if test $rjk_cv_have_gcry_error_t = yes; then
 603   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 604 fi
 605
 606 # Checks for functions
 607 if test $ac_cv_type_long_long = yes; then
 608   AC_CHECK_FUNCS([atoll strtoll],[:],[
 609     missing_functions="$missing_functions $ac_func"
 610   ])
 611   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 612   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 613                  [rjk_cv_strtoll_declared],[
 614     AC_EGREP_HEADER([strtoll], [stdlib.h],
 615                     [rjk_cv_strtoll_declared=yes],
 616                     [rjk_cv_strtoll_declared=no])])
 617   if test $rjk_cv_strtoll_declared = yes; then
 618     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 619   fi
 620   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 621                  [rjk_cv_atoll_declared],[
 622     AC_EGREP_HEADER([atoll], [stdlib.h],
 623                     [rjk_cv_atoll_declared=yes],
 624                     [rjk_cv_atoll_declared=no])])
 625   if test $rjk_cv_atoll_declared = yes; then
 626     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 627   fi
 628 fi
 629 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
 630   missing_functions="$missing_functions $ac_func"
 631 ])
 632 # fsync will do if fdatasync not available
 633 AC_CHECK_FUNCS([fdatasync],[:],[
 634   AC_CHECK_FUNCS([fsync],
 635                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 636                  [missing_functions="$missing_functions fdatasync"])])
 637 if test ! -z "$missing_functions"; then
 638   AC_MSG_ERROR([missing functions:$missing_functions])
 639 fi
 640
 641 # Functions we can take or leave
 642 AC_CHECK_FUNCS([fls])
 643
 644 if test $want_server = yes; then
 645   # <db.h> had better be version 3 or later
 646   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 647     AC_PREPROC_IFELSE([
 648                        #include <db.h>
 649                        #ifndef DB_VERSION_MAJOR
 650                        # error cannot determine db version
 651                        #endif
 652                        #if DB_VERSION_MAJOR < 4
 653                        # error inadequate db version
 654                        #endif
 655                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
 656                        # error inadequate db version
 657                        #endif
 658                       ],
 659                       [rjk_cv_db_version=ok],
 660                       [rjk_cv_db_version=inadequate])
 661     if test $rjk_cv_db_version = ok; then
 662       AC_PREPROC_IFELSE([
 663                          #include <db.h>
 664                          #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
 665                          # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
 666                          #endif
 667                         ],
 668                         [rjk_cv_db_version=ok],
 669                         [rjk_cv_db_version=toxic])
 670     fi
 671   ])
 672   case $rjk_cv_db_version in
 673   ok )
 674     ;;
 675   inadequate )
 676     AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
 677     ;;
 678   toxic )
 679     AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
 680     ;;
 681   esac
 682 fi
 683
 684 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
 685 if test $want_gtk = yes; then
 686   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
 687 fi
 688 AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
 689
 690 if test "x$GCC" = xyes; then
 691   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
 692   # by default.
 693   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
 694     AC_TRY_COMPILE([#include <limits.h>],[
 695       long long n = LLONG_MAX;
 696     ],[rjk_cv_cstd=default],[
 697       old_CC="$CC"
 698       CC="${CC} -std=gnu99"
 699       AC_TRY_COMPILE([#include <limits.h>],[
 700         long long n = LLONG_MAX;
 701       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
 702       CC="$old_CC"
 703     ])
 704   ])
 705   case $rjk_cv_cstd in
 706   default | unknown )
 707     ;;
 708   * )
 709     CC="${CC} -std=${rjk_cv_cstd}"
 710     ;;
 711   esac
 712
 713   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 714   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 715     old_CC="$CC"
 716     if test $GCC = yes; then
 717       CC="$CC -Wall -Werror"
 718     fi
 719     AC_COMPILE_IFELSE([
 720       static int x(char *f) {
 721        return *f;
 722       }
 723       int z(const char *g) {
 724         return x((char *)g);
 725       }],
 726       [rjk_cv_pr29478=no],
 727       [rjk_cv_pr29478=yes]
 728     )
 729     CC="$old_CC"
 730   ])
 731   if test $rjk_cv_pr29478 = yes; then
 732     gcc_werror=''
 733   fi
 734
 735   AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
 736                  [rjk_cv_gcc44_stupidity],[
 737     old_CC="$CC"
 738     if test $GCC = yes; then
 739       CC="$CC -Wreturn-type -Werror"
 740     fi
 741     AC_COMPILE_IFELSE([
 742       static void *threadfn(void) {
 743         for(;;)
 744           ;
 745       }],
 746       [rjk_cv_gcc44_stupidity=no],
 747       [rjk_cv_gcc44_stupidity=yes])
 748     CC="$old_CC"
 749   ])
 750   if test $rjk_cv_gcc44_stupidity = yes; then
 751     AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
 752   fi
 753
 754   # a reasonable default set of warnings
 755   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
 756         -Wwrite-strings -Wmissing-prototypes \
 757         -Wmissing-declarations -Wnested-externs"
 758
 759   # Fix up GTK+ and GLib compiler flags
 760   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 761   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 762
 763   if test "$gcc_werror" != ''; then
 764     # GCC 2.95 doesn't know to ignore warnings from system headers
 765     AC_CACHE_CHECK([whether -Werror is usable],
 766                     rjk_cv_werror, [
 767       save_CFLAGS="${CFLAGS}"
 768       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 769       AC_TRY_COMPILE([#if WITH_GTK
 770  #include <gtk/gtk.h>
 771 #endif
 772
 773 struct s { int a, b; };
 774 const struct s sv = { .a = 1 };],
 775                      [],
 776                      [rjk_cv_werror=yes],
 777                      [rjk_cv_werror=no])
 778       CFLAGS="${save_CFLAGS}"
 779     ])
 780     if test $rjk_cv_werror = no; then
 781       gcc_werror=''
 782     fi
 783   fi
 784   CC="${CC} $gcc_werror"
 785
 786   # for older GCCs that don't know %ju (etc)
 787   AC_CACHE_CHECK([whether -Wno-format is required],
 788                  rjk_cv_noformat,
 789                  AC_TRY_COMPILE([#include <stdio.h>
 790 #include <stdint.h>
 791 ],
 792                                 [printf("%ju", (uintmax_t)0);],
 793                                 [rjk_cv_noformat=no],
 794                                 [rjk_cv_noformat=yes]))
 795   if test $rjk_cv_noformat = yes; then
 796     CC="${CC} -Wno-format"
 797   fi
 798
 799   AC_CACHE_CHECK([whether -Wshadow is OK],
 800                  rjk_cv_shadow,
 801                  oldCC="${CC}"
 802                  CC="${CC} -Wshadow"
 803                  [AC_TRY_COMPILE([
 804 #include <unistd.h>
 805 #include <vorbis/vorbisfile.h>
 806 ],
 807                                 [],
 808                                 [rjk_cv_shadow=yes],
 809                                 [rjk_cv_shadow=no])
 810                  CC="${oldCC}"])
 811   if test $rjk_cv_shadow = yes; then
 812     CC="${CC} -Wshadow"
 813   fi
 814 fi
 815
 816 RJK_GCOV
 817
 818 AH_BOTTOM([#ifdef __GNUC__
 819 # define attribute(x) __attribute__(x)
 820 #else
 821 # define attribute(x)
 822 #endif])
 823
 824 AC_CONFIG_FILES([Makefile
 825                  images/Makefile
 826                  scripts/Makefile
 827                  lib/Makefile
 828                  server/Makefile
 829                  cgi/Makefile
 830                  clients/Makefile
 831                  disobedience/Makefile
 832                  disobedience/manual/Makefile
 833                  doc/Makefile
 834                  templates/Makefile
 835                  plugins/Makefile
 836                  driver/Makefile
 837                  debian/Makefile
 838                  sounds/Makefile
 839                  python/Makefile
 840                  examples/Makefile
 841                  libtests/Makefile
 842                  tests/Makefile])
 843 AC_OUTPUT
 844
 845 if test $GCC = yes && test "$gcc_werror" = ''; then
 846   AC_MSG_WARN([building without -Werror])
 847 fi
 848 if test $want_python = no; then
 849   AC_MSG_WARN([cannot run the test suit without Python])
 850 fi
 851 if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
 852   AC_MSG_WARN([libsamplerate will be required in a future version])
 853 fi
 854
 855 # Local Variables:
 856 # indent-tabs-mode:nil
 857 # End: