chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 # General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  19 # USA
  20 #
  21
  22 AC_INIT([disorder], [1.5.99+], [richard+disorder@sfere.greenend.org.uk])
  23 AC_CONFIG_AUX_DIR([config.aux])
  24 AM_INIT_AUTOMAKE(disorder, [1.5.99+])
  25 AC_CONFIG_SRCDIR([server/disorderd.c])
  26 AM_CONFIG_HEADER([config.h])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_gtk=yes
  33 want_python=yes
  34
  35 # APIs we want
  36 want_alsa=yes
  37 want_oss=yes
  38 want_coreaudio=yes
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_SET_MAKE
  43 if test "x$GCC" = xyes; then
  44   gcc_werror=-Werror
  45 else
  46   gcc_werror=""
  47 fi
  48
  49 AC_ARG_WITH([alsa],
  50             [AS_HELP_STRING([--without-alsa],
  51                             [do not build with ALSA support])],
  52             [want_alsa=$withval])
  53 AC_ARG_WITH([oss],
  54             [AS_HELP_STRING([--without-oss],
  55                             [do not build with OSS support])],
  56             [want_oss=$withval])
  57 AC_ARG_WITH([coreaudio],
  58             [AS_HELP_STRING([--without-coreaudio],
  59                             [do not build with Core Audio support])],
  60             [want_coreaudio=$withval])
  61
  62 AC_MSG_CHECKING([for a known target platform])
  63 case "$host" in
  64 *empeg* )
  65   AC_MSG_RESULT([empeg car stereo])
  66   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
  67   # work around broken toolchain
  68   AC_CHECK_LIB([gpg-error], [gpg_strerror])
  69   AC_CHECK_LIB([pthread], [pthread_create])
  70   want_server=no
  71  ;;
  72 *linux* | *Linux* )
  73   AC_MSG_RESULT([Linux])
  74   want_server=yes
  75   ;;
  76 *-apple-darwin* )
  77   AC_MSG_RESULT([Mac OS X])
  78   want_server=yes
  79   if test $want_coreaudio = yes; then
  80     COREAUDIO="-framework CoreAudio"
  81   fi
  82   browser=open
  83   ;;
  84 * )
  85   AC_MSG_RESULT([unknown, winging it])
  86   want_server=no
  87   ;;
  88 esac
  89 AC_SUBST([COREAUDIO])
  90
  91 AC_ARG_WITH([browser],
  92             [AS_HELP_STRING([--with-browser=BROWSER],
  93                             [use BROWSER to display HTML])],
  94             [browser=$withval])
  95
  96 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
  97   rjk_cv_browser=UNKNOWN
  98   for candidate in x-www-browser firefox mozilla konqueror netscape; do
  99     if type $candidate >/dev/null 2>&1; then
 100       rjk_cv_browser="$candidate"
 101       break
 102     fi
 103   done
 104 ])
 105 if test -z "$browser"; then
 106   browser="$rjk_cv_browser"
 107 fi
 108 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 109
 110 AC_ARG_WITH([server],
 111             [AS_HELP_STRING([--without-server],
 112                             [do not build server])],
 113             [want_server=$withval])
 114 AC_ARG_WITH([gtk],
 115             [AS_HELP_STRING([--without-gtk],
 116                             [do not build GTK+ client])],
 117             [want_gtk=$withval])
 118 AC_ARG_WITH([python],
 119             [AS_HELP_STRING([--without-python],
 120                             [do not build Python support])],
 121             [want_python=$withval])
 122
 123 subdirs="scripts lib clients doc examples debian"
 124
 125 if test $want_server = yes; then
 126   subdirs="${subdirs} server plugins driver templates sounds images"
 127 fi
 128 if test $want_python = yes; then
 129   AM_PATH_PYTHON
 130   subdirs="${subdirs} python"
 131 fi
 132 if test $want_gtk = yes; then
 133   subdirs="${subdirs} disobedience"
 134   if test $want_server = no; then
 135     subdirs="${subdirs} images"
 136   fi
 137 fi
 138 subdirs="${subdirs} tests"
 139 AC_SUBST([subdirs])
 140
 141 # libtool config
 142 AC_LIBTOOL_DLOPEN
 143 AC_DISABLE_STATIC
 144
 145 AC_PROG_LIBTOOL
 146
 147 missing_libraries=""
 148 missing_headers=""
 149 missing_functions=""
 150
 151 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 152
 153 # Macs might have libraries under fink's root
 154 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 155 if test "x$FINK" != xnone; then
 156   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 157     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 158   ])
 159   finkdir="${rjk_cv_finkprefix}"
 160   finkbindir="${rjk_cv_finkprefix}/bin"
 161   CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/gc -I${rjk_cv_finkprefix}/include"
 162   if test $want_server = yes; then
 163     CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
 164   fi
 165   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 166 else
 167   finkbindir=""
 168 fi
 169 AC_SUBST([finkdir])
 170 AC_SUBST([finkbindir])
 171
 172 # Checks for libraries.
 173 # We save up a list of missing libraries that we can't do without
 174 # and report them all at once.
 175 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 176             [missing_libraries="$missing_libraries libgc"])
 177 AC_CHECK_LIB(gcrypt, gcry_md_open,
 178              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 179             [missing_libraries="$missing_libraries libgcrypt"])
 180 AC_CHECK_LIB(pcre, pcre_compile,
 181              [AC_SUBST(LIBPCRE,[-lpcre])],
 182              [missing_libraries="$missing_libraries libpcre"])
 183 if test $want_alsa = yes; then
 184   AC_CHECK_LIB([asound], [snd_pcm_open],
 185                [AC_SUBST(LIBASOUND,[-lasound])])
 186 fi
 187 if test $want_server = yes; then
 188   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 189                [AC_SUBST(LIBDB,[-ldb])],
 190                [missing_libraries="$missing_libraries libdb"])
 191   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 192                [:],
 193                [missing_libraries="$missing_libraries libvorbis"])
 194   AC_CHECK_LIB(vorbisfile, ov_open,
 195                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 196                [missing_libraries="$missing_libraries libvorbisfile"],
 197                [-lvorbis])
 198   AC_CHECK_LIB(mad, mad_stream_init,
 199                [AC_SUBST(LIBMAD,[-lmad])],
 200                [missing_libraries="$missing_libraries libmad"])
 201   AC_CHECK_LIB([ao], [ao_initialize],
 202                [AC_SUBST(LIBAO,[-lao])],
 203                [missing_libraries="$missing_libraries libao"])
 204   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 205                [AC_SUBST(LIBFLAC,[-lFLAC])],
 206                [missing_libraries="$missing_libraries libFLAC"])
 207 fi
 208
 209 if test $want_gtk = yes; then
 210   AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 211   AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 212 fi
 213
 214 # Some platforms have iconv already
 215 AC_CHECK_FUNC(iconv_open, [:],
 216               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 217                             [AC_SUBST(LIBICONV,[-liconv])],
 218                             [missing_functions="$missing_functions iconv_open"])])
 219 AC_CHECK_FUNC([gethostbyname],[:],[
 220   AC_CHECK_LIB(nsl,gethostbyname,
 221                [AC_SUBST(LIBNSL,[-lnsl])],
 222                [missing_functions="$missing_functions gethostbyname"])])
 223 AC_CHECK_FUNC([socket],[:],[
 224   AC_CHECK_LIB(socket,socket,
 225                [AC_SUBST(LIBSOCKET,[-lsocket])],
 226                [missing_functions="$missing_functions socket"])])
 227 AC_CHECK_FUNC([dlopen],[:],[
 228   AC_CHECK_LIB(dl,dlopen,
 229                [AC_SUBST(LIBDL,[-ldl])],
 230                [missing_functions="$missing_functions dlopen"])])
 231
 232 if test ! -z "$missing_libraries"; then
 233   AC_MSG_ERROR([missing libraries:$missing_libraries])
 234 fi
 235
 236 # We require that libpcre support UTF-8
 237 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 238
 239 # Checks for header files.
 240 RJK_FIND_GC_H
 241 if test $want_oss = yes; then
 242   AC_CHECK_HEADERS([sys/soundcard.h])
 243 fi
 244 if test $want_alsa = yes; then
 245   AC_CHECK_HEADERS([alsa/asoundlib.h])
 246 fi
 247 if test $want_coreaudio = yes; then
 248   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 249 fi
 250 AC_CHECK_HEADERS([inttypes.h])
 251 # We don't bother checking very standard stuff
 252 # Compilation will fail if any of these headers are missing, so we
 253 # check for them here and fail early.
 254 if test $want_server = yes; then
 255   AC_CHECK_HEADERS([db.h],[:],[
 256     missing_headers="$missing_headers $ac_header"
 257   ])
 258   AC_CHECK_HEADERS([FLAC/file_decoder.h])
 259 fi
 260 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 261                  getopt.h iconv.h langinfo.h \
 262                  pcre.h sys/ioctl.h \
 263                  syslog.h unistd.h],[:],[
 264   missing_headers="$missing_headers $ac_header"
 265 ])
 266
 267 if test ! -z "$missing_headers"; then
 268   AC_MSG_ERROR([missing headers:$missing_headers])
 269 fi
 270
 271 # Checks for typedefs, structures, and compiler characteristics.
 272 AC_C_CONST
 273 AC_TYPE_SIZE_T
 274 AC_C_INLINE
 275 AC_C_BIGENDIAN
 276 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 277 #include <netinet/in.h>])
 278
 279 # enable -Werror when we check for certain characteristics:
 280
 281 old_CFLAGS="${CFLAGS}"
 282 CFLAGS="${CFLAGS} $gcc_werror"
 283 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 284
 285 # Some GCC invocations warn for converting function pointers to void *.
 286 # This is fair enough, as it's technically forbidden, but we use dlsym()
 287 # which can pretty much only exist if object and function pointers are
 288 # interconvertable.  So we disable -Werror if need be.
 289 if test ! -z "$gcc_werror"; then
 290   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 291                  [rjk_cv_function_pointer_cast],[
 292     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 293   void somefunction(void);],
 294                       [(void *)somefunction])],
 295                       [rjk_cv_function_pointer_cast=yes],
 296                       [rjk_cv_function_pointer_cast=no])])
 297   if test $rjk_cv_function_pointer_cast = no; then
 298     gcc_werror=""
 299   fi
 300 fi
 301
 302 CFLAGS="${old_CFLAGS}"
 303
 304 # gcrypt maintainers keep changing everything.  Design your interface
 305 # first, then implement it once, rather than getting it wrong three or
 306 # four times and shipping between each attempt.
 307 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 308                [rjk_cv_gcrypt_hash_handle],[
 309   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 310 #include <gcrypt.h>
 311 ],
 312                [gcry_md_hd_t h;])],
 313                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 314     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 315 #include <gcrypt.h>
 316 ],
 317                  [GcryMDHd h;])],
 318                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 319                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 320 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 321                    [libgcrypt hash handle type])
 322
 323 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 324                [rjk_cv_have_gcry_error_t],[
 325   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 326 #include <gcrypt.h>
 327 ],
 328                  [gcry_error_t e;])],
 329                  [rjk_cv_have_gcry_error_t=yes],
 330                  [rjk_cv_have_gcry_error_t=no])])
 331 if test $rjk_cv_have_gcry_error_t = yes; then
 332   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 333 fi
 334
 335 # Checks for functions
 336 if test $ac_cv_type_long_long = yes; then
 337   AC_CHECK_FUNCS([atoll strtoll],[:],[
 338     missing_functions="$missing_functions $ac_func"
 339   ])
 340   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 341   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 342                  [rjk_cv_strtoll_declared],[
 343     AC_EGREP_HEADER([strtoll], [stdlib.h],
 344                     [rjk_cv_strtoll_declared=yes],
 345                     [rjk_cv_strtoll_declared=no])])
 346   if test $rjk_cv_strtoll_declared = yes; then
 347     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 348   fi
 349   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 350                  [rjk_cv_atoll_declared],[
 351     AC_EGREP_HEADER([atoll], [stdlib.h],
 352                     [rjk_cv_atoll_declared=yes],
 353                     [rjk_cv_atoll_declared=no])])
 354   if test $rjk_cv_atoll_declared = yes; then
 355     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 356   fi
 357 fi
 358 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
 359   missing_functions="$missing_functions $ac_func"
 360 ])
 361 # fsync will do if fdatasync not available
 362 AC_CHECK_FUNCS([fdatasync],[:],[
 363   AC_CHECK_FUNCS([fsync],
 364                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 365                  [missing_functions="$missing_functions fdatasync"])])
 366 if test ! -z "$missing_functions"; then
 367   AC_MSG_ERROR([missing functions:$missing_functions])
 368 fi
 369 if test $want_server = yes; then
 370   # <db.h> had better be version 3 or later
 371   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 372     AC_PREPROC_IFELSE([
 373                        #include <db.h>
 374                        #ifndef DB_VERSION_MAJOR
 375                        # error cannot determine db version
 376                        #endif
 377                        #if DB_VERSION_MAJOR < 4
 378                        # error inadequate db version
 379                        #endif
 380                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR < 2
 381                        # error inadequate db version
 382                        #endif
 383                       ],
 384                       [rjk_cv_db_version=ok],
 385                       [rjk_cv_db_version=inadequate])
 386   ])
 387   if test $rjk_cv_db_version != ok; then
 388     AC_MSG_ERROR([need db.h version at least 4.2])
 389   fi
 390 fi
 391
 392 if test "x$GCC" = xyes; then
 393   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 394   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 395     old_CC="$CC"
 396     if test $GCC = yes; then
 397       CC="$CC -Wall -Werror"
 398     fi
 399     AC_COMPILE_IFELSE([
 400       static int x(char *f) {
 401        return *f;
 402       }
 403       int z(const char *g) {
 404         return x((char *)g);
 405       }],
 406       [rjk_cv_pr29478=no],
 407       [rjk_cv_pr29478=yes]
 408     )
 409     CC="$old_CC"
 410   ])
 411   if test $rjk_cv_pr29478 = yes; then
 412     gcc_werror=''
 413   fi
 414
 415   # a reasonable default set of warnings
 416   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
 417         -Wwrite-strings -Wmissing-prototypes \
 418         -Wmissing-declarations -Wnested-externs"
 419
 420   # Fix up GTK+ and GLib compiler flags
 421   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 422   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 423
 424   if test "$gcc_werror" != ''; then
 425     # GCC 2.95 doesn't know to ignore warnings from system headers
 426     AC_CACHE_CHECK([whether -Werror is usable],
 427                     rjk_cv_werror, [
 428       save_CFLAGS="${CFLAGS}"
 429       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 430       AC_TRY_COMPILE([#include <gtk/gtk.h>],
 431                      [],
 432                      [rjk_cv_werror=yes],
 433                      [rjk_cv_werror=no])
 434       CFLAGS="${save_CFLAGS}"
 435     ])
 436     if test $rjk_cv_werror = no; then
 437       gcc_werror=''
 438     fi
 439   fi
 440   CC="${CC} $gcc_werror"
 441
 442   # for older GCCs that don't know %ju (etc)
 443   AC_CACHE_CHECK([whether -Wno-format is required],
 444                  rjk_cv_noformat,
 445                  AC_TRY_COMPILE([#include <stdio.h>
 446 #include <stdint.h>
 447 ],
 448                                 [printf("%ju", (uintmax_t)0);],
 449                                 [rjk_cv_noformat=no],
 450                                 [rjk_cv_noformat=yes]))
 451   if test $rjk_cv_noformat = yes; then
 452     CC="${CC} -Wno-format"
 453   fi
 454
 455   AC_CACHE_CHECK([whether -Wshadow is OK],
 456                  rjk_cv_shadow,
 457                  oldCC="${CC}"
 458                  CC="${CC} -Wshadow"
 459                  [AC_TRY_COMPILE([
 460 #include <unistd.h>
 461 #include <vorbis/vorbisfile.h>
 462 ],
 463                                 [],
 464                                 [rjk_cv_shadow=yes],
 465                                 [rjk_cv_shadow=no])
 466                  CC="${oldCC}"])
 467   if test $rjk_cv_shadow = yes; then
 468     CC="${CC} -Wshadow"
 469   fi
 470
 471
 472 fi
 473
 474 AH_BOTTOM([#ifdef __GNUC__
 475 # define attribute(x) __attribute__(x)
 476 #else
 477 # define attribute(x)
 478 #endif])
 479
 480 AC_CONFIG_FILES([Makefile
 481                  templates/Makefile
 482                  images/Makefile
 483                  scripts/Makefile
 484                  lib/Makefile
 485                  server/Makefile
 486                  clients/Makefile
 487                  disobedience/Makefile
 488                  doc/Makefile
 489                  plugins/Makefile
 490                  driver/Makefile
 491                  debian/Makefile
 492                  sounds/Makefile
 493                  python/Makefile
 494                  examples/Makefile
 495                  tests/Makefile])
 496 AC_OUTPUT
 497
 498 if test $GCC = yes && test "$gcc_werror" = ''; then
 499   AC_MSG_WARN([building without -Werror])
 500 fi