[disorder] / scripts / make-unidata

#! /usr/bin/perl -w
#
# This file is part of DisOrder.
# Copyright (C) 2007 Richard Kettlewell
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
# USA
#
#
# Generate Unicode support tables
#
# This script will download data from unicode.org if the required files
# aren't in the current directory.
#
# After modifying this script you should run:
#  make -C lib rebuild-unicode check
#
# Things not supported yet:
#  - SpecialCasing.txt data for case mapping
#  - Title case offsets
#  - Some kind of hinting for composition
#  - ...
#
# NB the generated files DO NOT offer a stable ABI and so are not immediately
# suitable for use in a general-purpose library.  Things that would need to
# be done:
#  - Hide unidata.h from applications; it will never be ABI- or even API-stable.
#  - Stablized General_Category values
#  - Extend the unicode.h API to general utility rather than just what
#    DisOrder needs.
#  - ...
#
use strict;
use File::Basename;

sub out {
    print @_ or die "$!\n";
}

sub key {
    my $d = shift;
    local $_;

    return join("-", map($d->{$_}, sort keys %$d));
}

# Size of a subtable
#
# This can be varied to trade off the number of subtables against their size.
# 16 gave the smallest results last time I checked (on a Mac with a 32-bit
# build).
our $modulus = 16;

if(@ARGV) {
    $modulus = shift;
}

# Where to break the table.  There is a huge empty section of the Unicode
# code space and we deal with this by simply leaving it out of the table.
# This complicates the lookup function a little but should not affect
# performance in the cases we care about.
our $break_start = 0x30000;
our $break_end = 0xE0000;

# Similarly we simply omit the very top of the table and sort it out in the
# lookup function.
our $break_top = 0xE0200;

my %cats = ();			# known general categories
my %data = ();			# mapping of codepoints to information
my $max = 0;			# maximum codepoint
my $maxccc = 0;			# maximum combining class
my $maxud = 0;
my $minud = 0;			# max/min upper case offset
my $maxld = 0;
my $minld = 0;			# max/min lower case offset

# Make sure we have our desired input files.  We explicitly specify a
# Unicode standard version to make sure that a given version of DisOrder
# supports a given version of Unicode.
sub input {
    my $path = shift;
    my $lpath = basename($path);
    if(!-e $lpath) {
	system("wget http://www.unicode.org/Public/5.0.0/ucd/$path");
	chmod(0444, $lpath) or die "$lpath: $!\n";
    }
    open(STDIN, "<$lpath") or die "$lpath: $!\n";
    print STDERR "Reading $lpath...\n";
}


# Read the main data file
input("UnicodeData.txt");
my ($start, $end);
while(<>) {
    my @f = split(/;/, $_);
    my $c = hex($f[0]);		# codepoint
    my $name = $f[1];
    die "$f[0] $name is in the break\n" 
	if $c >= $break_start && $c < $break_end;
    my $gc = $f[2];		# General_Category
    # Variuos GCs we don't expect to see in UnicodeData.txt
    $cats{$gc} = 1;		# always record all GCs
    if($name =~ /first>/i) {
	$start = $c;
	next;
    } elsif($name =~ /last>/i) {
	$end = $c;
    } else {
	$start = $end = $c;
    }
    die "unexpected Cn" if $gc eq 'Cn';
    my $ccc = $f[3];		# Canonical_Combining_Class
    my $dm = $f[5];		# Decomposition_Type + Decomposition_Mapping
    my $sum = hex($f[12]) || $c; # Simple_Uppercase_Mapping
    my $slm = hex($f[13]) || $c; # Simple_Lowercase_Mapping
    # recalculate the upper/lower case mappings as offsets
    my $ud = $sum - $c;
    my $ld = $slm - $c;
    # update bounds on various values
    $maxccc = $ccc if $ccc > $maxccc; # assumed never to be -ve
    $minud = $ud if $ud < $minud;
    $maxud = $ud if $ud > $maxud;
    $minld = $ld if $ld < $minld;
    $maxld = $ld if $ld > $maxld;
    if($start != $end) {
	printf STDERR "> range %04X-%04X is %s\n", $start, $end, $gc;
    }
    for($c = $start; $c <= $end; ++$c) {
	my $d = {
	    "gc" => $gc,
	    "ccc" => $ccc,
	    "ud" => $ud,
	    "ld" => $ld,
	};
	if($dm ne '') {
	    if($dm !~ /</) {
		# This is a canonical decomposition
		$d->{canon} = $dm;
		$d->{compat} = $dm;
	    } else {
		# This is only a compatibility decomposition
		$dm =~ s/^<.*>\s*//;
		$d->{compat} = $dm;
	    }
	}
	$data{$c} = $d;
    }
    $cats{$gc} = 1;
    $max = $end if $end > $max;
}

sub read_prop_with_ranges {
    my $path = shift;
    my $propkey = shift;
    input($path);
    while(<>) {
	chomp;
	s/\s*\#.*//;
	next if $_ eq '';
	my ($range, $propval) = split(/\s*;\s*/, $_);
	if($range =~ /(.*)\.\.(.*)/) {
	    for my $c (hex($1) .. hex($2)) {
		die "($range)\n" if($c == 0xAC00 and $propkey eq 'gbreak');
		$data{$c}->{$propkey} = $propval;
	    }
	} else {
	    my $c = hex($range);
	    $data{$c}->{$propkey} = $propval;
	}
    }
}

