#!/usr/bin/perl -w

use strict qw(vars);

our ($basename);
$basename= @ARGV ? $ARGV[0] : 'safety';
die if $basename =~ m/^\-/;
$basename =~ s/\.wiring$//;

our ($mistakes, $currentline);

our (%segs);
# $segs{$seg}{Inv}
# $segs{$seg}{BoOb}
# $segs{$seg}{Posns}
# $segs{$seg}{FeatCount}              does not include Fixed
# $segs{$seg}{Feats}{$pt}{Kind}       Point or Fixed
# $segs{$seg}{Feats}{$pt}{Weight}     ) for Point only
# $segs{$seg}{Feats}{$pt}{Posns}      ) for Point only
# $segs{$seg}{Feats}{$pt}{BoOb}[]     ) for Point only
# $segs{$seg}{Feats}{$pt}{Fixed}      position, for Fixed only

# $segs{$seg}{Num}
# $segs{$seg}{Ends}[$combpos][$end] = [ $node,$side ]
# $segs{$seg}{Dist}[$combpos]

our (%nodes);
# $nodes{$node}[$side]{Seg}
# $nodes{$node}[$side]{End}

our ($maxptixln2) = 5;

our ($nextboardnum,@boardtype,@sensesin,$maxreverseobjnum);
our (@reversersboardnum,@sensesbase,@objkinds,%pin_used);
# $boardtype[$boardnum]
# $sensesin[$page]
# $maxreverseobjnum
# $reversersboardnum[$boardnum]  # undef => none; -1 => not yet determined
# $sensesbase[$boardnum]= ($page << 7) | $baselsbyte
# $pin_used{$objkind}[$objnum] = [ $boardnum, $pin_info, $objonboard ]
$nextboardnum= 0;
$sensesin[0]= 0;
@objkinds= qw(pt sense reverse);

our (%kind_count,%pin_info); # from BOARD.pin-info

our ($mode,$invertible);
$mode= 'barf';

sub line_barf () {
    return if $mistakes;
    mistake("first input line does not determine phase");
}

sub syntaxerror () {
    our (%syntaxerror_once);
    return if exists $syntaxerror_once{$mode};
    $syntaxerror_once{$mode}= 1;
    mistake("syntax error");
    return undef;
}

sub ditch ($) {
    my ($m) = @_;
    print STDERR "ditching $m\n";
}

sub begin_points () { }
sub line_points () {
    my ($seg,$pt,@boob,$bodef);
    m,^\s+(\w+)/([A-Za-z]+)\s+((\d+)\.\d+)\s+(\d*\.\d+)$, or
	return syntaxerror();
    ($seg,$pt,$boob[0],$bodef,$boob[1])=($1,$2,$3,$4,$5);
    $boob[1] =~ s/^\./$bodef./;
    mistake("unknown wiring for $seg in $seg/$pt") unless exists $segs{$seg};
    mistake("duplicate wiring for $seg/$pt") if exists $segs{$seg}{Feats}{$pt};
    $segs{$seg}{Feats}{$pt}= {
	Kind => Point,
	Weight => $segs{$seg}{Posns},
	Posns => 2,
	BoOb => [ map { pa_boob($_) } @boob ]
	};
    $segs{$seg}{Posns} *= 2;
    $segs{$seg}{FeatCount}++;
}

sub begin_fixed () { }
sub line_fixed () {
    my ($seg,$pt,$pos);
    m,^\s+(\w+)/([A-Za-z]+)(\d+)$, or return syntaxerror();
    ($seg,$pt,$pos)=($1,$2,$3);
    mistake("unknown wiring for $seg in $seg/$pt") unless exists $segs{$seg};
    mistake("duplicate fixed $seg/$pt") if exists $segs{$seg}{Feats}{$pt};
    $segs{$seg}{Feats}{$pt}= {
	Kind => Fixed,
	Fixed => $pos
	};
}

sub begin_segment () { }
sub line_segment () {
    my ($seg,$boob);
    m/^\s+(\w+)\s+(\d+\.\d+)$/ or return syntaxerror();
    ($seg,$boob)=($1,$2);
    mistake("duplicate topology for $seg") if exists $segs{$seg};
    $boob= pa_boob($boob);
    $segs{$seg}= {
	BoOb => $boob,
	Inv => $invertible,
	Posns => 1,
	Feats => { },
	FeatCount => 0
    };
    &{"line_segment_".($invertible?'invertible':'vanilla')}($boob);
}

