layout/layout

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use IO::Handle;
   5 use IO::File;
   6
   7 use strict;
   8 no strict 'subs';
   9
  10 our $scale= 7.0;
  11 our $page_x= 0;
  12 our $page_y= 0;
  13 our $quiet=0;
  14 our $debug=0;
  15 our $output_layer= '*';
  16 our $subsegcmapreq=0;
  17 our $subsegmovfeatpos='f';
  18 our $subsegcmapangscale;
  19
  20 our $ps_page_shift= 615;
  21 our $ps_page_xmul= 765.354;
  22 our $ps_page_ymul= 538.583;
  23
  24 our @eopts;
  25 our @segments= ('/');
  26 our %subsegcmap;
  27
  28 our $drawers= 'arsclmnog';
  29 our %chdraw_emap= qw(A ARScg
  30                      R aRscg
  31                      S aRScg
  32                      C arsCg
  33                      c Arscg
  34                      r arcs
  35                      L LMg
  36                      l l
  37                      M Mnog
  38                      N MNog
  39                      O MNOg
  40                      m mnol
  41                      G Garsclmno);
  42
  43 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  44     last if $ARGV[0] eq '-';
  45     $_= shift @ARGV;
  46     last if $_ eq '--';
  47     s/^\-//;
  48     while (length) {
  49         if (s/^D(\d+)//) { $debug= $1; }
  50         elsif (s/^D//) { $debug++; }
  51         elsif (s/^q//) { $quiet=1; }
  52         elsif (s/^l(\d+|\*)//) { $output_layer=$1; }
  53         elsif (s/^S([0-9.]+)$//) { $scale= $1 * 1.0; }
  54         elsif (s/^P(\d+)x(\d+)$//) { $page_x= $1; $page_y= $2; }
  55         elsif (s/^GR//) { $subsegcmapreq=1; }
  56         elsif (s/^GP(\d+|f)$//) { $subsegmovfeatpos=$1; }
  57         elsif (s/^GL(.*)$//) {
  58             my ($sscmfn) = $1;
  59             my ($sscmf, $datum, $csss, $angbits);
  60             local ($_);
  61             $sscmf= new IO::File $sscmfn, 'r'
  62                 or die "$sscmfn: cannot open: $!\n";
  63             for (;;) {
  64                 $!=0; $_= <$sscmf>; die $! unless defined $_;
  65                 last if m/^E/;
  66                 next unless m/^C/;
  67                 m,^C\s+(\w*/(?:[A-Za-z_]+)?)\s+(0x[0-9a-f]+)\s+(\d+)\s*$,
  68                     or die "$sscmfn:$.: syntax error in subseg cmap\n";
  69                 ($csss,$datum,$angbits)= ($1,$2,$3);
  70                 if (!defined $subsegcmapangscale) {
  71                     $subsegcmapangscale= 1<<$angbits;
  72                 } else {
  73                     die "angbits varies" if $subsegcmapangscale != 1<<$angbits;
  74                 }
  75                 $datum= hex($datum);
  76                 if ($datum & 0x0ff) {
  77                     die "sorry, cannot put any movfeatpos or segment in red";
  78                 }
  79                 $subsegcmap{$csss}= sprintf("%.6f %.6f",
  80                                             (($datum >> 8) & 0xff)/255.0,
  81                                             (($datum >> 16) & 0xff)/255.0);
  82             }
  83             $sscmf->error and die "$sscmfn: error reading: $!\n";
  84             close $sscmf;
  85         } elsif (s/^(e)
  86                ((?:[a-z]|\*|\?|\[[a-z][-a-z]*\])*?)
  87                (\~?) (\d*) (\=*|\-+|\++) (\d*|\*)
  88                ([a-z]+)$//ix) {
  89             my ($ee,$g,$n,$d,$c,$v,$cc) = ($1,$2,$3,$4,$5,$6,$7);
  90             my ($eo, $invert, $lfn, $ccc, $sense,$limit);
  91             $g =~ s/\?/\./g; $g =~ s/\*/\.\*/g;
  92             die '-[eE]GND[=]* not allowed' if $v eq '*' && length $d;
  93             $d= $output_layer if !length $d;
  94             $d= 5 if $d eq '*';
  95             $invert= length $n;
  96             $c= '=' if !length $c;
  97             if (length $v && $v ne '*') {
  98                 die '-[eE]GN[D]CCV not allowed' if length $c > 1;
  99                 $c= $c x $v;
 100             }
 101             if ($c =~ m/^[-+]/) {
 102                 die '-[eE]GN+/-* not allowed' if $v eq '*';
 103                 $sense= ($&.'1') + 0;
 104                 $limit= ($sense * $d) + length($c) - 1;
 105                 $lfn= sub {
 106                     ($output_layer eq '*' ? $d
 107                      : $_[0]) * $sense >= $limit
 108                          xor $invert;
 109                 };
 110             } elsif ($v eq '*') {
 111                 $lfn= sub { !$invert; };
 112             } else {
 113                 $limit= length($c) - 1;
 114                 $lfn= sub {
 115 #my ($lfn_result)=(
 116                     ($output_layer eq '*' ? 1
 117                      : abs($_[0] - $d) <= $limit)
 118                         xor $invert
 119 #)
 120                             ;
 121 #print STDERR "output layer $output_layer; asking re $_[0] rel $d lim $limit invert $invert result $lfn_result\n";
 122 #$lfn_result;
 123                 };
 124             }
 125             $ccc= '';
 126             foreach $c (split //, $cc) {
 127                 if ($ee eq 'e') {
 128                     die "bad -e option $c" unless defined $chdraw_emap{$c};
 129                     $ccc .=  $chdraw_emap{$c};
 130                 } else {
 131                     die "bad -E option $c" unless $c =~ m/[$drawers]/i;
 132                     $ccc .= $c;
 133                 }
 134             }
 135             $eo->{GlobRe}= $g;
 136             $eo->{LayerCheck}= $lfn;
 137             $eo->{DrawMods}= $ccc;
 138 #print STDERR "created eo $eo re $eo->{GlobRe} n=$n d=$d v=$v c=$c limit=$limit cc=$cc\n";
 139             push @eopts, $eo;
 140         } elsif (m/^S/) {
 141             die "-S option must come right at the start and have numeric arg";
 142         } else {
 143             die "unknown option -$_";
 144         }
 145     }
 146 }
 147
 148 our $ptscale= 72/25.4 / $scale;
 149
 150 our $psu_ulen= 4.5;
 151 our $psu_edgelw= 0.5;
 152 our $psu_ticklw= 0.1;
 153 our $psu_ticksperu= 1;
 154 our $psu_ticklen= 5.0;
 155 our $psu_gauge= 9;
 156 our $psu_sleeperlen= 17;
 157 our $psu_sleeperlw= 15;
 158 our $psu_raillw= 1.0;
 159 our $psu_thinlw= 1.0;
 160 our $psu_subseglw= 15.0;
 161
 162 our $lmu_marklw= 4;
 163 our $lmu_marktpt= 11;
 164 our $lmu_txtboxtxty= $lmu_marktpt * 0.300;
 165 our $lmu_txtboxh= $lmu_marktpt * 1.100;
 166 our $lmu_txtboxpadx= $lmu_marktpt * 0.335;
 167 our $lmu_txtboxoff= $lmu_marklw / 2;
 168 our $lmu_txtboxlw= 1;
 169
 170 our $olu_left= 10 * $scale;
 171 our $olu_right= 217 * $scale - $olu_left;
 172 our $olu_bottom= 20 * $scale;
 173 our $olu_top= 270 * $scale - $olu_bottom;
 174 our $olu_gap_x= 30;
 175 our $olu_gap_y= 60;
 176 our $olu_textheight= 15;
 177 our $olu_textallowperc= $lmu_marktpt * 5.0/11;
 178
 179 our $pi= atan2(0,-1);
 180
 181 sub allwidth2 ($) {
 182     my ($radius)= @_;
 183     return 27 unless defined $radius;
 184     $radius= abs($radius);
 185     return ($radius >= 450 ? 33 :
 186             $radius >= 400 ? 35 :
 187             37);
 188 }
 189 sub allwidth ($) { return allwidth2($_[0]) * 0.5; }
 190
 191 our $allwidthmax= allwidth(0);
 192 our $allwidthmin= allwidth(undef);
 193
 194 # Data structures:
 195 #  $ctx->{CmdLog}= undef                  } not in defobj
 196 #  $ctx->{CmdLog}[]= [ command args ]     } in defobj
 197 #  $ctx->{LocsMade}[]{Id}= $id
 198 #  $ctx->{LocsMade}[]{Neg}= 1 or 0
 199 #  $ctx->{Loc}{$id}{X}
 200 #  $ctx->{Loc}{$id}{Y}
 201 #  $ctx->{Loc}{$id}{A}
 202 #  $ctx->{Loc}{$id}{LayerKind}
 203 #  $ctx->{Trans}{X}       # transformation.  is ev representing
 204 #  $ctx->{Trans}{Y}       # new origin.  (is applied at _input_
 205 #  $ctx->{Trans}{A}       # not at plot-time)
 206 #  $ctx->{Trans}{R}       # but multiply all y coords by this!
 207 #  $ctx->{Draw}           # sequence of one or more chrs from uc $drawers
 208 #                         #  possibly including X meaning never draw
 209 #                         #  anything now (eg in defobj)
 210 #  $ctx->{DrawMap}        # =$fn s.t.
 211 #                         #  &$fn($drawchrs_spec_by_layer_cmdline)
 212 #                         #   = $drawchrs_we_should_use_due_to_obj_etc
 213 #  $ctx->{SegName}        # initial segment name (at start of object or file)
 214 #                         #  or nonexistent if in object in unknown segment
 215 #                         #  may have leading `-'
 216 #  $ctx->{SavedSegment}   # exists iff segment command used, is a $csss
 217 #  $ctx->{Layer}{Level}
 218 #  $ctx->{Layer}{Kind}
 219 #
 220 #  $objs{$id}{CmdLog}
 221 #  $objs{$id}{Loc}
 222 #  $objs{$id}{Part}       # 1 iff object is a part
 223 #
 224 #  $eopts[]{GlobRe}       # regexp for K
 225 #  $eopts[]{LayerCheck}   # =$fn where &$fn($l) is true iff layer matches
 226 #  $eopts[]{DrawMods}     # modifier chars for drawing
 227 #
 228 #  @segments= ( $csss0, $dist0, $csss1, $dist1, ..., $csssn )
 229 #                         # here each csss may have preceding `-'
 230 #
 231 #  $subsegcmap{$csss} = "$green $blue"
 232 #                         # $csss is canonical subseg spec; always has '/'
 233
 234 our $ctx;
 235 our %objs;
 236 our @al; # current cmd
 237
 238 our $o='';
 239 our $ol='';
 240
 241 our $param; # for parametric_curve
 242
 243 # ev_... functions
 244 #
 245 # Operate on Enhanced Vectors which are a location (coordinates) and a
 246 # direction at that location.  Representation is a hash with members X
 247 # Y and A (angle of the direction in radians, anticlockwise from
 248 # East).  May be absolute, or interpreted as relative, according to
 249 # context.
 250 #
 251 # Each function's first argument is a hashref whose X Y A members will
 252 # be created or overwritten; this hashref will be returned (so you can
 253 # use it `functionally' by passing {}).  The other arguments may be ev
 254 # hashrefs, or other info.  The results are in general undefined if
 255 # one of the arguments is the same hash as the result.
 256
 257 sub ev_byang ($$;$) {
 258     # ev_byang(R, ANG,[LEN])
 259     # result is evec LEN (default=1.0) from origin pointing in direction ANG
 260     my ($res,$ang,$len)=@_;
 261     $len=1.0 unless defined $len;
 262     $res->{X}= $len * cos($ang);
 263     $res->{Y}= $len * sin($ang);
 264     $res->{A}= $ang;
 265     $res;
 266 }
 267 sub ev_compose ($$$) {
 268     # ev_compose(SUM_R, A,B);
 269     # appends B to A, result is end of new B
 270     # (B's X is forwards from end of A, Y is translating left from end of A)
 271     # A may have a member R, which if provided then it should be 1.0 or -1.0,
 272     # and B's Y and A will be multiplied by R first (ie, we can reflect);
 273     my ($sum,$a,$b) = @_;
 274     my ($r);
 275     $r= defined $a->{R} ? $a->{R} : 1.0;
 276     $sum->{X}= $a->{X} + $b->{X} * cos($a->{A}) - $r * $b->{Y} * sin($a->{A});
 277     $sum->{Y}= $a->{Y} + $r * $b->{Y} * cos($a->{A}) + $b->{X} * sin($a->{A});
 278     $sum->{A}= $a->{A} + $r * $b->{A};
 279     $sum;
 280 }
 281 sub ev_decompose ($$$) {
 282     # ev_decompose(B_R, A,SUM)
 283     # computes B_R s.t. ev_compose({}, A, B_R) gives SUM
 284     my ($b,$a,$sum)=@_;
 285     my ($r,$brx,$bry);
 286     $r= defined $a->{R} ? $a->{R} : 1.0;
 287     $brx= $sum->{X} - $a->{X};
 288     $bry= $r * ($sum->{Y} - $a->{Y});
 289     $b->{X}= $brx * cos($a->{A}) + $bry * sin($a->{A});
 290     $b->{Y}= $bry * cos($a->{A}) - $brx * sin($a->{A});
 291     $b->{A}= $r * ($sum->{A} - $a->{A});
 292     $b;
 293 }
 294 sub ev_lincomb ($$$$) {
 295     # ev_linkcomb(RES,A,B,P)
 296     # gives P*A + (1-P)*B
 297     my ($r,$a,$b,$p) = @_;
 298     my ($q) = 1.0-$p;
 299     map { $r->{$_} = $q * $a->{$_} + $p * $b->{$_} } qw(X Y A);
 300     $r;
 301 }
 302 sub a_normalise ($$) {
 303     # a_normalise(A,Z)
 304     # adds or subtracts 2*$pi to/from A until it is in [ Z , Z+2*$pi >
 305     my ($a,$z)=@_;
 306     my ($r);
 307     $r= $z + fmod($a - $z, 2.0*$pi);
 308     $r += 2*$pi if $r < $z;
 309     return $r;
 310 }
 311 sub ev_bearing ($$) {
 312     # ev_bearing(A,B)
 313     # returns bearing of B from A
 314     # value returned is in [ A->{A}, A->{A} + 2*$pi >
 315     # A->{A} and B->{A} are otherwise ignored
 316     my ($a,$b)= @_;
 317     my ($r);
 318     $r= atan2($b->{Y} - $a->{Y},
 319               $b->{X} - $a->{X});
 320     $r= a_normalise($r,$a->{A});
 321     return $r;
 322 }
 323
 324 sub v_rotateright ($) {
 325     # v_rotateright(A)
 326     # returns image of A rotated 90 deg clockwise
 327     my ($a)= @_;
 328     return { X => $a->{Y}, Y => -$a->{X} };
 329 }
 330 sub v_dotproduct ($$) {
 331     # v_dotproduct(A,B)
 332     my ($a,$b)= @_;
 333     return $a->{X} * $b->{X} + $a->{Y} * $b->{Y};
 334 }
 335 sub v_scalarmult ($$) {
 336     # v_scalarmult(S,V)
 337     # multiplies V by scalar S and returns product
 338     my ($s,$v)=@_;
 339     return { X => $s * $v->{X}, Y => $s * $v->{Y} };
 340 }
 341 sub v_add ($;@) {
 342     # v_add(A,B,...)
 343     # vector sum of all inputs
 344     my (@i) = @_;
 345     my ($r,$i);
 346     $r= { X => 0.0, Y => 0.0 };
 347     foreach $i (@i) { $r->{X} += $i->{X}; $r->{Y} += $i->{Y}; }
 348     return $r;
 349 }
 350 sub v_subtract ($$) {
 351     # v_subtract(A,B)
 352     # returns vector from A to B, ie B - A
 353     my ($a,$b)= @_;
 354     return { X => $b->{X} - $a->{X},
 355              Y => $b->{Y} - $a->{Y} };
 356 }
 357 sub v_len ($) {
 358     # v_len(V)
 359     # scalar length of V
 360     my ($v)=@_;
 361     my ($x,$y) = ($v->{X}, $v->{Y});
 362     return sqrt($x*$x + $y*$y);
 363 }
 364 sub v_dist ($$) {
 365     # v_dist(A,B)
 366     # returns distance from A to B
 367     return v_len(v_subtract($_[0],$_[1]));
 368 }
 369
 370 sub upd_min ($$) {
 371     my ($limr,$now)=@_;
 372     $$limr= $now unless defined $$limr && $$limr <= $now;
 373 }
 374 sub upd_max ($$) {
 375     my ($limr,$now)=@_;
 376     $$limr= $now unless defined $$limr && $$limr >= $now;
 377 }
 378
 379 sub canf ($$) {
 380     my ($converter,$defaulter)=@_;
 381     my ($spec,$v);
 382     return &$defaulter unless @al;
 383     $spec= shift @al;
 384     $v= &$converter($spec);
 385     dv('canf ','$spec',$spec, '$v',$v);
 386     return $v;
 387 }
 388 sub can ($) { my ($c)=@_; canf($c, sub { die "too few args"; }); }
 389 sub cano ($$) { my ($c,$def)=@_; canf($c, sub { return $def }); }
 390
 391 sub signum ($) { return ($_[0] > 0) - ($_[0] < 0); }
 392
 393 sub bbox ($) {
 394     my ($objhash) = @_;
 395     my ($min_x, $max_x, $min_y, $max_y);
 396     my ($loc);
 397     foreach $loc (values %$objhash) {
 398         upd_min(\$min_x, $loc->{X} - abs($allwidthmax * sin($loc->{A})));
 399         upd_max(\$max_x, $loc->{X} + abs($allwidthmax * sin($loc->{A})));
 400         upd_min(\$min_y, $loc->{Y} - abs($allwidthmax * cos($loc->{A})));
 401         upd_max(\$max_y, $loc->{Y} + abs($allwidthmax * cos($loc->{A})));
 402     }
 403     return ($min_x, $max_x, $min_y, $max_y);
 404 }
 405
 406 our %units_len= qw(- mm  mm 1  cm 10  m 1000);
 407 our %units_ang= qw(- d   r 1); $units_ang{'d'}= 2*$pi / 360;
 408
 409 sub cva_len ($) { my ($sp)=@_; cva_units($sp,\%units_len); }
 410 sub cva_identity ($) { my ($sp)=@_; $sp; }
 411 sub cva_ang ($) { my ($sp)=@_; cva_units($sp,\%units_ang); }
 412 sub cva_absang ($) { input_absang(cva_ang($_[0])) }
 413 sub cva_units ($$) {
 414     my ($sp,$ua)=@_;
 415     my ($n,$u,$r);
 416     $sp =~ m/^([-0-9eE.]*[0-9.])([A-Za-z]*)$/
 417         or die "lexically invalid quantity";
 418     ($n,$u)= ($1,$2);
 419     $u=$ua->{'-'} unless length $u;
 420     defined $ua->{$u} or die "unknown unit $u";
 421     $r= $n * $ua->{$u};
 422     print DEBUG "cva_units($sp,)=$r ($n $u $ua->{$u})\n";
 423     return $r;
 424 }
 425 sub cva_idstr ($) {
 426     my ($sp)=@_;
 427     die "invalid id" unless $sp =~ m/^[a-z][_0-9A-Za-z]*$/;
 428     return $&;
 429 }
 430 sub cva_subsegspec ($) {
 431     my ($sp)=@_;
 432     die "invalid subsegment spec" unless
 433         $sp =~ m,^(\-?)([0-9A-Za-z_]*)(?:/(?:([A-Za-z_]+)(\d+))?)?$,;
 434     my ($sign,$segname,$movfeat,$movconf)=($1,$2,$3,$4);
 435     $segname= exists $ctx->{SegName} ?
 436         $sign.$ctx->{SegName}.$segname
 437             : '';
 438     $segname =~ s/^\-(.*)\-/$1/;
 439     return $segname.'/'.
 440         (defined $movfeat ? sprintf "%s%d", $movfeat, $movconf : '');
 441 }
 442 sub cva_idex ($) {
 443     my ($sp)=@_;
 444     my ($id,$r,$d,$k,$neg,$na,$obj_id,$vflip,$locs);
 445     if ($sp =~ s/^(\^?)(\w+)\!//) {
 446         $vflip= length($1);
 447         $obj_id= $2;
 448         die "invalid obj $obj_id in loc" unless exists $objs{$obj_id};
 449         $locs= $objs{$obj_id}{Loc};
 450     } else {
 451         $locs= $ctx->{Loc};
 452         $vflip= 0;
 453     }
 454     $neg= $sp =~ s/^\-//;
 455     $id= cva_idstr($sp);
 456     die "unknown $id" unless defined $locs->{$id};
 457     $r= $locs->{$id};
 458     $d= "idex $id";
 459     foreach $k (sort keys %$r) { $d .= " $k=$r->{$k}"; }
 460     printf DEBUG "%s\n", $d;
 461     if ($vflip) {
 462         $r= { X => $r->{X}, Y => -$r->{Y}, A => -$r->{A} };
 463     }
 464     if ($neg) {
 465         $na= $r->{A} + $pi;
 466         $na= a_normalise($na,0);
 467         $r= { X => $r->{X}, Y => $r->{Y}, A => $na };
 468     }
 469     return $r;
 470 }
 471 sub cva_idnew ($) {
 472     my ($sp)=@_;
 473     my ($id, $neg);
 474     $neg = $sp =~ s/^\-//;
 475     $id=cva_idstr($sp);
 476     die "duplicate $id" if exists $ctx->{Loc}{$id};
 477     $ctx->{Loc}{$id}{LayerKind}= $ctx->{Layer}{Kind};
 478     push @{ $ctx->{LocsMade} }, {
 479         Id => $id,
 480         Neg => $neg,
 481     };
 482     return $ctx->{Loc}{$id};
 483 }
 484 sub cva_cmd ($) { return cva_idstr($_[0]); }
 485 sub cva__enum ($$) {
 486     my ($sp,$el)=@_;
 487     return $sp if grep { $_ eq $sp } @$el;
 488     die "invalid option (permitted: @$el)";
 489 }
 490 sub cvam_enum { my (@e) = @_; return sub { cva__enum($_[0],\@e); }; }
 491
 492 sub cmd_abs {
 493     my ($i,$nl);
 494     $nl= can(\&cva_idnew);
 495     $i->{X}= can(\&cva_len);
 496     $i->{Y}= can(\&cva_len);
 497     $i->{A}= can(\&cva_ang);
 498     ev_compose($nl, $ctx->{Trans}, $i);
 499 }
 500 sub cmd_rel {
 501     my ($from,$to,$len,$right,$turn);
 502     $from= can(\&cva_idex);
 503     $to= can(\&cva_idnew);
 504     $len= cano(\&cva_len,0);
 505     $right= cano(\&cva_len,0) * $ctx->{Trans}{R};
 506     $turn= cano(\&cva_ang, 0) * $ctx->{Trans}{R};
 507     my ($u)= ev_compose({}, $from, { X => $len, Y => -$right, A => 0 });
 508     ev_compose($to, $u, { X => 0, Y => 0, A => $turn });
 509 }
 510
 511 sub dv__evreff ($) {
 512     my ($pfx) = @_;
 513     $pfx . ($pfx =~ m/\}$|\]$/ ? '' : '->');
 514 }
 515 sub dv__evr ($) {
 516     my ($v) = @_;
 517     return 'undef' if !defined $v;
 518     return $v if $v !~ m/\W/ && $v =~ m/[A-Z]/ && $v =~ m/^[a-z_]/i;
 519     return $v if $v =~ m/^[0-9.]+/;
 520     $v =~ s/[\\\']/\\$&/g;
 521     return "'$v'";
 522 }
 523 sub dv1 ($$$);
 524 sub dv1_kind ($$$$$$$) {
 525     my ($pfx,$expr,$ref,$ref_exp,$ixfmt,$ixesfn,$ixmapfn) = @_;
 526     my ($ix,$any);
 527     return 0 if $ref ne $ref_exp;
 528     $any=0;
 529     foreach $ix (&$ixesfn) {
 530         $any=1;
 531         my ($v)= &$ixmapfn($ix);
 532 #print STDERR "dv1_kind($pfx,$expr,$ref,$ref_exp,$ixmapfn) ix=$ix v=$v\n";
 533         dv1($pfx,$expr.sprintf($ixfmt,dv__evr($ix)),$v);
 534     }
 535     if (!$any) {
 536         printf DEBUG "%s%s= $ixfmt\n", $pfx, $expr, ' ';
 537     }
 538     1;
 539 }
 540 sub dv1 ($$$) {
 541     return 0 unless $debug;
 542     my ($pfx,$expr,$v) = @_;
 543     my ($ref);
 544     $ref= ref $v;
 545 #print STDERR "dv1 >$pfx|$ref<\n";
 546     if (!$ref) {
 547         printf DEBUG "%s%s= %s\n", $pfx,$expr, dv__evr($v);
 548         return;
 549     } elsif ($ref eq 'SCALAR') {
 550         dv1($pfx, ($expr =~ m/^\$/ ? "\$$expr" : '${'.$expr.'}'), $$v);
 551         return;
 552     }
 553     $expr.='->' unless $expr =~ m/\]$|\}$/;
 554     return if dv1_kind($pfx,$expr,$ref,'ARRAY','[%s]',
 555                        sub { ($[ .. $#$v) },
 556                        sub { $v->[$_[0]] });
 557     return if dv1_kind($pfx,$expr,$ref,'HASH','{%s}',
 558                        sub { sort keys %$v },
 559                        sub { $v->{$_[0]} });
 560     printf DEBUG "%s%s is %s\n", $pfx, $expr, $ref;
 561 }
 562
 563 sub dv {
 564     my ($pfx,@l) = @_;
 565     my ($expr,$v,$ref);
 566     while (@l) {
 567         ($expr,$v,@l)=@l;
 568         dv1($pfx,$expr,$v);
 569     }
 570 }
 571
 572 sub o ($) { $o .= $_[0]; }
 573 sub ol ($) { $ol .= $_[0]; }
 574 sub oflushpage () {
 575     return if $subsegcmapreq;
 576     print $o, $ol, "  showpage\n"
 577         or die $!;
 578     $o=$ol='';
 579 }
 580
 581 our $o_path_verb;
 582
 583 sub o_path_begin () {
 584     o("      newpath\n");
 585     $o_path_verb= 'moveto';
 586 }
 587 sub o_path_point ($) {
 588     my ($pt)=@_;
 589     o("        $pt $o_path_verb\n");
 590     $o_path_verb= 'lineto';
 591 }
 592 sub o_path_stroke ($) {
 593     my ($width)=@_;
 594     o("        $width setlinewidth stroke\n");
 595 }
 596 sub o_path_strokeonly () {
 597     o("      stroke\n");
 598 }
 599
 600 sub o_line ($$$) {
 601     my ($a,$b,$width)=@_;
 602     o_path_begin();
 603     o_path_point($a);
 604     o_path_point($b);
 605     o_path_stroke($width);
 606 }
 607
 608 sub current_draw () {
 609     my ($r);
 610     $r= $ctx->{Draw} =~ m/X/ ? '' : $ctx->{Draw};
 611     $r;
 612 }
 613
 614 sub psu_coords ($$$) {
 615     my ($ends,$inunit,$across)=@_;
 616     # $ends->[0]{X} etc.; $inunit 0 to 1 (but go to 1.5);
 617     # $across in mm, +ve to right.
 618     my (%ea_zo, $zo, $prop);
 619     $ea_zo{X}=$ea_zo{Y}=0;
 620     foreach $zo (qw(0 1)) {
 621         $prop= $zo ? $inunit : (1.0 - $inunit);
 622         $ea_zo{X} += $prop * ($ends->[$zo]{X} - $across * sin($ends->[0]{A}));
 623         $ea_zo{Y} += $prop * ($ends->[$zo]{Y} + $across * cos($ends->[0]{A}));
 624     }
 625 #    dv("psu_coords ", '$ends',$ends, '$inunit',$inunit, '$across',$across,
 626 #       '\\%ea_zo', \%ea_zo);
 627     return $ea_zo{X}." ".$ea_zo{Y};
 628 }
 629
 630 sub parametric__o_pt ($) {
 631     my ($pt)=@_;
 632     o_path_point("$pt->{X} $pt->{Y}");
 633 }
 634
 635 sub segment_used_len ($) {
 636     my ($used) = @_;
 637     return if @segments < 3;
 638     $segments[1] -= $used;
 639     return if $segments[1] > 0;
 640     @segments= @segments[2..$#segments];
 641     o("% segments @segments\n");
 642 }
 643
 644 sub parametric_segment ($$$$$) {
 645     my ($p0,$p1,$lenperp,$minradius,$calcfn) = @_;
 646     # makes $p (global) go from $p0 to $p1  ($p1>$p0)
 647     # $lenperp is the length of one unit p, ie the curve
 648     # must have a uniform `density' in parameter space
 649     # $calcfn is invoked with $p set and should return a loc
 650     # (ie, ref to X =>, Y =>, A =>).
 651     my ($pa,$pb,@ends,$side,$ppu,$e,$v,$tick,$draw,$allwidth);
 652     return unless $ctx->{Draw} =~ m/[ARSCG]/;
 653     $ppu= $psu_ulen/$lenperp;
 654     $allwidth= allwidth($minradius);
 655     my ($railctr)=($psu_gauge + $psu_raillw)*0.5;
 656     my ($tickend)=($allwidth - $psu_ticklen);
 657     my ($tickpitch)=($psu_ulen / $psu_ticksperu);
 658     my ($sleeperctr)=($psu_ulen*0.5);
 659     my ($sleeperend)=($psu_sleeperlen*0.5);
 660 print DEBUG "ps $p0 $p1 $lenperp ($ppu)\n";
 661     $draw= current_draw();
 662     if ($draw =~ m/G/) {
 663         my ($pt,$going,$red,$csegbare,$movfeat,$movstroke);
 664         $going=0;
 665         o("% segments @segments\n");
 666         o("    $psu_subseglw setlinewidth\n");
 667         $param=$p0;
 668         $pt= &$calcfn;
 669         for (;;) {
 670             $movstroke= "      stroke\n";
 671             $csegbare= $segments[0];
 672             $csegbare =~ s/^\-//;
 673             if ($subsegcmapreq) {
 674                 if (!exists $subsegcmap{$csegbare}) {
 675                     print "$csegbare\n" or die $!;
 676                     $subsegcmap{$csegbare}++;
 677                 }
 678             } else {
 679                 $movfeat= $csegbare =~ s,(/\D+)(\d+)$,$1, ? $2 : 'f';
 680                 if ($subsegmovfeatpos ne $movfeat) {
 681                     $movstroke= "%     no-stroke\n";
 682                 }
 683                 die "unknown subsegment colour for $csegbare\n"
 684                     unless exists $subsegcmap{$csegbare};
 685                 $red= $pt->{A} / (2*$pi);
 686                 $red *= $subsegcmapangscale;
 687                 $red += $subsegcmapangscale*2;
 688                 $red += $subsegcmapangscale/2 if $segments[0] =~ m/^\-/;
 689                 $red %= $subsegcmapangscale;
 690                 $red /= 255.0;
 691                 $red= sprintf("%f", $red);
 692                 o("    $red $subsegcmap{$csegbare} setrgbcolor\n");
 693             }
 694             o_path_begin();
 695             parametric__o_pt($pt);
 696
 697             $param += $ppu;
 698             last if $param>=$p1;
 699             segment_used_len($psu_ulen);
 700             $pt= &$calcfn;
 701             parametric__o_pt($pt);
 702             o($movstroke);
 703         }
 704         segment_used_len(($p1-($param-$ppu)) * $lenperp);
 705         $param=$p1;
 706         parametric__o_pt(&$calcfn);
 707         o($movstroke);
 708     }
 709     if ($draw =~ m/C/) {
 710         my ($pt);
 711         o("    $psu_thinlw setlinewidth\n");
 712         o_path_begin();
 713         for ($param=$p0; $param<$p1; $param += $ppu) {
 714             parametric__o_pt(&$calcfn);
 715         }
 716         $param=$p1;
 717         parametric__o_pt(&$calcfn);
 718         o("      stroke\n");
 719     }
 720     return unless $draw =~ m/[ARS]/;
 721     for ($pa= $p0; $pa<$p1; $pa=$pb) {
 722         $pb= $pa + $ppu;
 723         $param= $pa; $ends[0]= @ends ? $ends[1] : &$calcfn;
 724         $param= $pb; $ends[1]= &$calcfn;
 725 #print DEBUG "pa $pa $ends[0]{X} $ends[0]{Y} $ends[0]{A}\n";
 726 #print DEBUG "pb $pb $ends[1]{X} $ends[1]{Y} $ends[1]{A}\n";
 727         $e= $pb<=$p1 ? 1.0 : ($p1-$pa)/$ppu;
 728         o("    gsave\n");
 729         o_path_begin();
 730         o_path_point(psu_coords(\@ends,0,-$allwidth));
 731         o_path_point(psu_coords(\@ends,0,$allwidth));
 732         o_path_point(psu_coords(\@ends,$e,$allwidth));
 733         o_path_point(psu_coords(\@ends,$e,-$allwidth));
 734         o("        closepath clip\n");
 735         foreach $side qw(-1 1) {
 736             if ($draw =~ m/R/) {
 737                 o_line(psu_coords(\@ends,0,$side*$railctr),
 738                        psu_coords(\@ends,1.5,$side*$railctr),
 739                        $psu_raillw);
 740             }
 741         }
 742         if ($draw =~ m/S/) {
 743             o_line(psu_coords(\@ends,$sleeperctr,-$sleeperend),
 744                    psu_coords(\@ends,$sleeperctr,+$sleeperend),
 745                    $psu_sleeperlw);
 746         }
 747         if ($draw =~ m/A/) {
 748             o("        0.5 setgray\n");
 749             foreach $side qw(-1 1) {
 750                 o_line(psu_coords(\@ends,0,$side*$allwidth),
 751                        psu_coords(\@ends,1.5,$side*$allwidth),
 752                        $psu_edgelw);
 753                 for ($tick=0; $tick<1.5; $tick+=$tickpitch/$psu_ulen) {
 754                     o_line(psu_coords(\@ends,$tick,$side*$allwidth),
 755                            psu_coords(\@ends,$tick,$side*$tickend),
 756                            $psu_ticklw);
 757                 }
 758             }
 759         }
 760         o("      grestore\n");
 761     }
 762 }
 763
 764 sub arc ($$$$$) {
 765     my ($to, $ctr,$from, $radius,$delta) = @_;
 766     # does parametric_segment to draw an arc centred on $ctr
 767     # ($ctr->{A} ignored)
 768     # from $from with radius $radius (this must be consistent!)
 769     # and directionally-subtending an angle $delta.
 770     # sets $to->... to be the other end, and returns $to
 771     my ($beta);
 772     $to->{A}= $beta= $from->{A} + $delta;
 773     $to->{X}= $ctr->{X} - $radius * sin($beta);
 774     $to->{Y}= $ctr->{Y} + $radius * cos($beta);
 775     return if abs($delta*$radius) < 1e-9;
 776     parametric_segment(0.0,1.0, abs($radius*$delta), $radius, sub {
 777         my ($beta) = $from->{A} + $delta * $param;
 778         return { X => $ctr->{X} - $radius * sin($beta),
 779                  Y => $ctr->{Y} + $radius * cos($beta),
 780                  A => $beta }
 781     });
 782 }
 783
 784 # joins_xxx all take $results, $from, $to, $minradius
 785 # where $results->[]{Path}{K} etc. and $results->[]{SolKinds}[]
 786
 787 sub joins_twoarcs ($$$$) {
 788     my ($results, $from,$to,$minradius) = @_;
 789     # two circular arcs of equal maximum possible radius
 790     # algorithm courtesy of Simon Tatham (`Railway problem',
 791     # pers.comm. to ijackson@chiark 23.1.2004)
 792     my ($sigma,$distfact, $theta,$phi, $a,$b,$c,$d, $m,$r, $radius);
 793     my ($cvec,$cfrom,$cto,$midpt, $delta1,$delta2, $path,$reverse);
 794     $sigma= ev_bearing($from,$to);
 795     $distfact= v_dist($from,$to);
 796     $theta= 0.5 * $pi - ($from->{A} - $sigma);
 797     $phi=   0.5 * $pi - ($to->{A} + $pi - $sigma);
 798     $a= 2 * (1 + cos($theta - $phi));
 799     $b= 2 * (cos($theta) - cos($phi));
 800     $c= -1;
 801     $d= sqrt($b*$b - 4*$a*$c);
 802     o("%     twoarcs theta=".ang2deg($theta)." phi=".ang2deg($phi).
 803       " ${a}r^2 + ${b}r + ${c} = 0\n");
 804     foreach $m (qw(-1 1)) {
 805         if ($a < 1e-6) {
 806             o("%     twoarcs $m insoluble\n");
 807             next;
 808         }
 809         $r= -0.5 * (-$b + $m*$d) / $a;
 810         $radius= -$r * $distfact;
 811         o("%     twoarcs $m radius $radius ");
 812         if (abs($radius) < $minradius) { o("too-small\n"); next; }
 813         $cfrom=  ev_compose({}, $from, { X=>0, Y=>-$radius, A=>-0.5*$pi });
 814         $cto=    ev_compose({}, $to,   { X=>0, Y=> $radius, A=> 0.5*$pi });
 815         $midpt=  ev_lincomb({}, $cfrom, $cto, 0.5);
 816         $reverse= signum($r);
 817         if ($reverse<0) {
 818             $cfrom->{A} += $pi;
 819             $cto->{A} += $pi;
 820         }
 821         $delta1= ev_bearing($cfrom, $midpt) - $cfrom->{A};
 822         $delta2= ev_bearing($cto,   $midpt) - $cto->{A};
 823         o("ok deltas ".ang2deg($delta1)." ".ang2deg($delta2)."\n");
 824         if ($reverse<0) {
 825             $delta1 -= 2*$pi;
 826             $delta2 -= 2*$pi;
 827         }
 828         my ($fs);
 829         $path= [{ T=>Arc, F=>$from, C=>$cfrom, R=> $radius, D=>$delta1 },
 830                 { T=>Arc, F=>$to,   C=>$cto,   R=>-$radius, D=>$delta2 }];
 831         push @$results, { Path => $path,
 832                           SolKinds =>  [ 'twoarcs', 'cross' ] };
 833     }
 834 }
 835
 836 sub joins_arcsline ($$$$) {
 837     my ($results, $from,$to,$minradius) = @_;
 838     # two circular arcs of specified radius
 839     # with an intervening straight
 840     my ($lr,$inv, $c,$d,$alpha,$t,$k,$l,$rpmsina,$rcosa,$linelen, $path);
 841     if ($minradius<=1e-6) { o("%     arcsline no-radius\n"); return; }
 842     foreach $lr (qw(-1 +1)) {
 843         foreach $inv (qw(-1 +1)) {
 844             $c=ev_compose({},$from,{X=>0,Y=>-$lr*$minradius, A=>0 });
 845             $d=ev_compose({},$to,{X=>0, Y=>-$inv*$lr*$minradius, A=>$pi });
 846             $t= v_dist($c,$d);
 847             o("%     arcsline $lr $inv t=$t ");
 848             if ($t < 1e-6) { o("concentric"); next; }
 849             $c->{A}= $d->{A}= ev_bearing($c,$d);
 850             o("bearing ".ang2deg($c->{A}));
 851             if ($inv>0) {
 852                 o("\n");
 853                 $k= ev_compose({}, $c, { X=>0, Y=>$lr*$minradius, A=>0 });
 854                 $l= ev_compose({}, $d, { X=>0, Y=>$lr*$minradius, A=>0 });
 855                 $linelen= $t;
 856             } else {
 857                 my ($cosalpha) = 2.0 * $minradius / $t;
 858                 if ($cosalpha > (1.0 - 1e-6)) { o(" too-close\n"); next; }
 859                 $alpha= acos($cosalpha);
 860                 $rpmsina= $lr * $minradius * sin($alpha);
 861                 $rcosa= $minradius * $cosalpha;
 862                 $k= ev_compose({}, $c, { X=>$rcosa, Y=>$rpmsina, A=>0 });
 863                 $l= ev_compose({}, $d, { X=>-$rcosa, Y=>-$rpmsina, A=>0 });
 864                 $k->{A}= $l->{A}= ev_bearing($k,$l);
 865                 o(" alpha=".ang2deg($alpha)." kl^=".ang2deg($k->{A})."\n");
 866                 $linelen= v_dist($k,$l);
 867             }
 868             $path= [{ T => Arc, F => $from, C => $c,
 869                       R =>$lr*$minradius,
 870                       D => -$lr * a_normalise
 871                           ($lr * ($from->{A} - $k->{A}), 0) },
 872                     { T => Line, A => $k, B => $l, L => $linelen },
 873                     { T => Arc, F => $l, C => $d,
 874                       R => $inv*$lr*$minradius,
 875                       D => -$lr*$inv * a_normalise
 876                           (-$lr*$inv * ($to->{A} - $l->{A}), 0) }];
 877             push @$results,
 878             { Path => $path,
 879               SolKinds => [ 'arcsline', ($inv<0 ? 'cross' : 'loop') ] };
 880         }
 881     }
 882 }
 883
 884 sub joins_arcline ($$$$) {
 885     my ($results, $from,$to,$minradius) = @_;
 886     # one circular arc and a straight line
 887     my ($swap,$echoice,$path, $ap,$bp,$av,$bv, $e,$f, $ae,$af,$afae);
 888     my ($dak,$ak,$kj,$k,$j,$aja,$jl,$l,$jc,$lc,$c,$rj,$rb);
 889     foreach $swap (qw(-1 +1)) {
 890         foreach $echoice (qw(0 1)) {
 891             $ap= $from; $bp= { %$to }; $bp->{A} += $pi;
 892             ($ap,$bp)= ($bp,$ap) if $swap<0;
 893             $av= ev_byang({}, $ap->{A});
 894             $bv= ev_byang({}, $bp->{A});
 895             $e= ev_byang({}, 0.5 * ($ap->{A} + $bp->{A} + $echoice * $pi));
 896             $f= v_rotateright($e);
 897             o("%     arcline $swap $echoice e ".loc2dbg($e)."\n");
 898             $ae= v_dotproduct($av,$e);
 899             $af= v_dotproduct($av,$f);
 900             o("%     arcline $swap $echoice a.e=$ae a.f=$af ");
 901             if (abs($ae) < 1e-6) { o(" singular\n"); next; }
 902             $afae= $af/$ae;
 903             o("a.f/a.e=$afae\n");
 904             $dak= v_dotproduct(v_subtract($ap,$bp), $e);
 905             $ak= v_scalarmult($dak, $e);
 906             $kj= v_scalarmult($dak * $afae, $f);
 907             $k= v_add($ap, $ak);
 908             $j= v_add($k, $kj);
 909             $aja= v_dotproduct(v_subtract($ap,$j), $av);
 910             o("%     arcline $swap $echoice d_ak=$dak aj.a=$aja ");
 911             if ($aja < 0) { o(" backwards aj\n"); next; }
 912             $jl= v_scalarmult(0.5, v_subtract($j, $bp));
 913             $lc= v_scalarmult(-v_dotproduct($jl, $f) * $afae, $e);
 914             $l= v_add($j, $jl);
 915             $c= v_add($l, $lc);
 916             $rj= v_dotproduct(v_subtract($j,$c), v_rotateright($av));
 917             $rb= v_dotproduct(v_subtract($c,$bp), v_rotateright($bv));
 918             o("r_j=$rj r_b=$rb ");
 919             if ($rj * $rb < 0) { o(" backwards b\n"); next; }
 920             if (abs($rj) < $minradius) { o(" too-small\n"); next; }
 921             o("ok\n");
 922             $j->{A}= $ap->{A};
 923             $c->{A}= 0;
 924             $path= [{ T => Line, A => $ap, B => $j, L => $aja },
 925                     { T => Arc, F => $j, C => $c, R => $rj,
 926                       D => -signum($rj) * a_normalise
 927                           (-signum($rj) * ($bp->{A} + $pi - $j->{A}), 0) }];
 928             $path= [ reverse @$path ] if $swap<0;
 929             push @$results, { Path => $path, SolKinds =>  [ 'arcline' ] };
 930         }
 931     }
 932 }
 933
 934 sub cmd_join {
 935     my ($from,$to,$minradius);
 936     my (@results,$result);
 937     my ($path,$segment,$bestpath,$len,$scores,$bestscores,@bends,$skl);
 938     my ($crit,$cs,$i,$cmp);
 939     $from= can(\&cva_idex);
 940     $to= can(\&cva_idex);
 941     $minradius= can(\&cva_len);
 942     o("%   join ".loc2dbg($from)."..".loc2dbg($to)." $minradius\n");
 943     joins_twoarcs(\@results, $from,$to,$minradius);
 944     joins_arcsline(\@results, $from,$to,$minradius);
 945     joins_arcline(\@results, $from,$to,$minradius);
 946     foreach $result (@results) {
 947         $path= $result->{Path};
 948         $skl= $result->{SolKinds};
 949         o("%   possible path @$skl $path\n");
 950         $len= 0;
 951         @bends= ();
 952         foreach $segment (@$path) {
 953             if ($segment->{T} eq Arc) {
 954                 o("%     Arc C ".loc2dbg($segment->{C}).
 955                   " R $segment->{R} D ".ang2deg($segment->{D})."\n");
 956                 $len += abs($segment->{R} * $segment->{D});
 957                 push @bends, -abs($segment->{R}) * $segment->{D}; # right +ve
 958             } elsif ($segment->{T} eq Line) {
 959                 o("%     Line A ".loc2dbg($segment->{A}).
 960                   " B ".loc2dbg($segment->{A})." L $segment->{L}\n");
 961                 $len += abs($segment->{L});
 962             } else {
 963                 die "unknown segment $segment->{T}";
 964             }
 965         }
 966         o("%    length $len bends @bends.\n");
 967         $scores= [];
 968         foreach $crit (@al, 'short') {
 969             if ($crit eq 'long') { $cs= $len; }
 970             elsif ($crit eq 'short') { $cs= -$len; }
 971             elsif ($crit =~ m/^(begin|end|)(left|right)$/) {
 972                 if ($1 eq 'begin') { $cs= $bends[0]; }
 973                 elsif ($1 eq 'end') { $cs= $bends[$#bends]; }
 974                 else { $cs=0; map { $cs += $_ } @bends; }
 975                 $cs= -$cs if $2 eq 'left';
 976             } elsif ($crit =~ m/^(\!?)(twoarcs|arcs?line|cross|loop)$/) {
 977                 $cs= !!(grep { $2 eq $_ } @$skl) != ($1 eq '!');
 978             } else {
 979                 die "unknown sort criterion $crit";
 980             }
 981             push @$scores, $cs;
 982         }
 983         o("%    scores @$scores\n");
 984         if (defined $bestpath) {
 985             for ($i=0,$cmp=0; !$cmp && $i<@$scores; $i++) {
 986                 $cmp= $scores->[$i] <=> $bestscores->[$i];
 987             }
 988             next if $cmp < 0;
 989         }
 990         $bestpath= $path;
 991         $bestscores= $scores;
 992     }
 993     die "no solution" unless defined $bestpath;
 994     o("%   chose path $bestpath @al\n");
 995     @al= ();
 996     foreach $segment (@$bestpath) {
 997         if ($segment->{T} eq 'Arc') {
 998             arc({}, $segment->{C},$segment->{F},$segment->{R},$segment->{D});
 999         } elsif ($segment->{T} eq 'Line') {
1000             line($segment->{A}, $segment->{B}, $segment->{L});
1001         } else {
1002             die "unknown segment";
1003         }
1004     }
1005 }
1006
1007 sub line ($$$) {
1008     my ($from,$to,$len) = @_;
1009     parametric_segment(0.0, 1.0, abs($len) + 1e-6, undef, sub {
1010         ev_lincomb({}, $from, $to, $param);
1011     });
1012 }
1013
1014 sub cmd_extend {
1015     my ($from,$to,$radius,$len,$upto,$ctr,$beta,$ang,$how,$sign_r);
1016     $from= can(\&cva_idex);
1017     $to= can(\&cva_idnew);
1018     printf DEBUG "from $from->{X} $from->{Y} $from->{A}\n";
1019     $how= can(cvam_enum(qw(len upto ang uptoang parallel)));
1020     if ($how eq 'len') { $len= can(\&cva_len); }
1021     elsif ($how =~ m/ang$/) { $ang= can(\&cva_ang); }
1022     elsif ($how eq 'parallel' || $how eq 'upto') { $upto= can(\&cva_idex); }
1023     $radius= cano(\&cva_len, 'Inf'); # +ve is right hand bend
1024     if ($radius eq 'Inf') {
1025 #       print DEBUG "extend inf $len\n";
1026         if ($how eq 'upto') {
1027             $len= ($upto->{X} - $from->{X}) * cos($from->{A})
1028                 + ($upto->{Y} - $from->{Y}) * sin($from->{A});
1029         } elsif ($how eq 'len') {
1030         } else {
1031             die "len of straight spec by angle";
1032         }
1033         printf DEBUG "len $len\n";
1034         $to->{X}= $from->{X} + $len * cos($from->{A});
1035         $to->{Y}= $from->{Y} + $len * sin($from->{A});
1036         $to->{A}= $from->{A};
1037         line($from,$to,$len);
1038     } else {
1039         my ($sign_r, $sign_ang, $ctr, $beta_interval, $beta, $delta);
1040         print DEBUG "radius >$radius<\n";
1041         $radius *= $ctx->{Trans}{R};
1042         $sign_r= signum($radius);
1043         $sign_ang= 1;
1044         $ctr->{X}= $from->{X} + $radius * sin($from->{A});
1045         $ctr->{Y}= $from->{Y} - $radius * cos($from->{A});
1046         if ($how eq 'upto') {
1047             $beta= atan2(-$sign_r * ($upto->{X} - $ctr->{X}),
1048                          $sign_r * ($upto->{Y} - $ctr->{Y}));
1049             $beta_interval= 1.0;
1050         } elsif ($how eq 'parallel') {
1051             $beta= $upto->{A};
1052             $beta_interval= 1.0;
1053         } elsif ($how eq 'uptoang') {
1054             $beta= input_absang($ang);
1055             $beta_interval= 2.0;
1056         } elsif ($how eq 'len') {
1057             $sign_ang= signum($len);
1058             $beta= $from->{A} - $sign_r * $len / abs($radius);
1059             $beta_interval= 2.0;
1060         } else {
1061             $sign_ang= signum($ang);
1062             $beta= $from->{A} - $sign_r * $ang;
1063             $beta_interval= 2.0;
1064         }
1065     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1066         $beta += $sign_ang * $sign_r * 4.0 * $pi;
1067         for (;;) {
1068             $delta= $beta - $from->{A};
1069             last if $sign_ang * $sign_r * $delta <= 0;
1070             $beta -= $sign_ang * $sign_r * $beta_interval * $pi;
1071         }
1072     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1073         arc($to, ,$ctr,$from, $radius,$delta);
1074     }
1075     printf DEBUG "to $to->{X} $to->{Y} $to->{A}\n";
1076 }
1077
1078 sub loc2dbg ($) {
1079     my ($loc) = @_;
1080     return "$loc->{X} $loc->{Y} ".ang2deg($loc->{A});
1081 }
1082 sub ang2deg ($) {
1083     return $_[0] * 180 / $pi;
1084 }
1085 sub input_absang ($) {
1086     return $_[0] * $ctx->{Trans}{R} + $ctx->{Trans}{A};
1087 }
1088 sub input_abscoords ($$) {
1089     my ($in,$out);
1090     ($in->{X}, $in->{Y}) = @_;
1091     $in->{A}= 0.0;
1092     $out= ev_compose({}, $ctx->{Trans}, $in);
1093     return ($out->{X}, $out->{Y});
1094 }
1095
1096 sub newctx (;$) {
1097     my ($ctx_save) = @_;
1098     $ctx= {
1099         Trans => { X => 0.0, Y => 0.0, A => 0.0, R => 1.0 },
1100         InRunObj => "",
1101         DrawMap => sub { $_[0]; }
1102         };
1103     %{ $ctx->{Layer} }= %{ $ctx_save->{Layer} }
1104         if defined $ctx_save;
1105 }
1106
1107 our $defobj_save;
1108 our $defobj_ispart;
1109
1110 sub cmd_defobj { cmd__defobj(0); }
1111 sub cmd_defpart { cmd__defobj(1); }
1112 sub cmd__defobj ($) {
1113     my ($ispart) = @_;
1114     my ($id);
1115     $id= can(\&cva_idstr);
1116     die "nested defobj" if $defobj_save;
1117     die "repeated defobj" if exists $objs{$id};
1118     $defobj_save= $ctx;
1119     $defobj_ispart= $ispart;
1120     newctx($defobj_save);
1121     $ctx->{CmdLog}= [ ];
1122     $ctx->{InDefObj}= $id;
1123     $ctx->{Draw}= $defobj_save->{Draw}.'X';
1124     $ctx->{DrawMap}= sub { ''; };
1125     $ctx->{Layer}= { Level => 5, Kind => '' };
1126 }
1127
1128 sub cmd_enddef {
1129     my ($bit,$id);
1130     $id= $ctx->{InDefObj};
1131     die "unmatched enddef" unless defined $id;
1132     foreach $bit (qw(CmdLog Loc)) {
1133         $objs{$id}{$bit}= $ctx->{$bit};
1134     }
1135     $objs{$id}{Part}= $defobj_ispart;
1136     $ctx= $defobj_save;
1137     $defobj_save= undef;
1138     $defobj_ispart= undef;
1139 }
1140
1141 sub cmd__runobj ($) {
1142     my ($obj_id)=@_;
1143     my ($c);
1144     local (@al);
1145     dv("cmd__runobj $obj_id ",'$ctx',$ctx);
1146     foreach $c (@{ $objs{$obj_id}{CmdLog} }) {
1147         @al= @$c;
1148         next if $al[0] eq 'enddef';
1149         cmd__one();
1150     }
1151 }
1152
1153 sub cmd_segment {
1154     my ($csss,$length);
1155     $ctx->{SavedSegment}= pop @segments
1156         unless exists $ctx->{SavedSegment};
1157     @segments= ();
1158     while (@al>1) {
1159         $csss= can(\&cva_subsegspec);
1160         $length= can(\&cva_len);
1161         push @segments, $csss, $length;
1162     }
1163     $csss= can(\&cva_subsegspec);
1164     push @segments, $csss;
1165 }
1166
1167 sub layer_draw ($$) {
1168     my ($k,$l) = @_;
1169     my ($eo,$cc, $r);
1170     if ($k eq '') {
1171         $r= 'RLMN';
1172     } elsif ($k eq 's') {
1173         $r= '';
1174     } elsif ($k eq 'l') {
1175         $r= 'CLMN';
1176     } else {
1177         $r= 'ARSCLMNO';
1178     }
1179     foreach $eo (@eopts) {
1180 #print STDERR "$. layer $k$l eo $eo re $eo->{GlobRe} then $eo->{DrawMods} now $r\n";
1181         next unless $k =~ m/^$eo->{GlobRe}$/;
1182 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} match\n";
1183         next unless &{ $eo->{LayerCheck} }($l);
1184 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} checked\n";
1185         foreach $cc (split //, $eo->{DrawMods}) {
1186             $r =~ s/$cc//ig;
1187             $r .= $cc if $cc =~ m/[A-Z]/;
1188         }
1189     }
1190 #print STDERR "layer $k$l gives $r (before map)\n";
1191     $r= &{ $ctx->{DrawMap} }($r);
1192     return $r;
1193 }
1194
1195 sub cmd_layer {
1196     my ($kl, $k,$l);
1197     $kl= can(\&cva_identity);
1198     $kl =~ m/^([A-Za-z_]*)(\d*|\=|\*)$/ or die "invalid layer spec";
1199     ($k,$l)=($1,$2);
1200     $l= $output_layer if $l eq '*';
1201     $l= $ctx->{Layer}{Level} if $l =~ m/^\=?$/;
1202     $ctx->{Layer}{Kind}= $k;
1203     $ctx->{Layer}{Level}= $l;
1204     $ctx->{Draw}= layer_draw($k,$l);
1205 }
1206
1207 sub cmd_part { cmd__obj(Part); }
1208 sub cmd_obj { cmd__obj(1); }
1209 sub cmd_objflip { cmd__obj(-1); }
1210
1211 sub cmd__obj ($) {
1212     my ($how)=@_;
1213     my ($obj_id, $ctx_save, $pfx, $actual, $formal_id, $formal, $formcv);
1214     my ($part_name, $ctx_inobj, $obj, $id, $newid, $newpt);
1215     if ($how eq Part) {
1216         $part_name= can(\&cva_idstr);
1217         $how= (@al && $al[0] =~ s/^\^//) ? -1 : +1;
1218     }
1219     $obj_id= can(\&cva_idstr);
1220     if (defined $part_name) {
1221         $formal_id= can(\&cva_idstr);
1222         $actual= cano(\&cva_idex, undef);
1223         if (!defined $actual) {
1224             $actual= cva_idex("${part_name}_${formal_id}");
1225         }
1226     } else {
1227         $actual= can(\&cva_idex);
1228         $formal_id= can(\&cva_idstr);
1229     }
1230     $obj= $objs{$obj_id};
1231     dv("cmd__obj ",'$obj',$obj);
1232     die "unknown obj $obj_id" unless $obj;
1233     $formal= $obj->{Loc}{$formal_id};
1234     die "unknown formal $formal_id" unless $formal;
1235     $ctx_save= $ctx;
1236     newctx($ctx_save);
1237     $how *= $ctx_save->{Trans}{R};
1238     $ctx->{Trans}{R}= $how;
1239     $ctx->{Trans}{A}= $actual->{A} - $formal->{A}/$how;
1240     $formcv= ev_compose({}, $ctx->{Trans},$formal);
1241     $ctx->{Trans}{X}= $actual->{X} - $formcv->{X};
1242     $ctx->{Trans}{Y}= $actual->{Y} - $formcv->{Y};
1243     if (defined $part_name) {
1244         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${part_name}:";
1245     } else {
1246         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}::";
1247     }
1248     if ($segments[0] =~ m,(.*[^-]+)/,) {
1249         $ctx->{SegName}= $1;
1250     }
1251     $ctx->{DrawMap}= sub {
1252         my ($i) = @_;
1253         $i= &{ $ctx_save->{DrawMap} }($i);
1254         if ($obj->{Part}) {
1255             $i =~ s/[LMN]//g;
1256             $i =~ s/O/MNO/;
1257         } else {
1258             $i =~ s/[LM]//g;
1259             $i =~ s/N/MN/;
1260         }
1261         return $i;
1262     };
1263     $ctx->{Draw}= &{ $ctx->{DrawMap} }($ctx_save->{Draw});
1264     cmd__runobj($obj_id);
1265     if (defined $part_name) {
1266         $pfx= $part_name.'_';
1267     } else {
1268         if (@al && $al[0] eq '=') {
1269             $pfx= ''; shift @al;
1270         } else {
1271             $pfx= cano(\&cva_idstr,undef);
1272         }
1273     }
1274     if (exists $ctx->{SavedSegment}) {
1275         @segments= ($ctx->{SavedSegment});
1276     }
1277     $ctx_inobj= $ctx;
1278     $ctx= $ctx_save;
1279     if (defined $pfx) {
1280         foreach $id (keys %{ $ctx_inobj->{Loc} }) {
1281             next if $id eq $formal_id;
1282             $newid= $pfx.$id;
1283             next if exists $ctx_save->{Loc}{$newid};
1284             $newpt= cva_idnew($newid);
1285             %$newpt= %{ $ctx_inobj->{Loc}{$id} };
1286         }
1287     }
1288     if (defined $part_name) {
1289         my ($formalr_id, $actualr_id, $formalr, $actualr);
1290         while (@al) {
1291             die "part results come in pairs\n" unless @al>=2;
1292             ($formalr_id, $actualr_id, @al) = @al;
1293             if ($actualr_id =~ s/^\-//) {
1294                 $formalr_id= "-$formalr_id";
1295                 $formalr_id =~ s/^\-\-//;
1296             }
1297             {
1298                 local ($ctx) = $ctx_inobj;
1299                 $formalr= cva_idex($formalr_id);
1300             }
1301             $actualr= cva_idnew($actualr_id);
1302             %$actualr= %$formalr;
1303         }
1304     }
1305 }
1306
1307 sub cmd__do {
1308     my ($cmd);
1309 dv("cmd__do $ctx @al ",'$ctx',$ctx);
1310     $cmd= can(\&cva_cmd);
1311     my ($lm,$id,$loc,$io,$ad,$draw,$thendrawre);
1312     $io= defined $ctx->{InDefObj} ? "$ctx->{InDefObj}!" : $ctx->{InRunObj};
1313     o("%L cmd   $io $cmd @al\n");
1314     $ctx->{LocsMade}= [ ];
1315     {
1316         no strict 'refs';
1317         &{ "cmd_$cmd" };
1318     };
1319     die "too many args" if @al;
1320     foreach $lm (@{ $ctx->{LocsMade} }) {
1321         $id= $lm->{Id};
1322         $loc= $ctx->{Loc}{$id};
1323         $loc->{A} += $pi if $lm->{Neg};
1324         $ad= ang2deg($loc->{A});
1325         ol("%L point $io$id ".loc2dbg($loc)." ($lm->{Neg})\n");
1326         $draw= layer_draw($loc->{LayerKind}, $ctx->{Layer}{Level});
1327         if ($draw =~ m/[LM]/) {
1328             ol("    gsave\n".
1329                "      $loc->{X} $loc->{Y} translate $ad rotate\n");
1330             if ($draw =~ m/M/) {
1331                 ol("      0 $allwidthmin newpath moveto\n".
1332                    "      0 -$allwidthmin lineto\n".
1333                    "      $lmu_marklw setlinewidth stroke\n");
1334             }
1335             if ($draw =~ m/L/) {
1336                 ol("      /s ($id) def\n".
1337                    "      lf setfont\n".
1338                    "      /sx5  s stringwidth pop\n".
1339                    "      0.5 mul $lmu_txtboxpadx add def\n".
1340                    "      -90 rotate  0 $lmu_txtboxoff translate  newpath\n".
1341                    "      sx5 neg  0             moveto\n".
1342                    "      sx5 neg  $lmu_txtboxh  lineto\n".
1343                    "      sx5      $lmu_txtboxh  lineto\n".
1344                    "      sx5      0             lineto closepath\n".
1345                    "      gsave  1 setgray fill  grestore\n".
1346                    "      $lmu_txtboxlw setlinewidth stroke\n".
1347                    "      sx5 neg $lmu_txtboxpadx add  $lmu_txtboxtxty\n".
1348                    "      moveto s show\n");
1349             }
1350             ol("      grestore\n");
1351         }
1352     }
1353 }
1354
1355 sub cmd_showlibrary {
1356     my ($obj_id, $y, $x, $ctx_save, $width, $height);
1357     my ($max_x, $min_x, $max_y, $min_y, $nxty, $obj, $loc, $pat, $got, $glob);
1358     my ($adj);
1359     $x=$olu_left; $y=$olu_bottom; undef $nxty;
1360     $ctx_save= $ctx;
1361     foreach $obj_id (sort keys %objs) {
1362         $got= 1;
1363         foreach $glob (@al) {
1364             $pat= $glob;
1365             $got= !($pat =~ s/^\!//);
1366             die "bad pat" if $pat =~ m/[^0-9a-zA-Z_*?]/;
1367             $pat =~ s/\*/\.*/g; $pat =~ s/\?/./g;
1368             last if $obj_id =~ m/^$pat$/;
1369             $got= !$got;
1370         }
1371         next unless $got;
1372         $obj= $objs{$obj_id};
1373         next unless $obj->{Part};
1374         ($min_x, $max_x, $min_y, $max_y) = bbox($obj->{Loc});
1375         newctx($ctx_save);
1376
1377         for (;;) {
1378             $width= $max_x - $min_x;
1379             $height= $max_y - $min_y;
1380             if ($width < $height) {
1381                 $ctx->{Trans}{A}= 0;
1382                 $ctx->{Trans}{X}= $x - $min_x;
1383                 $ctx->{Trans}{Y}= $y - $min_y + $olu_textheight;
1384             } else {
1385                 ($width,$height)=($height,$width);
1386                 $ctx->{Trans}{A}= 0.5 * $pi;
1387                 $ctx->{Trans}{X}= $x + $max_y;
1388                 $ctx->{Trans}{Y}= $y - $min_x + $olu_textheight;
1389             }
1390             $adj= length($obj_id) * $olu_textallowperc - $width;
1391             $adj=0 if $adj<0;
1392             $width += $adj;
1393             $ctx->{Trans}{X} += 0.5 * $adj;
1394             if ($x + $width > $olu_right && defined $nxty) {
1395                 $x= $olu_left;
1396                 $y= $nxty;
1397                 undef $nxty;
1398             } elsif ($y + $height > $olu_top && $y > $olu_bottom) {
1399                 oflushpage();
1400                 $x= $olu_left; $y= $olu_bottom;
1401                 undef $nxty;
1402             } else {
1403                 last;
1404             }
1405         }
1406
1407         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}//";
1408         $ctx->{Draw}= $ctx_save->{Draw};
1409         cmd__runobj($obj_id);
1410         ol("    gsave\n".
1411            "      /s ($obj_id) def\n".
1412            "      lf setfont\n      ".
1413            ($x + 0.5*$width)." ".($y - $olu_textheight)." moveto\n".
1414            "      s stringwidth pop -0.5 mul  0  rmoveto\n".
1415            "      s show grestore\n");
1416         $x += $width + $olu_gap_x;
1417         upd_max(\$nxty, $y + $height + $olu_gap_y + $olu_textheight);
1418     }
1419     @al= ();
1420     $ctx= $ctx_save;
1421 }
1422
1423 sub cmd__one {
1424     cmd__do();
1425 }
1426
1427 o("%!\n".
1428   "  /lf /Courier-New findfont $lmu_marktpt scalefont def\n".
1429   "  $ps_page_shift 0 translate 90 rotate\n");
1430
1431 if ($page_x || $page_y) {
1432     o("  /Courier-New findfont 15 scalefont setfont\n".
1433       "  30 30 moveto (${page_x}x${page_y}) show\n");
1434 }
1435
1436 o("  -$ps_page_xmul $page_x mul  -$ps_page_ymul $page_y mul  translate\n".
1437   "  $ptscale $ptscale scale\n");
1438
1439 newctx();
1440
1441 open DEBUG, ($debug ? ">&2" : ">/dev/null") or die $!;
1442
1443 if ($debug) {
1444     select(DEBUG); $|=1;
1445     select(STDOUT); $|=1;
1446 }
1447
1448 $ctx->{Draw}= '';
1449 $ctx->{SegName}= '';
1450
1451 @al= qw(layer 5);
1452 cmd__one();
1453
1454 while (<>) {
1455     next if m/^\s*\#/;
1456     chomp; s/^\s+//; s/\s+$//;
1457     @al= split /\s+/, $_;
1458     next unless @al;
1459     print DEBUG "=== @al\n";
1460     last if $al[0] eq 'eof';
1461     push @{ $ctx->{CmdLog} }, [ @al ] if exists $ctx->{CmdLog};
1462     cmd__one();
1463 }
1464
1465 {
1466     my ($min_x, $max_x, $min_y, $max_y) = bbox($ctx->{Loc});
1467     my ($bboxstr);
1468     if (defined $min_x) {
1469         $bboxstr= sprintf("width  %.2d (%.2d..%2.d)\n".
1470                           "height %.2d (%.2d..%2.d)\n",
1471                           $max_x - $min_x, $min_x, $max_x,
1472                           $max_y - $min_y, $min_y, $max_y);
1473     } else {
1474         $bboxstr= "no locs, no bbox\n";
1475     }
1476     if (!$quiet) { print STDERR $bboxstr; }
1477     $bboxstr =~ s/^/\%L bbox /mg;
1478     o($bboxstr) or die $!;
1479
1480     if ($scale < 1.5) {
1481         my ($tick_x, $tick_y, $ticklen);
1482         $ticklen= 10;
1483         printf("    gsave 0.5 setgray 0.33 setlinewidth\n".
1484                "      /regmark {\n".
1485                "        newpath moveto\n".
1486                "        -%d 0 rmoveto %d 0 rlineto\n".
1487                "        -%d -%d rmoveto 0 %d rlineto stroke\n".
1488                "      } def\n",
1489                $ticklen, $ticklen*2, $ticklen, $ticklen, $ticklen*2)
1490             or die $!;
1491         for ($tick_x= $min_x; $tick_x < $max_x; $tick_x += 150) {
1492             for ($tick_y= $min_y; $tick_y < $max_y; $tick_y += 150) {
1493                 printf("      %f %f regmark\n",
1494                        $tick_x, $tick_y)
1495                     or die $!;
1496             }
1497         }
1498         printf("    grestore\n")
1499             or die $!;
1500     }
1501 }
1502
1503 oflushpage();