# Grapheme_Break etc
read_prop_with_ranges("auxiliary/GraphemeBreakProperty.txt", "gbreak");
read_prop_with_ranges("auxiliary/WordBreakProperty.txt", "wbreak");
read_prop_with_ranges("auxiliary/SentenceBreakProperty.txt", "sbreak");

# Compute the full list and fill in the Extend category properly
my %gbreak = ();
my %wbreak = ();
my %sbreak = ();
for my $c (keys %data) {
    if(!exists $data{$c}->{gbreak}) {
	$data{$c}->{gbreak} = 'Other';
    }
    $gbreak{$data{$c}->{gbreak}} = 1;

    if(!exists $data{$c}->{wbreak}) {
	if($data{$c}->{gbreak} eq 'Extend') {
	    $data{$c}->{wbreak} = 'Extend';
	} else {
	    $data{$c}->{wbreak} = 'Other';
	}
    }
    $wbreak{$data{$c}->{wbreak}} = 1;

    if(!exists $data{$c}->{sbreak}) {
	if($data{$c}->{gbreak} eq 'Extend') {
	    $data{$c}->{sbreak} = 'Extend';
	} else {
	    $data{$c}->{sbreak} = 'Other';
	}
    }
    $sbreak{$data{$c}->{sbreak}} = 1;
}

# Round up the maximum value to a whole number of subtables
$max += ($modulus - 1) - ($max % $modulus);

# Private use characters
# We only fill in values below $max, utf32__unidata() 
my $Co = {
    "gc" => "Co",
    "ccc" => 0,
    "ud" => 0,
    "ld" => 0
};
for(my $c = 0xE000; $c <= 0xF8FF && $c <= $max; ++$c) {
    $data{$c} = $Co;
}
for(my $c = 0xF0000; $c <= 0xFFFFD && $c <= $max; ++$c) {
    $data{$c} = $Co;
}
for(my $c = 0x100000; $c <= 0x10FFFD && $c <= $max; ++$c) {
    $data{$c} = $Co;
}

# Anything left is not assigned
my $Cn = {
    "gc" => "Cn",		# not assigned
    "ccc" => 0,
    "ud" => 0,
    "ld" => 0
};
for(my $c = 0; $c <= $max; ++$c) {
    if(!exists $data{$c}) {
	$data{$c} = $Cn;
    }
    if(!exists $data{$c}->{wbreak}) {
	$data{$c}->{wbreak} = 'Other';
    }
    if(!exists $data{$c}->{gbreak}) {
	$data{$c}->{gbreak} = 'Other';
    }
    if(!exists $data{$c}->{sbreak}) {
	$data{$c}->{sbreak} = 'Other';
    }
}
$cats{'Cn'} = 1;

# Read the casefolding data too
input("CaseFolding.txt");
while(<>) {
    chomp;
    next if /^\#/ or $_ eq '';
    my @f = split(/\s*;\s*/, $_);
    # Full case folding means use status C and F.
    # We discard status T, Turkish users may wish to change this.
    if($f[1] eq 'C' or $f[1] eq 'F') {
	my $c = hex($f[0]);
	$data{$c}->{casefold} = $f[2];
	# We are particularly interest in combining characters that
	# case-fold to non-combining characters, or characters that
	# case-fold to sequences with combining characters in non-initial
	# positions, as these required decomposiiton before case-folding
	my @d = map(hex($_), split(/\s+/, $data{$c}->{casefold}));
	if($data{$c}->{ccc} != 0) {
	    # This is a combining character
	    if($data{$d[0]}->{ccc} == 0) {
		# The first character of its case-folded form is NOT
		# a combining character.  The field name is the example
		# explicitly mentioned in the spec.
		$data{$c}->{ypogegrammeni} = 1;
	    }
	} else {
	    # This is a non-combining character; inspect the non-initial
	    # code points of the case-folded sequence
	    shift(@d);
	    if(grep($data{$_}->{ccc} != 0, @d)) {
		# Some non-initial code point in the case-folded for is NOT a
		# a combining character.
		$data{$c}->{ypogegrammeni} = 1;
	    }
	}
    }
}

# Generate the header file
print STDERR "Generating unidata.h...\n";
open(STDOUT, ">unidata.h") or die "unidata.h: $!\n";

out("/* Automatically generated file, see scripts/make-unidata */\n",
    "#ifndef UNIDATA_H\n",
    "#define UNIDATA_H\n");

# TODO choose stable values for General_Category
out("enum unicode_General_Category {\n",
    join(",\n",
	 map("  unicode_General_Category_$_", sort keys %cats)), "\n};\n");

out("enum unicode_Grapheme_Break {\n",
    join(",\n",
	 map("  unicode_Grapheme_Break_$_", sort keys %gbreak)),
    "\n};\n");
out("extern const char *const unicode_Grapheme_Break_names[];\n");

out("enum unicode_Word_Break {\n",
    join(",\n",
	 map("  unicode_Word_Break_$_", sort keys %wbreak)),
    "\n};\n");
out("extern const char *const unicode_Word_Break_names[];\n");

out("enum unicode_Sentence_Break {\n",
    join(",\n",
	 map("  unicode_Sentence_Break_$_", sort keys %sbreak)),
    "\n};\n");
out("extern const char *const unicode_Sentence_Break_names[];\n");

out("enum unicode_flags {\n",
    "  unicode_normalize_before_casefold = 1\n",
    "};\n",
    "\n");

