BOOSTER.CIR - BOOSTER AND POWER COMPENSATOR

* ngspice -b booster.cir | ~/an-things/chiark-utils/scripts/ngspice2genspic | ~/an-things/chiark-utils/scripts/genspic2gnuplot ./t && ./t.gnuplots.sh

.include lf356.mod
.include bat85.mod
.include miscdiodes.mod
.include bzx55.mod
.include irf5305.mod

*---------- input stage ----------
v18		10 0	18
v12		1 0	12

xmdrop		11 42 10	irf5305

cbypass		11 0	1u
*csmooth	11 0	10u

*---------- lmd18200t ----------
vgoahbl		311 0	pulse(	1 0 10u   0.1u 0.1u 50.5u 100u )
vgoalbh		211 0	pulse(	0 1 10.5u 0.1u 0.1u 49.5u 100u )

.model slmd18200t sw (vt=0.5 vh=0.1 ron=0.5 roff=1meg)
sswah		11 30	311 0	slmd18200t	on
sswbl		20 0	311 0	slmd18200t	on
sswal		30 0	211 0	slmd18200t	off
sswbh		11 20	211 0	slmd18200t	off

*---------- load ----------
rminload	20 30	330
.model sload sw (vt=0.5 vh=0.1 ron=6 roff=1meg)
vgoload		411 0	pulse(0 1 3.141592m 1u 1u 10.141592m 18.283184m)
sload		20 30	411 0	sload

*rload		20 30	6
*rload		20 30	90

*---------- output sensor ----------
xdsensebh	20 21	bat85
xdsenseah	30 21	bat85
xdsensebl	31 20	bat85
xdsenseal	31 30	bat85

*---------- resistor network (high side) ----------
rinh		21 22	5.1k
xzinh		22 1	bzx55-c8v2
rinh2		22 23	2.4k
rinhdo		23 24	3.0k
rinhdh		1 27	1.8k
rinhdth		27 24	0.5k
rinhdtl		24 26	0.5k
rinhdl		26 0	910

*---------- resistor network (low side) ----------
rinl		31 32	6.2k
xzinl		0 32	bzx55-c8v2
rinl2		32 33	1.3k
rinlu		1 33	3.9k

*---------- op-amp and output driver network ----------

x356		23 33  1 0  40	lf356/ns

ropd		40 0	330k
rodrv		40 41	10k
ropu		10 42	20k
xzosuf		41 42	bzx55-c8v2
cgateplus	11 42	100n

*---------- results ----------

rnought		0 9999	1k

.options itl4=1000 reltol=0.003

.print	tran	v(11) v(20) v(30) v(40) v(41) v(42) v(10) v(9999)
.tran	50n 20m
.tran	10n 20u
.tran	10n 2.2m 2m
.tran	10n 3.5m 3m
.tran	10n 8m 7.8m

.Probe
.End