#!/usr/bin/speedy -w -- -t100 -M1

use strict qw(vars);
use CGI::SpeedyCGI qw/:standard -no_xhtml/;
use CGI qw/:standard -no_xhtml/;

sub fail ($) {
    print(header(-status=>500),
          start_html('Error'),
          h1('Error'),
          escapeHTML($_[0]),
          end_html());
    exit 0;
}

our (@sections, %section_groups, %group_elems, %graphs);

#---------- initialisation code, run once - graphs setup ----------

BEGIN {

our $R= '/var/lib/collectd/rrd/chiark.greenend.org.uk';
our $SELF= '/home/ijackson/things/rrd-graphs';

our @timeranges= (3600, map { $_*86400 } qw(1 7 28), 13*7+1, 366);

sub graph_of_group ($$$$$) {
    my ($section, $group, $elem, $basis, $args) = @_;
    $basis->{Args}= $args;
    $basis->{Slower}= 0 unless exists $basis->{Slower};
    $basis->{TimeRanges} ||= \@timeranges;
    $graphs{$section,$group,$elem}= $basis;
    if (!exists $group_elems{$section,$group}) {
	# new group then
	if (!exists $section_groups{$section}) {
	    # new section even
	    push @sections, $section;
	}
	push @{ $section_groups{$section} }, $group;
    }
    push @{ $group_elems{$section,$group} }, $elem;
}

sub graph ($$$$) {
    my ($section, $gname, $basis, $args) = @_;
    graph_of_group($section, $gname,'', $basis, $args);
}

graph('General', 'Load and processes', { },
      [
       "DEF:load=$R/load/load.rrd:shortterm:AVERAGE",
       (map { "DEF:$_=$R/processes/ps_state-$_.rrd:value:AVERAGE" }
	    qw(blocked running stopped paging sleeping zombies)),
       "AREA:running#88f:running:STACK",
       "AREA:blocked#8f8:disk wait:STACK",
       "AREA:paging#f88:paging:STACK",
       "LINE:load#000:load",
       ]);

graph('General', 'Processes', { },
      [
       (map { "DEF:$_=$R/processes/ps_state-$_.rrd:value:AVERAGE" }
	    qw(blocked running stopped paging sleeping zombies)),
       "CDEF:busy=0".(join '', map { ",$_,+" } qw(running blocked paging)),
       "AREA:sleeping#ccc:sleeping:STACK",
       "AREA:stopped#00f:stopped:STACK",
       "AREA:zombies#ff0:zombie:STACK",
       "AREA:busy#000:busy:STACK",
       ]);

graph('General', 'CPU', { Units => '[%]' },
      [
       (map {
	   my $thing= $_;
	   (map { "DEF:$thing$_=$R/cpu-$_/cpu-$thing.rrd:value:AVERAGE" }
	        (0..7)),
	   "CDEF:$thing=0".join('', map { ",$thing$_,+" } (0..7)).",8.0,/";
       } qw(idle interrupt nice softirq steal system user wait)),
       "CDEF:allintr=softirq,steal,+,interrupt,+",
       "AREA:allintr#ff0:interrupt:STACK",
       "AREA:system#88f:system:STACK",
       "AREA:user#00f:user:STACK",
       "AREA:nice#ccc:nice:STACK",
       "AREA:wait#f00:wait:STACK",
       ]);

graph('General', 'Memory', { },
      [ '-b',1024,
       (map { "DEF:swap_$_=$R/swap/swap-$_.rrd:value:AVERAGE" }
	    qw(free used cached)),
       (map { "DEF:mem_$_=$R/memory/memory-$_.rrd:value:AVERAGE" }
	    qw(buffered free used cached)),
       "CDEF:c_swap_used=0,swap_used,-",
       "CDEF:c_swap_cached=0,swap_cached,-",
       "CDEF:c_swap_free=0,swap_free,-",
       "AREA:c_swap_used#000:used swap",
       "AREA:c_swap_cached#888:\"cached\" swap:STACK",
#       "AREA:c_swap_free#88f:free swap:STACK",
       "AREA:mem_used#ff0:used memory",
       "AREA:mem_buffered#00f:page cache:STACK",
       "AREA:mem_cached#008:buffer cache:STACK",
       "AREA:mem_free#ccc:unused memory:STACK",
       ]);

graph('General', 'Network', { Units => '[/sec; tx +ve; errs x1000]' },
      [
       (map {
	   ("DEF:tx_$_=$R/interface/if_$_-eth0.rrd:tx:AVERAGE",
	    "DEF:rx_$_=$R/interface/if_$_-eth0.rrd:rx:AVERAGE",
	    "CDEF:mrx_$_=0,rx_$_,-")
	   } qw(octets packets errors)),
       (map {
	   ("CDEF:${_}_kb=${_}_octets,1024,/",
	    "CDEF:${_}_errsx=${_}_errors,1000,*")
	   } qw(mrx tx)),
       "AREA:tx_kb#080:kby",
       "LINE:tx_packets#0f0:pkts",
       "LINE:tx_errsx#000:errs",
       "AREA:mrx_kb#008:kby",
       "LINE:mrx_packets#00f:pkts",
       "LINE:mrx_errsx#444:errs",
      ]);

graph('General', 'Users', {  },
      [
       "DEF:users=$R/users/users.rrd:users:AVERAGE",
       "LINE:users#008:users"
       ]);

foreach my $src (<$R/df/df-*.rrd>) {
    my $vol= $src;
    $vol =~ s,\.rrd$,, or next;
    $vol =~ s,.*/,,;
    $vol =~ s,^df-,,;
    graph('Disk space', $vol, {
	     Slower => 1,
          },
	  [ '-A','-l',0,'-r',
	   qw(-b 1024 -l 0),
	   (map { "DEF:$_=$src:$_:AVERAGE" } qw(free used)),
	   "AREA:used#000:used:STACK",
	   "AREA:free#88f:free:STACK",
	   ]);
}

our %news_name_map;

if (!open NM, '<', "$SELF/data/news/name-map") {
    die unless $!==&ENOENT;
} else {
    while (<NM>) {
	s/^\s*//; s/\s+$//;
	next unless m/^[^\#]/;
	m/^(\S+)\s+(in|out|\*)\s+(\S+)$/ or die;
	if ($2 eq '*') {
	    $news_name_map{$1,$_}= $3 foreach qw(in out);
	} else {
	    $news_name_map{$1,$2}= $3;
	}
    }
}

our @news_graphs;

foreach my $src (<$SELF/data/news/*.rrd>) {
    my $site= $src;
    $site =~ s,\.rrd$,, or next;
    $site =~ s,.*/,,;
    $site =~ s,_(in|out)$,,;
    my $inout= $1;
    $site =~ s/^([-.0-9a-z]+)_//;
    my $us= $1; # all very well but we ignore it
    my $newsite= $news_name_map{$site,$inout};
    $site= $newsite if defined $newsite;
    next if $site eq '-';
    #my $sk= join '.', reverse split /\./, $site;
    my $sk= $site;
    $sk .= " $&" if $sk =~ s/^[^.]*(?:news|nntp|peer)[^.]*\.//;
    $sk .= " $inout";
    push @news_graphs, [ $sk, $site, $inout, $src ];
}

foreach my $siteinfo (sort { $a->[0] cmp $b->[0] } @news_graphs) {
    my ($sortkey, $site, $inout, $src)= @$siteinfo;
    graph_of_group("News", $site, $inout,
	  {
		Units => '[art/s]',
		TimeRanges => [ map { $_*86400 } qw(1 7 31), 366, 366*3 ]
	    }, $inout eq 'out' ?
	  [
	   (map { "DEF:$_=$src:$_:AVERAGE" }
	        qw(missing deferred unwanted accepted rejected body_missing)),
	   "AREA:accepted#00f:ok",
	   "AREA:body_missing#ff0:miss:STACK",
	   "AREA:rejected#f00:rej:STACK",
	   "AREA:unwanted#aaa:unw:STACK",
	   "AREA:deferred#ddd:defer:STACK",
	   ] :
	  [
	   (map { "DEF:$_=$src:$_:AVERAGE" }
	        qw(accepted refused rejected duplicate)),
	   (map { ("DEF:bytes_$_=$src:${_}_size:AVERAGE",
		   "CDEF:kb_$_=bytes_$_,1024,/")
	      } qw(accepted duplicate)),
	   "AREA:accepted#00f:ok:STACK",
	   "AREA:rejected#f00:rej:STACK",
	   "AREA:duplicate#000:dupe:STACK",
	   "AREA:refused#aaa:unw:STACK",
	   "CDEF:kb_accepted_smooth=kb_accepted,<interval/60>,TREND",
	   "LINE:kb_duplicate#ff0:kb dupe",
	   "LINE:kb_accepted_smooth#008:~kb",
	   ]);
}

}

#---------- right, that was the initialisation ----------

our $self= url(-relative=>1);

if (param('debug')) {
    print "Content-Type: text/plain\n\n";
}

our @navsettings;

@navsettings= ();

sub navsetting ($) {
    my ($nav) = @_;
    my $var= $nav->{Variable};
    $$var= param($nav->{Param});
    $$var= $nav->{Default} if !defined $$var;
    die $nav->{Param} unless grep { $_ eq $$var } @{ $nav->{Values} };
    push @navsettings, $nav;
}

our $section;

navsetting({
    Desc => 'Section',
    Param => 'section',
    Variable => \$section,
    Default => $sections[0],
    Values => [@sections],
    Show => sub { return $_[0]; }
});


sub num_param ($$$$) {
    my ($param,$def,$min,$max) = @_;
    my $v= param($param);
    return $def if !defined $v;
    $v =~ m/^([1-9]\d{0,8})$/ or die;
    $v= $1;
    die unless $v >= $min && $v <= $max;
    return $v + 0;
}

our $group= param('graph');

our $elem= param('elem');
if (defined $elem) {
    my $g= $graphs{$section,$group,$elem};
    die unless $g;

    my $width= num_param('w',370,100,1600);
    my $height= num_param('h',200,100,1600);

    my $sloth= param('sloth');
    die unless defined $sloth;
    $sloth =~ m/^(\d+)$/ or die;
    $sloth= $1+0;
    my $end= $g->{TimeRanges}[$sloth];
    die unless defined $end;

    my $cacheid= "$section!$group!$elem!$sloth!$width!$height";
    my $cachepath= "cache/$cacheid.png";

    my @args= @{ $g->{Args} };
    s,\<interval/(\d+)\>, $end/$1 ,ge foreach @args;
    unshift @args, qw(--end now --start), "end-${end}s";
    
    my $title= $group;
    if (length $elem) { $title.= " $elem"; }

    $title .= " $g->{Units}" if $g->{Units};
    unshift @args, '-t', $title, '-w',$width, '-h',$height;
    unshift @args, qw(-a PNG --full-size-mode);

    if (param('debug')) {
        print((join "\n",@args),"\n"); exit 0;
    }

#print STDERR "||| ",(join ' ', map { "'$_'" } @args)." |||\n";
    exec(qw(sh -ec), <<'END', 'x', $cachepath, @args);
        p="$1"; shift
        rrdtool graph "$p" --lazy "$@" >/dev/null
	printf "Content-Type: image/png\n\n"
	exec cat "$p"
END
    die $!;
}

sub start_page ($) {
    my ($title) = @_;
    print header(), start_html($title);
    my $outerdelim= '';
    foreach my $nav (@navsettings) {
	print $outerdelim;
	print $nav->{Desc}, ": ";
	my $delim= '';
	my $current= $nav->{Variable};  $current= $$current;
	foreach my $couldbe (@{ $nav->{Values} }) {
	    print $delim;
	    my $show= $nav->{Show}($couldbe);
	    if ($couldbe eq $current) {
		print "<b>$show</b>";
	    } else {
		my $u= $self;
		my $delim2= '?';
		foreach my $nav2 (@navsettings) {
		    my $current2= $nav2->{Variable};  $current2= $$current2;
		    $current2= $couldbe if $nav2->{Param} eq $nav->{Param};
		    next if $current2 eq $nav2->{Default};
		    $u .= $delim2;  $u .= "$nav2->{Param}=$current2";
		    $delim2= '&';
	        }
		print a({href=>$u}, $show);
	    }
	    $delim= ' | ';
	}
	$outerdelim= "<br>\n";
    }
    print "\n";

    print h1("$title");
}

our $detail= param('detail');
if ($detail) {
    my $elems= $group_elems{$section,$detail};
    die unless $elems;
    start_page("$detail graphs");
    foreach my $tsloth (0..5) {
	foreach my $elem (@$elems) {
	    my $g= $graphs{$section,$detail,$elem};
	    die unless $g;
	    next if $tsloth >= @{ $g->{TimeRanges} };
	    my $imgurl= "$self?graph=$detail&section=$section".
		"&sloth=$tsloth&elem=$elem";
	    print a({href=>"$imgurl&w=780&h=800"},
		    img({src=>$imgurl, alt=>''}));
	}
    }
    print end_html();
    exit 0;
}

our $sloth;

navsetting({
    Desc => 'Time interval',
    Param => 'sloth',
    Variable => \$sloth,
    Default => 1,
    Values => [0..3],
    Show => sub {
	my ($sl) = @_;
	return ('Narrower', 'Normal', 'Wider', 'Extra wide')[$sl];
    }
});

if (param('debug')) {
    use Data::Dumper;
    print Dumper(\%graphs);
    exit 0;
}

start_page("$section graphs");

foreach my $group (@{ $section_groups{$section} }) {
    print a({href=>"$self?detail=$group&section=$section"});
    my $imgurl= "$self?graph=$group&section=$section";
    print "<span style=\"white-space:nowrap\">";
    my $elems= $group_elems{$section,$group};
    foreach my $elem (@$elems) {
	my $g= $graphs{$section,$group,$elem};
	print img({src=>"$imgurl&elem=$elem&sloth=".($sloth + $g->{Slower}),
	           alt=>''});
    }
    print "</span>";
    print "</a>\n";
}