layout/layout

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use IO::Handle;
   5 use IO::File;
   6
   7 use strict;
   8 no strict 'subs';
   9
  10 our $file_lineno= 0;
  11 our $file_filename;
  12
  13 our $scale= 7.0;
  14 our $page_x= 0;
  15 our $page_y= 0;
  16 our $quiet=0;
  17 our $debug=0;
  18 our $output_layer= '*';
  19 our $subsegcmapreq=0;
  20 our $subsegmovfeatpos='f';
  21 our $subsegcmapangscale;
  22
  23 our $ps_page_shift= 615;
  24 our $ps_page_xmul= 765.354;
  25 our $ps_page_ymul= 538.583;
  26
  27 our @eopts;
  28 our @segments= ('/');
  29 our @ident_strings= ();
  30 our %subsegcmap;
  31 our %segcmap;
  32
  33 our $drawers= 'arqscldmnog';
  34 our %chdraw_emap= qw(A ARScgd
  35                      R aRscgD
  36                      S aRScgd
  37                      C arsCgd
  38                      c Arscgd
  39                      r arcs
  40                      L LMg
  41                      l l
  42                      D D
  43                      d d
  44                      M Mnog
  45                      N MNog
  46                      O MNOg
  47                      m mnol
  48                      G Garsclmno);
  49
  50 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  51     last if $ARGV[0] eq '-';
  52     $_= shift @ARGV;
  53     last if $_ eq '--';
  54     s/^\-//;
  55     while (length) {
  56         if (s/^D(\d+)//) { $debug= $1; }
  57         elsif (s/^D//) { $debug++; }
  58         elsif (s/^q//) { $quiet=1; }
  59         elsif (s/^l(\d+|\*)//) { $output_layer=$1; }
  60         elsif (s/^S([0-9.]+)$//) { $scale= $1 * 1.0; }
  61         elsif (s/^P(\d+)x(\d+)$//) { $page_x= $1; $page_y= $2; }
  62         elsif (s/^GR//) { $subsegcmapreq=1; }
  63         elsif (s/^GP(\d+|f)$//) { $subsegmovfeatpos=$1; }
  64         elsif (s/^GL(.*)$//) {
  65             my ($sscmfn) = $1;
  66             my ($sscmf, $datum, $csss, $angbits);
  67             local ($_);
  68             $sscmf= new IO::File $sscmfn, 'r'
  69                 or die "$sscmfn: cannot open: $!\n";
  70             for (;;) {
  71                 $!=0; $_= <$sscmf>; die $! unless defined $_;
  72                 last if m/^E/;
  73                 next unless m/^C/;
  74                 m,^C\s+(\w*/(?:[A-Za-z_]+)?)\s+(0x[0-9a-f]+)\s+(\d+)\s*$,
  75                     or die "$sscmfn:$.: syntax error in subseg cmap\n";
  76                 ($csss,$datum,$angbits)= ($1,$2,$3);
  77                 if (!defined $subsegcmapangscale) {
  78                     $subsegcmapangscale= 1<<$angbits;
  79                 } else {
  80                     die "angbits varies" if $subsegcmapangscale != 1<<$angbits;
  81                 }
  82                 $datum= hex($datum);
  83                 if ($datum & 0x0ff) {
  84                     die "sorry, cannot put any movfeatpos or segment in red";
  85                 }
  86                 $subsegcmap{$csss}= sprintf("%.6f %.6f",
  87                                             (($datum >> 8) & 0xff)/255.0,
  88                                             (($datum >> 16) & 0xff)/255.0);
  89             }
  90             $sscmf->error and die "$sscmfn: error reading: $!\n";
  91             close $sscmf;
  92         } elsif (s/^(e)
  93                ((?:[a-z]|\*|\?|\[[a-z][-a-z]*\])*?)
  94                (\~?) (\d*) (\=*|\-+|\++) (\d*|\*)
  95                ([a-z]+)$//ix) {
  96             my ($ee,$g,$n,$d,$c,$v,$cc) = ($1,$2,$3,$4,$5,$6,$7);
  97             my ($eo, $invert, $lfn, $ccc, $sense,$limit);
  98             $g =~ s/\?/\./g; $g =~ s/\*/\.\*/g;
  99             die '-[eE]GND[=]* not allowed' if $v eq '*' && length $d;
 100             $d= $output_layer if !length $d;
 101             $d= 5 if $d eq '*';
 102             $invert= length $n;
 103             $c= '=' if !length $c;
 104             if (length $v && $v ne '*') {
 105                 die '-[eE]GN[D]CCV not allowed' if length $c > 1;
 106                 $c= $c x $v;
 107             }
 108             if ($c =~ m/^[-+]/) {
 109                 die '-[eE]GN+/-* not allowed' if $v eq '*';
 110                 $sense= ($&.'1') + 0;
 111                 $limit= ($sense * $d) + length($c) - 1;
 112                 $lfn= sub {
 113                     ($output_layer eq '*' ? $d
 114                      : $_[0]) * $sense >= $limit
 115                          xor $invert;
 116                 };
 117             } elsif ($v eq '*') {
 118                 $lfn= sub { !$invert; };
 119             } else {
 120                 $limit= length($c) - 1;
 121                 $lfn= sub {
 122 #my ($lfn_result)=(
 123                     ($output_layer eq '*' ? 1
 124                      : abs($_[0] - $d) <= $limit)
 125                         xor $invert
 126 #)
 127                             ;
 128 #print STDERR "output layer $output_layer; asking re $_[0] rel $d lim $limit invert $invert result $lfn_result\n";
 129 #$lfn_result;
 130                 };
 131             }
 132             $ccc= '';
 133             foreach $c (split //, $cc) {
 134                 if ($ee eq 'e') {
 135                     die "bad -e option $c" unless defined $chdraw_emap{$c};
 136                     $ccc .=  $chdraw_emap{$c};
 137                 } else {
 138                     die "bad -E option $c" unless $c =~ m/[$drawers]/i;
 139                     $ccc .= $c;
 140                 }
 141             }
 142             $eo->{GlobRe}= $g;
 143             $eo->{LayerCheck}= $lfn;
 144             $eo->{DrawMods}= $ccc;
 145 #print STDERR "created eo $eo re $eo->{GlobRe} n=$n d=$d v=$v c=$c limit=$limit cc=$cc\n";
 146             push @eopts, $eo;
 147         } elsif (m/^S/) {
 148             die "-S option must come right at the start and have numeric arg";
 149         } else {
 150             die "unknown option -$_";
 151         }
 152     }
 153 }
 154
 155 our $ptscale= 72/25.4 / $scale;
 156
 157 our $psu_ulen= 4.5;
 158 our $psu_edgelw= 0.5;
 159 our $psu_ticklw= 0.1;
 160 our $psu_ticksperu= 1;
 161 our $psu_ticklen= 5.0;
 162 our $psu_gauge= 9;
 163 our $psu_sleeperlen= 17;
 164 our $psu_sleeperlw= 15;
 165 our $psu_raillw= 1.0;
 166 our $psu_thinlw= 1.0;
 167 our %psu_subseglw;
 168 $psu_subseglw{'e'}= 20.0;
 169 $psu_subseglw{'m'}= 15.0;
 170 $psu_subseglw{'q'}= 20.0;
 171
 172 our $lmu_marklw= 4;
 173 our $lmu_marktpt= 11;
 174 our $lmu_txtboxtxty= $lmu_marktpt * 0.300;
 175 our $lmu_txtboxh= $lmu_marktpt * 1.100;
 176 our $lmu_txtboxpadx= $lmu_marktpt * 0.335;
 177 our $lmu_txtboxoff= $lmu_marklw / 2;
 178 our $lmu_txtboxlw= 1;
 179 our $lmu_lenlabeloffctr= -$lmu_marklw * 1.0;
 180 our $lmu_lenlabeloff=     $lmu_marklw * 0.5;
 181
 182 our $olu_left= 10 * $scale;
 183 our $olu_right= 217 * $scale - $olu_left;
 184 our $olu_bottom= 25 * $scale;
 185 our $olu_top= 270 * $scale - $olu_bottom;
 186 our $olu_gap_x= 30;
 187 our $olu_gap_y= 60;
 188 our $olu_textheight= 15;
 189 our $olu_textallowperc= $lmu_marktpt * 5.0/11;
 190
 191 our $pi= atan2(0,-1);
 192
 193 sub allwidth2 ($) {
 194     my ($radius)= @_;
 195     return 27 unless defined $radius;
 196     $radius= abs($radius);
 197     return ($radius >= 450 ? 33 :
 198             $radius >= 400 ? 35 :
 199             37);
 200 }
 201 sub allwidth ($) { return allwidth2($_[0]) * 0.5; }
 202
 203 our $allwidthmax= allwidth(0);
 204 our $allwidthmin= allwidth(undef);
 205
 206 # Data structures:
 207 #  $ctx->{CmdLog}= undef                  } not in defobj
 208 #  $ctx->{CmdLog}[]= [ command args ]     } in defobj
 209 #  $ctx->{Parent}= $parent_ctx or undef
 210 #  $ctx->{LocsMade}[]{Id}= $id
 211 #  $ctx->{LocsMade}[]{Neg}= 1 or 0
 212 #  $ctx->{Loc}{$id}{X}
 213 #  $ctx->{Loc}{$id}{Y}
 214 #  $ctx->{Loc}{$id}{A}
 215 #  $ctx->{Loc}{$id}{LayerKind}
 216 #  $ctx->{Trans}{X}       # transformation.  is ev representing
 217 #  $ctx->{Trans}{Y}       # new origin.  (is applied at _input_
 218 #  $ctx->{Trans}{A}       # not at plot-time)
 219 #  $ctx->{Trans}{R}       # but multiply all y coords by this!
 220 #  $ctx->{Draw}           # sequence of one or more chrs from uc $drawers
 221 #                         #  possibly including X meaning never draw
 222 #                         #  anything now (eg in defobj)
 223 #  $ctx->{DrawMap}        # =$fn s.t.
 224 #                         #  &$fn($drawchrs_spec_by_layer_cmdline)
 225 #                         #   = $drawchrs_we_should_use_due_to_obj_etc
 226 #  $ctx->{SegName}        # initial segment name (at start of object or file)
 227 #                         #  or nonexistent if in object in unknown segment
 228 #                         #  may have leading `-'
 229 #  $ctx->{SegMapN}{$s}= $o
 230 #  $ctx->{SegMapNM}{$s}= $o
 231 #  $ctx->{SavedSegment}   # exists iff segment command used, is a $csss
 232 #  $ctx->{Layer}{Level}
 233 #  $ctx->{Layer}{Kind}
 234 #
 235 #  $objs{$id}{CmdLog}
 236 #  $objs{$id}{Loc}
 237 #  $objs{$id}{Part}       # 1 iff object is a part
 238 #
 239 #  $eopts[]{GlobRe}       # regexp for K
 240 #  $eopts[]{LayerCheck}   # =$fn where &$fn($l) is true iff layer matches
 241 #  $eopts[]{DrawMods}     # modifier chars for drawing
 242 #
 243 #  @segments= ( $csss0, $dist0, $csss1, $dist1, ..., $csssn )
 244 #                         # here each csss may have preceding `-'
 245 #
 246 #  $subsegcmap{$csss} = "$green $blue"
 247 #                         # $csss is canonical subseg spec; always has '/'
 248
 249 our $ctx;
 250 our %objs;
 251 our @al; # current cmd
 252
 253 our $o='';
 254 our $ol='';
 255
 256 our $param; # for parametric_segment
 257
 258 # ev_... functions
 259 #
 260 # Operate on Enhanced Vectors which are a location (coordinates) and a
 261 # direction at that location.  Representation is a hash with members X
 262 # Y and A (angle of the direction in radians, anticlockwise from
 263 # East).  May be absolute, or interpreted as relative, according to
 264 # context.
 265 #
 266 # Each function's first argument is a hashref whose X Y A members will
 267 # be created or overwritten; this hashref will be returned (so you can
 268 # use it `functionally' by passing {}).  The other arguments may be ev
 269 # hashrefs, or other info.  The results are in general undefined if
 270 # one of the arguments is the same hash as the result.
 271
 272 sub ev_byang ($$;$) {
 273     # ev_byang(R, ANG,[LEN])
 274     # result is evec LEN (default=1.0) from origin pointing in direction ANG
 275     my ($res,$ang,$len)=@_;
 276     $len=1.0 unless defined $len;
 277     $res->{X}= $len * cos($ang);
 278     $res->{Y}= $len * sin($ang);
 279     $res->{A}= $ang;
 280     $res;
 281 }
 282 sub ev_compose ($$$) {
 283     # ev_compose(SUM_R, A,B);
 284     # appends B to A, result is end of new B
 285     # (B's X is forwards from end of A, Y is translating left from end of A)
 286     # A may have a member R, which if provided then it should be 1.0 or -1.0,
 287     # and B's Y and A will be multiplied by R first (ie, we can reflect);
 288     my ($sum,$a,$b) = @_;
 289     my ($r);
 290     $r= defined $a->{R} ? $a->{R} : 1.0;
 291     $sum->{X}= $a->{X} + $b->{X} * cos($a->{A}) - $r * $b->{Y} * sin($a->{A});
 292     $sum->{Y}= $a->{Y} + $r * $b->{Y} * cos($a->{A}) + $b->{X} * sin($a->{A});
 293     $sum->{A}= $a->{A} + $r * $b->{A};
 294     $sum;
 295 }
 296 sub ev_decompose ($$$) {
 297     # ev_decompose(B_R, A,SUM)
 298     # computes B_R s.t. ev_compose({}, A, B_R) gives SUM
 299     my ($b,$a,$sum)=@_;
 300     my ($r,$brx,$bry);
 301     $r= defined $a->{R} ? $a->{R} : 1.0;
 302     $brx= $sum->{X} - $a->{X};
 303     $bry= $r * ($sum->{Y} - $a->{Y});
 304     $b->{X}= $brx * cos($a->{A}) + $bry * sin($a->{A});
 305     $b->{Y}= $bry * cos($a->{A}) - $brx * sin($a->{A});
 306     $b->{A}= $r * ($sum->{A} - $a->{A});
 307     $b;
 308 }
 309 sub ev_lincomb ($$$$) {
 310     # ev_linkcomb(RES,A,B,P)
 311     # gives P*A + (1-P)*B
 312     my ($r,$a,$b,$p) = @_;
 313     my ($q) = 1.0-$p;
 314     map { $r->{$_} = $q * $a->{$_} + $p * $b->{$_} } qw(X Y A);
 315     $r;
 316 }
 317 sub a_normalise ($$) {
 318     # a_normalise(A,Z)
 319     # adds or subtracts 2*$pi to/from A until it is in [ Z , Z+2*$pi >
 320     my ($a,$z)=@_;
 321     my ($r);
 322     $r= $z + fmod($a - $z, 2.0*$pi);
 323     $r += 2*$pi if $r < $z;
 324     return $r;
 325 }
 326 sub ev_bearing ($$) {
 327     # ev_bearing(A,B)
 328     # returns bearing of B from A
 329     # value returned is in [ A->{A}, A->{A} + 2*$pi >
 330     # A->{A} and B->{A} are otherwise ignored
 331     my ($a,$b)= @_;
 332     my ($r);
 333     $r= atan2($b->{Y} - $a->{Y},
 334               $b->{X} - $a->{X});
 335     $r= a_normalise($r,$a->{A});
 336     return $r;
 337 }
 338
 339 sub v_rotateright ($) {
 340     # v_rotateright(A)
 341     # returns image of A rotated 90 deg clockwise
 342     my ($a)= @_;
 343     return { X => $a->{Y}, Y => -$a->{X} };
 344 }
 345 sub v_dotproduct ($$) {
 346     # v_dotproduct(A,B)
 347     my ($a,$b)= @_;
 348     return $a->{X} * $b->{X} + $a->{Y} * $b->{Y};
 349 }
 350 sub v_scalarmult ($$) {
 351     # v_scalarmult(S,V)
 352     # multiplies V by scalar S and returns product
 353     my ($s,$v)=@_;
 354     return { X => $s * $v->{X}, Y => $s * $v->{Y} };
 355 }
 356 sub v_add ($;@) {
 357     # v_add(A,B,...)
 358     # vector sum of all inputs
 359     my (@i) = @_;
 360     my ($r,$i);
 361     $r= { X => 0.0, Y => 0.0 };
 362     foreach $i (@i) { $r->{X} += $i->{X}; $r->{Y} += $i->{Y}; }
 363     return $r;
 364 }
 365 sub v_subtract ($$) {
 366     # v_subtract(A,B)
 367     # returns vector from A to B, ie B - A
 368     my ($a,$b)= @_;
 369     return { X => $b->{X} - $a->{X},
 370              Y => $b->{Y} - $a->{Y} };
 371 }
 372 sub v_len ($) {
 373     # v_len(V)
 374     # scalar length of V
 375     my ($v)=@_;
 376     my ($x,$y) = ($v->{X}, $v->{Y});
 377     return sqrt($x*$x + $y*$y);
 378 }
 379 sub v_dist ($$) {
 380     # v_dist(A,B)
 381     # returns distance from A to B
 382     return v_len(v_subtract($_[0],$_[1]));
 383 }
 384
 385 sub upd_min ($$) {
 386     my ($limr,$now)=@_;
 387     $$limr= $now unless defined $$limr && $$limr <= $now;
 388 }
 389 sub upd_max ($$) {
 390     my ($limr,$now)=@_;
 391     $$limr= $now unless defined $$limr && $$limr >= $now;
 392 }
 393
 394 sub canf ($$) {
 395     my ($converter,$defaulter)=@_;
 396     my ($spec,$v);
 397     return &$defaulter unless @al;
 398     $spec= shift @al;
 399     $v= &$converter($spec);
 400     dv('canf ','$spec',$spec, '$v',$v);
 401     return $v;
 402 }
 403 sub can ($) { my ($c)=@_; canf($c, sub { die "too few args"; }); }
 404 sub cano ($$) { my ($c,$def)=@_; canf($c, sub { return $def }); }
 405
 406 sub signum ($) { return ($_[0] > 0) - ($_[0] < 0); }
 407
 408 sub bbox ($) {
 409     my ($objhash) = @_;
 410     my ($min_x, $max_x, $min_y, $max_y);
 411     my ($loc);
 412     foreach $loc (values %$objhash) {
 413         upd_min(\$min_x, $loc->{X} - abs($allwidthmax * sin($loc->{A})));
 414         upd_max(\$max_x, $loc->{X} + abs($allwidthmax * sin($loc->{A})));
 415         upd_min(\$min_y, $loc->{Y} - abs($allwidthmax * cos($loc->{A})));
 416         upd_max(\$max_y, $loc->{Y} + abs($allwidthmax * cos($loc->{A})));
 417     }
 418     return ($min_x, $max_x, $min_y, $max_y);
 419 }
 420
 421 our %units_len= qw(- mm  mm 1  cm 10  m 1000);
 422 our %units_ang= qw(- d   r 1); $units_ang{'d'}= 2*$pi / 360;
 423
 424 sub cva_len ($) { my ($sp)=@_; cva_units($sp,\%units_len); }
 425 sub cva_identity ($) { my ($sp)=@_; $sp; }
 426 sub cva_ang ($) { my ($sp)=@_; cva_units($sp,\%units_ang); }
 427 sub cva_absang ($) { input_absang(cva_ang($_[0])) }
 428 sub cva_units ($$) {
 429     my ($sp,$ua)=@_;
 430     my ($n,$u,$r);
 431     $sp =~ m/^([-0-9eE.]*[0-9.])([A-Za-z]*)$/
 432         or die "lexically invalid quantity";
 433     ($n,$u)= ($1,$2);
 434     $u=$ua->{'-'} unless length $u;
 435     defined $ua->{$u} or die "unknown unit $u";
 436     $r= $n * $ua->{$u};
 437     print DEBUG "cva_units($sp,)=$r ($n $u $ua->{$u})\n";
 438     return $r;
 439 }
 440 sub cva_idstr ($) {
 441     my ($sp)=@_;
 442     die "invalid id" unless $sp =~ m/^[a-z][_0-9A-Za-z]*$/;
 443     return $&;
 444 }
 445 sub cva_idex ($) {
 446     my ($sp)=@_;
 447     my ($id,$r,$d,$k,$neg,$na,$obj_id,$vflip,$locs);
 448     if ($sp =~ s/^(\^?)(\w+)\!//) {
 449         $vflip= length($1);
 450         $obj_id= $2;
 451         die "invalid obj $obj_id in loc" unless exists $objs{$obj_id};
 452         $locs= $objs{$obj_id}{Loc};
 453     } else {
 454         $locs= $ctx->{Loc};
 455         $vflip= 0;
 456     }
 457     $neg= $sp =~ s/^\-//;
 458     $id= cva_idstr($sp);
 459     die "unknown $id" unless defined $locs->{$id};
 460     $r= $locs->{$id};
 461     $d= "idex $id";
 462     foreach $k (sort keys %$r) { $d .= " $k=$r->{$k}"; }
 463     printf DEBUG "%s\n", $d;
 464     if ($vflip) {
 465         $r= { X => $r->{X}, Y => -$r->{Y}, A => -$r->{A} };
 466     }
 467     if ($neg) {
 468         $na= $r->{A} + $pi;
 469         $na= a_normalise($na,0);
 470         $r= { X => $r->{X}, Y => $r->{Y}, A => $na };
 471     }
 472     return $r;
 473 }
 474 sub cva_idnew ($) {
 475     my ($sp)=@_;
 476     my ($id, $neg);
 477     $neg = $sp =~ s/^\-//;
 478     $id=cva_idstr($sp);
 479     die "duplicate $id" if exists $ctx->{Loc}{$id};
 480     $ctx->{Loc}{$id}{LayerKind}= $ctx->{Layer}{Kind};
 481     push @{ $ctx->{LocsMade} }, {
 482         Id => $id,
 483         Neg => $neg,
 484     };
 485     return $ctx->{Loc}{$id};
 486 }
 487 sub cva_cmd ($) { return cva_idstr($_[0]); }
 488 sub cva__enum ($$) {
 489     my ($sp,$el)=@_;
 490     return $sp if grep { $_ eq $sp } @$el;
 491     die "invalid option (permitted: @$el)";
 492 }
 493 sub cvam_enum { my (@e) = @_; return sub { cva__enum($_[0],\@e); }; }
 494
 495 sub cmd_abs {
 496     my ($i,$nl);
 497     $nl= can(\&cva_idnew);
 498     $i->{X}= can(\&cva_len);
 499     $i->{Y}= can(\&cva_len);
 500     $i->{A}= can(\&cva_ang);
 501     ev_compose($nl, $ctx->{Trans}, $i);
 502 }
 503 sub cmd_rel {
 504     my ($from,$to,$len,$right,$turn);
 505     $from= can(\&cva_idex);
 506     $to= can(\&cva_idnew);
 507     $len= cano(\&cva_len,0);
 508     $right= cano(\&cva_len,0) * $ctx->{Trans}{R};
 509     $turn= cano(\&cva_ang, 0) * $ctx->{Trans}{R};
 510     my ($u)= ev_compose({}, $from, { X => $len, Y => -$right, A => 0 });
 511     ev_compose($to, $u, { X => 0, Y => 0, A => $turn });
 512 }
 513
 514 sub dv__evreff ($) {
 515     my ($pfx) = @_;
 516     $pfx . ($pfx =~ m/\}$|\]$/ ? '' : '->');
 517 }
 518 sub dv__evr ($) {
 519     my ($v) = @_;
 520     return 'undef' if !defined $v;
 521     return $v if $v !~ m/\W/ && $v =~ m/[A-Z]/ && $v =~ m/^[a-z_]/i;
 522     return $v if $v =~ m/^[0-9.]+/;
 523     $v =~ s/[\\\']/\\$&/g;
 524     return "'$v'";
 525 }
 526 sub dv1 ($$$);
 527 sub dv1_kind ($$$$$$$) {
 528     my ($pfx,$expr,$ref,$ref_exp,$ixfmt,$ixesfn,$ixmapfn) = @_;
 529     my ($ix,$any);
 530     return 0 if $ref ne $ref_exp;
 531     $any=0;
 532     foreach $ix (&$ixesfn) {
 533         $any=1;
 534         my ($v)= &$ixmapfn($ix);
 535 #print STDERR "dv1_kind($pfx,$expr,$ref,$ref_exp,$ixmapfn) ix=$ix v=$v\n";
 536         dv1($pfx,$expr.sprintf($ixfmt,dv__evr($ix)),$v);
 537     }
 538     if (!$any) {
 539         printf DEBUG "%s%s= $ixfmt\n", $pfx, $expr, ' ';
 540     }
 541     1;
 542 }
 543 sub dv1 ($$$) {
 544     return 0 unless $debug;
 545     my ($pfx,$expr,$v) = @_;
 546     my ($ref);
 547     $ref= ref $v;
 548 #print STDERR "dv1 >$pfx|$ref<\n";
 549     if (!$ref) {
 550         printf DEBUG "%s%s= %s\n", $pfx,$expr, dv__evr($v);
 551         return;
 552     } elsif ($ref eq 'SCALAR') {
 553         dv1($pfx, ($expr =~ m/^\$/ ? "\$$expr" : '${'.$expr.'}'), $$v);
 554         return;
 555     }
 556     $expr.='->' unless $expr =~ m/\]$|\}$/;
 557     return if dv1_kind($pfx,$expr,$ref,'ARRAY','[%s]',
 558                        sub { ($[ .. $#$v) },
 559                        sub { $v->[$_[0]] });
 560     return if dv1_kind($pfx,$expr,$ref,'HASH','{%s}',
 561                        sub { sort keys %$v },
 562                        sub { $v->{$_[0]} });
 563     printf DEBUG "%s%s is %s\n", $pfx, $expr, $ref;
 564 }
 565
 566 sub dv {
 567     my ($pfx,@l) = @_;
 568     my ($expr,$v,$ref);
 569     while (@l) {
 570         ($expr,$v,@l)=@l;
 571         dv1($pfx,$expr,$v);
 572     }
 573 }
 574
 575 sub o ($) { $o .= $_[0]; }
 576 sub ol ($) { $ol .= $_[0]; }
 577 sub oflushpage () {
 578     return if $subsegcmapreq;
 579
 580     print $o, $ol, "  showpage\n"
 581         or die $!;
 582     $o=$ol='';
 583 }
 584
 585 our $o_path_verb;
 586
 587 sub o_path_begin () {
 588     o("      newpath\n");
 589     $o_path_verb= 'moveto';
 590 }
 591 sub o_path_point ($) {
 592     my ($pt)=@_;
 593     o("        $pt $o_path_verb\n");
 594     $o_path_verb= 'lineto';
 595 }
 596 sub o_path_stroke ($) {
 597     my ($width)=@_;
 598     o("        $width setlinewidth stroke\n");
 599 }
 600 sub o_path_strokeonly () {
 601     o("      stroke\n");
 602 }
 603
 604 sub o_line ($$$) {
 605     my ($a,$b,$width)=@_;
 606     o_path_begin();
 607     o_path_point($a);
 608     o_path_point($b);
 609     o_path_stroke($width);
 610 }
 611
 612 sub current_draw () {
 613     my ($r);
 614     $r= $ctx->{Draw} =~ m/X/ ? '' : $ctx->{Draw};
 615     $r;
 616 }
 617
 618 sub psu_coords ($$$) {
 619     my ($ends,$inunit,$across)=@_;
 620     # $ends->[0]{X} etc.; $inunit 0 to 1 (but go to 1.5);
 621     # $across in mm, +ve to right.
 622     my (%ea_zo, $zo, $prop);
 623     $ea_zo{X}=$ea_zo{Y}=0;
 624     foreach $zo (qw(0 1)) {
 625         $prop= $zo ? $inunit : (1.0 - $inunit);
 626         $ea_zo{X} += $prop * ($ends->[$zo]{X} - $across * sin($ends->[0]{A}));
 627         $ea_zo{Y} += $prop * ($ends->[$zo]{Y} + $across * cos($ends->[0]{A}));
 628     }
 629 #    dv("psu_coords ", '$ends',$ends, '$inunit',$inunit, '$across',$across,
 630 #       '\\%ea_zo', \%ea_zo);
 631     return $ea_zo{X}." ".$ea_zo{Y};
 632 }
 633
 634 sub parametric__o_pt ($) {
 635     my ($pt)=@_;
 636     o_path_point("$pt->{X} $pt->{Y}");
 637 }
 638
 639 our $segused_incurrent;
 640 our $segused_currentpt;
 641 our $segmentpart_counter=0;
 642 our $segused_restorecounter;
 643
 644 sub segment_used__print ($) {
 645     my ($pt) = @_;
 646     if ($segused_incurrent > 0 && $segused_restorecounter==1) {
 647         o("%L segmentpart ".
 648           $segmentpart_counter++." ".
 649           $ctx->{Layer}{Level}.$ctx->{Layer}{Kind}." ".
 650           $segments[0]." ".
 651           $segused_incurrent." ".
 652           loc2dbg($segused_currentpt)." ".
 653           loc2dbg($pt)."\n");
 654     }
 655     $segused_incurrent= undef;
 656     $segused_currentpt= undef;
 657 }
 658
 659 sub segment_used__len ($$) {
 660     my ($used,$pt) = @_;
 661     $segused_incurrent += $used;
 662
 663     return if @segments < 3;
 664     $segments[1] -= $used;
 665     return if $segments[1] > 0;
 666
 667     segment_used__print($pt);
 668     segment_used_begin($pt);
 669
 670     @segments= @segments[2..$#segments];
 671     o("% segments @segments\n");
 672 }
 673
 674 sub segment_state_save () {
 675     return [ 0, $segused_incurrent, $segused_currentpt,
 676              $segmentpart_counter, @segments ];
 677 }
 678 sub segment_state_restore ($) {
 679     my ($r) = @_;
 680     ($segused_restorecounter, $segused_incurrent, $segused_currentpt,
 681      $segmentpart_counter, @segments) = @$r;
 682     $r->[0]++;
 683 }
 684
 685 sub segment_used_begin ($) {
 686     $segused_incurrent= 0;
 687     $segused_currentpt= $_[0];
 688 }
 689 sub segment_used_middle ($$) {
 690     my ($used,$pt) = @_;
 691     segment_used__len($used,$pt);
 692 }
 693 sub segment_used_end ($$) {
 694     my ($used,$pt) = @_;
 695     segment_used__len($used,$pt);
 696     segment_used__print($pt);
 697 }
 698 sub parametric_segment ($$$$$) {
 699     my ($p0,$p1,$lenperp,$minradius,$calcfn) = @_;
 700     # makes $param (global) go from $p0 to $p1  ($p1>$p0)
 701     # $lenperp is the length of one unit p, ie the curve
 702     # must have a uniform `density' in parameter space
 703     # $calcfn is invoked with $param set and should return a loc
 704     # (ie, ref to X =>, Y =>, A =>).
 705     my ($pa,$pb,@ends,$side,$ppu,$e,$v,$tick,$draw,$allwidth);
 706     return unless $ctx->{Draw} =~ m/[ARSCGQ]/;
 707     $ppu= $psu_ulen/$lenperp;
 708     $allwidth= allwidth($minradius);
 709     my ($railctr)=($psu_gauge + $psu_raillw)*0.5;
 710     my ($tickend)=($allwidth - $psu_ticklen);
 711     my ($tickpitch)=($psu_ulen / $psu_ticksperu);
 712     my ($sleeperctr)=($psu_ulen*0.5);
 713     my ($sleeperend)=($psu_sleeperlen*0.5);
 714 print DEBUG "ps $p0 $p1 $lenperp ($ppu)\n";
 715     $draw= current_draw();
 716     if ($draw =~ m/[QG]/) {
 717         my ($pt,$going,$red,$csegbare,$movfeat,$movstroke);
 718         my ($used_last,$me,$segsave);
 719         o("gsave\n");
 720         $segsave= segment_state_save();
 721         foreach $me ($draw =~ m/Q/ ? qw(q) : qw(e m)) {
 722             segment_state_restore($segsave);
 723             $going=0;
 724             o("% segments @segments\n");
 725             $param=$p0;
 726             $pt= &$calcfn;
 727             segment_used_begin($pt);
 728             for (;;) {
 729                 $movstroke= "      cmapreq-stroke\n";
 730                 $csegbare= $segments[0];
 731                 $csegbare =~ s/^\-//;
 732                 if ($subsegcmapreq) {
 733                     if (!exists $subsegcmap{$csegbare}) {
 734                         print "$csegbare\n" or die $!;
 735                         $subsegcmap{$csegbare}++;
 736                     }
 737                 } else {
 738                     if ($draw =~ m/Q/) {
 739                         $csegbare =~ m,^[^/]*,;
 740 #print STDERR "looking for \`$&' $me\n";
 741                         $movstroke= $segcmap{$&};
 742                         $movstroke= "%     no-colour    "
 743                             unless defined $movstroke;
 744                     } elsif ($draw =~ m/G/) {
 745                         $movfeat= $csegbare =~ s,(/\D+)(\d+)$,$1, ? $2 : 'f';
 746                         die "unknown subsegment colour for $csegbare\n"
 747                             unless exists $subsegcmap{$csegbare};
 748                         $red= $pt->{A} / (2*$pi);
 749                         $red *= $subsegcmapangscale;
 750                         $red += $subsegcmapangscale*2;
 751                         $red += $subsegcmapangscale/2
 752                             if $segments[0] =~ m/^\-/;
 753                         $red %= $subsegcmapangscale;
 754                         $red += $subsegcmapangscale if $me eq 'e';
 755                         $red= sprintf("%f", $red / 255.0);
 756                         $movstroke= "    $red $subsegcmap{$csegbare}".
 757                                     " setrgbcolor\n";
 758                         if ($subsegmovfeatpos ne $movfeat ||
 759                             ($me eq 'e' && $csegbare =~ m,^/,)) {
 760                             $movstroke= "%     no-stroke    ";
 761                         }
 762                     }
 763                     $movstroke .=
 764                         "    $psu_subseglw{$me} setlinewidth stroke\n";
 765                 }
 766                 o_path_begin();
 767                 parametric__o_pt($pt);
 768
 769                 $param += $ppu;
 770                 last if $param>=$p1;
 771                 $pt= &$calcfn;
 772                 segment_used_middle($psu_ulen,$pt);
 773                 parametric__o_pt($pt);
 774                 o($movstroke);
 775             }
 776             $used_last= $p1-($param-$ppu);
 777             $param=$p1;
 778             $pt= &$calcfn;
 779             segment_used_end($used_last * $lenperp, $pt);
 780             parametric__o_pt($pt);
 781             o($movstroke);
 782         }
 783         o("grestore\n");
 784     }
 785     if ($draw =~ m/C/) {
 786         my ($pt);
 787         o("    $psu_thinlw setlinewidth\n");
 788         o_path_begin();
 789         for ($param=$p0; $param<$p1; $param += $ppu) {
 790             parametric__o_pt(&$calcfn);
 791         }
 792         $param=$p1;
 793         parametric__o_pt(&$calcfn);
 794         o("      stroke\n");
 795     }
 796     if ($draw =~ m/[ARS]/) { for ($pa= $p0; $pa<$p1; $pa=$pb) {
 797         $pb= $pa + $ppu;
 798         $param= $pa; $ends[0]= @ends ? $ends[1] : &$calcfn;
 799         $param= $pb; $ends[1]= &$calcfn;
 800 #print DEBUG "pa $pa $ends[0]{X} $ends[0]{Y} $ends[0]{A}\n";
 801 #print DEBUG "pb $pb $ends[1]{X} $ends[1]{Y} $ends[1]{A}\n";
 802         $e= $pb<=$p1 ? 1.0 : ($p1-$pa)/$ppu;
 803         o("    gsave\n");
 804         o_path_begin();
 805         o_path_point(psu_coords(\@ends,0,-$allwidth));
 806         o_path_point(psu_coords(\@ends,0,$allwidth));
 807         o_path_point(psu_coords(\@ends,$e,$allwidth));
 808         o_path_point(psu_coords(\@ends,$e,-$allwidth));
 809         o("        closepath clip\n");
 810         foreach $side qw(-1 1) {
 811             if ($draw =~ m/R/) {
 812                 o_line(psu_coords(\@ends,0,$side*$railctr),
 813                        psu_coords(\@ends,1.5,$side*$railctr),
 814                        $psu_raillw);
 815             }
 816         }
 817         if ($draw =~ m/S/) {
 818             o_line(psu_coords(\@ends,$sleeperctr,-$sleeperend),
 819                    psu_coords(\@ends,$sleeperctr,+$sleeperend),
 820                    $psu_sleeperlw);
 821         }
 822         if ($draw =~ m/A/) {
 823             o("        0.5 setgray\n");
 824             foreach $side qw(-1 1) {
 825                 o_line(psu_coords(\@ends,0,$side*$allwidth),
 826                        psu_coords(\@ends,1.5,$side*$allwidth),
 827                        $psu_edgelw);
 828                 for ($tick=0; $tick<1.5; $tick+=$tickpitch/$psu_ulen) {
 829                     o_line(psu_coords(\@ends,$tick,$side*$allwidth),
 830                            psu_coords(\@ends,$tick,$side*$tickend),
 831                            $psu_ticklw);
 832                 }
 833             }
 834         }
 835         o("      grestore\n");
 836     } }
 837     if ($draw =~ m/D/) {
 838         my ($pt,$ad,$len,$off);
 839         $param= ($p0+$p1)*0.5;
 840         $pt= &$calcfn;
 841         $ad= ang2deg($pt->{A});
 842         $len= sprintf "%.0f", $lenperp * abs($p1-$p0);
 843         $off= $draw =~ m/C/ ? $lmu_lenlabeloff : $lmu_lenlabeloffctr;
 844         ol("      gsave\n".
 845            "        $pt->{X} $pt->{Y} translate\n".
 846            "        $ad rotate\n".
 847            "        lf setfont\n".
 848            "        0 $off moveto\n".
 849            "        ($len) show\n".
 850            "      grestore\n");
 851     }
 852 }
 853
 854 sub arc ($$$$$) {
 855     my ($to, $ctr,$from, $radius,$delta) = @_;
 856     # does parametric_segment to draw an arc centred on $ctr
 857     # ($ctr->{A} ignored)
 858     # from $from with radius $radius (this must be consistent!)
 859     # and directionally-subtending an angle $delta.
 860     # sets $to->... to be the other end, and returns $to
 861     my ($beta);
 862     $to->{A}= $beta= $from->{A} + $delta;
 863     $to->{X}= $ctr->{X} - $radius * sin($beta);
 864     $to->{Y}= $ctr->{Y} + $radius * cos($beta);
 865     return if abs($delta*$radius) < 1e-9;
 866     parametric_segment(0.0,1.0, abs($radius*$delta), $radius, sub {
 867         my ($beta) = $from->{A} + $delta * $param;
 868         return { X => $ctr->{X} - $radius * sin($beta),
 869                  Y => $ctr->{Y} + $radius * cos($beta),
 870                  A => $beta }
 871     });
 872 }
 873
 874 # joins_xxx all take $results, $from, $to, $minradius
 875 # where $results->[]{Path}{K} etc. and $results->[]{SolKinds}[]
 876
 877 sub joins_twoarcs ($$$$) {
 878     my ($results, $from,$to,$minradius) = @_;
 879     # two circular arcs of equal maximum possible radius
 880     # algorithm courtesy of Simon Tatham (`Railway problem',
 881     # pers.comm. to ijackson@chiark 23.1.2004)
 882     my ($sigma,$distfact, $theta,$phi, $a,$b,$c,$d, $m,$r, $radius);
 883     my ($cvec,$cfrom,$cto,$midpt, $delta1,$delta2, $path,$reverse);
 884     $sigma= ev_bearing($from,$to);
 885     $distfact= v_dist($from,$to);
 886     $theta= 0.5 * $pi - ($from->{A} - $sigma);
 887     $phi=   0.5 * $pi - ($to->{A} + $pi - $sigma);
 888     $a= 2 * (1 + cos($theta - $phi));
 889     $b= 2 * (cos($theta) - cos($phi));
 890     $c= -1;
 891     $d= sqrt($b*$b - 4*$a*$c);
 892     o("%     twoarcs theta=".ang2deg($theta)." phi=".ang2deg($phi).
 893       " ${a}r^2 + ${b}r + ${c} = 0\n");
 894     foreach $m (qw(-1 1)) {
 895         if ($a < 1e-6) {
 896             o("%     twoarcs $m insoluble\n");
 897             next;
 898         }
 899         $r= -0.5 * (-$b + $m*$d) / $a;
 900         $radius= -$r * $distfact;
 901         o("%     twoarcs $m radius $radius ");
 902         if (abs($radius) < $minradius) { o("too-small\n"); next; }
 903         $cfrom=  ev_compose({}, $from, { X=>0, Y=>-$radius, A=>-0.5*$pi });
 904         $cto=    ev_compose({}, $to,   { X=>0, Y=> $radius, A=> 0.5*$pi });
 905         $midpt=  ev_lincomb({}, $cfrom, $cto, 0.5);
 906         $reverse= signum($r);
 907         if ($reverse<0) {
 908             $cfrom->{A} += $pi;
 909             $cto->{A} += $pi;
 910         }
 911         $delta1= ev_bearing($cfrom, $midpt) - $cfrom->{A};
 912         $delta2= ev_bearing($cto,   $midpt) - $cto->{A};
 913         o("ok deltas ".ang2deg($delta1)." ".ang2deg($delta2)."\n");
 914         if ($reverse<0) {
 915             $delta1 -= 2*$pi;
 916             $delta2 -= 2*$pi;
 917         }
 918         my ($fs);
 919         $path= [{ T=>Arc, F=>$from, C=>$cfrom, R=> $radius, D=>$delta1 },
 920                 { T=>Arc, F=>$to,   C=>$cto,   R=>-$radius, D=>$delta2 }];
 921         push @$results, { Path => $path,
 922                           SolKinds =>  [ 'twoarcs', 'cross' ] };
 923     }
 924 }
 925
 926 sub joins_arcsline ($$$$) {
 927     my ($results, $from,$to,$minradius) = @_;
 928     # two circular arcs of specified radius
 929     # with an intervening straight
 930     my ($lr,$inv, $c,$d,$alpha,$t,$k,$l,$rpmsina,$rcosa,$linelen, $path);
 931     if ($minradius<=1e-6) { o("%     arcsline no-radius\n"); return; }
 932     foreach $lr (qw(-1 +1)) {
 933         foreach $inv (qw(-1 +1)) {
 934             $c=ev_compose({},$from,{X=>0,Y=>-$lr*$minradius, A=>0 });
 935             $d=ev_compose({},$to,{X=>0, Y=>-$inv*$lr*$minradius, A=>$pi });
 936             $t= v_dist($c,$d);
 937             o("%     arcsline $lr $inv t=$t ");
 938             if ($t < 1e-6) { o("concentric"); next; }
 939             $c->{A}= $d->{A}= ev_bearing($c,$d);
 940             o("bearing ".ang2deg($c->{A}));
 941             if ($inv>0) {
 942                 o("\n");
 943                 $k= ev_compose({}, $c, { X=>0, Y=>$lr*$minradius, A=>0 });
 944                 $l= ev_compose({}, $d, { X=>0, Y=>$lr*$minradius, A=>0 });
 945                 $linelen= $t;
 946             } else {
 947                 my ($cosalpha) = 2.0 * $minradius / $t;
 948                 if ($cosalpha > (1.0 - 1e-6)) { o(" too-close\n"); next; }
 949                 $alpha= acos($cosalpha);
 950                 $rpmsina= $lr * $minradius * sin($alpha);
 951                 $rcosa= $minradius * $cosalpha;
 952                 $k= ev_compose({}, $c, { X=>$rcosa, Y=>$rpmsina, A=>0 });
 953                 $l= ev_compose({}, $d, { X=>-$rcosa, Y=>-$rpmsina, A=>0 });
 954                 $k->{A}= $l->{A}= ev_bearing($k,$l);
 955                 o(" alpha=".ang2deg($alpha)." kl^=".ang2deg($k->{A})."\n");
 956                 $linelen= v_dist($k,$l);
 957             }
 958             $path= [{ T => Arc, F => $from, C => $c,
 959                       R =>$lr*$minradius,
 960                       D => -$lr * a_normalise
 961                           ($lr * ($from->{A} - $k->{A}), 0) },
 962                     { T => Line, A => $k, B => $l, L => $linelen },
 963                     { T => Arc, F => $l, C => $d,
 964                       R => $inv*$lr*$minradius,
 965                       D => -$lr*$inv * a_normalise
 966                           (-$lr*$inv * ($to->{A} - $l->{A}), 0) }];
 967             push @$results,
 968             { Path => $path,
 969               SolKinds => [ 'arcsline', ($inv<0 ? 'cross' : 'loop') ] };
 970         }
 971     }
 972 }
 973
 974 sub joins_arcline ($$$$) {
 975     my ($results, $from,$to,$minradius) = @_;
 976     # one circular arc and a straight line
 977     my ($swap,$echoice,$path, $ap,$bp,$av,$bv, $e,$f, $ae,$af,$afae);
 978     my ($dak,$ak,$kj,$k,$j,$aja,$jl,$l,$jc,$lc,$c,$rj,$rb);
 979     foreach $swap (qw(-1 +1)) {
 980         foreach $echoice (qw(0 1)) {
 981             $ap= $from; $bp= { %$to }; $bp->{A} += $pi;
 982             ($ap,$bp)= ($bp,$ap) if $swap<0;
 983             $av= ev_byang({}, $ap->{A});
 984             $bv= ev_byang({}, $bp->{A});
 985             $e= ev_byang({}, 0.5 * ($ap->{A} + $bp->{A} + $echoice * $pi));
 986             $f= v_rotateright($e);
 987             o("%     arcline $swap $echoice e ".loc2dbg($e)."\n");
 988             $ae= v_dotproduct($av,$e);
 989             $af= v_dotproduct($av,$f);
 990             o("%     arcline $swap $echoice a.e=$ae a.f=$af ");
 991             if (abs($ae) < 1e-6) { o(" singular\n"); next; }
 992             $afae= $af/$ae;
 993             o("a.f/a.e=$afae\n");
 994             $dak= v_dotproduct(v_subtract($ap,$bp), $e);
 995             $ak= v_scalarmult($dak, $e);
 996             $kj= v_scalarmult($dak * $afae, $f);
 997             $k= v_add($ap, $ak);
 998             $j= v_add($k, $kj);
 999             $aja= v_dotproduct(v_subtract($ap,$j), $av);
1000             o("%     arcline $swap $echoice d_ak=$dak aj.a=$aja ");
1001             if ($aja < 0) { o(" backwards aj\n"); next; }
1002             $jl= v_scalarmult(0.5, v_subtract($j, $bp));
1003             $lc= v_scalarmult(-v_dotproduct($jl, $f) * $afae, $e);
1004             $l= v_add($j, $jl);
1005             $c= v_add($l, $lc);
1006             $rj= v_dotproduct(v_subtract($j,$c), v_rotateright($av));
1007             $rb= v_dotproduct(v_subtract($c,$bp), v_rotateright($bv));
1008             o("r_j=$rj r_b=$rb ");
1009             if ($rj * $rb < 0) { o(" backwards b\n"); next; }
1010             if (abs($rj) < $minradius) { o(" too-small\n"); next; }
1011             o("ok\n");
1012             $j->{A}= $ap->{A};
1013             $c->{A}= 0;
1014             $path= [{ T => Line, A => $ap, B => $j, L => $aja },
1015                     { T => Arc, F => $j, C => $c, R => $rj,
1016                       D => -signum($rj) * a_normalise
1017                           (-signum($rj) * ($bp->{A} + $pi - $j->{A}), 0) }];
1018             $path= [ reverse @$path ] if $swap<0;
1019             push @$results, { Path => $path, SolKinds =>  [ 'arcline' ] };
1020         }
1021     }
1022 }
1023
1024 sub cmd_join {
1025     my ($from,$to,$minradius);
1026     my (@results,$result);
1027     my ($path,$segment,$bestpath,$len,$scores,$bestscores,@bends,$skl);
1028     my ($crit,$cs,$i,$cmp);
1029     $from= can(\&cva_idex);
1030     $to= can(\&cva_idex);
1031     $minradius= can(\&cva_len);
1032     o("%   join ".loc2dbg($from)."..".loc2dbg($to)." $minradius\n");
1033     joins_twoarcs(\@results, $from,$to,$minradius);
1034     joins_arcsline(\@results, $from,$to,$minradius);
1035     joins_arcline(\@results, $from,$to,$minradius);
1036     foreach $result (@results) {
1037         $path= $result->{Path};
1038         $skl= $result->{SolKinds};
1039         o("%   possible path @$skl $path\n");
1040         $len= 0;
1041         @bends= ();
1042         foreach $segment (@$path) {
1043             if ($segment->{T} eq Arc) {
1044                 o("%     Arc C ".loc2dbg($segment->{C}).
1045                   " R $segment->{R} D ".ang2deg($segment->{D})."\n");
1046                 $len += abs($segment->{R} * $segment->{D});
1047                 push @bends, -abs($segment->{R}) * $segment->{D}; # right +ve
1048             } elsif ($segment->{T} eq Line) {
1049                 o("%     Line A ".loc2dbg($segment->{A}).
1050                   " B ".loc2dbg($segment->{A})." L $segment->{L}\n");
1051                 $len += abs($segment->{L});
1052             } else {
1053                 die "unknown segment $segment->{T}";
1054             }
1055         }
1056         o("%    length $len bends @bends.\n");
1057         $scores= [];
1058         foreach $crit (@al, 'short') {
1059             if ($crit eq 'long') { $cs= $len; }
1060             elsif ($crit eq 'short') { $cs= -$len; }
1061             elsif ($crit =~ m/^(begin|end|)(left|right)$/) {
1062                 if ($1 eq 'begin') { $cs= $bends[0]; }
1063                 elsif ($1 eq 'end') { $cs= $bends[$#bends]; }
1064                 else { $cs=0; map { $cs += $_ } @bends; }
1065                 $cs= -$cs if $2 eq 'left';
1066             } elsif ($crit =~ m/^(\!?)(twoarcs|arcs?line|cross|loop)$/) {
1067                 $cs= !!(grep { $2 eq $_ } @$skl) != ($1 eq '!');
1068             } else {
1069                 die "unknown sort criterion $crit";
1070             }
1071             push @$scores, $cs;
1072         }
1073         o("%    scores @$scores\n");
1074         if (defined $bestpath) {
1075             for ($i=0,$cmp=0; !$cmp && $i<@$scores; $i++) {
1076                 $cmp= $scores->[$i] <=> $bestscores->[$i];
1077             }
1078             next if $cmp < 0;
1079         }
1080         $bestpath= $path;
1081         $bestscores= $scores;
1082     }
1083     die "no solution" unless defined $bestpath;
1084     o("%   chose path $bestpath @al\n");
1085     @al= ();
1086     foreach $segment (@$bestpath) {
1087         if ($segment->{T} eq 'Arc') {
1088             arc({}, $segment->{C},$segment->{F},$segment->{R},$segment->{D});
1089         } elsif ($segment->{T} eq 'Line') {
1090             line($segment->{A}, $segment->{B}, $segment->{L});
1091         } else {
1092             die "unknown segment";
1093         }
1094     }
1095 }
1096
1097 sub line ($$$) {
1098     my ($from,$to,$len) = @_;
1099     if ($len < 0) {
1100         ($from,$to,$len) = ($to,$from,-$len);
1101     }
1102     parametric_segment(0.0, 1.0, $len + 1e-6, undef, sub {
1103         ev_lincomb({}, $from, $to, $param);
1104     });
1105 }
1106
1107 sub cmd_extend {
1108     my ($from,$to,$radius,$len,$upto,$ctr,$beta,$ang,$how,$sign_r);
1109     $from= can(\&cva_idex);
1110     $to= can(\&cva_idnew);
1111     printf DEBUG "from $from->{X} $from->{Y} $from->{A}\n";
1112     $how= can(cvam_enum(qw(len upto ang uptoang parallel)));
1113     if ($how eq 'len') { $len= can(\&cva_len); }
1114     elsif ($how =~ m/ang$/) { $ang= can(\&cva_ang); }
1115     elsif ($how eq 'parallel' || $how eq 'upto') { $upto= can(\&cva_idex); }
1116     $radius= cano(\&cva_len, 'Inf'); # +ve is right hand bend
1117     if ($radius eq 'Inf') {
1118 #       print DEBUG "extend inf $len\n";
1119         if ($how eq 'upto') {
1120             $len= ($upto->{X} - $from->{X}) * cos($from->{A})
1121                 + ($upto->{Y} - $from->{Y}) * sin($from->{A});
1122         } elsif ($how eq 'len') {
1123         } else {
1124             die "len of straight spec by angle";
1125         }
1126         printf DEBUG "len $len\n";
1127         $to->{X}= $from->{X} + $len * cos($from->{A});
1128         $to->{Y}= $from->{Y} + $len * sin($from->{A});
1129         $to->{A}= $from->{A};
1130         line($from,$to,$len);
1131     } else {
1132         my ($sign_r, $sign_ang, $ctr, $beta_interval, $beta, $delta);
1133         print DEBUG "radius >$radius<\n";
1134         $radius *= $ctx->{Trans}{R};
1135         $sign_r= signum($radius);
1136         $sign_ang= 1;
1137         $ctr->{X}= $from->{X} + $radius * sin($from->{A});
1138         $ctr->{Y}= $from->{Y} - $radius * cos($from->{A});
1139         if ($how eq 'upto') {
1140             $beta= atan2(-$sign_r * ($upto->{X} - $ctr->{X}),
1141                          $sign_r * ($upto->{Y} - $ctr->{Y}));
1142             $beta_interval= 1.0;
1143         } elsif ($how eq 'parallel') {
1144             $beta= $upto->{A};
1145             $beta_interval= 1.0;
1146         } elsif ($how eq 'uptoang') {
1147             $beta= input_absang($ang);
1148             $beta_interval= 2.0;
1149         } elsif ($how eq 'len') {
1150             $sign_ang= signum($len);
1151             $beta= $from->{A} - $sign_r * $len / abs($radius);
1152             $beta_interval= 2.0;
1153         } else {
1154             $sign_ang= signum($ang);
1155             $beta= $from->{A} - $sign_r * $ang;
1156             $beta_interval= 2.0;
1157         }
1158     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1159         $beta += $sign_ang * $sign_r * 4.0 * $pi;
1160         for (;;) {
1161             $delta= $beta - $from->{A};
1162             last if $sign_ang * $sign_r * $delta <= 0;
1163             $beta -= $sign_ang * $sign_r * $beta_interval * $pi;
1164         }
1165     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1166         arc($to, ,$ctr,$from, $radius,$delta);
1167     }
1168     printf DEBUG "to $to->{X} $to->{Y} $to->{A}\n";
1169 }
1170
1171 sub loc2dbg ($) {
1172     my ($loc) = @_;
1173     return "$loc->{X} $loc->{Y} ".ang2deg($loc->{A});
1174 }
1175 sub ang2deg ($) {
1176     return $_[0] * 180 / $pi;
1177 }
1178 sub input_absang ($) {
1179     return $_[0] * $ctx->{Trans}{R} + $ctx->{Trans}{A};
1180 }
1181 sub input_abscoords ($$) {
1182     my ($in,$out);
1183     ($in->{X}, $in->{Y}) = @_;
1184     $in->{A}= 0.0;
1185     $out= ev_compose({}, $ctx->{Trans}, $in);
1186     return ($out->{X}, $out->{Y});
1187 }
1188
1189 sub newctx (;$) {
1190     my ($ctx_save) = @_;
1191     $ctx= {
1192         Trans => { X => 0.0, Y => 0.0, A => 0.0, R => 1.0 },
1193         InRunObj => "",
1194         DrawMap => sub { $_[0]; },
1195         SegMapN => { },
1196         SegMapNM => { }
1197         };
1198     if (defined $ctx_save) {
1199         %{ $ctx->{Layer} }= %{ $ctx_save->{Layer} };
1200         $ctx->{Parent}= $ctx_save;
1201     }
1202 }
1203
1204 our $defobj_save;
1205 our $defobj_ispart;
1206
1207 sub cmd_defobj { cmd__defobj(0); }
1208 sub cmd_defpart { cmd__defobj(1); }
1209 sub cmd__defobj ($) {
1210     my ($ispart) = @_;
1211     my ($id);
1212     $id= can(\&cva_idstr);
1213     die "nested defobj" if $defobj_save;
1214     die "repeated defobj" if exists $objs{$id};
1215     $defobj_save= $ctx;
1216     $defobj_ispart= $ispart;
1217     newctx($defobj_save);
1218     $ctx->{CmdLog}= [ ];
1219     $ctx->{InDefObj}= $id;
1220     $ctx->{Draw}= $defobj_save->{Draw}.'X';
1221     $ctx->{DrawMap}= sub { ''; };
1222     $ctx->{Layer}= { Level => 5, Kind => '' };
1223 }
1224
1225 sub cmd_enddef {
1226     my ($bit,$id);
1227     $id= $ctx->{InDefObj};
1228     die "unmatched enddef" unless defined $id;
1229     foreach $bit (qw(CmdLog Loc)) {
1230         $objs{$id}{$bit}= $ctx->{$bit};
1231     }
1232     $objs{$id}{Part}= $defobj_ispart;
1233     $ctx= $defobj_save;
1234     $defobj_save= undef;
1235     $defobj_ispart= undef;
1236 }
1237
1238 sub cmd__runobj ($) {
1239     my ($obj_id)=@_;
1240     my ($c);
1241     local (@al);
1242     dv("cmd__runobj $obj_id ",'$ctx',$ctx);
1243     foreach $c (@{ $objs{$obj_id}{CmdLog} }) {
1244         @al= @$c;
1245         next if $al[0] eq 'enddef';
1246         cmd__one();
1247     }
1248 }
1249
1250 sub cva_segment ($) {
1251     my ($sp)=@_;
1252     die "invalid segment" if $sp =~ m/[^0-9A-Za-z_]/;
1253     return $sp;
1254 }
1255
1256 sub cva_subsegspec ($) {
1257     my ($sp)=@_;
1258     die "invalid subsegment spec" unless
1259         $sp =~ m,^(\-?)([0-9A-Za-z_]*)(?:/(?:([A-Za-z_]+)(\d+))?)?$,;
1260     my ($sign,$segname,$movfeat,$movconf)=($1,$2,$3,$4);
1261
1262     if (!exists $ctx->{SegName}) {
1263         $segname= '';
1264         $sign= '';
1265     } else {
1266         my ($map_ctx);
1267
1268         $ctx->{SegName} =~ m/^\-?/ or die;
1269         $sign .= $&;
1270         $segname= $'.$segname;
1271
1272         for ($map_ctx= $ctx;
1273              defined $map_ctx;
1274              $map_ctx= $map_ctx->{Parent}) {
1275             if (defined $movfeat &&
1276                 exists $map_ctx->{SegMapNM}{"$segname/$movfeat"}) {
1277                 $movfeat= $map_ctx->{SegMapNM}{"$segname/$movfeat"};
1278             }
1279             if (exists $map_ctx->{SegMapN}{$segname}) {
1280                 $map_ctx->{SegMapN}{$segname} =~ m/^\-?/ or die;
1281                 $sign .= $&;
1282                 $segname= $';
1283             }
1284         }
1285         $sign =~ s/\-\-//g;
1286     }
1287
1288     return $sign.$segname.'/'.
1289         (defined $movfeat ? sprintf "%s%d", $movfeat, $movconf : '');
1290 }
1291
1292 sub cmd_segment {
1293     my ($csss,$length);
1294     $ctx->{SavedSegment}= pop @segments
1295         unless exists $ctx->{SavedSegment};
1296     @segments= ();
1297     while (@al>1) {
1298         $csss= can(\&cva_subsegspec);
1299         $length= can(\&cva_len);
1300         push @segments, $csss, $length;
1301     }
1302     $csss= can(\&cva_subsegspec);
1303     push @segments, $csss;
1304 }
1305
1306 sub cva_segmap_s {
1307     my ($sp) = @_;
1308     $sp =~ m,^\w+(?:/[a-zA-Z_]+)?$,
1309         or die "invalid (sub)segment mapping S \`$sp'";
1310     return $sp;
1311 }
1312
1313 sub cva_segmap_n {
1314     my ($sp) = @_;
1315     $sp =~ m,^\-?\w+$, or die "invalid segment mapping N' \`$sp'";
1316     return $sp;
1317 }
1318
1319 sub cva_segmap_m {
1320     my ($sp) = @_;
1321     $sp =~ m,^[a-zA-Z_]+$, or die "invalid segment mapping M' \`$sp'";
1322     return $sp;
1323 }
1324
1325 sub cmd_segmap {
1326     my ($s,$d);
1327     while (@al) {
1328         $s= can(\&cva_segmap_s);
1329         if ($s =~ m,/,) {
1330             $ctx->{SegMapNM}{$s}= can(\&cva_segmap_m);
1331         } else {
1332             $ctx->{SegMapN}{$s}= can(\&cva_segmap_n);
1333         }
1334     }
1335 }
1336
1337 sub cmd_segend {
1338     @al=();
1339 };
1340
1341 sub cmd_segcmap {
1342     my ($seg,$colour);
1343     $seg= can(\&cva_segment);
1344     $segcmap{$seg}= "@al";
1345     @al= ();
1346 };
1347
1348 sub layer_draw ($$) {
1349     my ($k,$l) = @_;
1350     my ($eo,$cc, $r);
1351     if ($k eq '') {
1352         $r= 'RLMN';
1353     } elsif ($k eq 's') {
1354         $r= '';
1355     } elsif ($k eq 'l') {
1356         $r= 'CLMN';
1357     } else {
1358         $r= 'ARSCLMNO';
1359     }
1360     foreach $eo (@eopts) {
1361 #print STDERR "$. layer $k$l eo $eo re $eo->{GlobRe} then $eo->{DrawMods} now $r\n";
1362         next unless $k =~ m/^$eo->{GlobRe}$/;
1363 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} match\n";
1364         next unless &{ $eo->{LayerCheck} }($l);
1365 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} checked\n";
1366         foreach $cc (split //, $eo->{DrawMods}) {
1367             $r =~ s/$cc//ig;
1368             $r .= $cc if $cc =~ m/[A-Z]/;
1369         }
1370     }
1371 #print STDERR "layer $k$l gives $r (before map)\n";
1372     $r= &{ $ctx->{DrawMap} }($r);
1373     return $r;
1374 }
1375
1376 sub cmd_layer {
1377     my ($kl, $k,$l);
1378     $kl= can(\&cva_identity);
1379     $kl =~ m/^([A-Za-z_]*)(\d*|\=|\*)$/ or die "invalid layer spec";
1380     ($k,$l)=($1,$2);
1381     $l= $output_layer if $l eq '*';
1382     $l= $ctx->{Layer}{Level} if $l =~ m/^\=?$/;
1383     $ctx->{Layer}{Kind}= $k;
1384     $ctx->{Layer}{Level}= $l;
1385     $ctx->{Draw}= layer_draw($k,$l);
1386 }
1387
1388 sub cmd_part { cmd__obj(Part); }
1389 sub cmd_obj { cmd__obj(1); }
1390 sub cmd_objflip { cmd__obj(-1); }
1391
1392 sub cmd__obj ($) {
1393     my ($how)=@_;
1394     my ($obj_id, $ctx_save, $pfx, $actual, $formal_id, $formal, $formcv);
1395     my ($part_name, $ctx_inobj, $obj, $id, $newid, $newpt);
1396     if ($how eq Part) {
1397         $part_name= can(\&cva_idstr);
1398         $how= (@al && $al[0] =~ s/^\^//) ? -1 : +1;
1399     }
1400     $obj_id= can(\&cva_idstr);
1401     if (defined $part_name) {
1402         $formal_id= can(\&cva_idstr);
1403         $actual= cano(\&cva_idex, undef);
1404         if (!defined $actual) {
1405             $actual= cva_idex("${part_name}_${formal_id}");
1406         }
1407     } else {
1408         $actual= can(\&cva_idex);
1409         $formal_id= can(\&cva_idstr);
1410     }
1411     $obj= $objs{$obj_id};
1412     dv("cmd__obj ",'$obj',$obj);
1413     die "unknown obj $obj_id" unless $obj;
1414     $formal= $obj->{Loc}{$formal_id};
1415     die "unknown formal $formal_id" unless $formal;
1416     $ctx_save= $ctx;
1417     newctx($ctx_save);
1418     $how *= $ctx_save->{Trans}{R};
1419     $ctx->{Trans}{R}= $how;
1420     $ctx->{Trans}{A}= $actual->{A} - $formal->{A}/$how;
1421     $formcv= ev_compose({}, $ctx->{Trans},$formal);
1422     $ctx->{Trans}{X}= $actual->{X} - $formcv->{X};
1423     $ctx->{Trans}{Y}= $actual->{Y} - $formcv->{Y};
1424     if (defined $part_name) {
1425         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${part_name}:";
1426     } else {
1427         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}::";
1428     }
1429     if ($segments[0] =~ m,(.*[^-]+)/,) {
1430         $ctx->{SegName}= $1;
1431     }
1432     $ctx->{DrawMap}= sub {
1433         my ($i) = @_;
1434         $i= &{ $ctx_save->{DrawMap} }($i);
1435         if ($obj->{Part}) {
1436             $i =~ s/[LMN]//g;
1437             $i =~ s/O/MNO/;
1438         } else {
1439             $i =~ s/[LM]//g;
1440             $i =~ s/N/MN/;
1441         }
1442         return $i;
1443     };
1444     $ctx->{Draw}= &{ $ctx->{DrawMap} }($ctx_save->{Draw});
1445     cmd__runobj($obj_id);
1446     if (defined $part_name) {
1447         $pfx= $part_name.'_';
1448     } else {
1449         if (@al && $al[0] eq '=') {
1450             $pfx= ''; shift @al;
1451         } else {
1452             $pfx= cano(\&cva_idstr,undef);
1453         }
1454     }
1455     if (exists $ctx->{SavedSegment}) {
1456         @segments= ($ctx->{SavedSegment});
1457     }
1458     $ctx_inobj= $ctx;
1459     $ctx= $ctx_save;
1460     if (defined $pfx) {
1461         foreach $id (keys %{ $ctx_inobj->{Loc} }) {
1462             next if $id eq $formal_id;
1463             $newid= $pfx.$id;
1464             next if exists $ctx_save->{Loc}{$newid};
1465             $newpt= cva_idnew($newid);
1466             %$newpt= %{ $ctx_inobj->{Loc}{$id} };
1467         }
1468     }
1469     if (defined $part_name) {
1470         my ($formalr_id, $actualr_id, $formalr, $actualr);
1471         while (@al) {
1472             die "part results come in pairs\n" unless @al>=2;
1473             ($formalr_id, $actualr_id, @al) = @al;
1474             if ($actualr_id =~ s/^\-//) {
1475                 $formalr_id= "-$formalr_id";
1476                 $formalr_id =~ s/^\-\-//;
1477             }
1478             {
1479                 local ($ctx) = $ctx_inobj;
1480                 $formalr= cva_idex($formalr_id);
1481             }
1482             $actualr= cva_idnew($actualr_id);
1483             %$actualr= %$formalr;
1484         }
1485     }
1486 }
1487
1488 sub cmd__do {
1489     my ($cmd);
1490 dv("cmd__do $ctx @al ",'$ctx',$ctx);
1491     $cmd= can(\&cva_cmd);
1492     my ($lm,$id,$loc,$io,$ad,$draw,$thendrawre);
1493     $io= defined $ctx->{InDefObj} ? "$ctx->{InDefObj}!" : $ctx->{InRunObj};
1494     o("%L cmd   $io $cmd @al\n");
1495     $ctx->{LocsMade}= [ ];
1496     {
1497         no strict 'refs';
1498         &{ "cmd_$cmd" };
1499     };
1500     die "too many args" if @al;
1501     foreach $lm (@{ $ctx->{LocsMade} }) {
1502         $id= $lm->{Id};
1503         $loc= $ctx->{Loc}{$id};
1504         $loc->{A} += $pi if $lm->{Neg};
1505         $ad= ang2deg($loc->{A});
1506         ol("%L point $io$id ".loc2dbg($loc)." ($lm->{Neg})\n");
1507         $draw= layer_draw($loc->{LayerKind}, $ctx->{Layer}{Level});
1508         if ($draw =~ m/[LM]/) {
1509             ol("    gsave\n".
1510                "      $loc->{X} $loc->{Y} translate $ad rotate\n");
1511             if ($draw =~ m/M/) {
1512                 ol("      0 $allwidthmin newpath moveto\n".
1513                    "      0 -$allwidthmin lineto\n".
1514                    "      $lmu_marklw setlinewidth stroke\n");
1515             }
1516             if ($draw =~ m/L/) {
1517                 ol("      /s ($id) def\n".
1518                    "      lf setfont\n".
1519                    "      /sx5  s stringwidth pop\n".
1520                    "      0.5 mul $lmu_txtboxpadx add def\n".
1521                    "      -90 rotate  0 $lmu_txtboxoff translate  newpath\n".
1522                    "      sx5 neg  0             moveto\n".
1523                    "      sx5 neg  $lmu_txtboxh  lineto\n".
1524                    "      sx5      $lmu_txtboxh  lineto\n".
1525                    "      sx5      0             lineto closepath\n".
1526                    "      gsave  1 setgray fill  grestore\n".
1527                    "      $lmu_txtboxlw setlinewidth stroke\n".
1528                    "      sx5 neg $lmu_txtboxpadx add  $lmu_txtboxtxty\n".
1529                    "      moveto s show\n");
1530             }
1531             ol("      grestore\n");
1532         }
1533     }
1534 }
1535
1536 sub cmd_ident {
1537     my ($vs, @lt, $inf, $strft);
1538     $vs= "@al";
1539     $vs= $1 if $vs =~ m/^\$Revision\: ([0-9.]+)\ \$$/;
1540     if (!defined $file_filename) {
1541         $inf= "$vs (unknown file: $file_lineno)";
1542     } elsif (!stat $file_filename ||
1543              !(@lt= localtime((stat _)[9]))) {
1544         $inf= "$file_filename ($1 $!)";
1545     } else {
1546         $strft= strftime "%Y-%m-%d %H:%M:%S +%Z", @lt;
1547         $inf= "$file_filename ($1 $strft)";
1548     }
1549     push @ident_strings, $inf;
1550     @al= ();
1551 }
1552
1553 sub cmd_showlibrary {
1554     my ($obj_id, $y, $x, $ctx_save, $width, $height);
1555     my ($max_x, $min_x, $max_y, $min_y, $nxty, $obj, $loc, $pat, $got, $glob);
1556     my ($adj);
1557     $x=$olu_left; $y=$olu_bottom; undef $nxty;
1558     $ctx_save= $ctx;
1559     foreach $obj_id (sort keys %objs) {
1560         $got= 1;
1561         foreach $glob (@al) {
1562             $pat= $glob;
1563             $got= !($pat =~ s/^\!//);
1564             die "bad pat" if $pat =~ m/[^0-9a-zA-Z_*?]/;
1565             $pat =~ s/\*/\.*/g; $pat =~ s/\?/./g;
1566             last if $obj_id =~ m/^$pat$/;
1567             $got= !$got;
1568         }
1569         next unless $got;
1570         $obj= $objs{$obj_id};
1571         next unless $obj->{Part};
1572         ($min_x, $max_x, $min_y, $max_y) = bbox($obj->{Loc});
1573         newctx($ctx_save);
1574
1575         for (;;) {
1576             $width= $max_x - $min_x;
1577             $height= $max_y - $min_y;
1578             if ($width < $height) {
1579                 $ctx->{Trans}{A}= 0;
1580                 $ctx->{Trans}{X}= $x - $min_x;
1581                 $ctx->{Trans}{Y}= $y - $min_y + $olu_textheight;
1582             } else {
1583                 ($width,$height)=($height,$width);
1584                 $ctx->{Trans}{A}= 0.5 * $pi;
1585                 $ctx->{Trans}{X}= $x + $max_y;
1586                 $ctx->{Trans}{Y}= $y - $min_x + $olu_textheight;
1587             }
1588             $adj= length($obj_id) * $olu_textallowperc - $width;
1589             $adj=0 if $adj<0;
1590             $width += $adj;
1591             $ctx->{Trans}{X} += 0.5 * $adj;
1592             if ($x + $width > $olu_right && defined $nxty) {
1593                 $x= $olu_left;
1594                 $y= $nxty;
1595                 undef $nxty;
1596             } elsif ($y + $height > $olu_top && $y > $olu_bottom) {
1597                 oflushpage();
1598                 $x= $olu_left; $y= $olu_bottom;
1599                 undef $nxty;
1600             } else {
1601                 last;
1602             }
1603         }
1604
1605         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}//";
1606         $ctx->{Draw}= $ctx_save->{Draw};
1607         cmd__runobj($obj_id);
1608         ol("    gsave\n".
1609            "      /s ($obj_id) def\n".
1610            "      lf setfont\n      ".
1611            ($x + 0.5*$width)." ".($y - $olu_textheight)." moveto\n".
1612            "      s stringwidth pop -0.5 mul  0  rmoveto\n".
1613            "      s show grestore\n");
1614         $x += $width + $olu_gap_x;
1615         upd_max(\$nxty, $y + $height + $olu_gap_y + $olu_textheight);
1616     }
1617     @al= ();
1618     $ctx= $ctx_save;
1619 }
1620
1621 sub cmd__one {
1622     cmd__do();
1623 }
1624
1625 o("%!\n".
1626   "  /lf /Courier-New findfont $lmu_marktpt scalefont def\n".
1627   "  $ps_page_shift 0 translate 90 rotate\n".
1628   "  gsave\n");
1629
1630 if ($page_x || $page_y) {
1631     o("  /Courier-New findfont 15 scalefont setfont\n".
1632       "  30 30 moveto (${page_x}x${page_y}) show\n");
1633 }
1634
1635 o("  -$ps_page_xmul $page_x mul  -$ps_page_ymul $page_y mul  translate\n".
1636   "  $ptscale $ptscale scale\n");
1637
1638 newctx();
1639
1640 open DEBUG, ($debug ? ">&2" : ">/dev/null") or die $!;
1641
1642 if ($debug) {
1643     select(DEBUG); $|=1;
1644     select(STDOUT); $|=1;
1645 }
1646
1647 $ctx->{Draw}= '';
1648 $ctx->{SegName}= '';
1649
1650 @al= qw(layer 5);
1651 cmd__one();
1652
1653 while (<>) {
1654     $file_lineno++;
1655     if (m/^\#line (\d+)$/) { $file_lineno= $1; next; }
1656     if (m/^\#line (\d+) (.*)$/) {
1657         $file_lineno= $1;
1658         $file_filename= $2;
1659         $file_filename =~ s/^\"(.*)\"$/$1/;
1660         next;
1661     }
1662     next if m/^\s*\#/;
1663     chomp; s/^\s+//; s/\s+$//;
1664     @al= split /\s+/, $_;
1665     next unless @al;
1666     print DEBUG "=== @al\n";
1667     last if $al[0] eq 'eof';
1668     push @{ $ctx->{CmdLog} }, [ @al ] if exists $ctx->{CmdLog};
1669     cmd__one();
1670 }
1671
1672 {
1673     my ($min_x, $max_x, $min_y, $max_y) = bbox($ctx->{Loc});
1674     my ($bboxstr);
1675     if (defined $min_x) {
1676         $bboxstr= sprintf("width  %.2d (%.2d..%2.d)\n".
1677                           "height %.2d (%.2d..%2.d)\n",
1678                           $max_x - $min_x, $min_x, $max_x,
1679                           $max_y - $min_y, $min_y, $max_y);
1680     } else {
1681         $bboxstr= "no locs, no bbox\n";
1682     }
1683     if (!$quiet) { print STDERR $bboxstr; }
1684     $bboxstr =~ s/^/\%L bbox /mg;
1685     o($bboxstr) or die $!;
1686
1687     if ($scale < 1.5) {
1688         my ($tick_x, $tick_y, $ticklen);
1689         $ticklen= 10;
1690         o(sprintf
1691           "    gsave 0.5 setgray 0.33 setlinewidth\n".
1692           "      /regmark {\n".
1693           "        newpath moveto\n".
1694           "        -%d 0 rmoveto %d 0 rlineto\n".
1695           "        -%d -%d rmoveto 0 %d rlineto stroke\n".
1696           "      } def\n",
1697           $ticklen, $ticklen*2, $ticklen, $ticklen, $ticklen*2);
1698         for ($tick_x= $min_x; $tick_x < $max_x; $tick_x += 150) {
1699             for ($tick_y= $min_y; $tick_y < $max_y; $tick_y += 150) {
1700                 o(sprintf "      %f %f regmark\n", $tick_x, $tick_y);
1701             }
1702         }
1703         o("    grestore\n");
1704     }
1705 }
1706
1707 ol("grestore\n");
1708
1709 if (@ident_strings) {
1710     my ($is);
1711     $is= join('; ', @ident_strings);
1712     $is =~ s/[()\\]/\\$&/g;
1713     ol("25 50 moveto".
1714        "/Courier-New findfont 6 scalefont setfont\n".
1715        " ($is) show\n");
1716 }
1717
1718 oflushpage();