#!/usr/bin/perl -w
use strict;
our $us = $0; $us =~ s#.*/##;

use POSIX;
use Data::Dumper;

our $papersize =  'creditcard';
our $fontname = 'Courier';
our $fontname_num = 'Courier';
our $gapratio = 1;
our $blankratio = 1;
our @borders = (4,4);

our @lp_options = ( [ 'blank-below', 'blank-to-right', ],
		    [ 'landscape', 'portrait' ],
		    [ 'single-column', 'multi-column', ] );
our @lp_fixed;

our $usage = <<END;
usage: $us [<options>] <foo-mail-pregen> <foo-mail-pregen-opts>...
options:
  -p<papersize>           for libpaper, or "creditcard"  default is $papersize
  -F[<numberfont>,]<font> font name                      default is $fontname
  -b<border>|-b<bx>x<by>  all in mm
  -g<gapratio>            number-to-addr gap adjustment
  -b<blankratio>          (blank space size) / (text size)
  -D                      debug
END

open DEBUG, ">/dev/null" or die $!;

our @paperpts;

sub badusage () { die "bad usage\n\n$usage"; }

sub mm2pt { map { $_ * 72.0 / 25.4 } @_; }

sub max {
    my $r = undef;
    foreach (@_) {
	$r = $_ if !defined $r or $_ > $r;
    }
    return $r;
}

sub min {
    my $r = undef;
    foreach (@_) {
	$r = $_ if !defined $r or $_ < $r;
    }
    return $r;
}

my $fontname_re = '[^()\\,]+';
my $dbl_re = '(?:[0-9]+\.?|[0-9]*\.[0-9]+)';

for (;;) {
    badusage unless @ARGV;
    last unless $ARGV[0] =~ m/^-/;
    $_ = shift @ARGV;
    last if m/^--?$/;
    while (m/^-./) {
	if (s/^-p(\w+)$//) {
	    $papersize = $1;
	    @paperpts = ();
	} elsif (s/^-p($dbl_re)x($dbl_re)$//o) {
	    $papersize = undef;
	    @paperpts = mm2pt($1,$2);
	} elsif (s/^-F($fontname_re)$//o) {
	    $fontname = $fontname_num = $1;
	} elsif (s/^-F($fontname_re),($fontname_re)$//o) {
	    ($fontname_num, $fontname) = ($1, $2);
	} elsif (s/^-b($dbl_re)$//o) {
	    @borders = ($1,$1);
	} elsif (s/^-b($dbl_re)x($dbl_re)$//o) {
	    @borders = ($1,$1);
	} elsif (s/^-g($dbl_re)$//o) {
	    $gapratio = $1;
	} elsif (s/^-b($dbl_re)$//o) {
	    $blankratio = $1;
	} elsif (s/^-D/-/) {
	    open DEBUG, ">&STDERR" or die $!;
	} else {
	    badusage;
	}
    }
}

if (!@paperpts) {
    if ($papersize eq 'creditcard') {
	# ISO/IEC 7810 ID-1, from en.wikipedia.org/wiki/Payment_card
	@paperpts = mm2pt qw(85.60 53.98);
    } else {
	$!=0; $?=0; my $r = `paperconf -sp $1`;
	defined $r or die "paperconf failed: $? $!\n";
	$r =~ m/^([0-9.]+) ([0-9.]+)$/ or die "$_ ?";
	@paperpts = ($1,$2);
    }
}

@borders = mm2pt @borders;

@ARGV >= 2 or badusage;

our @strings;

sub readstrings () {
    my $nlen = 0;

    open P, "-|", @ARGV or die $!;
    while (<P>) {
	chomp or die;
	m/^(\d+) (\S+)$/ or die "$_ ?";
	$nlen = length($1) if length($1) > $nlen;
	push @strings, [ $1, $2 ];
    }
    $!=0; $?=0; close P or die "$us: generator failed: $! $?\n";
}

our @lp_values;
our @numbers_bbox;
our @texts_bbox;
our $gap_width;
our @core_size;
our @item_size;
our $rotate_paper;
our @eff_paper_size;
our @laycount;

sub wontfit ($) {
    print DEBUG " NO @_\n";
    return 0;
}

sub psstring ($) {
    local ($_) = @_;
    s/[()\\]/\\$&/g;
    return "($_)";
}

our @numbers_1_bbox;
our @nom_gap_1_bbox;
our @texts_1_bbox;