sub begin_endwiring () {
}

sub begin_boards () {
}
sub line_boards () {
    my ($num,$type,$k);
    m/^\s+(\d+)\s+(\w+)$/ or return syntaxerror();
    ($num,$type)=($1,$2);
    mistake("board $num when expected $nextboardnum")
	if $num != $nextboardnum;

    $nextboardnum++;
    $boardtype[$num]= $type;
    require "./$type.pin-info";

    my ($sense_count, $page);
    $sense_count= $kind_count{$type}{'sense'};
    for ($page=0;
	 $sensesin[$page] + $sense_count > 128;
	 $page++) {
	mistake("too many senses for encoding scheme")
	    if $page > 7;
	push @sensesin, 0
	    if $page > $#sensesin;
    }
    $sensesbase[$num]= ($page << 7) | $sensesin[$page];
    $sensesin[$page] += $sense_count;

    &{"line_boards_$type"}($num);
}

sub line_boards_reversers { }
sub line_boards_detectors { }
sub line_segment_vanilla ($) { }
sub line_segment_invertible ($) {
    my ($boob) = @_;
    $reversersboardnum[$boob->[0]]= -1;
}

sub mistake ($) {
    my ($m) = @_;
    print STDERR "mistake: $m\n in $mode, \`$currentline'\n";
    $mistakes++;
}

sub line_endwiring () {
    my (@ns,$seg,$subspec,$dist);
    my ($segr,@subsegil,$feat,$pos,$featr,$combpos,%featposwant);
    my ($end,$node,$side,$nsr,$endposr);
    m,^\s*segment\s+(\w+\.\d+)\s+(\w+\.\d+)\s+(\w+)(?:/((?:[A-Za-z]+\d+)+)\*\d+)?\s+([0-9.]+)$, or return syntaxerror();
    ($ns[0],$ns[1],$seg,$subspec,$dist)=($1,$2,$3,$4,$5);
    if (!exists $segs{$seg}) {
	ditch("unwired $seg$subspec");
	return;
    }
    $segr= $segs{$seg};
    @subsegil= defined $subspec ? $subspec =~ m/([A-Za-z]+)(\d+)/g : ();
    while (@subsegil) {
	($feat,$pos,@subsegil) = @subsegil;
	if (!exists $segr->{Feats}{$feat}) {
	    mistake("no wiring for $seg/$feat");
	    next;
	}
	$featr= $segr->{Feats}{$feat};
	if (exists $featr->{Fixed}) {
	    if ($pos != $featr->{Fixed}) {
		ditch("fixed-elsewise $seg$subspec");
		return;
	    }
	} else {
	    mistake("position $seg/$feat$pos exceeds wiring")
		unless $pos < $featr->{Posns};
	    $featposwant{$feat}= $pos;
	}
    }
    $combpos= 0;
    for $feat (keys %{ $segr->{Feats} }) {
	$featr= $segr->{Feats}{$feat};
	next if exists $featr->{Fixed};
	mistake("wiring $seg/$feat not covered by $seg/$subspec")
	    if !exists $featposwant{$feat};
	$combpos += $featposwant{$feat} * $featr->{Weight};
    }
    mistake("duplicate topology for $seg/$subspec")
	if defined $segs{$seg}{Dist}[$combpos];
    $segs{$seg}{Dist}[$combpos]= $dist;
    $endposr= $segr->{Ends}[$combpos];
    die "$seg $combpos @$endposr ?" if defined $endposr && @$endposr;
    for ($end=0; $end<2; $end++) {
	$ns[$end] =~ m/^([a-z]\w+)\.([01])$/;
	($node,$side)=($1,$2);
	$nsr= $nodes{$node}[$side];
	if (!exists $nsr->{Seg}) {
	    $nodes{$node}[$side]= { Seg => $seg, End => $end };
	} else {
	    $seg eq $nsr->{Seg} or
		mistake("topology for $node.$side both $seg and $nsr->{Seg}");
	    $end == $nsr->{End} or
		mistake("topology for $node.$side $seg both ends ($end".
			" and also $nsr->{End})");
	}
	$segr->{Ends}[$combpos][$end]= [ $node, $side ];
    }
}

