[disorder] / configure.ac

# Process this file with autoconf to produce a configure script.
#
# This file is part of DisOrder.
# Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
# Portions copyright (C) 2007 Ross Younger
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
# USA
#

AC_INIT([disorder], [2.0+], [richard+disorder@sfere.greenend.org.uk])
AC_CONFIG_AUX_DIR([config.aux])
AM_INIT_AUTOMAKE(disorder, [2.0+])
AC_CONFIG_SRCDIR([server/disorderd.c])
AM_CONFIG_HEADER([config.h])

# Find host type
AC_CANONICAL_HOST

# What we want to build
want_gtk=yes
want_python=yes

# APIs we want
want_alsa=yes
want_oss=yes
want_coreaudio=yes

# Checks for programs.
AC_PROG_CC
AC_SET_MAKE
if test "x$GCC" = xyes; then
  gcc_werror=-Werror
else
  gcc_werror=""
fi

AC_ARG_WITH([alsa],
	    [AS_HELP_STRING([--without-alsa],
			    [do not build with ALSA support])],
	    [want_alsa=$withval])
AC_ARG_WITH([oss],
	    [AS_HELP_STRING([--without-oss],
			    [do not build with OSS support])],
	    [want_oss=$withval])
AC_ARG_WITH([coreaudio],
	    [AS_HELP_STRING([--without-coreaudio],
			    [do not build with Core Audio support])],
	    [want_coreaudio=$withval])

AC_MSG_CHECKING([for a known target platform])
case "$host" in
*empeg* )
  AC_MSG_RESULT([empeg car stereo])
  AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
  # work around broken toolchain
  AC_CHECK_LIB([gpg-error], [gpg_strerror])
  AC_CHECK_LIB([pthread], [pthread_create])
  want_server=no
 ;;
*linux* | *Linux* )
  AC_MSG_RESULT([Linux])
  want_server=yes
  ;;
*-apple-darwin* )
  AC_MSG_RESULT([Mac OS X])
  want_server=yes
  if test $want_coreaudio = yes; then
    COREAUDIO="-framework CoreAudio"
  fi
  browser=open
  AC_MSG_CHECKING([Mac OS X target version])
  # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
  # behaviour.  But we provide a command line option to override it and
  # we default to wide support instead of supporting only the build platform.
  #
  # Currently if you ask for 10.5 you will get a deprecation warning
  # when building the CoreAudio support code.  For the time being the
  # answer to this is "don't do that then".  If a good reason to ask
  # for a 10.5 deployment target emerges then this will be fixed.
  if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
    MACOSX_DEPLOYMENT_TARGET=10.0
  fi
  AC_ARG_WITH([deployment-target],
              [AS_HELP_STRING([--with-deployment-target=TARGET],
                              [set target OS X version])],
              [MACOSX_DEPLOYMENT_TARGET=$withval])
  # Convert to desired format
  underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
  minver="MAC_OS_X_VERSION_$underscored"
  AC_MSG_RESULT([$minver])
  AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
                     [define to minimum version of Mac OS X to support])
  ;;
*-freebsd* )
  AC_MSG_RESULT([FreeBSD])
  want_server=yes
  # Ports install to /usr/local but the compiler stupidly doesn't look
  # there by default
  LDFLAGS="${LDFLAGS} -L/usr/local/lib"
  CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
  # libdb installs elsewhere again
  LDFLAGS="${LDFLAGS} -L/usr/local/lib/db44"
  CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/db44"
  ;;
* )
  AC_MSG_RESULT([unknown, winging it])
  want_server=no
  ;;
esac
AC_SUBST([COREAUDIO])

AC_ARG_WITH([browser],
            [AS_HELP_STRING([--with-browser=BROWSER],
			    [use BROWSER to display HTML])],
            [browser=$withval])

AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
  rjk_cv_browser=UNKNOWN
  for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
    if type $candidate >/dev/null 2>&1; then
      rjk_cv_browser="$candidate"
      break
    fi
  done
])
if test -z "$browser"; then
  browser="$rjk_cv_browser"
fi
AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])

AC_ARG_WITH([server],
	    [AS_HELP_STRING([--without-server],
			    [do not build server])],
	    [want_server=$withval])
AC_ARG_WITH([gtk],
	    [AS_HELP_STRING([--without-gtk],
			    [do not build GTK+ client])],
	    [want_gtk=$withval])
AC_ARG_WITH([python],
	    [AS_HELP_STRING([--without-python],
			    [do not build Python support])],
	    [want_python=$withval])

subdirs="scripts lib clients doc examples debian"

if test $want_server = yes; then
  subdirs="${subdirs} server plugins driver templates sounds images"
fi
if test $want_gtk = yes; then
  subdirs="${subdirs} disobedience"
  if test $want_server = no; then
    subdirs="${subdirs} images"
  fi
fi
if test $want_python = yes; then
  AM_PATH_PYTHON([2.4])
  subdirs="${subdirs} python tests"
fi
AC_SUBST([subdirs])

# libtool config
AC_LIBTOOL_DLOPEN
AC_DISABLE_STATIC

AC_PROG_LIBTOOL

AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
  rjk_cv_gnused="not found"
  for candidate in sed gsed; do
    if $candidate --version >/dev/null 2>&1; then
      rjk_cv_gnused=$candidate 
    fi
  done
])
GNUSED="${GNUSED:-$rjk_cv_gnused}"
if test "$GNUSED" = "not found"; then
  AC_MSG_ERROR([GNU sed is required to build this program])
fi
AC_SUBST([GNUSED])

missing_libraries=""
missing_headers=""
missing_functions=""

AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])

# Macs might have libraries under fink's root
AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
if test "x$FINK" != xnone; then
  AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
    rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
  ])
  finkdir="${rjk_cv_finkprefix}"
  finkbindir="${rjk_cv_finkprefix}/bin"
  CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/gc -I${rjk_cv_finkprefix}/include"
  if test $want_server = yes; then
    CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
  fi
  LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
else
  finkbindir=""
fi
AC_SUBST([finkdir])
AC_SUBST([finkbindir])

# Checks for libraries.
# We save up a list of missing libraries that we can't do without
# and report them all at once.
AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
            [missing_libraries="$missing_libraries libgc"])
AC_CHECK_LIB(gcrypt, gcry_md_open,
             [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
            [missing_libraries="$missing_libraries libgcrypt"])
AC_CHECK_LIB(pcre, pcre_compile,
	     [AC_SUBST(LIBPCRE,[-lpcre])],
	     [missing_libraries="$missing_libraries libpcre"])
if test $want_alsa = yes; then
  AC_CHECK_LIB([asound], [snd_pcm_open],
               [AC_SUBST(LIBASOUND,[-lasound])])
fi
if test $want_server = yes; then
  RJK_CHECK_LIB(db, db_create, [#include <db.h>],
	       [AC_SUBST(LIBDB,[-ldb])],
	       [missing_libraries="$missing_libraries libdb"])
  AC_CHECK_LIB(vorbis, vorbis_info_clear,
	       [:],
	       [missing_libraries="$missing_libraries libvorbis"])
  AC_CHECK_LIB(vorbisfile, ov_open,
	       [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
	       [missing_libraries="$missing_libraries libvorbisfile"],
	       [-lvorbis])
  AC_CHECK_LIB(mad, mad_stream_init,
	       [AC_SUBST(LIBMAD,[-lmad])],
	       [missing_libraries="$missing_libraries libmad"])
  AC_CHECK_LIB([ao], [ao_initialize],
	       [AC_SUBST(LIBAO,[-lao])],
	       [missing_libraries="$missing_libraries libao"])
  AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
	       [AC_SUBST(LIBFLAC,[-lFLAC])],
	       [missing_libraries="$missing_libraries libFLAC"])
fi
AC_CHECK_LIB([pthread], [pthread_create],
             [AC_SUBST(LIBPTHREAD,[-lpthread])],
	     [missing_libraries="$missing_libraries libpthread"])

if test $want_gtk = yes; then
  AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
  AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
fi

# Some platforms have iconv already
AC_CHECK_FUNC(iconv_open, [:],
              [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
                            [AC_SUBST(LIBICONV,[-liconv])],
                            [missing_functions="$missing_functions iconv_open"])])
AC_CHECK_FUNC([gethostbyname],[:],[
  AC_CHECK_LIB(nsl,gethostbyname,
               [AC_SUBST(LIBNSL,[-lnsl])],
               [missing_functions="$missing_functions gethostbyname"])])
AC_CHECK_FUNC([socket],[:],[
  AC_CHECK_LIB(socket,socket,
               [AC_SUBST(LIBSOCKET,[-lsocket])],
               [missing_functions="$missing_functions socket"])])
AC_CHECK_FUNC([dlopen],[:],[
  AC_CHECK_LIB(dl,dlopen,
	       [AC_SUBST(LIBDL,[-ldl])],
	       [missing_functions="$missing_functions dlopen"])])

if test ! -z "$missing_libraries"; then
  AC_MSG_ERROR([missing libraries:$missing_libraries])
fi

# Checks for header files.
RJK_FIND_GC_H
if test $want_oss = yes; then
  AC_CHECK_HEADERS([sys/soundcard.h])
fi
if test $want_alsa = yes; then
  AC_CHECK_HEADERS([alsa/asoundlib.h])
fi
if test $want_coreaudio = yes; then
  AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
fi
AC_CHECK_HEADERS([inttypes.h])
# We don't bother checking very standard stuff
# Compilation will fail if any of these headers are missing, so we
# check for them here and fail early.
if test $want_server = yes; then
  AC_CHECK_HEADERS([db.h],[:],[
    missing_headers="$missing_headers $ac_header"
  ])
  AC_CHECK_HEADERS([FLAC/file_decoder.h])
fi
AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
		 getopt.h iconv.h langinfo.h \
		 pcre.h sys/ioctl.h \
	         syslog.h unistd.h],[:],[
  missing_headers="$missing_headers $ac_header"
])

if test ! -z "$missing_headers"; then
  AC_MSG_ERROR([missing headers:$missing_headers])
fi

# We require that libpcre support UTF-8
RJK_REQUIRE_PCRE_UTF8([-lpcre])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T
AC_C_INLINE
AC_C_BIGENDIAN
AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
#include <netinet/in.h>])

# enable -Werror when we check for certain characteristics:

old_CFLAGS="${CFLAGS}"
CFLAGS="${CFLAGS} $gcc_werror"
AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])

# Some GCC invocations warn for converting function pointers to void *.
# This is fair enough, as it's technically forbidden, but we use dlsym()
# which can pretty much only exist if object and function pointers are
# interconvertable.  So we disable -Werror if need be.
if test ! -z "$gcc_werror"; then
  AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
		 [rjk_cv_function_pointer_cast],[
    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
  void somefunction(void);],
		      [(void *)somefunction])],
		      [rjk_cv_function_pointer_cast=yes],
		      [rjk_cv_function_pointer_cast=no])])
  if test $rjk_cv_function_pointer_cast = no; then
    gcc_werror=""
  fi
fi

CFLAGS="${old_CFLAGS}"

# gcrypt maintainers keep changing everything.  Design your interface
# first, then implement it once, rather than getting it wrong three or
# four times and shipping between each attempt.
AC_CACHE_CHECK([for hash handle type in <grypt.h>],
               [rjk_cv_gcrypt_hash_handle],[
  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
#include <gcrypt.h>
],
               [gcry_md_hd_t h;])],
               [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
#include <gcrypt.h>
],
		 [GcryMDHd h;])],
		 [rjk_cv_gcrypt_hash_handle=GcryMDHd],
		 [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
                   [libgcrypt hash handle type])

AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
               [rjk_cv_have_gcry_error_t],[
  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
#include <gcrypt.h>
],
		 [gcry_error_t e;])],
		 [rjk_cv_have_gcry_error_t=yes],
		 [rjk_cv_have_gcry_error_t=no])])
if test $rjk_cv_have_gcry_error_t = yes; then
  AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
fi

# Checks for functions
if test $ac_cv_type_long_long = yes; then
  AC_CHECK_FUNCS([atoll strtoll],[:],[
    missing_functions="$missing_functions $ac_func"
  ])
  # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
  AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
                 [rjk_cv_strtoll_declared],[
    AC_EGREP_HEADER([strtoll], [stdlib.h],
                    [rjk_cv_strtoll_declared=yes],
                    [rjk_cv_strtoll_declared=no])])
  if test $rjk_cv_strtoll_declared = yes; then
    AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
  fi
  AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
                 [rjk_cv_atoll_declared],[
    AC_EGREP_HEADER([atoll], [stdlib.h],
                    [rjk_cv_atoll_declared=yes],
                    [rjk_cv_atoll_declared=no])])
  if test $rjk_cv_atoll_declared = yes; then
    AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
  fi
fi
AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
  missing_functions="$missing_functions $ac_func"
])
# fsync will do if fdatasync not available
AC_CHECK_FUNCS([fdatasync],[:],[
  AC_CHECK_FUNCS([fsync],
                 [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
                 [missing_functions="$missing_functions fdatasync"])])
if test ! -z "$missing_functions"; then
  AC_MSG_ERROR([missing functions:$missing_functions])
fi
if test $want_server = yes; then
  # <db.h> had better be version 3 or later
  AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
    AC_PREPROC_IFELSE([
		       #include <db.h>
		       #ifndef DB_VERSION_MAJOR
		       # error cannot determine db version
		       #endif
		       #if DB_VERSION_MAJOR < 4
		       # error inadequate db version
		       #endif
		       #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
		       # error inadequate db version
		       #endif
		      ],
		      [rjk_cv_db_version=ok],
		      [rjk_cv_db_version=inadequate])
  ])
  if test $rjk_cv_db_version != ok; then
    AC_MSG_ERROR([need db.h version at least 4.2])
  fi
fi

if test "x$GCC" = xyes; then
  # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
  AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
    old_CC="$CC"
    if test $GCC = yes; then
      CC="$CC -Wall -Werror"
    fi
    AC_COMPILE_IFELSE([
      static int x(char *f) {
       return *f;
      }
      int z(const char *g) {
	return x((char *)g);
      }],
      [rjk_cv_pr29478=no],
      [rjk_cv_pr29478=yes]
    )
    CC="$old_CC"
  ])
  if test $rjk_cv_pr29478 = yes; then
    gcc_werror=''
  fi

  # a reasonable default set of warnings
  CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
	-Wwrite-strings -Wmissing-prototypes \
	-Wmissing-declarations -Wnested-externs"

  # Fix up GTK+ and GLib compiler flags
  GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
  GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"

  if test "$gcc_werror" != ''; then
    # GCC 2.95 doesn't know to ignore warnings from system headers
    AC_CACHE_CHECK([whether -Werror is usable],
		    rjk_cv_werror, [
      save_CFLAGS="${CFLAGS}"
      CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
      AC_TRY_COMPILE([#include <gtk/gtk.h>],
		     [],
		     [rjk_cv_werror=yes],
		     [rjk_cv_werror=no])
      CFLAGS="${save_CFLAGS}"
    ])
    if test $rjk_cv_werror = no; then
      gcc_werror=''
    fi
  fi
  CC="${CC} $gcc_werror"

  # for older GCCs that don't know %ju (etc)
  AC_CACHE_CHECK([whether -Wno-format is required],
		 rjk_cv_noformat,
		 AC_TRY_COMPILE([#include <stdio.h>
#include <stdint.h>
],
			        [printf("%ju", (uintmax_t)0);],
				[rjk_cv_noformat=no],
				[rjk_cv_noformat=yes]))
  if test $rjk_cv_noformat = yes; then
    CC="${CC} -Wno-format"
  fi

  AC_CACHE_CHECK([whether -Wshadow is OK],
		 rjk_cv_shadow,
                 oldCC="${CC}"
		 CC="${CC} -Wshadow"
		 [AC_TRY_COMPILE([
#include <unistd.h>
#include <vorbis/vorbisfile.h>
],
				[],
				[rjk_cv_shadow=yes],
				[rjk_cv_shadow=no])
		 CC="${oldCC}"])
  if test $rjk_cv_shadow = yes; then
    CC="${CC} -Wshadow"
  fi
fi

RJK_GCOV

AH_BOTTOM([#ifdef __GNUC__
# define attribute(x) __attribute__(x)
#else
# define attribute(x)
#endif])

AC_CONFIG_FILES([Makefile
		 templates/Makefile
		 images/Makefile
		 scripts/Makefile
		 lib/Makefile
		 server/Makefile
		 clients/Makefile
		 disobedience/Makefile
		 doc/Makefile
		 plugins/Makefile
		 driver/Makefile
		 debian/Makefile
		 sounds/Makefile
		 python/Makefile
		 examples/Makefile
		 tests/Makefile])
AC_OUTPUT

if test $GCC = yes && test "$gcc_werror" = ''; then
  AC_MSG_WARN([building without -Werror])
fi
if test $want_python = no; then
  AC_MSG_WARN([cannot run the test suit without Python])
fi
Commit	Line	Data
460b9539	1	# Process this file with autoconf to produce a configure script.
	2	#
	3	# This file is part of DisOrder.
dea8f8aa	4	# Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
313acc77	5	# Portions copyright (C) 2007 Ross Younger
460b9539	6	#
	7	# This program is free software; you can redistribute it and/or modify
	8	# it under the terms of the GNU General Public License as published by
	9	# the Free Software Foundation; either version 2 of the License, or
	10	# (at your option) any later version.
	11	#
	12	# This program is distributed in the hope that it will be useful, but
	13	# WITHOUT ANY WARRANTY; without even the implied warranty of
	14	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	15	# General Public License for more details.
	16	#
	17	# You should have received a copy of the GNU General Public License
	18	# along with this program; if not, write to the Free Software
	19	# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
	20	# USA
	21	#
	22
5fbe4ce2	23	AC_INIT([disorder], [2.0+], [richard+disorder@sfere.greenend.org.uk])
460b9539	24	AC_CONFIG_AUX_DIR([config.aux])
5fbe4ce2	25	AM_INIT_AUTOMAKE(disorder, [2.0+])
460b9539	26	AC_CONFIG_SRCDIR([server/disorderd.c])
	27	AM_CONFIG_HEADER([config.h])
	28
dea8f8aa RK	29	# Find host type
	30	AC_CANONICAL_HOST
	31
460b9539	32	# What we want to build
460b9539	33	want_gtk=yes
	34	want_python=yes
	35
e2f0c461 RK	36	# APIs we want
	37	want_alsa=yes
	38	want_oss=yes
	39	want_coreaudio=yes
	40
a9f0ad12 RK	41	# Checks for programs.
	42	AC_PROG_CC
	43	AC_SET_MAKE
	44	if test "x$GCC" = xyes; then
	45	gcc_werror=-Werror
	46	else
	47	gcc_werror=""
	48	fi
	49
e2f0c461 RK	50	AC_ARG_WITH([alsa],
	51	[AS_HELP_STRING([--without-alsa],
	52	[do not build with ALSA support])],
	53	[want_alsa=$withval])
	54	AC_ARG_WITH([oss],
	55	[AS_HELP_STRING([--without-oss],
	56	[do not build with OSS support])],
	57	[want_oss=$withval])
	58	AC_ARG_WITH([coreaudio],
	59	[AS_HELP_STRING([--without-coreaudio],
	60	[do not build with Core Audio support])],
	61	[want_coreaudio=$withval])
	62
a9f0ad12	63	AC_MSG_CHECKING([for a known target platform])
dea8f8aa	64	case "$host" in
a9f0ad12	65	empeg )
e3426f7b	66	AC_MSG_RESULT([empeg car stereo])
a9f0ad12 RK	67	AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
	68	# work around broken toolchain
	69	AC_CHECK_LIB([gpg-error], [gpg_strerror])
e3426f7b	70	AC_CHECK_LIB([pthread], [pthread_create])
a9f0ad12	71	want_server=no
a9f0ad12	72	;;
dea8f8aa	73	linux \| Linux )
a9f0ad12	74	AC_MSG_RESULT([Linux])
e3426f7b	75	want_server=yes
dea8f8aa	76	;;
9086a105	77	-apple-darwin )
e3426f7b	78	AC_MSG_RESULT([Mac OS X])
e2f0c461 RK	79	want_server=yes
	80	if test $want_coreaudio = yes; then
	81	COREAUDIO="-framework CoreAudio"
	82	fi
0ec4c5e6	83	browser=open
8fcf5c48 RK	84	AC_MSG_CHECKING([Mac OS X target version])
	85	# We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
	86	# behaviour. But we provide a command line option to override it and
	87	# we default to wide support instead of supporting only the build platform.
	88	#
	89	# Currently if you ask for 10.5 you will get a deprecation warning
	90	# when building the CoreAudio support code. For the time being the
	91	# answer to this is "don't do that then". If a good reason to ask
	92	# for a 10.5 deployment target emerges then this will be fixed.
	93	if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
	94	MACOSX_DEPLOYMENT_TARGET=10.0
	95	fi
	96	AC_ARG_WITH([deployment-target],
	97	[AS_HELP_STRING([--with-deployment-target=TARGET],
	98	[set target OS X version])],
	99	[MACOSX_DEPLOYMENT_TARGET=$withval])
	100	# Convert to desired format
	101	underscored=`echo $MACOSX_DEPLOYMENT_TARGET\|sed 's/\./_/'`
	102	minver="MAC_OS_X_VERSION_$underscored"
	103	AC_MSG_RESULT([$minver])
	104	AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
	105	[define to minimum version of Mac OS X to support])
9086a105	106	;;
70f47acd RK	107	-freebsd )
	108	AC_MSG_RESULT([FreeBSD])
	109	want_server=yes
edbd470f	110	# Ports install to /usr/local but the compiler stupidly doesn't look
edbd470f	111	# there by default
70f47acd	112	LDFLAGS="${LDFLAGS} -L/usr/local/lib"
e6ea27d8	113	CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
edbd470f	114	# libdb installs elsewhere again
edbd470f	115	LDFLAGS="${LDFLAGS} -L/usr/local/lib/db44"
e6ea27d8	116	CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/db44"
70f47acd	117	;;
dea8f8aa	118	* )
a9f0ad12	119	AC_MSG_RESULT([unknown, winging it])
e3426f7b	120	want_server=no
dea8f8aa RK	121	;;
dea8f8aa RK	122	esac
9086a105	123	AC_SUBST([COREAUDIO])
dea8f8aa	124
f486ea18 RK	125	AC_ARG_WITH([browser],
	126	[AS_HELP_STRING([--with-browser=BROWSER],
	127	[use BROWSER to display HTML])],
	128	[browser=$withval])
	129
	130	AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
	131	rjk_cv_browser=UNKNOWN
58d97da4	132	for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
f486ea18 RK	133	if type $candidate >/dev/null 2>&1; then
	134	rjk_cv_browser="$candidate"
	135	break
	136	fi
	137	done
	138	])
	139	if test -z "$browser"; then
	140	browser="$rjk_cv_browser"
	141	fi
	142	AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
	143
460b9539	144	AC_ARG_WITH([server],
	145	[AS_HELP_STRING([--without-server],
	146	[do not build server])],
	147	[want_server=$withval])
	148	AC_ARG_WITH([gtk],
	149	[AS_HELP_STRING([--without-gtk],
	150	[do not build GTK+ client])],
	151	[want_gtk=$withval])
	152	AC_ARG_WITH([python],
	153	[AS_HELP_STRING([--without-python],
	154	[do not build Python support])],
	155	[want_python=$withval])
	156
1798e51d	157	subdirs="scripts lib clients doc examples debian"
460b9539	158
	159	if test $want_server = yes; then
	160	subdirs="${subdirs} server plugins driver templates sounds images"
	161	fi
460b9539	162	if test $want_gtk = yes; then
	163	subdirs="${subdirs} disobedience"
	164	if test $want_server = no; then
	165	subdirs="${subdirs} images"
	166	fi
	167	fi
56fac00d RK	168	if test $want_python = yes; then
	169	AM_PATH_PYTHON([2.4])
	170	subdirs="${subdirs} python tests"
	171	fi
460b9539	172	AC_SUBST([subdirs])
	173
	174	# libtool config
	175	AC_LIBTOOL_DLOPEN
	176	AC_DISABLE_STATIC
	177
	178	AC_PROG_LIBTOOL
	179
edbd470f	180	AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
	181	rjk_cv_gnused="not found"
	182	for candidate in sed gsed; do
	183	if $candidate --version >/dev/null 2>&1; then
	184	rjk_cv_gnused=$candidate
	185	fi
	186	done
	187	])
	188	GNUSED="${GNUSED:-$rjk_cv_gnused}"
	189	if test "$GNUSED" = "not found"; then
	190	AC_MSG_ERROR([GNU sed is required to build this program])
	191	fi
	192	AC_SUBST([GNUSED])
	193
460b9539	194	missing_libraries=""
	195	missing_headers=""
	196	missing_functions=""
	197
	198	AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
	199
	200	# Macs might have libraries under fink's root
	201	AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
	202	if test "x$FINK" != xnone; then
	203	AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
	204	rjk_cv_finkprefix="`echo "$FINK" \| sed 's,/bin/fink$,,'`"
	205	])
f9592fe7	206	finkdir="${rjk_cv_finkprefix}"
e83d0967	207	finkbindir="${rjk_cv_finkprefix}/bin"
762f2539	208	CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/gc -I${rjk_cv_finkprefix}/include"
460b9539	209	if test $want_server = yes; then
	210	CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
	211	fi
	212	LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
e83d0967 RK	213	else
e83d0967 RK	214	finkbindir=""
460b9539	215	fi
f9592fe7	216	AC_SUBST([finkdir])
e83d0967	217	AC_SUBST([finkbindir])
460b9539	218
	219	# Checks for libraries.
	220	# We save up a list of missing libraries that we can't do without
	221	# and report them all at once.
	222	AC_CHECK_LIB(gc, GC_malloc, [AC_SUBST(LIBGC,[-lgc])],
	223	[missing_libraries="$missing_libraries libgc"])
	224	AC_CHECK_LIB(gcrypt, gcry_md_open,
	225	[AC_SUBST(LIBGCRYPT,[-lgcrypt])],
	226	[missing_libraries="$missing_libraries libgcrypt"])
	227	AC_CHECK_LIB(pcre, pcre_compile,
	228	[AC_SUBST(LIBPCRE,[-lpcre])],
	229	[missing_libraries="$missing_libraries libpcre"])
e2f0c461 RK	230	if test $want_alsa = yes; then
	231	AC_CHECK_LIB([asound], [snd_pcm_open],
	232	[AC_SUBST(LIBASOUND,[-lasound])])
	233	fi
460b9539	234	if test $want_server = yes; then
	235	RJK_CHECK_LIB(db, db_create, [#include <db.h>],
	236	[AC_SUBST(LIBDB,[-ldb])],
	237	[missing_libraries="$missing_libraries libdb"])
	238	AC_CHECK_LIB(vorbis, vorbis_info_clear,
	239	[:],
	240	[missing_libraries="$missing_libraries libvorbis"])
	241	AC_CHECK_LIB(vorbisfile, ov_open,
	242	[AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
	243	[missing_libraries="$missing_libraries libvorbisfile"],
	244	[-lvorbis])
	245	AC_CHECK_LIB(mad, mad_stream_init,
	246	[AC_SUBST(LIBMAD,[-lmad])],
	247	[missing_libraries="$missing_libraries libmad"])
	248	AC_CHECK_LIB([ao], [ao_initialize],
	249	[AC_SUBST(LIBAO,[-lao])],
	250	[missing_libraries="$missing_libraries libao"])
c57f1201	251	AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
	252	[AC_SUBST(LIBFLAC,[-lFLAC])],
	253	[missing_libraries="$missing_libraries libFLAC"])
d19ccd72	254	fi
edbd470f	255	AC_CHECK_LIB([pthread], [pthread_create],
	256	[AC_SUBST(LIBPTHREAD,[-lpthread])],
	257	[missing_libraries="$missing_libraries libpthread"])
460b9539	258
	259	if test $want_gtk = yes; then
	260	AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
	261	AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
	262	fi
	263
	264	# Some platforms have iconv already
	265	AC_CHECK_FUNC(iconv_open, [:],
	266	[RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
	267	[AC_SUBST(LIBICONV,[-liconv])],
	268	[missing_functions="$missing_functions iconv_open"])])
	269	AC_CHECK_FUNC([gethostbyname],[:],[
	270	AC_CHECK_LIB(nsl,gethostbyname,
	271	[AC_SUBST(LIBNSL,[-lnsl])],
	272	[missing_functions="$missing_functions gethostbyname"])])
	273	AC_CHECK_FUNC([socket],[:],[
	274	AC_CHECK_LIB(socket,socket,
	275	[AC_SUBST(LIBSOCKET,[-lsocket])],
	276	[missing_functions="$missing_functions socket"])])
	277	AC_CHECK_FUNC([dlopen],[:],[
	278	AC_CHECK_LIB(dl,dlopen,
	279	[AC_SUBST(LIBDL,[-ldl])],
	280	[missing_functions="$missing_functions dlopen"])])
	281
	282	if test ! -z "$missing_libraries"; then
	283	AC_MSG_ERROR([missing libraries:$missing_libraries])
	284	fi
	285
460b9539	286	# Checks for header files.
460b9539	287	RJK_FIND_GC_H
e2f0c461 RK	288	if test $want_oss = yes; then
	289	AC_CHECK_HEADERS([sys/soundcard.h])
	290	fi
	291	if test $want_alsa = yes; then
	292	AC_CHECK_HEADERS([alsa/asoundlib.h])
	293	fi
	294	if test $want_coreaudio = yes; then
	295	AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
	296	fi
	297	AC_CHECK_HEADERS([inttypes.h])
146e86fb	298	# We don't bother checking very standard stuff
460b9539	299	# Compilation will fail if any of these headers are missing, so we
460b9539	300	# check for them here and fail early.
460b9539	301	if test $want_server = yes; then
	302	AC_CHECK_HEADERS([db.h],[:],[
	303	missing_headers="$missing_headers $ac_header"
	304	])
762806f1	305	AC_CHECK_HEADERS([FLAC/file_decoder.h])
460b9539	306	fi
	307	AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
	308	getopt.h iconv.h langinfo.h \
	309	pcre.h sys/ioctl.h \
	310	syslog.h unistd.h],[:],[
	311	missing_headers="$missing_headers $ac_header"
	312	])
	313
	314	if test ! -z "$missing_headers"; then
	315	AC_MSG_ERROR([missing headers:$missing_headers])
	316	fi
	317
70f47acd RK	318	# We require that libpcre support UTF-8
	319	RJK_REQUIRE_PCRE_UTF8([-lpcre])
	320
460b9539	321	# Checks for typedefs, structures, and compiler characteristics.
	322	AC_C_CONST
	323	AC_TYPE_SIZE_T
	324	AC_C_INLINE
5330d674	325	AC_C_BIGENDIAN
460b9539	326	AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
	327	#include <netinet/in.h>])
	328
	329	# enable -Werror when we check for certain characteristics:
	330
	331	old_CFLAGS="${CFLAGS}"
	332	CFLAGS="${CFLAGS} $gcc_werror"
	333	AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
	334
	335	# Some GCC invocations warn for converting function pointers to void *.
	336	# This is fair enough, as it's technically forbidden, but we use dlsym()
	337	# which can pretty much only exist if object and function pointers are
	338	# interconvertable. So we disable -Werror if need be.
	339	if test ! -z "$gcc_werror"; then
	340	AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
	341	[rjk_cv_function_pointer_cast],[
	342	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
	343	void somefunction(void);],
	344	[(void *)somefunction])],
	345	[rjk_cv_function_pointer_cast=yes],
	346	[rjk_cv_function_pointer_cast=no])])
	347	if test $rjk_cv_function_pointer_cast = no; then
	348	gcc_werror=""
	349	fi
	350	fi
	351
	352	CFLAGS="${old_CFLAGS}"
	353
	354	# gcrypt maintainers keep changing everything. Design your interface
	355	# first, then implement it once, rather than getting it wrong three or
	356	# four times and shipping between each attempt.
	357	AC_CACHE_CHECK([for hash handle type in <grypt.h>],
	358	[rjk_cv_gcrypt_hash_handle],[
	359	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
	360	#include <gcrypt.h>
	361	],
	362	[gcry_md_hd_t h;])],
	363	[rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
	364	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
	365	#include <gcrypt.h>
	366	],
	367	[GcryMDHd h;])],
	368	[rjk_cv_gcrypt_hash_handle=GcryMDHd],
	369	[rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
	370	AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
	371	[libgcrypt hash handle type])
	372
	373	AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
	374	[rjk_cv_have_gcry_error_t],[
	375	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
	376	#include <gcrypt.h>
	377	],
	378	[gcry_error_t e;])],
	379	[rjk_cv_have_gcry_error_t=yes],
	380	[rjk_cv_have_gcry_error_t=no])])
	381	if test $rjk_cv_have_gcry_error_t = yes; then
	382	AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
	383	fi
	384
	385	# Checks for functions
	386	if test $ac_cv_type_long_long = yes; then
	387	AC_CHECK_FUNCS([atoll strtoll],[:],[
	388	missing_functions="$missing_functions $ac_func"
	389	])
390	# Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
391	AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
392	[rjk_cv_strtoll_declared],[
393	AC_EGREP_HEADER([strtoll], [stdlib.h],
394	[rjk_cv_strtoll_declared=yes],
395	[rjk_cv_strtoll_declared=no])])
396	if test $rjk_cv_strtoll_declared = yes; then
397	AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
398	fi
399	AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
400	[rjk_cv_atoll_declared],[
401	AC_EGREP_HEADER([atoll], [stdlib.h],
402	[rjk_cv_atoll_declared=yes],
403	[rjk_cv_atoll_declared=no])])
404	if test $rjk_cv_atoll_declared = yes; then
405	AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
406	fi
407	fi
408	AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
409	missing_functions="$missing_functions $ac_func"
410	])
411	# fsync will do if fdatasync not available
412	AC_CHECK_FUNCS([fdatasync],[:],[
413	AC_CHECK_FUNCS([fsync],
414	[AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
415	[missing_functions="$missing_functions fdatasync"])])
416	if test ! -z "$missing_functions"; then
417	AC_MSG_ERROR([missing functions:$missing_functions])
418	fi
419	if test $want_server = yes; then
420	# <db.h> had better be version 3 or later
421	AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
422	AC_PREPROC_IFELSE([
423	#include <db.h>
424	#ifndef DB_VERSION_MAJOR
425	# error cannot determine db version
426	#endif
427	#if DB_VERSION_MAJOR < 4
428	# error inadequate db version
429	#endif
f4687532	430	#if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
460b9539	431	# error inadequate db version
	432	#endif
	433	],
	434	[rjk_cv_db_version=ok],
	435	[rjk_cv_db_version=inadequate])
	436	])
	437	if test $rjk_cv_db_version != ok; then
	438	AC_MSG_ERROR([need db.h version at least 4.2])
	439	fi
	440	fi
	441
	442	if test "x$GCC" = xyes; then