sub prepare_metrics () {
    print DEBUG " prepare_metrics\n";
    my $pchild = open GI, "-|"; defined $pchild or die $!;
    my @sets = 
	([ \@numbers_1_bbox, $fontname_num, map { $_->[0] } @strings ],
	 [ \@nom_gap_1_bbox, $fontname_num, 'x'                      ],
	 [ \@texts_1_bbox,   $fontname,     map { $_->[1] } @strings ],
	);
    if (!$pchild) {
	foreach my $set (@sets) {
	    my ($ra, $fn, @s) = @$set;
	    print DEBUG "  want $fn ",scalar(@s),"\n";
	    print psstring($fn)," findfont 10 scalefont setfont\n" or die $!;
	    print "0 0 moveto ", psstring($_), " show showpage\n" or die $!
		foreach @s;
	}
	close STDOUT or die $!;
	exit 0;
    }
    my $gchild = open GO, "-|"; defined $gchild or die $!;
    if (!$gchild) {
	open STDIN, "<&GI" or die $!;
	open STDERR, ">&STDOUT" or die $!;
	exec qw(gs -dSAFER -dNOPAUSE -q -dBATCH -sDEVICE=bbox -) 
	    or die "$us: exec gs: $!\n";
    }
    foreach my $set (@sets) {
	my ($ra, $fn, @s) = @$set;
	my @bb;
	for (my $count=0; $count < @s; $count++) {
	    $_ = <GO>; defined or die "gs fail or eof";
	    printf DEBUG "    %s (%d) |%s", $fn, $count, $_;
	    if (my @tbb =
 m/^\%\%HiResBoundingBox: ($dbl_re) ($dbl_re) ($dbl_re) ($dbl_re)$/
		) {
		$bb[0] = min $bb[0], $tbb[0];
		$bb[1] = min $bb[1], $tbb[1];
		$bb[2] = max $bb[2], $tbb[2];
		$bb[3] = max $bb[3], $tbb[3];
	    } elsif (m/^\%\%/) {
	    } else {
		print STDERR "$us: warning: gs: $_" or die;
	    }
	}
	print DEBUG "  metrics $fn @bb\n";
	@$ra = map { $_ * 0.1 } @bb;
    }
    $!=0; $?=0; close GO or die "gs $! $?";
    $!=0; $?=0; close GI or die "gs paste $! $?";
}

sub do_layout_recursive_search ($);
sub do_layout_recursive_search ($) {
    my ($lpi) = @_;

    if ($lpi < @lp_options) {
	foreach my $v ($lp_fixed[$lpi] or @{ $lp_options[$lpi] }) {
	    $lp_values[$lpi] = $v;
	    return 1 if do_layout_recursive_search $lpi+1;
	}
	return 0;
    }

    print DEBUG " try", (map { sprintf " %-10.10s", $_ } @lp_values), ":";

    my %lp_y;
    $lp_y{$_} = 1 foreach @lp_values;

    $rotate_paper =
	($paperpts[0] > $paperpts[1] # paper looks like landscape
	 xor $lp_y{'landscape'});
    @eff_paper_size = !$rotate_paper ? @paperpts : reverse @paperpts;

    @item_size = @core_size;
    my $blank_coord = !!$lp_y{'blank-below'};
    $item_size[$blank_coord] *= (1.0 + $blankratio);

    foreach my $coord (qw(0 1)) {
	my $avail = $eff_paper_size[$coord] - $borders[$coord] * 2;
	my $each = $item_size[$coord];
	if (!$coord) {
	    $each += $gap_width;
	    $avail += $gap_width;
	}
	$laycount[$coord] = floor($avail / $each);
	$laycount[$coord] >= 1 or return wontfit "cannot fit even one $coord";
    }

    if ($lp_y{'single-column'}) {
	$laycount[0] = 1;
    } else {
	$laycount[0] >= 2 
	    or return wontfit "requested multi-column but only one";
    }

    $laycount[0] * $laycount[1] >= @strings
	or return wontfit "layout fits too few @laycount";

    print DEBUG " OK @laycount\n";
    return 1;
}

sub do_layout ($) {
    my ($fontsize) = @_;

    print DEBUG "layout $fontsize\n";

    @numbers_bbox = map { $_ * $fontsize } @numbers_1_bbox;
    $gap_width = $gapratio * $fontsize *
	($nom_gap_1_bbox[2] - $nom_gap_1_bbox[0]);
    @texts_bbox = map { $_ * $fontsize } @texts_1_bbox;

    $core_size[0] =
	($numbers_bbox[2] - $numbers_bbox[0]) +
	$gap_width +
	($texts_bbox[2] - $texts_bbox[0]);

    $core_size[1] = max
	$numbers_bbox[3] - $numbers_bbox[1],
	$texts_bbox[3] - $texts_bbox[1];

    return do_layout_recursive_search 0;
}

our $usesz;

sub determine_size_layout () {
    my $minsz;
    my $maxsz;

    for (;;) {
	my $trysz =
	    !defined $minsz ? 1 :
	    !defined $maxsz ? $minsz * 4 :
	    sqrt($minsz * $maxsz);

	my $ok = do_layout $trysz;

	if ($ok) { $minsz = $trysz; } else { $maxsz = $trysz; }

	defined $minsz or die "cannot fit at even at ${trysz}pt\n";

	if (defined $maxsz && ($maxsz / $minsz) < 1.01) {
	    $usesz = $minsz;
	    last;
	}
    }

    do_layout $usesz or die;
    
    print DEBUG Dumper($usesz, \@lp_values, \@numbers_bbox,
		       \@texts_bbox, $gap_width, \@core_size,
		       \@item_size, $rotate_paper, \@eff_paper_size,
		       \@laycount);
}

readstrings();
prepare_metrics();
determine_size_layout();