sub o ($) {
    print STDOUT $_[0] or die $!;
}

sub pa_boob ($) {
    my ($boob) = @_;
    if ($boob !~ m/^([1-9]\d*|0)\.([1-9]\d*|0)$/) {
	mistake("invalid board object $boob");
	return [ 0,0 ];
    }
    return [ $1,$2 ];
}

# boob2objnum_KIND($boardnum,$objnum,$boardtype,$mkused
#  -> global object number

sub boob2objnum_pt {
    my ($boardnum,$obj)=@_;
    mistake("point encoding out of range") if
	$boardnum >= (1 << (10 - $maxptixln2));
    die if $obj >= (1 << $maxptixln2);
    return ($boardnum << $maxptixln2) | $obj;
}

sub boob2objnum_reverse {
    my ($orgboardnum,$obj,$boardtype)=@_;
    # Converts board and object number (in canonical pic number plus
    # and reverse0...reverse5 as seen on pinout diagrams), to the
    # segment number for POLARITY command numbered as shown in
    # README.protocol.
    #
    # There are three basic stages:
    #
    #  * We invert the on-board mapping; ie, we untangle the
    #    tangling between the message from master to slave pic
    #    and the actual pins (see reverse.asm, polarity_local_do)
    #
    #  * We figure out which bit of which message byte the
    #    object corresponds to.  (see reverse.asm, command_polarity)
    #
    #  * We compute the README.protocol segment number.
    
    my ($cycle,$boardincycle,$cyclebasebyte,$byte,$bit,$boardnum,$rv);
    $boardnum= $reversersboardnum[$orgboardnum];
    die "$orgboardnum $boardnum" unless defined $boardnum;
    die "$orgboardnum $boardnum" unless $boardnum >= 0;
    die unless $boardtype eq 'reversers';
    die $obj if $obj > 5;
#print STDERR "data2safety $boardnum.$obj ";
    $obj = sprintf '%d', $obj;
    $obj =~ y/302154/543210/; # mapping due to polarity_do_here
#print STDERR " obj=$obj";
    $cycle= int(($boardnum+3) / 7);
#print STDERR " cycle=$cycle";
    $boardincycle= ($boardnum+3) - $cycle*7;
#print STDERR " boardin=$boardincycle";
    $cyclebasebyte= $cycle*6 - 2;
#print STDERR " baseby=$cyclebasebyte";
    if ($boardnum==2 && $obj > 2) {
	$byte= 0; $bit= $obj-3;
	$rv= 3 - $bit; # only these three in byte 0, a special case;
#print STDERR " special bit=$bit => $rv\n";
	return $rv;
    } elsif ($boardincycle<5) {
	$byte= $cyclebasebyte + $boardincycle; $bit= $obj + 1;
    } elsif ($boardincycle==6) {
	$byte= $cyclebasebyte + 5; $bit= $obj + 1;
    } elsif ($boardincycle==5) {
	$byte= $cyclebasebyte + 5 - $bit; $bit= 0;
    } else {
	die;
    }
    $rv= $byte*7 + 3 - $bit;
#print STDERR " ordinary byte=$byte bit=$bit => $rv\n";
    return $rv;
}

sub boob2objnum_sense {
    my ($boardnum,$obj)=@_;
    my ($inpage);
    $inpage= $obj + $sensesbase[$boardnum];
    die if $inpage > 127;
    return ($boardnum << 7) | $inpage;
}    

sub boob2objnum ($$$$) {
    my ($boardnum,$obj,$kind,$mkused) = @_;
    my ($type);
    $type= $boardtype[$boardnum];
    return &{"boob2objnum_$kind"}($boardnum,$obj,$type,$mkused);
}

sub boob_used ($$$) {
    my ($boardnum,$obj,$kind) = @_;
    my ($objnum);
    $objnum= boob2objnum($boardnum, $obj, $kind, 0);
    return $pin_used{$kind}[$objnum];
}

sub boob_used_bit ($$$) {
    my ($boardnum,$obj,$kind) = @_;
    return defined boob_used($boardnum,$obj,$kind) ? 1 : 0;
}