# Choose the narrowest type that will fit the required values
sub choosetype {
    my ($min, $max) = @_;
    if($min >= 0) {
	return "char" if $max <= 127;
	return "unsigned char" if $max <= 255;
	return "int16_t" if $max < 32767;
	return "uint16_t" if $max < 65535;
	return "int32_t";
    } else {
	return "char" if $min >= -127 && $max <= 127;
	return "int16_t" if $min >= -32767 && $max <= 32767;
	return "int32_t";
    }
}

out("struct unidata {\n",
    "  const uint32_t *compat;\n",
    "  const uint32_t *canon;\n",
    "  const uint32_t *casefold;\n",
#    "  ".choosetype($minud, $maxud)." upper_offset;\n",
#    "  ".choosetype($minld, $maxld)." lower_offset;\n",
    "  ".choosetype(0, $maxccc)." ccc;\n",
    "  char general_category;\n",
    "  uint8_t flags;\n",
    "  char grapheme_break;\n",
    "  char word_break;\n",
    "  char sentence_break;\n",
    "};\n");
# compat, canon and casefold do have have non-BMP characters, so we
# can't use a simple 16-bit table.  We could use UTF-8 or UTF-16
# though, saving a bit of space (probably not that much...) at the
# cost of marginally reduced performance and additional complexity

out("extern const struct unidata *const unidata[];\n");

out("#define UNICODE_NCHARS ", ($max + 1), "\n");
out("#define UNICODE_MODULUS $modulus\n");
out("#define UNICODE_BREAK_START $break_start\n");
out("#define UNICODE_BREAK_END $break_end\n");
out("#define UNICODE_BREAK_TOP $break_top\n");

out("#endif\n");

close STDOUT or die "unidata.h: $!\n";

print STDERR "Generating unidata.c...\n";
open(STDOUT, ">unidata.c") or die "unidata.c: $!\n";

out("/* Automatically generated file, see scripts/make-unidata */\n",
    "#include <config.h>\n",
    "#include \"types.h\"\n",
    "#include \"unidata.h\"\n");

# Short aliases to keep .c file small

out(map(sprintf("#define %s unicode_General_Category_%s\n", $_, $_),
	sort keys %cats));
out(map(sprintf("#define GB%s unicode_Grapheme_Break_%s\n", $_, $_),
	sort keys %gbreak));
out(map(sprintf("#define WB%s unicode_Word_Break_%s\n", $_, $_),
	sort keys %wbreak));
out(map(sprintf("#define SB%s unicode_Sentence_Break_%s\n", $_, $_),
	sort keys %sbreak));

# Names for *_Break properties
out("const char *const unicode_Grapheme_Break_names[] = {\n",
    join(",\n",
	 map("  \"$_\"", sort keys %gbreak)),
    "\n};\n");
out("const char *const unicode_Word_Break_names[] = {\n",
    join(",\n",
	 map("  \"$_\"", sort keys %wbreak)),
    "\n};\n");
out("const char *const unicode_Sentence_Break_names[] = {\n",
    join(",\n",
	 map("  \"$_\"", sort keys %sbreak)),
    "\n};\n");

# Generate the decomposition mapping tables.  We look out for duplicates
# in order to save space and report this as decompsaved at the end.  In
# Unicode 5.0.0 this saves 1795 entries, which is at least 14Kbytes.
my $decompnum = 0;
my %decompnums = ();
my $decompsaved = 0;
out("static const uint32_t ");
for(my $c = 0; $c <= $max; ++$c) {
    # If canon is set then compat will be too and will be identical.
    # If compat is set the canon might be clear.  So we use the
    # compat version and fix up the symbols after.
    if(exists $data{$c} && exists $data{$c}->{compat}) {
	my $s = join(",",
		     (map(hex($_), split(/\s+/, $data{$c}->{compat})), 0));
	if(!exists $decompnums{$s}) {
	    out(",\n") if $decompnum != 0;
	    out("cd$decompnum\[]={$s}");
	    $decompnums{$s} = $decompnum++;
	} else {
	    ++$decompsaved;
	}
	$data{$c}->{compatsym} = "cd$decompnums{$s}";
	if(exists $data{$c}->{canon}) {
	    $data{$c}->{canonsym} = "cd$decompnums{$s}";
	}
    }
}
out(";\n");

# ...and the case folding table.  Again we compress equal entries to save
# space.  In Unicode 5.0.0 this saves 51 entries or at least 408 bytes.
# This doesns't seem as worthwhile as the decomposition mapping saving above.
my $cfnum = 0;
my %cfnums = ();
my $cfsaved = 0;
out("static const uint32_t ");
for(my $c = 0; $c <= $max; ++$c) {
    if(exists $data{$c} && exists $data{$c}->{casefold}) {
	my $s = join(",",
		     (map(hex($_), split(/\s+/, $data{$c}->{casefold})), 0));
	if(!exists $cfnums{$s}) {
	    out(",\n") if $cfnum != 0;
	    out("cf$cfnum\[]={$s}");
	    $cfnums{$s} = $cfnum++;
	} else {
	    ++$cfsaved;
	}
	$data{$c}->{cfsym} = "cf$cfnums{$s}";
    }
}
out(";\n");

# Visit all the $modulus-character blocks in turn and generate the
# required subtables.  As above we spot duplicates to save space.  In
# Unicode 5.0.0 with $modulus=128 and current table data this saves
# 1372 subtables or at least three and a half megabytes on 32-bit
# platforms.

my %subtable = ();		# base->subtable number
my %subtableno = ();		# subtable number -> content
my $subtablecounter = 0;	# counter for subtable numbers
my $subtablessaved = 0;		# number of tables saved
for(my $base = 0; $base <= $max; $base += $modulus) {
    next if $base >= $break_start && $base < $break_end;
    next if $base >= $break_top;
    my @t;
    for(my $c = $base; $c < $base + $modulus; ++$c) {
	my $d = $data{$c};
	my $canonsym = ($data{$c}->{canonsym} or "0");
	my $compatsym = ($data{$c}->{compatsym} or "0");
	my $cfsym = ($data{$c}->{cfsym} or "0");
	my @flags = ();
	if($data{$c}->{ypogegrammeni}) {
	    push(@flags, "unicode_normalize_before_casefold");
	}
	my $flags = @flags ? join("|", @flags) : 0;
	push(@t, "{".
	     join(",",
		  $compatsym,
		  $canonsym,
		  $cfsym,
#		  $d->{ud},
#		  $d->{ld},
		  $d->{ccc},
		  $d->{gc},
		  $flags,
		  "GB$d->{gbreak}",
		  "WB$d->{wbreak}",
		  "SB$d->{sbreak}",
	     )."}");
    }
    my $t = join(",\n", @t);
    if(!exists $subtable{$t}) {
	out(sprintf("/* %04X-%04X */\n", $base, $base + $modulus - 1));
	out("static const struct unidata st$subtablecounter\[] = {\n",
	    "$t\n",
	    "};\n");
	$subtable{$t} = $subtablecounter++;
    } else {
	++$subtablessaved;
    }
    $subtableno{$base} = $subtable{$t};
}

out("const struct unidata *const unidata[]={\n");
for(my $base = 0; $base <= $max; $base += $modulus) {
    next if $base >= $break_start && $base < $break_end;
    next if $base >= $break_top;
    #out("st$subtableno{$base} /* ".sprintf("%04x", $base)." */,\n");
    out("st$subtableno{$base},\n");
}
out("};\n");

close STDOUT or die "unidata.c: $!\n";

printf STDERR "modulus=%d\n", $modulus;
printf STDERR "max=%04X\n", $max;
print STDERR "subtables=$subtablecounter, subtablessaved=$subtablessaved\n";
print STDERR "decompsaved=$decompsaved cfsaved=$cfsaved\n";
Commit	Line	Data
61507e3c RK	1	#! /usr/bin/perl -w
61507e3c RK	2	#
e5a5a138 RK	3	# This file is part of DisOrder.
	4	# Copyright (C) 2007 Richard Kettlewell
	5	#
	6	# This program is free software; you can redistribute it and/or modify
	7	# it under the terms of the GNU General Public License as published by
	8	# the Free Software Foundation; either version 2 of the License, or
	9	# (at your option) any later version.
	10	#
	11	# This program is distributed in the hope that it will be useful, but
	12	# WITHOUT ANY WARRANTY; without even the implied warranty of
	13	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	14	# General Public License for more details.
	15	#
	16	# You should have received a copy of the GNU General Public License
	17	# along with this program; if not, write to the Free Software
	18	# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
	19	# USA
	20	#
	21	#
	22	# Generate Unicode support tables
	23	#
	24	# This script will download data from unicode.org if the required files
	25	# aren't in the current directory.
	26	#
	27	# After modifying this script you should run:
	28	# make -C lib rebuild-unicode check
	29	#
	30	# Things not supported yet:
	31	# - SpecialCasing.txt data for case mapping
	32	# - Title case offsets
	33	# - Some kind of hinting for composition
e5a5a138 RK	34	# - ...
	35	#
	36	# NB the generated files DO NOT offer a stable ABI and so are not immediately
	37	# suitable for use in a general-purpose library. Things that would need to
	38	# be done:
	39	# - Hide unidata.h from applications; it will never be ABI- or even API-stable.
	40	# - Stablized General_Category values
	41	# - Extend the unicode.h API to general utility rather than just what
	42	# DisOrder needs.
	43	# - ...
	44	#
61507e3c	45	use strict;
35b651f0	46	use File::Basename;
61507e3c RK	47
	48	sub out {
	49	print @_ or die "$!\n";
	50	}
	51
	52	sub key {
	53	my $d = shift;
	54	local $_;
	55
	56	return join("-", map($d->{$_}, sort keys %$d));
	57	}
	58
e5a5a138 RK	59	# Size of a subtable
	60	#
	61	# This can be varied to trade off the number of subtables against their size.
c2e01e0a RK	62	# 16 gave the smallest results last time I checked (on a Mac with a 32-bit
	63	# build).
	64	our $modulus = 16;
	65
	66	if(@ARGV) {
	67	$modulus = shift;
	68	}
e5a5a138	69
1a05e381 RK	70	# Where to break the table. There is a huge empty section of the Unicode
	71	# code space and we deal with this by simply leaving it out of the table.
	72	# This complicates the lookup function a little but should not affect
	73	# performance in the cases we care about.
	74	our $break_start = 0x30000;
	75	our $break_end = 0xE0000;
	76
	77	# Similarly we simply omit the very top of the table and sort it out in the
	78	# lookup function.
	79	our $break_top = 0xE0200;
	80
61507e3c RK	81	my %cats = (); # known general categories
61507e3c RK	82	my %data = (); # mapping of codepoints to information
61507e3c	83	my $max = 0; # maximum codepoint
e5a5a138 RK	84	my $maxccc = 0; # maximum combining class
	85	my $maxud = 0;
	86	my $minud = 0; # max/min upper case offset
	87	my $maxld = 0;
	88	my $minld = 0; # max/min lower case offset
	89
	90	# Make sure we have our desired input files. We explicitly specify a
	91	# Unicode standard version to make sure that a given version of DisOrder
	92	# supports a given version of Unicode.
