spice/lf356.mod

   1 *//////////////////////////////////////////////////////////////////////
   2 * (C) National Semiconductor, Inc.
   3 * Models developed and under copyright by:
   4 * National Semiconductor, Inc.
   5
   6 */////////////////////////////////////////////////////////////////////
   7 * Legal Notice: This material is intended for free software support.
   8 * The file may be copied, and distributed; however, reselling the
   9 *  material is illegal
  10
  11 *////////////////////////////////////////////////////////////////////
  12 * For ordering or technical information on these models, contact:
  13 * National Semiconductor's Customer Response Center
  14 *                 7:00 A.M.--7:00 P.M.  U.S. Central Time
  15 *                                (800) 272-9959
  16 * For Applications support, contact the Internet address:
  17 *  amps-apps@galaxy.nsc.com
  18 * ///////////////////////////////////////////////////////////////////
  19 * User Notes:
  20 *
  21 * 1. Input resistance (Rin) for these JFET op amps is 1TOhm.  Rin is
  22 *    modeled by assuming the option GMIN=1TOhm.  If a different (non-
  23 *    default) GMIN value is needed, users may recalculate as follows:
  24 *    Rin=(R1||GMIN+R2||GMIN), where R1=R2,
  25 *    to maintain a consistent Rin model.
  26
  27 *//////////////////////////////////////////////////////////
  28 *LF356 Monolithic JFET-Input OP-AMP MACRO-MODEL
  29 *//////////////////////////////////////////////////////////
  30 *
  31 * connections:    non-inverting input
  32 *                 |   inverting input
  33 *                 |   |   positive power supply
  34 *                 |   |   |   negative power supply
  35 *                 |   |   |   |   output
  36 *                 |   |   |   |   |
  37 *                 |   |   |   |   |
  38 .SUBCKT LF356/NS  1   2  99  50  28
  39 *
  40 *Features:
  41 *Low input bias current =             30pA
  42 *Low input offset current =            3pA
  43 *High input impedance =              1Tohm
  44 *Low input offset voltage =            1mV
  45 *
  46 ****************INPUT STAGE**************
  47 *
  48 IOS 2 1 3P
  49 *^Input offset current
  50 R1 1 3 1E12
  51 R2 3 2 1E12
  52 I1 99 4 100U
  53 J1 5 2 4 JX
  54 J2 6 7 4 JX
  55 R3 5 50 20K
  56 R4 6 50 20K
  57 *Fp2=20 MHz
  58 C4 5 6 1.9894E-13
  59 *
  60 ***********COMMON MODE EFFECT***********
  61 *
  62 I2 99 50 4.65MA
  63 *^Quiescent supply current
  64 *EOS 7 1 POLY(1) 16 49 3E-3 1
  65 BEOS 7 1 V=3E-3+V(16,49)
  66 *Input offset voltage.^
  67 R8 99 49 50K
  68 R9 49 50 50K
  69 *
  70 *********OUTPUT VOLTAGE LIMITING********
  71 V2 99 8 2.63
  72 D1 9 8 DX
  73 D2 10 9 DX
  74 V3 10 50 2.63
  75 *
  76 **************SECOND STAGE**************
  77 *
  78 EH 99 98 99 49 1
  79 *F1 9 98 POLY(1) VA3 0 0 0 1.5944E7
  80 BF1 9 98 I=1.5944e7*I(va3)^3
  81 *1.5944e7*(I(VA3)
  82 G1 98 9 5 6 2E-3
  83 R5 98 9 100MEG
  84 VA3 9 11 0
  85 *Fp1=31.96 HZ
  86 C3 98 11 49.9798P
  87 *
  88 *********COMMON-MODE ZERO STAGE*********
  89 *
  90 G4 98 16 3 49 1E-8
  91 L2 98 17 530.52M
  92 R13 17 16 1K
  93 *
  94 **************OUTPUT STAGE**************
  95 *
  96 F6  99 50 VA7 1
  97 F5  99 23 VA8 1
  98 D5  21 23 DX
  99 VA7 99 21 0
 100 D6  23 99 DX
 101 E1  99 26 99 9 1
 102 VA8 26 27 0
 103 R16 27 28 20
 104 V5  28 25 -.25V
 105 D4  25  9 DX
 106 V4  24 28 -.25V
 107 D3   9 24 DX
 108 *
 109 ***************MODELS USED**************
 110 *
 111 .MODEL DX D(IS=1E-15)
 112 .MODEL JX PJF(BETA=1.25E-5 VTO=-2.00 IS=30E-12)
 113 *
 114 .ENDS
 115 *$