sub so_boob ($$$) {
    my ($kind,$mkused,$bo) = @_;
    my ($type,$pi);
    if (defined $bo) {
	my ($board,$obj)= @$bo;
	my ($objnum,$type,$pi);
	mistake("unknown board number $board")
	    unless defined $boardtype[$board];
	$type= $boardtype[$board];
	$pi= $pin_info{$type}{$kind};
	mistake("object reference $kind $board.$obj out of range for".
		" board type $type")
	    unless defined $pi->[$obj];
	$objnum= boob2objnum($board,$obj,$kind,$mkused);
	$pin_used{$kind}[$objnum]= [ $board, $pi->[$obj], $obj ]
	    if $mkused;
	return sprintf("%#4x /* %d.%-2d*/", $objnum, $board, $obj);
    } else {
	return "   0 /*none*/ ";
    }
}

sub so_objboob ($$$) {
    my ($kind,$mkused,$obj) = @_;
    return so_boob($kind,$mkused, defined $obj ? $obj->{BoOb} : undef);
}

sub mainread () {
    $mistakes= 0;
    while (<>) {
	next if m/^\#/;
	chomp;
	s/\s+$//;
	next unless m/\S/;
	last if m/^end$/;
	if (m/^(invertible|vanilla|points|fixed|endwiring|boards)$/) {
	    $mode= $1;
	    $invertible= ($mode eq 'invertible');
	    $mode= 'segment' if $mode =~ m/^(?:vanilla|invertible)$/;
	    &{"begin_$mode"};
	} else {
	    $currentline= $_;
	    &{"line_$mode"};
	}
    }
}

sub redaction () {
    my ($num,$mappednum,$i,$objnum);
    $maxreverseobjnum= 0;
    for ($num=0, $mappednum=0; $num<@boardtype; $num++) {
	next unless defined $reversersboardnum[$num];
	die if $reversersboardnum[$num] != -1;
	$reversersboardnum[$num]= $mappednum;
	for ($i=0; $i<6; $i++) {
	    $objnum= boob2objnum($mappednum,$i,'reverse',0);
	    $maxreverseobjnum= $objnum+1 if $objnum >= $maxreverseobjnum;
	}
	$mappednum++;
    }
}    

sub nummap ($) {
    my ($p) = @_;
    $p =~ s/\d{1,6}/ sprintf "%06d%d",$&,$& /ge;
    return $p;
}

