chiark / gitweb /
examples/disorder.init.in: Read settings from `/etc/default/disorder'.
[disorder] / configure.ac
... / ...
CommitLineData
1# Process this file with autoconf to produce a configure script.
2#
3# This file is part of DisOrder.
4# Copyright (C) 2004-2014 Richard Kettlewell
5# Portions copyright (C) 2007 Ross Younger
6#
7# This program is free software: you can redistribute it and/or modify
8# it under the terms of the GNU General Public License as published by
9# the Free Software Foundation, either version 3 of the License, or
10# (at your option) any later version.
11#
12# This program is distributed in the hope that it will be useful,
13# but WITHOUT ANY WARRANTY; without even the implied warranty of
14# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15# GNU General Public License for more details.
16#
17# You should have received a copy of the GNU General Public License
18# along with this program. If not, see <http://www.gnu.org/licenses/>.
19#
20
21AC_INIT([disorder], [5.1.1], [rjk@greenend.org.uk])
22AC_CONFIG_AUX_DIR([config.aux])
23AM_INIT_AUTOMAKE([foreign])
24AC_CONFIG_SRCDIR([server/disorderd.c])
25AM_CONFIG_HEADER([config.h])
26AC_CONFIG_MACRO_DIR([m4])
27
28# Find host type
29AC_CANONICAL_HOST
30
31# What we want to build
32want_gtk=yes
33want_python=yes
34want_tests=yes
35want_server=yes
36want_gstdecode=whatever
37want_cgi=yes
38
39# APIs we want
40want_alsa=yes
41want_oss=yes
42want_coreaudio=yes
43want_pulseaudio=yes
44want_gstreamer=yes
45
46# By default we don't want gtk-osx. But if you ask for --with-gtk-osx...
47#
48# Disobedience can be built to a native OS X application. There are some
49# caveats:
50# - you will still need Fink (or something) for other libraries
51# - if you wanted an application bundle you are out of luck
52# - the menu bar is still in the main window (not at the top of the screen)
53# - drag and drop doesn't work
54#
55# So it's still rather rough and ready. But it does work...
56#
57# See:
58# http://www.gtk-osx.org/
59# http://live.gnome.org/GTK%2B/OSX/Framework
60want_gtkosx=no
61
62# Checks for programs.
63AC_PROG_CC
64AM_PROG_CC_C_O
65AC_PROG_AWK
66AC_SET_MAKE
67if test "x$GCC" = xyes; then
68 gcc_werror=-Werror
69 case "$CC" in
70 *-std=* )
71 ;;
72 * )
73 CC="${CC} -std=gnu99"
74 ;;
75 esac
76else
77 AC_MSG_ERROR([GNU C is required to build this program])
78 gcc_werror=""
79fi
80
81AC_ARG_WITH([alsa],
82 [AS_HELP_STRING([--without-alsa],
83 [do not build with ALSA support])],
84 [want_alsa=$withval])
85AC_ARG_WITH([pulseaudio],
86 [AS_HELP_STRING([--without-pulseaudio],
87 [do not build with PulseAudio support])],
88 [want_pulseaudio=$withval])
89AC_ARG_WITH([oss],
90 [AS_HELP_STRING([--without-oss],
91 [do not build with OSS support])],
92 [want_oss=$withval])
93AC_ARG_WITH([coreaudio],
94 [AS_HELP_STRING([--without-coreaudio],
95 [do not build with Core Audio support])],
96 [want_coreaudio=$withval])
97AC_ARG_WITH([tests],
98 [AS_HELP_STRING([--without-tests],
99 [do not build test suit])],
100 [want_tests=$withval])
101AC_ARG_WITH([gtk-osx],
102 [AS_HELP_STRING([--with-gtk-osx],
103 [use native GTK+ (OS X only)])],
104 [want_gtkosx=$withval])
105AC_ARG_WITH([gstreamer],
106 [AS_HELP_STRING([--with-gstreamer], [select GStreamer version])],
107 [want_gstreamer=$withval])
108
109AC_MSG_CHECKING([for a known target platform])
110case "$host" in
111*empeg* )
112 AC_MSG_RESULT([empeg car stereo])
113 AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
114 # work around broken toolchain
115 AC_CHECK_LIB([gpg-error], [gpg_strerror])
116 AC_CHECK_LIB([pthread], [pthread_create])
117 want_server=no
118 want_cgi=no
119 ;;
120*linux* | *Linux* )
121 AC_MSG_RESULT([Linux])
122 AC_DEFINE_UNQUOTED([PATH_PROC_MOUNTS],["/proc/mounts"],[path to kernel mount list])
123 ;;
124*-apple-darwin* )
125 AC_MSG_RESULT([Mac OS X])
126 # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
127 # so we'll just turn off the warning.
128 CC="$CC -Wno-deprecated-declarations"
129 if test $want_coreaudio = yes; then
130 COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
131 fi
132 browser=open
133 AC_MSG_CHECKING([Mac OS X target version])
134 # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
135 # behaviour. But we provide a command line option to override it and
136 # we default to wide support instead of supporting only the build platform.
137 #
138 # Currently if you ask for 10.5 you will get a deprecation warning
139 # when building the CoreAudio support code. For the time being the
140 # answer to this is "don't do that then". If a good reason to ask
141 # for a 10.5 deployment target emerges then this will be fixed.
142 if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
143 MACOSX_DEPLOYMENT_TARGET=10.0
144 fi
145 AC_ARG_WITH([deployment-target],
146 [AS_HELP_STRING([--with-deployment-target=TARGET],
147 [set target OS X version])],
148 [MACOSX_DEPLOYMENT_TARGET=$withval])
149 # Convert to desired format
150 underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
151 minver="MAC_OS_X_VERSION_$underscored"
152 AC_MSG_RESULT([$minver])
153 AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
154 [define to minimum version of Mac OS X to support])
155
156 if test $want_gtkosx = no; then
157 # Fink's GTK+ is hopelessly broken
158 PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
159 export PKG_CONFIG_PATH
160 fi
161
162 ;;
163*-freebsd* )
164 AC_MSG_RESULT([FreeBSD])
165 # Ports install to /usr/local but the compiler stupidly doesn't look
166 # there by default
167 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
168 CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
169 # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
170 AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
171 rjk_cv_libdb="none"
172 for db in db43 db44 db45 db47 db48; do
173 if test -e /usr/local/lib/$db; then
174 rjk_cv_libdb=$db
175 break
176 fi
177 done
178 ])
179 if test $rjk_cv_libdb != none; then
180 LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
181 CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
182 fi
183 # iconv needs bodging
184 AC_SUBST(LIBICONV,[-liconv])
185 ;;
186* )
187 AC_MSG_RESULT([unknown, winging it])
188 ;;
189esac
190AC_SUBST([COREAUDIO])
191
192AC_ARG_WITH([browser],
193 [AS_HELP_STRING([--with-browser=BROWSER],
194 [use BROWSER to display HTML])],
195 [browser=$withval])
196
197AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
198 rjk_cv_browser=UNKNOWN
199 for candidate in sensible-browser x-www-browser firefox mozilla chromium google-chrome konqueror netscape; do
200 if type $candidate >/dev/null 2>&1; then
201 rjk_cv_browser="$candidate"
202 break
203 fi
204 done
205])
206if test -z "$browser"; then
207 browser="$rjk_cv_browser"
208fi
209AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
210
211# Figure out what version of sox is installed
212AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
213 rjk_cv_soxver=UNKNOWN
214 if sox --version > /dev/null 2>&1; then
215 rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
216 else
217 rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
218 fi
219])
220
221# Decide what command line options to use
222#
223# sox version endian bits deployed
224# 12.17.9 -x -[bwld] debian etch, ubuntu dapper
225# 14.0.0 -x/-[BL] -[bwld] ubuntu hardy
226# 14.0.1 -x/-[BL] -[1248] debian lenny
227# 14.2.0 -x/-[BL] -[1248] debian sid (at 2008-12)
228
229AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
230 case $rjk_cv_soxver in
231 [[0-9]].* | 1[[0123]].* )
232 rjk_cv_soxgen=0
233 ;;
234 * )
235 rjk_cv_soxgen=1
236 ;;
237 esac
238])
239AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
240 [default sox generation])
241
242AC_ARG_WITH([server],
243 [AS_HELP_STRING([--without-server],
244 [do not build server])],
245 [want_server=$withval])
246AC_ARG_WITH([cgi],
247 [AS_HELP_STRING([--without-cgi],
248 [do not build CGI])],
249 [want_cgi=$withval])
250AC_ARG_WITH([gtk],
251 [AS_HELP_STRING([--without-gtk],
252 [do not build GTK+ client])],
253 [want_gtk=$withval])
254AC_ARG_WITH([python],
255 [AS_HELP_STRING([--without-python],
256 [do not build Python support])],
257 [want_python=$withval])
258AC_ARG_WITH([gstdecode],
259 [AS_HELP_STRING([--with-gstdecode],
260 [require GStreamer-based decoder])],
261 [want_gstdecode=$withval])
262
263if test $want_server = no; then
264 want_cgi=no
265 want_gstdecode=no
266fi
267
268#
269# OS Document Root CGI directory
270# == ============= =============
271# Debian /var/www /usr/lib/cgi-bin
272# Ubuntu /var/www /usr/lib/cgi-bin
273# Red Hat /var/www/html /var/www/cgi-bin
274# or: /home/httpd/html/ /home/httpd/cgi-bin
275# Slackware /var/www/htdocs (unknown)
276# SuSE /srv/www/html /srv/www/cgi-bin
277# Gentoo /var/www/localhost/htdocs /var/www/localhost/cgi-bin/
278# FreeBSD /usr/local/www/data /usr/local/www/cgi-bin
279# or: /usr/local/www/???/data /usr/local/www/???/cgi-bin
280# OS X /Library/WebServer/Documents /Library/WebServer/CGI-Executables
281# Apache /usr/local/apache/htdocs (none)
282#
283# Sources:
284# http://wiki.linuxquestions.org/wiki/Apache
285# http://mapserver.gis.umn.edu/docs/howto/suse-linux
286# http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
287# http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
288# http://httpd.apache.org/docs/
289#
290if test $want_cgi = yes; then
291 if test -z "$httpdir"; then
292 AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
293 rjk_cv_httpdir="/usr/local/apache/htdocs"
294 for dir in /var/www/html \
295 /var/www/htdocs \
296 /var/www/localhost/htdocs \
297 /var/www \
298 /home/httpd/html \
299 /srv/www/html \
300 /usr/local/www/data \
301 /usr/local/www/*/data \
302 /Library/WebServer/Documents \
303 /usr/local/apache/htdocs; do
304 if test -d "$dir"; then
305 rjk_cv_httpdir="$dir"
306 fi
307 done
308 ])
309 httpdir="$rjk_cv_httpdir"
310 fi
311 if test ! -z "$cgidir"; then
312 # This is a bit harsh but should stop any disasters
313 AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
314 fi
315 if test -z "$cgiexecdir"; then
316 AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
317 rjk_cv_cgiexecdir="/usr/lib/cgi-bin"
318 for dir in /usr/lib/cgi-bin \
319 /Library/WebServer/CGI-Executables \
320 /srv/www/cgi-bin \
321 /var/www/cgi-bin \
322 /home/httpd/cgi-bin \
323 /var/www/localhost/cgi-bin \
324 /usr/local/lib/cgi-bin \
325 /usr/local/www/cgi-bin \
326 /usr/local/www/*/cgi-bin; do
327 if test -d "$dir"; then
328 rjk_cv_cgiexecdir="$dir"
329 break
330 fi
331 done
332 ])
333 cgiexecdir="$rjk_cv_cgiexecdir"
334 fi
335fi
336AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
337AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
338if test -z "$pkghttpdir"; then
339 pkghttpdir='$(httpdir)/disorder'
340fi
341AC_SUBST([pkghttpdir])
342
343if test -z "$dochtmldir"; then
344 dochtmldir='$(docdir)/html'
345fi
346AC_SUBST([dochtmldir])
347
348subdirs="scripts common lib"
349if test $want_tests = yes; then
350 subdirs="${subdirs} libtests"
351fi
352subdirs="${subdirs} clients doc examples debian"
353
354if test $want_server = yes; then
355 subdirs="${subdirs} server plugins sounds"
356fi
357if test $want_cgi = yes; then
358 subdirs="${subdirs} cgi templates images"
359fi
360if test $want_gtk = yes; then
361 subdirs="${subdirs} disobedience"
362 if test $want_server = no; then
363 subdirs="${subdirs} images"
364 fi
365fi
366if test $want_tests = yes && test $want_python = yes; then
367 AM_PATH_PYTHON([2.5])
368 subdirs="${subdirs} python tests"
369fi
370AC_SUBST([subdirs])
371
372# libtool config
373AC_LIBTOOL_DLOPEN
374AC_DISABLE_STATIC
375
376AC_PROG_LIBTOOL
377
378AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
379 rjk_cv_gnused="not found"
380 for candidate in sed gsed; do
381 if $candidate --version >/dev/null 2>&1; then
382 rjk_cv_gnused=$candidate
383 fi
384 done
385])
386GNUSED="${GNUSED:-$rjk_cv_gnused}"
387if test "$GNUSED" = "not found"; then
388 AC_MSG_ERROR([GNU sed is required to build this program])
389fi
390AC_SUBST([GNUSED])
391
392AC_CHECK_PROGS([GROG],[grog])
393AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
394
395missing_libraries=""
396missing_headers=""
397missing_functions=""
398
399AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
400
401AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
402
403# Macs might have libraries under fink's root
404AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
405if test "x$FINK" != xnone; then
406 # Find Fink prefix
407 AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
408 rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
409 ])
410 # Add include and link paths
411 finkdir="${rjk_cv_finkprefix}"
412 finkbindir="${rjk_cv_finkprefix}/bin"
413 CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
414 if test $want_server = yes; then
415 CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
416 fi
417 LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
418 # Distinguish 32- and 64-bit fink
419 AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
420 odata=`otool -v -h $finkbindir/dpkg`
421 case "$odata" in
422 *X86_64* )
423 rjk_cv_finkbits=64
424 ;;
425 *I386* )
426 rjk_cv_finkbits=32
427 ;;
428 * )
429 rjk_cv_finkbits=unknown
430 ;;
431 esac
432 ])
433 # Match Fink so we can use its libraries
434 case $rjk_cv_finkbits in
435 32 | 64 )
436 CC="$CC -m$rjk_cv_finkbits"
437 ;;
438 esac
439else
440 finkbindir=""
441fi
442AC_SUBST([finkdir])
443AC_SUBST([finkbindir])
444
445# Checks for packages.
446case $want_gstdecode,$want_gstreamer in
447 yes,no) AC_MSG_ERROR([gstdecode requires GStreamer]) ;;
448 whatever,no) want_gstdecode=no ;;
449 no,*) want_gstreamer=no ;;
450 *,yes) want_gstreamer="1.0 0.10" ;;
451esac
452
453AH_TEMPLATE([HAVE_GSTREAMER_0_10],
454 [Define if building against GStreamer 0.10])
455AH_TEMPLATE([HAVE_GSTREAMER_1_0],
456 [Define if building against GStreamer 1.0])
457
458mdw_gstreamer_version=nil
459for i in $want_gstreamer; do
460 case $i in
461 0.10) v=0.10 V=0_10 ;;
462 1.0) v=1.0 V=1_0 ;;
463 *) AC_MSG_ERROR([unrecognized GStreamer version]) ;;
464 esac
465 PKG_CHECK_MODULES([GSTREAMER],
466 [gstreamer-$v gstreamer-app-$v gstreamer-audio-$v gstreamer-pbutils-$v],
467 [have_gstreamer=$v], [have_gstreamer=no])
468 case $have_gstreamer in no) continue ;; esac
469 AC_DEFINE_UNQUOTED([HAVE_GSTREAMER_$V], [1])
470 mdw_gstreamer_version=$v
471 break
472done
473
474case $want_gstdecode,$have_gstreamer,$have_gst_plugins_base in
475 whatever,no,* | whatever,*,no)
476 want_gstdecode=no
477 ;;
478 yes,no,* | yes,*,no)
479 case $have_gstreamer in
480 no) missing_libraries="$missing_libraries gstreamer" ;;
481 esac
482 ;;
483 *)
484 want_gstdecode=yes
485 ;;
486esac
487
488mdw_SAVE_CFLAGS=$CFLAGS
489mdw_SAVE_LIBS=$LIBS
490CFLAGS="$CFLAGS $GSTREAMER_CFLAGS"
491LIBS="$LIBS $GSTREAMER_LIBS"
492AC_CHECK_FUNCS([gst_audio_info_from_caps])
493CFLAGS=$mdw_SAVE_CFLAGS
494LIBS=$mdw_SAVE_LIBS
495
496# Checks for libraries.
497# We save up a list of missing libraries that we can't do without
498# and report them all at once.
499AC_CHECK_LIB(gc, GC_malloc, [AC_SUBST(LIBGC,[-lgc])],
500 [missing_libraries="$missing_libraries libgc"])
501mdw_SAVE_LIBS=$LIBS
502LIBS="$LIBS $LIBGC"
503AC_CHECK_FUNCS(GC_get_all_interior_pointers)
504LIBS=$mdw_SAVE_LIBS
505AC_CHECK_LIB(gcrypt, gcry_md_open,
506 [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
507 [missing_libraries="$missing_libraries libgcrypt"])
508PKG_CHECK_MODULES([PCRE2], [libpcre2-8], [have_pcre2=yes], [have_pcre2=no])
509case $have_pcre2 in
510 yes)
511 CFLAGS="$CFLAGS $PCRE2_CFLAGS" LIBPCRE=$PCRE2_LIBS
512 AC_DEFINE([HAVE_LIBPCRE2], [1], [Define if building with libpcre2.])
513 ;;
514 no)
515 AC_CHECK_LIB(pcre, pcre_compile,
516 [AC_SUBST(LIBPCRE,[-lpcre])],
517 [missing_libraries="$missing_libraries libpcre"])
518 ;;
519esac
520if test $want_alsa = yes; then
521 AC_CHECK_LIB([asound], [snd_pcm_open],
522 [AC_SUBST(LIBASOUND,[-lasound])])
523fi
524if test $want_pulseaudio = yes; then
525 PKG_CHECK_MODULES([PULSEAUDIO],[libpulse],
526 [AC_DEFINE([HAVE_PULSEAUDIO],[1],[define to 1 for PulseAudio support])],
527 [missing_libraries="$missing_libraries libpulse"])
528 PKG_CHECK_MODULES([PULSEAUDIO_SIMPLE],[libpulse-simple],,
529 [missing_libraries="$missing_libraries libpulse-simple"])
530fi
531AC_CHECK_LIB([samplerate],[src_new],
532 [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
533if test $want_server = yes; then
534 RJK_CHECK_LIB(db, db_create, [#include <db.h>],
535 [AC_SUBST(LIBDB,[-ldb])],
536 [missing_libraries="$missing_libraries libdb"])
537 AC_CHECK_LIB(vorbis, vorbis_info_clear,
538 [:],
539 [missing_libraries="$missing_libraries libvorbis"])
540 AC_CHECK_LIB(vorbisfile, ov_open,
541 [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
542 [missing_libraries="$missing_libraries libvorbisfile"],
543 [-lvorbis])
544 AC_CHECK_LIB(mad, mad_stream_init,
545 [AC_SUBST(LIBMAD,[-lmad])],
546 [missing_libraries="$missing_libraries libmad"])
547 AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
548 [AC_SUBST(LIBFLAC,[-lFLAC])],
549 [missing_libraries="$missing_libraries libFLAC"])
550fi
551AC_CHECK_LIB([pthread], [pthread_create],
552 [AC_SUBST(LIBPTHREAD,[-lpthread])],
553 [missing_libraries="$missing_libraries libpthread"])
554
555if test $want_gtk = yes; then
556 if test $want_gtkosx = yes; then
557 GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
558 GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
559 GTK_LIBS="-framework Gtk -framework GLib"
560 else
561 AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
562 AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
563 fi
564fi
565
566# Some platforms have iconv already
567AC_CHECK_FUNC(iconv_open, [:],
568 [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
569 [AC_SUBST(LIBICONV,[-liconv])],
570 [missing_functions="$missing_functions iconv_open"])])
571AC_CHECK_FUNC([gethostbyname],[:],[
572 AC_CHECK_LIB(nsl,gethostbyname,
573 [AC_SUBST(LIBNSL,[-lnsl])],
574 [missing_functions="$missing_functions gethostbyname"])])
575AC_CHECK_FUNC([socket],[:],[
576 AC_CHECK_LIB(socket,socket,
577 [AC_SUBST(LIBSOCKET,[-lsocket])],
578 [missing_functions="$missing_functions socket"])])
579AC_CHECK_FUNC([dlopen],[:],[
580 AC_CHECK_LIB(dl,dlopen,
581 [AC_SUBST(LIBDL,[-ldl])],
582 [missing_functions="$missing_functions dlopen"])])
583
584if test ! -z "$missing_libraries"; then
585 AC_MSG_ERROR([missing libraries:$missing_libraries])
586fi
587
588# Checks for header files.
589RJK_FIND_GC_H
590if test $want_oss = yes; then
591 AC_CHECK_HEADERS([sys/soundcard.h])
592fi
593if test $want_alsa = yes; then
594 AC_CHECK_HEADERS([alsa/asoundlib.h])
595fi
596if test $want_coreaudio = yes; then
597 AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
598fi
599AC_CHECK_HEADERS([inttypes.h sys/time.h sys/socket.h netinet/in.h \
600 arpa/inet.h sys/un.h netdb.h pwd.h langinfo.h])
601# We don't bother checking very standard stuff
602# Compilation will fail if any of these headers are missing, so we
603# check for them here and fail early.
604if test $want_server = yes; then
605 AC_CHECK_HEADERS([db.h],[:],[
606 missing_headers="$missing_headers $ac_header"
607 ])
608fi
609AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
610 getopt.h iconv.h langinfo.h \
611 sys/ioctl.h \
612 syslog.h unistd.h],[:],[
613 missing_headers="$missing_headers $ac_header"
614])
615case $have_pcre2 in
616 no)
617 AC_CHECK_HEADERS([pcre.h], [:],
618 [missing_headers="$missing_headers $ac_header"])
619 ;;
620esac
621AC_CHECK_HEADERS([samplerate.h])
622
623if test ! -z "$missing_headers"; then
624 AC_MSG_ERROR([missing headers:$missing_headers])
625fi
626
627# We require that libpcre support UTF-8
628case $have_pcre2 in
629 yes) RJK_REQUIRE_PCRE2_UTF8([$PCRE2_CFLAGS], [$PCRE2_LIBS]) ;;
630 no) RJK_REQUIRE_PCRE_UTF8([-lpcre]) ;;
631esac
632
633# Checks for typedefs, structures, and compiler characteristics.
634AC_C_CONST
635AC_TYPE_SIZE_T
636AC_C_INLINE
637AC_C_BIGENDIAN
638AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
639#include <netinet/in.h>])
640
641# Figure out how we'll check for devices being mounted and unmounted
642AC_CACHE_CHECK([for list of mounted filesystems],[rjk_cv_mtab],[
643 if test -e /etc/mtab; then
644 rjk_cv_mtab=/etc/mtab
645 else
646 rjk_cv_mtab=none
647 fi
648])
649if test $rjk_cv_mtab != none; then
650 AC_DEFINE_UNQUOTED([PATH_MTAB],["$rjk_cv_mtab"],[path to file containing mount list])
651fi
652
653# enable -Werror when we check for certain characteristics:
654
655old_CFLAGS="${CFLAGS}"
656CFLAGS="${CFLAGS} $gcc_werror"
657AC_CHECK_TYPES([long long,uint32_t,uint16_t,uint8_t,intmax_t,uintmax_t])
658CFLAGS="${old_CFLAGS}"
659
660# gcrypt maintainers keep changing everything. Design your interface
661# first, then implement it once, rather than getting it wrong three or
662# four times and shipping between each attempt.
663AC_CACHE_CHECK([for hash handle type in <grypt.h>],
664 [rjk_cv_gcrypt_hash_handle],[
665 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
666#include <gcrypt.h>
667],
668 [gcry_md_hd_t h;])],
669 [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
670 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
671#include <gcrypt.h>
672],
673 [GcryMDHd h;])],
674 [rjk_cv_gcrypt_hash_handle=GcryMDHd],
675 [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
676AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
677 [libgcrypt hash handle type])
678
679AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
680 [rjk_cv_have_gcry_error_t],[
681 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
682#include <gcrypt.h>
683],
684 [gcry_error_t e;])],
685 [rjk_cv_have_gcry_error_t=yes],
686 [rjk_cv_have_gcry_error_t=no])])
687if test $rjk_cv_have_gcry_error_t = yes; then
688 AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
689fi
690
691# Checks for functions
692if test $ac_cv_type_long_long = yes; then
693 AC_CHECK_FUNCS([atoll strtoll],[:],[
694 missing_functions="$missing_functions $ac_func"
695 ])
696 # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
697 AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
698 [rjk_cv_strtoll_declared],[
699 AC_EGREP_HEADER([strtoll], [stdlib.h],
700 [rjk_cv_strtoll_declared=yes],
701 [rjk_cv_strtoll_declared=no])])
702 if test $rjk_cv_strtoll_declared = yes; then
703 AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
704 fi
705 AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
706 [rjk_cv_atoll_declared],[
707 AC_EGREP_HEADER([atoll], [stdlib.h],
708 [rjk_cv_atoll_declared=yes],
709 [rjk_cv_atoll_declared=no])])
710 if test $rjk_cv_atoll_declared = yes; then
711 AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
712 fi
713fi
714AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
715 missing_functions="$missing_functions $ac_func"
716])
717# fsync will do if fdatasync not available
718AC_CHECK_FUNCS([fdatasync],[:],[
719 AC_CHECK_FUNCS([fsync],
720 [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
721 [missing_functions="$missing_functions fdatasync"])])
722if test ! -z "$missing_functions"; then
723 AC_MSG_ERROR([missing functions:$missing_functions])
724fi
725# dlsym will do if dlfunc not available
726AC_CHECK_FUNCS([dlfunc],[:],[
727 AC_DEFINE([dlfunc],[dlsym],[define dlfunc to dlsym if not available])
728])
729if test ! -z "$missing_functions"; then
730 AC_MSG_ERROR([missing functions:$missing_functions])
731fi
732
733# Functions we can take or leave
734AC_CHECK_FUNCS([fls getfsstat closesocket])
735
736if test $want_server = yes; then
737 # <db.h> had better be version 3 or later
738 AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
739 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
740 #include <db.h>
741 #ifndef DB_VERSION_MAJOR
742 # error cannot determine db version
743 #endif
744 #if DB_VERSION_MAJOR < 4
745 # error inadequate db version
746 #endif
747 #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
748 # error inadequate db version
749 #endif
750 ],[])],
751 [rjk_cv_db_version=ok],
752 [rjk_cv_db_version=inadequate])
753 if test $rjk_cv_db_version = ok; then
754 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
755 #include <db.h>
756 #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
757 # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
758 #endif
759 ],[])],
760 [rjk_cv_db_version=ok],
761 [rjk_cv_db_version=toxic])
762 fi
763 ])
764 case $rjk_cv_db_version in
765 ok )
766 ;;
767 inadequate )
768 AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
769 ;;
770 toxic )
771 AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
772 ;;
773 esac
774fi
775
776AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
777if test $want_gtk = yes; then
778 AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
779fi
780AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
781AM_CONDITIONAL([GSTDECODE], [test x$want_gstdecode = xyes])
782
783# Some GCC invocations warn for converting function pointers to void *.
784# This is fair enough, as it's technically forbidden, but we use dlsym()
785# which can pretty much only exist if object and function pointers are
786# interconvertable. So we disable -Werror if need be.
787if test ! -z "$gcc_werror" && test "$ac_cv_func_dlfunc" != yes; then
788 CFLAGS="${CFLAGS} $gcc_werror"
789 AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
790 [rjk_cv_function_pointer_cast],[
791 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
792 void somefunction(void);],
793 [(void *)somefunction])],
794 [rjk_cv_function_pointer_cast=yes],
795 [rjk_cv_function_pointer_cast=no])])
796 if test $rjk_cv_function_pointer_cast = no; then
797 gcc_werror=""
798 fi
799 CFLAGS="${old_CFLAGS}"
800fi
801
802if test "x$GCC" = xyes; then
803 # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
804 # by default.
805 AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
806 AC_TRY_COMPILE([#include <limits.h>],[
807 long long n = LLONG_MAX;
808 ],[rjk_cv_cstd=default],[
809 old_CC="$CC"
810 CC="${CC} -std=gnu99"
811 AC_TRY_COMPILE([#include <limits.h>],[
812 long long n = LLONG_MAX;
813 ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
814 CC="$old_CC"
815 ])
816 ])
817 case $rjk_cv_cstd in
818 default | unknown )
819 ;;
820 * )
821 CC="${CC} -std=${rjk_cv_cstd}"
822 ;;
823 esac
824
825 # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
826 AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
827 old_CC="$CC"
828 if test $GCC = yes; then
829 CC="$CC -Wall -Werror"
830 fi
831 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
832 static int x(char *f) {
833 return *f;
834 }
835 int z(const char *g) {
836 return x((char *)g);
837 }],[])],
838 [rjk_cv_pr29478=no],
839 [rjk_cv_pr29478=yes]
840 )
841 CC="$old_CC"
842 ])
843 if test $rjk_cv_pr29478 = yes; then
844 gcc_werror=''
845 fi
846
847 AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
848 [rjk_cv_gcc44_stupidity],[
849 old_CC="$CC"
850 if test $GCC = yes; then
851 CC="$CC -Wreturn-type -Werror"
852 fi
853 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[
854 static void *threadfn(void) {
855 for(;;)
856 ;
857 }],[])],
858 [rjk_cv_gcc44_stupidity=no],
859 [rjk_cv_gcc44_stupidity=yes])
860 CC="$old_CC"
861 ])
862 if test $rjk_cv_gcc44_stupidity = yes; then
863 AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
864 fi
865
866 # a reasonable default set of warnings
867 CC="${CC} -Wall -W -Wpointer-arith \
868 -Wwrite-strings -Wmissing-prototypes \
869 -Wmissing-declarations -Wnested-externs"
870
871 # Fix up GTK+ and GLib compiler flags
872 GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
873 GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
874
875 if test "$gcc_werror" != ''; then
876 # GCC 2.95 doesn't know to ignore warnings from system headers
877 AC_CACHE_CHECK([whether -Werror is usable],
878 rjk_cv_werror, [
879 save_CFLAGS="${CFLAGS}"
880 CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
881 AC_TRY_COMPILE([#if WITH_GTK
882 #include <gtk/gtk.h>
883#endif
884
885struct s { int a, b; };
886const struct s sv = { .a = 1 };],
887 [],
888 [rjk_cv_werror=yes],
889 [rjk_cv_werror=no])
890 CFLAGS="${save_CFLAGS}"
891 ])
892 if test $rjk_cv_werror = no; then
893 gcc_werror=''
894 fi
895 fi
896 CC="${CC} $gcc_werror"
897
898 # for older GCCs that don't know %ju (etc)
899 AC_CACHE_CHECK([whether -Wno-format is required],
900 rjk_cv_noformat,
901 AC_TRY_COMPILE([#include <stdio.h>
902#include <stdint.h>
903],
904 [printf("%ju", (uintmax_t)0);],
905 [rjk_cv_noformat=no],
906 [rjk_cv_noformat=yes]))
907 if test $rjk_cv_noformat = yes; then
908 CC="${CC} -Wno-format"
909 fi
910
911 AC_CACHE_CHECK([whether -Wshadow is OK],
912 rjk_cv_shadow,
913 oldCC="${CC}"
914 CC="${CC} -Wshadow"
915 [AC_TRY_COMPILE([
916#include <unistd.h>
917#include <vorbis/vorbisfile.h>
918],
919 [],
920 [rjk_cv_shadow=yes],
921 [rjk_cv_shadow=no])
922 CC="${oldCC}"])
923 if test $rjk_cv_shadow = yes; then
924 CC="${CC} -Wshadow"
925 fi
926fi
927
928RJK_GCOV
929
930AH_BOTTOM([#ifdef __GNUC__
931# define attribute(x) __attribute__(x)
932#else
933# define attribute(x)
934#endif])
935
936AC_CONFIG_FILES([Makefile
937 images/Makefile
938 scripts/Makefile
939 common/Makefile
940 lib/Makefile
941 server/Makefile
942 cgi/Makefile
943 clients/Makefile
944 disobedience/Makefile
945 disobedience/manual/Makefile
946 doc/Makefile
947 templates/Makefile
948 plugins/Makefile
949 debian/Makefile
950 sounds/Makefile
951 python/Makefile
952 examples/Makefile
953 libtests/Makefile
954 tests/Makefile])
955AC_OUTPUT
956
957# A hack: communicate our selection of GStreamer version back to the
958# Debian packaging machinery so that it can build the right dependencies.
959echo '### extra control substitutions for Debian' >debian/substvars.auto.new
960case $mdw_gstreamer_version in
961 nil) ;;
962 *) echo >>debian/substvars.auto.new \
963 "disorder:GstVersion=gstreamer$mdw_gstreamer_version" ;;
964esac
965mv debian/substvars.auto.new debian/substvars.auto
966
967if test $GCC = yes && test "$gcc_werror" = ''; then
968 AC_MSG_WARN([building without -Werror])
969fi
970if test $want_python = no; then
971 AC_MSG_WARN([cannot run the test suit without Python])
972fi
973if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
974 AC_MSG_WARN([libsamplerate will be required in a future version])
975fi
976
977# Local Variables:
978# indent-tabs-mode:nil
979# End: