dnl -*-m4-*-
dnl
dnl $Id: configure.in,v 1.4 2003/11/29 23:38:37 mdw Exp $
dnl
dnl Configuration script
dnl
dnl (c) 2001 Mark Wooding
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of Anag: a simple wordgame helper.
dnl
dnl Anag is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl 
dnl Anag is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl 
dnl You should have received a copy of the GNU General Public License
dnl along with Anag; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl ----- Revision history --------------------------------------------------
dnl
dnl $Log: configure.in,v $
dnl Revision 1.4  2003/11/29 23:38:37  mdw
dnl Debianization.
dnl
dnl Revision 1.3  2002/08/11 12:59:00  mdw
dnl New Tcl/Tk interface; regular expression support.
dnl
dnl Revision 1.2  2001/02/06 10:06:25  mdw
dnl Find a suitable Java compiler.  If there isn't one, don't compile the
dnl Java bits.
dnl
dnl Revision 1.1  2001/02/04 17:14:42  mdw
dnl Initial checkin
dnl

AC_INIT(anag.c)
AM_INIT_AUTOMAKE(anag, 1.1.0)
AM_CONFIG_HEADER(config.h)
AC_PROG_CC
mdw_GCC_FLAGS

AC_CHECK_PROGS([JAVAC], [jikes javac], [none])
if test "$JAVAC" = "none"; then
  AC_MSG_WARN([No Java compiler found])
  JARFILES=""
else
  JARFILES="anag.jar"
fi
AC_SUBST([JARFILES])

AC_CHECK_PROGS([WISH], [wish wish8], [none])
if test "$WISH" = "none"; then
  AC_MSG_WARN([No Tcl/Tk interpreter found])
  TKPROGS=""
else
  TKPROGS="anag-gui"
fi
AC_SUBST([TKPROGS])

EXTNODE=""
AC_CHECK_FUNCS([regcomp])
mdw_CHECK_MANYLIBS([pcre_fullinfo], [pcre], [AC_DEFINE([HAVE_PCRE])])

AC_ARG_WITH(dictionary,
[  --with-dictionary=DICT  set default word list to be DICT],
[DICTIONARY=$withval],
[DICTIONARY="/usr/dict/words"])
AC_DEFINE_UNQUOTED([DICTIONARY], ["$DICTIONARY"])
AC_SUBST([DICTIONARY])

mdw_DEFINE_PATHS([
  ANAG=mdw_PATH([${bindir}])/mdw_PROG([anag])
])

AC_SUBST([ANAG])
AC_OUTPUT(Makefile anag-gui)

dnl ----- That's all, folks -------------------------------------------------