sub writeout () {
    my (@segs,$segn,$seg,$segr,$pt,$ptv, $delim);
    my ($comb,$pi,$feat,$featr,$end,$boob);
    my ($node,$side,$otherend,$nodeotherside,$otherseg,$otherbackrelus);
    o("/* autogenerated - do not edit */\n\n");
    @segs=();
    for $seg (sort { nummap($a) cmp nummap($b) } keys %segs) {
	$segs{$seg}{Num}= @segs;
	push @segs, $seg;
    }
    o(sprintf
      "#define NUM_SEGMENTS %s\n\n".
      "#include \"layout-data.h\"\n\n",
      scalar @segs);
    foreach $seg (@segs) {
	$segr= $segs{$seg};

	o("static const SegPosCombInfo spci_${seg}"."[]= {");
	$delim='';
	for ($comb=0; $comb < $segr->{Posns}; $comb++) {
	    $pi='';
	    foreach $feat (keys %{ $segr->{Feats} }) {
		$featr= $segr->{Feats}{$feat};
		next if exists $featr->{Fixed};
		$pi.= sprintf("%s%d", $feat,
			      ($comb / $featr->{Weight}) % $featr->{Posns});
	    }
	    o("$delim\n");
	    o(sprintf "  { %-8s %4d",
	      '"'.$pi.'",',
	      $segr->{Dist}[$comb]);
	    for ($end=0; $end<2; $end++) {
		o(", { ");
		$otherend= $segr->{Ends}[$comb][$end];
		defined $otherend or die "$seg $comb $end ?";
		($node,$side) = @$otherend;
		$nodeotherside= $nodes{$node}[1-$side];
		if (defined $nodeotherside) {
		    $otherseg= $nodeotherside->{Seg};
		    $otherbackrelus= $nodeotherside->{End} ^ $end ^ 1;
		    o(sprintf "/*%5s.%d %-5s*/ %d,%3d",
		      $node,$side,
		      ($otherbackrelus?'-':' ').$otherseg,
		      $otherbackrelus,
		      $segs{$otherseg}{Num});
		} else {
		    o(sprintf "/*%5s.%d*/ 0,NOTA(Segment)",
		      $node,$side);
		}
		o(" }");
	    }
	    o(sprintf " }");
	    $delim= ',';
	}
	o("\n};\n");

	next unless $segr->{FeatCount};

	for $pt (keys %{ $segr->{Feats} }) {
	    $ptv= $segr->{Feats}{$pt};
	    next if exists $ptv->{Fixed};
	    o("static const BoardObject mfbo_${seg}_${pt}"."[]= {");
	    $delim=' ';
	    foreach $boob (@{ $ptv->{BoOb} }) {
		o($delim);
		o(so_boob('pt',1, $boob));
		$delim= ', ';
	    }
	    o(" };\n");
	}
	    
	o("static const MovFeatInfo mfi_${seg}"."[]= {");
	$delim='';
	for $pt (keys %{ $segr->{Feats} }) {
	    $ptv= $segr->{Feats}{$pt};
	    next if exists $ptv->{Fixed};
	    o("$delim\n");
	    o("  { \"$pt\", mfk_".lc($ptv->{Kind}).",".
	      " $ptv->{Posns}, $ptv->{Weight}, mfbo_${seg}_$pt }");
	    $delim=',';
	}
	o("\n};\n");
    }
    o("const SegmentNum info_nsegments=NUM_SEGMENTS;\n");
    o("const SegmentInfo info_segments[NUM_SEGMENTS]= {");
    $delim= '';
    foreach $seg (@segs) {
	$segr= $segs{$seg};
	o("$delim\n");
	o(sprintf "  { %-7s %d, %2d,%-9s %3d,%-10s %-6s,%-6s }",
	  "\"$seg\",", $segr->{Inv},
	  $segr->{FeatCount}, ($segr->{FeatCount} ? "mfi_$seg," : '0,'),
	  $segr->{Posns}, "spci_$seg,",
	  so_objboob('sense',1, $segr),
	  so_objboob('reverse',1, $segr->{Inv} ? $segr : undef));
	$delim= ',';
    }
    o("\n};\n");
    o("const BoardObject info_maxreverse= $maxreverseobjnum;\n");
}

# writeasm_KIND()

sub o_section ($$) {
    my ($sec,$docstring) = @_;
    o("\n;----------\n".
      "  org $sec\n");
    o($docstring);
}
sub o_section_end_fill ($$$) {
    my ($lastnumdone, $fillvalue, $entrysize) = @_;
    if ($entrysize == 1 and $lastnumdone & 1) {
	o(", $fillvalue & 0xff\n");
	$lastnumdone++;
    } else {
	o("\n");
    }
    o(sprintf "  fill %s, %d*(maxpics-%d)\n\n",
      $fillvalue, $entrysize, $lastnumdone);
}

sub o_db ($;$) {
    my ($ix,$every) = @_;
    $every=16 unless defined $every;
    o(($every ? $ix % $every : $ix) ? ',' : "\n  db ");
}

sub writeasm_sense {
    my ($num, $base);
    o_section('pic2detinfo',<<'END');
; Table indexed by pic no., giving information about sensing
; Each element is two bytes:
;  1st byte   bit 7     Set iff this board exists for the purposes of sensing
;             bits 6-3  Not used, set to zero
;             bits 2-0  Top 3 bits of sense segment numbers on this board
;  2nd byte   bit 7     Set iff this board is a Detectors board
;             bits 6-0  Base for bottom 7 bits of segment number
;                       (per-board segment no. is added to this; carry
;                        to upper 3 bits is not permitted)
END
    o("SenseExists equ 0x80\n".
      "Detectors equ 0x80\n".
      "Reversers equ 0x00\n\n");
    for ($num=0; $num<@boardtype; $num++) {
	if (!defined $boardtype[$num]) { o("  dw  0\t\t\t\t; $num\n"); next; }
	$base= $sensesbase[$num];
	o(sprintf "  db  SenseExists | 0x%02x, %12s | 0x%02x\t; %d\n",
	  $base >> 7, ucfirst($boardtype[$num]), $base & 0x7f, $num);
    }
    o_section_end_fill($num, 0, 2);
}

sub writeasm_pt {
    my ($num, $elemsize, $byte, $bit, $objnum);
    o_section('picno2ptmap',<<'END');
; Bitmap indexed first by pic no, and then by point no. on that board,
; saying whether the point is present or not.  Each pic has 4 bytes,
; ie 32 bits.  First byte is points 0 to 7, in bits 0 to 7 respectively
; so that MSbit of byte 3 (4th byte) is point no.31.  Unused boards
; or boards with no points are all-bits-0.
END
    for ($num=0; $num<@boardtype; $num++) {
	if (!defined $boardtype[$num]) { o("  dw  0\t\t\t\t; $num"); next; }
	die if $maxptixln2 < 4; # must be whole no. of 16-bit words
	$elemsize= 1 << ($maxptixln2-3);
	for ($byte=0; $byte < $elemsize; $byte++) {
	    o_db($byte, 0);
	    o("b'");
	    for ($bit=7; $bit>=0; $bit--) {
		o(boob_used_bit($num, $byte*8 + $bit, 'pt'));
	    }
	    o("'");
	}
	o(" ; $num");
    }
    o("\n");
    o_section_end_fill($num, 0, $elemsize);

    my($typeix,$type,$pt,$pi);
    o_section('bkptix2portnumbitnum',<<"END");
; Table giving physical ports and pins for points for each
; kind of board.  Index is point number (for reversers boards)
; or point number + 2^$maxptixln2 (for detectors boards).
; Value is one byte, either 0xff meaning that board type has
; no such point, or top nybble being port number (0 for A, 1 for B,
; etc.) and bottom nybble being bit number.  Ie,
;   Index:  00Dppppp    where D is 1 iff detectors board and p is pt ix
;   Value:  0ppp0bbb    where p is port num and b is bit num; or 0xff
END
    o("  radix hex\n");
    for ($typeix=0; $typeix<2; $typeix++) {
	$type= qw(reversers detectors)[$typeix];
	die $type unless $pin_info{$type};
	o("; $type:");
	for ($pt=0; $pt < (1 << $maxptixln2); $pt++) {
	    o_db($pt);
	    $pi= $pin_info{$type}{'pt'}[$pt];
	    if (defined $pi) {
		$pi =~ m/^(\d)\,(\d)\,/ or die;
		o($1.$2);
	    } else {
		o('ff');
	    }
	}
	o("\n");
    }
    o("  radix dec\n\n");
}

sub writeasm_reverse {
    my ($num,$kc,$bit, @portae,$pu);
    o_section('picno2revmasks',<<END);
; Table listing which reversers are connected/enabled.  Index is pic
; number.  Each entry is 2 bytes: mask for port A followed by mask for
; port E.  A 1 bit is a connected reverser.  Both masks are 0 for
; non-reversers boards.
END
    for ($num=0; $num<@boardtype; $num++) {
	@portae= ([],[]);
	$kc= $kind_count{$boardtype[$num]}{'reverse'};
	for ($bit= $kc-1; $bit>=0; $bit--) {
	    $pu= boob_used($num, $bit, 'reverse');
	    next unless $pu;
	    $pu->[1] =~ m/^([04])\,\d,(0x\w{2})$/ or die;
	    push @{ $portae[!!$1] }, $2;
	}
	o('  db ');
	o(join(', ', map { @$_ ? join('|',@$_) : '0' } @portae));
	o(sprintf " ; %d\n",$num);
    }
    o_section_end_fill($num, '0x0000', 2);
}

sub writeasm () {
    my ($k,$w,$i,@d,$or,$p,$portnum,$bit,$each);
    close STDOUT or die $!;
    open STDOUT, ">$basename+pindata.asm" or die $!;
    o("; autogenerated - do not edit\n");
    o("  include pindata.inc\n".
      "  radix dec\n".
      "ff equ 0xff\n");
    $each= 10;
    for $k (@objkinds) {
	&{"writeasm_$k"}();
    }
    o("\n  end\n");
}
mainread();
redaction();
writeout();
writeasm();