0b7052da	93	sub input {
35b651f0 RK	94	my $path = shift;
	95	my $lpath = basename($path);
	96	if(!-e $lpath) {
	97	system("wget http://www.unicode.org/Public/5.0.0/ucd/$path");
	98	chmod(0444, $lpath) or die "$lpath: $!\n";
e5a5a138	99	}
0b7052da	100	open(STDIN, "<$lpath") or die "$lpath: $!\n";
bcf9ed7f	101	print STDERR "Reading $lpath...\n";
e5a5a138	102	}
61507e3c	103
e5a5a138 RK	104
e5a5a138 RK	105	# Read the main data file
0b7052da	106	input("UnicodeData.txt");
1a05e381	107	my ($start, $end);
61507e3c RK	108	while(<>) {
	109	my @f = split(/;/, $_);
	110	my $c = hex($f[0]); # codepoint
61507e3c	111	my $name = $f[1];
1a05e381 RK	112	die "$f[0] $name is in the break\n"
1a05e381 RK	113	if $c >= $break_start && $c < $break_end;
e5a5a138	114	my $gc = $f[2]; # General_Category
bcf9ed7f	115	# Variuos GCs we don't expect to see in UnicodeData.txt
0a4af692	116	$cats{$gc} = 1; # always record all GCs
1a05e381 RK	117	if($name =~ /first>/i) {
	118	$start = $c;
	119	next;
	120	} elsif($name =~ /last>/i) {
	121	$end = $c;
	122	} else {
	123	$start = $end = $c;
	124	}
bcf9ed7f	125	die "unexpected Cn" if $gc eq 'Cn';
e5a5a138 RK	126	my $ccc = $f[3]; # Canonical_Combining_Class
	127	my $dm = $f[5]; # Decomposition_Type + Decomposition_Mapping
	128	my $sum = hex($f[12]) \|\| $c; # Simple_Uppercase_Mapping
	129	my $slm = hex($f[13]) \|\| $c; # Simple_Lowercase_Mapping
61507e3c RK	130	# recalculate the upper/lower case mappings as offsets
	131	my $ud = $sum - $c;
	132	my $ld = $slm - $c;
e5a5a138 RK	133	# update bounds on various values
	134	$maxccc = $ccc if $ccc > $maxccc; # assumed never to be -ve
	135	$minud = $ud if $ud < $minud;
	136	$maxud = $ud if $ud > $maxud;
	137	$minld = $ld if $ld < $minld;
	138	$maxld = $ld if $ld > $maxld;
1a05e381	139	if($start != $end) {
0e843521	140	printf STDERR "> range %04X-%04X is %s\n", $start, $end, $gc;
1a05e381 RK	141	}
1a05e381 RK	142	for($c = $start; $c <= $end; ++$c) {
0e843521 RK	143	my $d = {
	144	"gc" => $gc,
	145	"ccc" => $ccc,
	146	"ud" => $ud,
	147	"ld" => $ld,
	148	};
	149	if($dm ne '') {
	150	if($dm !~ /</) {
	151	# This is a canonical decomposition
	152	$d->{canon} = $dm;
	153	$d->{compat} = $dm;
	154	} else {
	155	# This is only a compatibility decomposition
	156	$dm =~ s/^<.>\s//;
	157	$d->{compat} = $dm;
	158	}
	159	}
1a05e381 RK	160	$data{$c} = $d;
1a05e381 RK	161	}
61507e3c	162	$cats{$gc} = 1;
1a05e381	163	$max = $end if $end > $max;
61507e3c RK	164	}
61507e3c RK	165
0b7052da RK	166	sub read_prop_with_ranges {
	167	my $path = shift;
	168	my $propkey = shift;
	169	input($path);
	170	while(<>) {
	171	chomp;
	172	s/\s\#.//;
	173	next if $_ eq '';
	174	my ($range, $propval) = split(/\s;\s/, $_);
	175	if($range =~ /(.)\.\.(.)/) {
	176	for my $c (hex($1) .. hex($2)) {
0e843521 RK	177	die "($range)\n" if($c == 0xAC00 and $propkey eq 'gbreak');
0e843521 RK	178	$data{$c}->{$propkey} = $propval;
0b7052da RK	179	}
	180	} else {
	181	my $c = hex($range);
0e843521	182	$data{$c}->{$propkey} = $propval;
35b651f0	183	}
0b7052da RK	184	}
	185	}
	186
349b7b74	187	# Grapheme_Break etc
0b7052da	188	read_prop_with_ranges("auxiliary/GraphemeBreakProperty.txt", "gbreak");
0b7052da	189	read_prop_with_ranges("auxiliary/WordBreakProperty.txt", "wbreak");
349b7b74	190	read_prop_with_ranges("auxiliary/SentenceBreakProperty.txt", "sbreak");
0b7052da	191
349b7b74 RK	192	# Compute the full list and fill in the Extend category properly
	193	my %gbreak = ();
	194	my %wbreak = ();
	195	my %sbreak = ();