f368d6c7 RK	443	# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
	444	AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
	445	old_CC="$CC"
	446	if test $GCC = yes; then
	447	CC="$CC -Wall -Werror"
	448	fi
	449	AC_COMPILE_IFELSE([
	450	static int x(char *f) {
	451	return *f;
	452	}
	453	int z(const char *g) {
	454	return x((char *)g);
	455	}],
	456	[rjk_cv_pr29478=no],
	457	[rjk_cv_pr29478=yes]
	458	)
	459	CC="$old_CC"
	460	])
	461	if test $rjk_cv_pr29478 = yes; then
	462	gcc_werror=''
	463	fi
	464
460b9539	465	# a reasonable default set of warnings
	466	CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
	467	-Wwrite-strings -Wmissing-prototypes \
	468	-Wmissing-declarations -Wnested-externs"
	469
	470	# Fix up GTK+ and GLib compiler flags
	471	GTK_CFLAGS="`echo \"$GTK_CFLAGS\"\|sed 's/-I/-isystem /g'`"
	472	GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"\|sed 's/-I/-isystem /g'`"
	473
f368d6c7 RK	474	if test "$gcc_werror" != ''; then
	475	# GCC 2.95 doesn't know to ignore warnings from system headers
	476	AC_CACHE_CHECK([whether -Werror is usable],
	477	rjk_cv_werror, [
	478	save_CFLAGS="${CFLAGS}"
	479	CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
	480	AC_TRY_COMPILE([#include <gtk/gtk.h>],
	481	[],
	482	[rjk_cv_werror=yes],
	483	[rjk_cv_werror=no])
	484	CFLAGS="${save_CFLAGS}"
	485	])
	486	if test $rjk_cv_werror = no; then
	487	gcc_werror=''
	488	fi
460b9539	489	fi
	490	CC="${CC} $gcc_werror"
	491
	492	# for older GCCs that don't know %ju (etc)
9a5f7aba	493	AC_CACHE_CHECK([whether -Wno-format is required],
460b9539	494	rjk_cv_noformat,
	495	AC_TRY_COMPILE([#include <stdio.h>
	496	#include <stdint.h>
	497	],
	498	[printf("%ju", (uintmax_t)0);],
	499	[rjk_cv_noformat=no],
	500	[rjk_cv_noformat=yes]))
	501	if test $rjk_cv_noformat = yes; then
	502	CC="${CC} -Wno-format"
	503	fi
	504
9a5f7aba	505	AC_CACHE_CHECK([whether -Wshadow is OK],
460b9539	506	rjk_cv_shadow,
	507	oldCC="${CC}"
	508	CC="${CC} -Wshadow"
	509	[AC_TRY_COMPILE([
	510	#include <unistd.h>
	511	#include <vorbis/vorbisfile.h>
	512	],
	513	[],
	514	[rjk_cv_shadow=yes],
	515	[rjk_cv_shadow=no])
	516	CC="${oldCC}"])
	517	if test $rjk_cv_shadow = yes; then
	518	CC="${CC} -Wshadow"
	519	fi
460b9539	520	fi
460b9539	521
1a00f590 RK	522	RJK_GCOV
1a00f590 RK	523
460b9539	524	AH_BOTTOM([#ifdef __GNUC__
	525	# define attribute(x) __attribute__(x)
	526	#else
	527	# define attribute(x)
	528	#endif])
	529
	530	AC_CONFIG_FILES([Makefile
	531	templates/Makefile
	532	images/Makefile
	533	scripts/Makefile
	534	lib/Makefile
	535	server/Makefile
	536	clients/Makefile
	537	disobedience/Makefile
	538	doc/Makefile
	539	plugins/Makefile
	540	driver/Makefile
	541	debian/Makefile
	542	sounds/Makefile
	543	python/Makefile
c5dbcd79 RK	544	examples/Makefile
c5dbcd79 RK	545	tests/Makefile])
460b9539	546	AC_OUTPUT
f368d6c7 RK	547
	548	if test $GCC = yes && test "$gcc_werror" = ''; then
	549	AC_MSG_WARN([building without -Werror])
	550	fi
56fac00d RK	551	if test $want_python = no; then
	552	AC_MSG_WARN([cannot run the test suit without Python])
	553	fi