0b7052da	196	for my $c (keys %data) {
349b7b74 RK	197	if(!exists $data{$c}->{gbreak}) {
	198	$data{$c}->{gbreak} = 'Other';
	199	}
	200	$gbreak{$data{$c}->{gbreak}} = 1;
	201
0b7052da	202	if(!exists $data{$c}->{wbreak}) {
349b7b74	203	if($data{$c}->{gbreak} eq 'Extend') {
0b7052da RK	204	$data{$c}->{wbreak} = 'Extend';
	205	} else {
	206	$data{$c}->{wbreak} = 'Other';
35b651f0 RK	207	}
35b651f0 RK	208	}
349b7b74 RK	209	$wbreak{$data{$c}->{wbreak}} = 1;
	210
	211	if(!exists $data{$c}->{sbreak}) {
	212	if($data{$c}->{gbreak} eq 'Extend') {
	213	$data{$c}->{sbreak} = 'Extend';
	214	} else {
	215	$data{$c}->{sbreak} = 'Other';
	216	}
	217	}
	218	$sbreak{$data{$c}->{sbreak}} = 1;
35b651f0 RK	219	}
35b651f0 RK	220
e5a5a138 RK	221	# Round up the maximum value to a whole number of subtables
e5a5a138 RK	222	$max += ($modulus - 1) - ($max % $modulus);
61507e3c	223
bcf9ed7f RK	224	# Private use characters
	225	# We only fill in values below $max, utf32__unidata()
	226	my $Co = {
	227	"gc" => "Co",
	228	"ccc" => 0,
	229	"ud" => 0,
	230	"ld" => 0
	231	};
	232	for(my $c = 0xE000; $c <= 0xF8FF && $c <= $max; ++$c) {
	233	$data{$c} = $Co;
	234	}
	235	for(my $c = 0xF0000; $c <= 0xFFFFD && $c <= $max; ++$c) {
	236	$data{$c} = $Co;
	237	}
	238	for(my $c = 0x100000; $c <= 0x10FFFD && $c <= $max; ++$c) {
	239	$data{$c} = $Co;
	240	}
	241
	242	# Anything left is not assigned
	243	my $Cn = {
	244	"gc" => "Cn", # not assigned
	245	"ccc" => 0,
	246	"ud" => 0,
	247	"ld" => 0
	248	};
61507e3c RK	249	for(my $c = 0; $c <= $max; ++$c) {
61507e3c RK	250	if(!exists $data{$c}) {
bcf9ed7f RK	251	$data{$c} = $Cn;
	252	}
	253	if(!exists $data{$c}->{wbreak}) {
	254	$data{$c}->{wbreak} = 'Other';
	255	}
	256	if(!exists $data{$c}->{gbreak}) {
	257	$data{$c}->{gbreak} = 'Other';
	258	}
	259	if(!exists $data{$c}->{sbreak}) {
	260	$data{$c}->{sbreak} = 'Other';
61507e3c RK	261	}
	262	}
	263	$cats{'Cn'} = 1;
	264
e5a5a138	265	# Read the casefolding data too
0b7052da	266	input("CaseFolding.txt");
e5a5a138 RK	267	while(<>) {
	268	chomp;
	269	next if /^\#/ or $_ eq '';
	270	my @f = split(/\s;\s/, $_);
	271	# Full case folding means use status C and F.
	272	# We discard status T, Turkish users may wish to change this.
	273	if($f[1] eq 'C' or $f[1] eq 'F') {
	274	my $c = hex($f[0]);
	275	$data{$c}->{casefold} = $f[2];
	276	# We are particularly interest in combining characters that
	277	# case-fold to non-combining characters, or characters that
	278	# case-fold to sequences with combining characters in non-initial
	279	# positions, as these required decomposiiton before case-folding
	280	my @d = map(hex($_), split(/\s+/, $data{$c}->{casefold}));
	281	if($data{$c}->{ccc} != 0) {
	282	# This is a combining character
	283	if($data{$d[0]}->{ccc} == 0) {
	284	# The first character of its case-folded form is NOT
	285	# a combining character. The field name is the example
	286	# explicitly mentioned in the spec.
	287	$data{$c}->{ypogegrammeni} = 1;
	288	}
	289	} else {
	290	# This is a non-combining character; inspect the non-initial
	291	# code points of the case-folded sequence
	292	shift(@d);
	293	if(grep($data{$_}->{ccc} != 0, @d)) {
	294	# Some non-initial code point in the case-folded for is NOT a
	295	# a combining character.
	296	$data{$c}->{ypogegrammeni} = 1;
	297	}
	298	}
	299	}
	300	}
	301
	302	# Generate the header file
bcf9ed7f	303	print STDERR "Generating unidata.h...\n";
61507e3c RK	304	open(STDOUT, ">unidata.h") or die "unidata.h: $!\n";
61507e3c RK	305
e5a5a138 RK	306	out("/* Automatically generated file, see scripts/make-unidata */\n",
e5a5a138 RK	307	"#ifndef UNIDATA_H\n",
61507e3c RK	308	"#define UNIDATA_H\n");
61507e3c RK	309
e5a5a138	310	# TODO choose stable values for General_Category
14523635	311	out("enum unicode_General_Category {\n",
61507e3c	312	join(",\n",
14523635	313	map(" unicode_General_Category_$_", sort keys %cats)), "\n};\n");
e5a5a138	314
349b7b74 RK	315	out("enum unicode_Grapheme_Break {\n",
	316	join(",\n",
	317	map(" unicode_Grapheme_Break_$_", sort keys %gbreak)),
	318	"\n};\n");
	319	out("extern const char *const unicode_Grapheme_Break_names[];\n");
	320
0b7052da RK	321	out("enum unicode_Word_Break {\n",
0b7052da RK	322	join(",\n",
349b7b74	323	map(" unicode_Word_Break_$_", sort keys %wbreak)),
0b7052da	324	"\n};\n");
bb48024f	325	out("extern const char *const unicode_Word_Break_names[];\n");
0b7052da	326
349b7b74 RK	327	out("enum unicode_Sentence_Break {\n",
	328	join(",\n",
	329	map(" unicode_Sentence_Break_$_", sort keys %sbreak)),
	330	"\n};\n");
	331	out("extern const char *const unicode_Sentence_Break_names[];\n");
	332
e5a5a138	333	out("enum unicode_flags {\n",
0b7052da	334	" unicode_normalize_before_casefold = 1\n",
e5a5a138 RK	335	"};\n",
	336	"\n");
	337
	338	# Choose the narrowest type that will fit the required values
	339	sub choosetype {
	340	my ($min, $max) = @_;
	341	if($min >= 0) {
	342	return "char" if $max <= 127;
	343	return "unsigned char" if $max <= 255;
	344	return "int16_t" if $max < 32767;
	345	return "uint16_t" if $max < 65535;
	346	return "int32_t";
	347	} else {
	348	return "char" if $min >= -127 && $max <= 127;
	349	return "int16_t" if $min >= -32767 && $max <= 32767;
	350	return "int32_t";
	351	}
	352	}
	353
61507e3c	354	out("struct unidata {\n",
e5a5a138 RK	355	" const uint32_t *compat;\n",
	356	" const uint32_t *canon;\n",
	357	" const uint32_t *casefold;\n",
1a05e381 RK	358	# " ".choosetype($minud, $maxud)." upper_offset;\n",
1a05e381 RK	359	# " ".choosetype($minld, $maxld)." lower_offset;\n",
e5a5a138	360	" ".choosetype(0, $maxccc)." ccc;\n",
14523635	361	" char general_category;\n",
e5a5a138	362	" uint8_t flags;\n",
349b7b74	363	" char grapheme_break;\n",
0b7052da	364	" char word_break;\n",
349b7b74	365	" char sentence_break;\n",
61507e3c	366	"};\n");
e5a5a138 RK	367	# compat, canon and casefold do have have non-BMP characters, so we
	368	# can't use a simple 16-bit table. We could use UTF-8 or UTF-16
	369	# though, saving a bit of space (probably not that much...) at the
	370	# cost of marginally reduced performance and additional complexity
61507e3c RK	371
	372	out("extern const struct unidata *const unidata[];\n");
	373
	374	out("#define UNICODE_NCHARS ", ($max + 1), "\n");
e5a5a138	375	out("#define UNICODE_MODULUS $modulus\n");
1a05e381 RK	376	out("#define UNICODE_BREAK_START $break_start\n");
	377	out("#define UNICODE_BREAK_END $break_end\n");
	378	out("#define UNICODE_BREAK_TOP $break_top\n");
61507e3c RK	379
	380	out("#endif\n");
	381
	382	close STDOUT or die "unidata.h: $!\n";
	383
bcf9ed7f	384	print STDERR "Generating unidata.c...\n";
61507e3c RK	385	open(STDOUT, ">unidata.c") or die "unidata.c: $!\n";
61507e3c RK	386
e5a5a138 RK	387	out("/* Automatically generated file, see scripts/make-unidata */\n",
	388	"#include <config.h>\n",
	389	"#include \"types.h\"\n",
	390	"#include \"unidata.h\"\n");
	391
349b7b74	392	# Short aliases to keep .c file small
e5a5a138	393
14523635 RK	394	out(map(sprintf("#define %s unicode_General_Category_%s\n", $_, $_),
	395	sort keys %cats));
	396	out(map(sprintf("#define GB%s unicode_Grapheme_Break_%s\n", $_, $_),
	397	sort keys %gbreak));
	398	out(map(sprintf("#define WB%s unicode_Word_Break_%s\n", $_, $_),
	399	sort keys %wbreak));
	400	out(map(sprintf("#define SB%s unicode_Sentence_Break_%s\n", $_, $_),
	401	sort keys %sbreak));
e5a5a138	402
349b7b74 RK	403	# Names for *_Break properties
	404	out("const char *const unicode_Grapheme_Break_names[] = {\n",
	405	join(",\n",
	406	map(" \"$_\"", sort keys %gbreak)),
	407	"\n};\n");
bb48024f RK	408	out("const char *const unicode_Word_Break_names[] = {\n",
bb48024f RK	409	join(",\n",
349b7b74 RK	410	map(" \"$_\"", sort keys %wbreak)),
	411	"\n};\n");
	412	out("const char *const unicode_Sentence_Break_names[] = {\n",
	413	join(",\n",
	414	map(" \"$_\"", sort keys %sbreak)),
bb48024f RK	415	"\n};\n");
bb48024f RK	416
e5a5a138 RK	417	# Generate the decomposition mapping tables. We look out for duplicates
	418	# in order to save space and report this as decompsaved at the end. In
	419	# Unicode 5.0.0 this saves 1795 entries, which is at least 14Kbytes.
	420	my $decompnum = 0;
	421	my %decompnums = ();
	422	my $decompsaved = 0;
	423	out("static const uint32_t ");
	424	for(my $c = 0; $c <= $max; ++$c) {
	425	# If canon is set then compat will be too and will be identical.
	426	# If compat is set the canon might be clear. So we use the
	427	# compat version and fix up the symbols after.
bcf9ed7f	428	if(exists $data{$c} && exists $data{$c}->{compat}) {
e5a5a138 RK	429	my $s = join(",",
	430	(map(hex($_), split(/\s+/, $data{$c}->{compat})), 0));
	431	if(!exists $decompnums{$s}) {
	432	out(",\n") if $decompnum != 0;
	433	out("cd$decompnum\[]={$s}");
	434	$decompnums{$s} = $decompnum++;
	435	} else {
	436	++$decompsaved;
	437	}
	438	$data{$c}->{compatsym} = "cd$decompnums{$s}";
	439	if(exists $data{$c}->{canon}) {
	440	$data{$c}->{canonsym} = "cd$decompnums{$s}";
	441	}
	442	}
	443	}
	444	out(";\n");
	445
	446	# ...and the case folding table. Again we compress equal entries to save
	447	# space. In Unicode 5.0.0 this saves 51 entries or at least 408 bytes.
	448	# This doesns't seem as worthwhile as the decomposition mapping saving above.
	449	my $cfnum = 0;
	450	my %cfnums = ();
	451	my $cfsaved = 0;
	452	out("static const uint32_t ");
	453	for(my $c = 0; $c <= $max; ++$c) {
bcf9ed7f	454	if(exists $data{$c} && exists $data{$c}->{casefold}) {
e5a5a138 RK	455	my $s = join(",",
	456	(map(hex($_), split(/\s+/, $data{$c}->{casefold})), 0));
	457	if(!exists $cfnums{$s}) {
	458	out(",\n") if $cfnum != 0;
	459	out("cf$cfnum\[]={$s}");
	460	$cfnums{$s} = $cfnum++;
	461	} else {
	462	++$cfsaved;
	463	}
	464	$data{$c}->{cfsym} = "cf$cfnums{$s}";
	465	}
	466	}
	467	out(";\n");
	468
	469	# Visit all the $modulus-character blocks in turn and generate the
	470	# required subtables. As above we spot duplicates to save space. In
	471	# Unicode 5.0.0 with $modulus=128 and current table data this saves
	472	# 1372 subtables or at least three and a half megabytes on 32-bit
	473	# platforms.
61507e3c	474
61507e3c RK	475	my %subtable = (); # base->subtable number
	476	my %subtableno = (); # subtable number -> content
	477	my $subtablecounter = 0; # counter for subtable numbers
e5a5a138 RK	478	my $subtablessaved = 0; # number of tables saved
e5a5a138 RK	479	for(my $base = 0; $base <= $max; $base += $modulus) {
1a05e381 RK	480	next if $base >= $break_start && $base < $break_end;
1a05e381 RK	481	next if $base >= $break_top;
61507e3c	482	my @t;
e5a5a138	483	for(my $c = $base; $c < $base + $modulus; ++$c) {
61507e3c	484	my $d = $data{$c};
e5a5a138 RK	485	my $canonsym = ($data{$c}->{canonsym} or "0");
	486	my $compatsym = ($data{$c}->{compatsym} or "0");
	487	my $cfsym = ($data{$c}->{cfsym} or "0");
35b651f0 RK	488	my @flags = ();
	489	if($data{$c}->{ypogegrammeni}) {
	490	push(@flags, "unicode_normalize_before_casefold");
	491	}
35b651f0	492	my $flags = @flags ? join("\|", @flags) : 0;
e5a5a138 RK	493	push(@t, "{".
	494	join(",",
	495	$compatsym,
	496	$canonsym,
	497	$cfsym,
1a05e381 RK	498	# $d->{ud},
1a05e381 RK	499	# $d->{ld},
0b7052da RK	500	$d->{ccc},
0b7052da RK	501	$d->{gc},
e5a5a138	502	$flags,
349b7b74 RK	503	"GB$d->{gbreak}",
	504	"WB$d->{wbreak}",
	505	"SB$d->{sbreak}",
e5a5a138	506	)."}");
61507e3c RK	507	}
	508	my $t = join(",\n", @t);
	509	if(!exists $subtable{$t}) {
0e843521	510	out(sprintf("/* %04X-%04X */\n", $base, $base + $modulus - 1));
e5a5a138	511	out("static const struct unidata st$subtablecounter\[] = {\n",
61507e3c RK	512	"$t\n",
	513	"};\n");
	514	$subtable{$t} = $subtablecounter++;
e5a5a138 RK	515	} else {
e5a5a138 RK	516	++$subtablessaved;
61507e3c RK	517	}
	518	$subtableno{$base} = $subtable{$t};
	519	}
	520
bcf9ed7f	521	out("const struct unidata *const unidata[]={\n");
e5a5a138	522	for(my $base = 0; $base <= $max; $base += $modulus) {
1a05e381 RK	523	next if $base >= $break_start && $base < $break_end;
1a05e381 RK	524	next if $base >= $break_top;
0a4af692	525	#out("st$subtableno{$base} /* ".sprintf("%04x", $base)." */,\n");
e5a5a138	526	out("st$subtableno{$base},\n");
61507e3c RK	527	}
	528	out("};\n");
	529
	530	close STDOUT or die "unidata.c: $!\n";
	531
c2e01e0a	532	printf STDERR "modulus=%d\n", $modulus;
bcf9ed7f RK	533	printf STDERR "max=%04X\n", $max;
bcf9ed7f RK	534	print STDERR "subtables=$subtablecounter, subtablessaved=$subtablessaved\n";
e5a5a138	535	print STDERR "decompsaved=$decompsaved cfsaved=$cfsaved\n";