layout/layout

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use IO::Handle;
   5 use IO::File;
   6
   7 use strict;
   8 no strict 'subs';
   9
  10 our $scale= 7.0;
  11 our $page_x= 0;
  12 our $page_y= 0;
  13 our $quiet=0;
  14 our $debug=0;
  15 our $output_layer= '*';
  16 our $subsegcmapreq=0;
  17 our $subsegmovfeatpos='f';
  18 our $subsegcmapangscale;
  19
  20 our $ps_page_shift= 615;
  21 our $ps_page_xmul= 765.354;
  22 our $ps_page_ymul= 538.583;
  23
  24 our @eopts;
  25 our @segments= ('/');
  26 our %subsegcmap;
  27
  28 our $drawers= 'arscldmnog';
  29 our %chdraw_emap= qw(A ARScgd
  30                      R aRscgD
  31                      S aRScgd
  32                      C arsCgd
  33                      c Arscgd
  34                      r arcs
  35                      L LMg
  36                      l l
  37                      M Mnog
  38                      N MNog
  39                      O MNOg
  40                      m mnol
  41                      G Garsclmno);
  42
  43 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  44     last if $ARGV[0] eq '-';
  45     $_= shift @ARGV;
  46     last if $_ eq '--';
  47     s/^\-//;
  48     while (length) {
  49         if (s/^D(\d+)//) { $debug= $1; }
  50         elsif (s/^D//) { $debug++; }
  51         elsif (s/^q//) { $quiet=1; }
  52         elsif (s/^l(\d+|\*)//) { $output_layer=$1; }
  53         elsif (s/^S([0-9.]+)$//) { $scale= $1 * 1.0; }
  54         elsif (s/^P(\d+)x(\d+)$//) { $page_x= $1; $page_y= $2; }
  55         elsif (s/^GR//) { $subsegcmapreq=1; }
  56         elsif (s/^GP(\d+|f)$//) { $subsegmovfeatpos=$1; }
  57         elsif (s/^GL(.*)$//) {
  58             my ($sscmfn) = $1;
  59             my ($sscmf, $datum, $csss, $angbits);
  60             local ($_);
  61             $sscmf= new IO::File $sscmfn, 'r'
  62                 or die "$sscmfn: cannot open: $!\n";
  63             for (;;) {
  64                 $!=0; $_= <$sscmf>; die $! unless defined $_;
  65                 last if m/^E/;
  66                 next unless m/^C/;
  67                 m,^C\s+(\w*/(?:[A-Za-z_]+)?)\s+(0x[0-9a-f]+)\s+(\d+)\s*$,
  68                     or die "$sscmfn:$.: syntax error in subseg cmap\n";
  69                 ($csss,$datum,$angbits)= ($1,$2,$3);
  70                 if (!defined $subsegcmapangscale) {
  71                     $subsegcmapangscale= 1<<$angbits;
  72                 } else {
  73                     die "angbits varies" if $subsegcmapangscale != 1<<$angbits;
  74                 }
  75                 $datum= hex($datum);
  76                 if ($datum & 0x0ff) {
  77                     die "sorry, cannot put any movfeatpos or segment in red";
  78                 }
  79                 $subsegcmap{$csss}= sprintf("%.6f %.6f",
  80                                             (($datum >> 8) & 0xff)/255.0,
  81                                             (($datum >> 16) & 0xff)/255.0);
  82             }
  83             $sscmf->error and die "$sscmfn: error reading: $!\n";
  84             close $sscmf;
  85         } elsif (s/^(e)
  86                ((?:[a-z]|\*|\?|\[[a-z][-a-z]*\])*?)
  87                (\~?) (\d*) (\=*|\-+|\++) (\d*|\*)
  88                ([a-z]+)$//ix) {
  89             my ($ee,$g,$n,$d,$c,$v,$cc) = ($1,$2,$3,$4,$5,$6,$7);
  90             my ($eo, $invert, $lfn, $ccc, $sense,$limit);
  91             $g =~ s/\?/\./g; $g =~ s/\*/\.\*/g;
  92             die '-[eE]GND[=]* not allowed' if $v eq '*' && length $d;
  93             $d= $output_layer if !length $d;
  94             $d= 5 if $d eq '*';
  95             $invert= length $n;
  96             $c= '=' if !length $c;
  97             if (length $v && $v ne '*') {
  98                 die '-[eE]GN[D]CCV not allowed' if length $c > 1;
  99                 $c= $c x $v;
 100             }
 101             if ($c =~ m/^[-+]/) {
 102                 die '-[eE]GN+/-* not allowed' if $v eq '*';
 103                 $sense= ($&.'1') + 0;
 104                 $limit= ($sense * $d) + length($c) - 1;
 105                 $lfn= sub {
 106                     ($output_layer eq '*' ? $d
 107                      : $_[0]) * $sense >= $limit
 108                          xor $invert;
 109                 };
 110             } elsif ($v eq '*') {
 111                 $lfn= sub { !$invert; };
 112             } else {
 113                 $limit= length($c) - 1;
 114                 $lfn= sub {
 115 #my ($lfn_result)=(
 116                     ($output_layer eq '*' ? 1
 117                      : abs($_[0] - $d) <= $limit)
 118                         xor $invert
 119 #)
 120                             ;
 121 #print STDERR "output layer $output_layer; asking re $_[0] rel $d lim $limit invert $invert result $lfn_result\n";
 122 #$lfn_result;
 123                 };
 124             }
 125             $ccc= '';
 126             foreach $c (split //, $cc) {
 127                 if ($ee eq 'e') {
 128                     die "bad -e option $c" unless defined $chdraw_emap{$c};
 129                     $ccc .=  $chdraw_emap{$c};
 130                 } else {
 131                     die "bad -E option $c" unless $c =~ m/[$drawers]/i;
 132                     $ccc .= $c;
 133                 }
 134             }
 135             $eo->{GlobRe}= $g;
 136             $eo->{LayerCheck}= $lfn;
 137             $eo->{DrawMods}= $ccc;
 138 #print STDERR "created eo $eo re $eo->{GlobRe} n=$n d=$d v=$v c=$c limit=$limit cc=$cc\n";
 139             push @eopts, $eo;
 140         } elsif (m/^S/) {
 141             die "-S option must come right at the start and have numeric arg";
 142         } else {
 143             die "unknown option -$_";
 144         }
 145     }
 146 }
 147
 148 our $ptscale= 72/25.4 / $scale;
 149
 150 our $psu_ulen= 4.5;
 151 our $psu_edgelw= 0.5;
 152 our $psu_ticklw= 0.1;
 153 our $psu_ticksperu= 1;
 154 our $psu_ticklen= 5.0;
 155 our $psu_gauge= 9;
 156 our $psu_sleeperlen= 17;
 157 our $psu_sleeperlw= 15;
 158 our $psu_raillw= 1.0;
 159 our $psu_thinlw= 1.0;
 160 our %psu_subseglw;
 161 $psu_subseglw{'e'}= 20.0;
 162 $psu_subseglw{'m'}= 15.0;
 163
 164 our $lmu_marklw= 4;
 165 our $lmu_marktpt= 11;
 166 our $lmu_txtboxtxty= $lmu_marktpt * 0.300;
 167 our $lmu_txtboxh= $lmu_marktpt * 1.100;
 168 our $lmu_txtboxpadx= $lmu_marktpt * 0.335;
 169 our $lmu_txtboxoff= $lmu_marklw / 2;
 170 our $lmu_txtboxlw= 1;
 171 our $lmu_lenlabeloffctr= -$lmu_marklw * 1.0;
 172 our $lmu_lenlabeloff=     $lmu_marklw * 0.5;
 173
 174 our $olu_left= 10 * $scale;
 175 our $olu_right= 217 * $scale - $olu_left;
 176 our $olu_bottom= 20 * $scale;
 177 our $olu_top= 270 * $scale - $olu_bottom;
 178 our $olu_gap_x= 30;
 179 our $olu_gap_y= 60;
 180 our $olu_textheight= 15;
 181 our $olu_textallowperc= $lmu_marktpt * 5.0/11;
 182
 183 our $pi= atan2(0,-1);
 184
 185 sub allwidth2 ($) {
 186     my ($radius)= @_;
 187     return 27 unless defined $radius;
 188     $radius= abs($radius);
 189     return ($radius >= 450 ? 33 :
 190             $radius >= 400 ? 35 :
 191             37);
 192 }
 193 sub allwidth ($) { return allwidth2($_[0]) * 0.5; }
 194
 195 our $allwidthmax= allwidth(0);
 196 our $allwidthmin= allwidth(undef);
 197
 198 # Data structures:
 199 #  $ctx->{CmdLog}= undef                  } not in defobj
 200 #  $ctx->{CmdLog}[]= [ command args ]     } in defobj
 201 #  $ctx->{Parent}= $parent_ctx or undef
 202 #  $ctx->{LocsMade}[]{Id}= $id
 203 #  $ctx->{LocsMade}[]{Neg}= 1 or 0
 204 #  $ctx->{Loc}{$id}{X}
 205 #  $ctx->{Loc}{$id}{Y}
 206 #  $ctx->{Loc}{$id}{A}
 207 #  $ctx->{Loc}{$id}{LayerKind}
 208 #  $ctx->{Trans}{X}       # transformation.  is ev representing
 209 #  $ctx->{Trans}{Y}       # new origin.  (is applied at _input_
 210 #  $ctx->{Trans}{A}       # not at plot-time)
 211 #  $ctx->{Trans}{R}       # but multiply all y coords by this!
 212 #  $ctx->{Draw}           # sequence of one or more chrs from uc $drawers
 213 #                         #  possibly including X meaning never draw
 214 #                         #  anything now (eg in defobj)
 215 #  $ctx->{DrawMap}        # =$fn s.t.
 216 #                         #  &$fn($drawchrs_spec_by_layer_cmdline)
 217 #                         #   = $drawchrs_we_should_use_due_to_obj_etc
 218 #  $ctx->{SegName}        # initial segment name (at start of object or file)
 219 #                         #  or nonexistent if in object in unknown segment
 220 #                         #  may have leading `-'
 221 #  $ctx->{SegMapN}{$s}= $o
 222 #  $ctx->{SegMapNM}{$s}= $o
 223 #  $ctx->{SavedSegment}   # exists iff segment command used, is a $csss
 224 #  $ctx->{Layer}{Level}
 225 #  $ctx->{Layer}{Kind}
 226 #
 227 #  $objs{$id}{CmdLog}
 228 #  $objs{$id}{Loc}
 229 #  $objs{$id}{Part}       # 1 iff object is a part
 230 #
 231 #  $eopts[]{GlobRe}       # regexp for K
 232 #  $eopts[]{LayerCheck}   # =$fn where &$fn($l) is true iff layer matches
 233 #  $eopts[]{DrawMods}     # modifier chars for drawing
 234 #
 235 #  @segments= ( $csss0, $dist0, $csss1, $dist1, ..., $csssn )
 236 #                         # here each csss may have preceding `-'
 237 #
 238 #  $subsegcmap{$csss} = "$green $blue"
 239 #                         # $csss is canonical subseg spec; always has '/'
 240
 241 our $ctx;
 242 our %objs;
 243 our @al; # current cmd
 244
 245 our $o='';
 246 our $ol='';
 247
 248 our $param; # for parametric_segment
 249
 250 # ev_... functions
 251 #
 252 # Operate on Enhanced Vectors which are a location (coordinates) and a
 253 # direction at that location.  Representation is a hash with members X
 254 # Y and A (angle of the direction in radians, anticlockwise from
 255 # East).  May be absolute, or interpreted as relative, according to
 256 # context.
 257 #
 258 # Each function's first argument is a hashref whose X Y A members will
 259 # be created or overwritten; this hashref will be returned (so you can
 260 # use it `functionally' by passing {}).  The other arguments may be ev
 261 # hashrefs, or other info.  The results are in general undefined if
 262 # one of the arguments is the same hash as the result.
 263
 264 sub ev_byang ($$;$) {
 265     # ev_byang(R, ANG,[LEN])
 266     # result is evec LEN (default=1.0) from origin pointing in direction ANG
 267     my ($res,$ang,$len)=@_;
 268     $len=1.0 unless defined $len;
 269     $res->{X}= $len * cos($ang);
 270     $res->{Y}= $len * sin($ang);
 271     $res->{A}= $ang;
 272     $res;
 273 }
 274 sub ev_compose ($$$) {
 275     # ev_compose(SUM_R, A,B);
 276     # appends B to A, result is end of new B
 277     # (B's X is forwards from end of A, Y is translating left from end of A)
 278     # A may have a member R, which if provided then it should be 1.0 or -1.0,
 279     # and B's Y and A will be multiplied by R first (ie, we can reflect);
 280     my ($sum,$a,$b) = @_;
 281     my ($r);
 282     $r= defined $a->{R} ? $a->{R} : 1.0;
 283     $sum->{X}= $a->{X} + $b->{X} * cos($a->{A}) - $r * $b->{Y} * sin($a->{A});
 284     $sum->{Y}= $a->{Y} + $r * $b->{Y} * cos($a->{A}) + $b->{X} * sin($a->{A});
 285     $sum->{A}= $a->{A} + $r * $b->{A};
 286     $sum;
 287 }
 288 sub ev_decompose ($$$) {
 289     # ev_decompose(B_R, A,SUM)
 290     # computes B_R s.t. ev_compose({}, A, B_R) gives SUM
 291     my ($b,$a,$sum)=@_;
 292     my ($r,$brx,$bry);
 293     $r= defined $a->{R} ? $a->{R} : 1.0;
 294     $brx= $sum->{X} - $a->{X};
 295     $bry= $r * ($sum->{Y} - $a->{Y});
 296     $b->{X}= $brx * cos($a->{A}) + $bry * sin($a->{A});
 297     $b->{Y}= $bry * cos($a->{A}) - $brx * sin($a->{A});
 298     $b->{A}= $r * ($sum->{A} - $a->{A});
 299     $b;
 300 }
 301 sub ev_lincomb ($$$$) {
 302     # ev_linkcomb(RES,A,B,P)
 303     # gives P*A + (1-P)*B
 304     my ($r,$a,$b,$p) = @_;
 305     my ($q) = 1.0-$p;
 306     map { $r->{$_} = $q * $a->{$_} + $p * $b->{$_} } qw(X Y A);
 307     $r;
 308 }
 309 sub a_normalise ($$) {
 310     # a_normalise(A,Z)
 311     # adds or subtracts 2*$pi to/from A until it is in [ Z , Z+2*$pi >
 312     my ($a,$z)=@_;
 313     my ($r);
 314     $r= $z + fmod($a - $z, 2.0*$pi);
 315     $r += 2*$pi if $r < $z;
 316     return $r;
 317 }
 318 sub ev_bearing ($$) {
 319     # ev_bearing(A,B)
 320     # returns bearing of B from A
 321     # value returned is in [ A->{A}, A->{A} + 2*$pi >
 322     # A->{A} and B->{A} are otherwise ignored
 323     my ($a,$b)= @_;
 324     my ($r);
 325     $r= atan2($b->{Y} - $a->{Y},
 326               $b->{X} - $a->{X});
 327     $r= a_normalise($r,$a->{A});
 328     return $r;
 329 }
 330
 331 sub v_rotateright ($) {
 332     # v_rotateright(A)
 333     # returns image of A rotated 90 deg clockwise
 334     my ($a)= @_;
 335     return { X => $a->{Y}, Y => -$a->{X} };
 336 }
 337 sub v_dotproduct ($$) {
 338     # v_dotproduct(A,B)
 339     my ($a,$b)= @_;
 340     return $a->{X} * $b->{X} + $a->{Y} * $b->{Y};
 341 }
 342 sub v_scalarmult ($$) {
 343     # v_scalarmult(S,V)
 344     # multiplies V by scalar S and returns product
 345     my ($s,$v)=@_;
 346     return { X => $s * $v->{X}, Y => $s * $v->{Y} };
 347 }
 348 sub v_add ($;@) {
 349     # v_add(A,B,...)
 350     # vector sum of all inputs
 351     my (@i) = @_;
 352     my ($r,$i);
 353     $r= { X => 0.0, Y => 0.0 };
 354     foreach $i (@i) { $r->{X} += $i->{X}; $r->{Y} += $i->{Y}; }
 355     return $r;
 356 }
 357 sub v_subtract ($$) {
 358     # v_subtract(A,B)
 359     # returns vector from A to B, ie B - A
 360     my ($a,$b)= @_;
 361     return { X => $b->{X} - $a->{X},
 362              Y => $b->{Y} - $a->{Y} };
 363 }
 364 sub v_len ($) {
 365     # v_len(V)
 366     # scalar length of V
 367     my ($v)=@_;
 368     my ($x,$y) = ($v->{X}, $v->{Y});
 369     return sqrt($x*$x + $y*$y);
 370 }
 371 sub v_dist ($$) {
 372     # v_dist(A,B)
 373     # returns distance from A to B
 374     return v_len(v_subtract($_[0],$_[1]));
 375 }
 376
 377 sub upd_min ($$) {
 378     my ($limr,$now)=@_;
 379     $$limr= $now unless defined $$limr && $$limr <= $now;
 380 }
 381 sub upd_max ($$) {
 382     my ($limr,$now)=@_;
 383     $$limr= $now unless defined $$limr && $$limr >= $now;
 384 }
 385
 386 sub canf ($$) {
 387     my ($converter,$defaulter)=@_;
 388     my ($spec,$v);
 389     return &$defaulter unless @al;
 390     $spec= shift @al;
 391     $v= &$converter($spec);
 392     dv('canf ','$spec',$spec, '$v',$v);
 393     return $v;
 394 }
 395 sub can ($) { my ($c)=@_; canf($c, sub { die "too few args"; }); }
 396 sub cano ($$) { my ($c,$def)=@_; canf($c, sub { return $def }); }
 397
 398 sub signum ($) { return ($_[0] > 0) - ($_[0] < 0); }
 399
 400 sub bbox ($) {
 401     my ($objhash) = @_;
 402     my ($min_x, $max_x, $min_y, $max_y);
 403     my ($loc);
 404     foreach $loc (values %$objhash) {
 405         upd_min(\$min_x, $loc->{X} - abs($allwidthmax * sin($loc->{A})));
 406         upd_max(\$max_x, $loc->{X} + abs($allwidthmax * sin($loc->{A})));
 407         upd_min(\$min_y, $loc->{Y} - abs($allwidthmax * cos($loc->{A})));
 408         upd_max(\$max_y, $loc->{Y} + abs($allwidthmax * cos($loc->{A})));
 409     }
 410     return ($min_x, $max_x, $min_y, $max_y);
 411 }
 412
 413 our %units_len= qw(- mm  mm 1  cm 10  m 1000);
 414 our %units_ang= qw(- d   r 1); $units_ang{'d'}= 2*$pi / 360;
 415
 416 sub cva_len ($) { my ($sp)=@_; cva_units($sp,\%units_len); }
 417 sub cva_identity ($) { my ($sp)=@_; $sp; }
 418 sub cva_ang ($) { my ($sp)=@_; cva_units($sp,\%units_ang); }
 419 sub cva_absang ($) { input_absang(cva_ang($_[0])) }
 420 sub cva_units ($$) {
 421     my ($sp,$ua)=@_;
 422     my ($n,$u,$r);
 423     $sp =~ m/^([-0-9eE.]*[0-9.])([A-Za-z]*)$/
 424         or die "lexically invalid quantity";
 425     ($n,$u)= ($1,$2);
 426     $u=$ua->{'-'} unless length $u;
 427     defined $ua->{$u} or die "unknown unit $u";
 428     $r= $n * $ua->{$u};
 429     print DEBUG "cva_units($sp,)=$r ($n $u $ua->{$u})\n";
 430     return $r;
 431 }
 432 sub cva_idstr ($) {
 433     my ($sp)=@_;
 434     die "invalid id" unless $sp =~ m/^[a-z][_0-9A-Za-z]*$/;
 435     return $&;
 436 }
 437 sub cva_idex ($) {
 438     my ($sp)=@_;
 439     my ($id,$r,$d,$k,$neg,$na,$obj_id,$vflip,$locs);
 440     if ($sp =~ s/^(\^?)(\w+)\!//) {
 441         $vflip= length($1);
 442         $obj_id= $2;
 443         die "invalid obj $obj_id in loc" unless exists $objs{$obj_id};
 444         $locs= $objs{$obj_id}{Loc};
 445     } else {
 446         $locs= $ctx->{Loc};
 447         $vflip= 0;
 448     }
 449     $neg= $sp =~ s/^\-//;
 450     $id= cva_idstr($sp);
 451     die "unknown $id" unless defined $locs->{$id};
 452     $r= $locs->{$id};
 453     $d= "idex $id";
 454     foreach $k (sort keys %$r) { $d .= " $k=$r->{$k}"; }
 455     printf DEBUG "%s\n", $d;
 456     if ($vflip) {
 457         $r= { X => $r->{X}, Y => -$r->{Y}, A => -$r->{A} };
 458     }
 459     if ($neg) {
 460         $na= $r->{A} + $pi;
 461         $na= a_normalise($na,0);
 462         $r= { X => $r->{X}, Y => $r->{Y}, A => $na };
 463     }
 464     return $r;
 465 }
 466 sub cva_idnew ($) {
 467     my ($sp)=@_;
 468     my ($id, $neg);
 469     $neg = $sp =~ s/^\-//;
 470     $id=cva_idstr($sp);
 471     die "duplicate $id" if exists $ctx->{Loc}{$id};
 472     $ctx->{Loc}{$id}{LayerKind}= $ctx->{Layer}{Kind};
 473     push @{ $ctx->{LocsMade} }, {
 474         Id => $id,
 475         Neg => $neg,
 476     };
 477     return $ctx->{Loc}{$id};
 478 }
 479 sub cva_cmd ($) { return cva_idstr($_[0]); }
 480 sub cva__enum ($$) {
 481     my ($sp,$el)=@_;
 482     return $sp if grep { $_ eq $sp } @$el;
 483     die "invalid option (permitted: @$el)";
 484 }
 485 sub cvam_enum { my (@e) = @_; return sub { cva__enum($_[0],\@e); }; }
 486
 487 sub cmd_abs {
 488     my ($i,$nl);
 489     $nl= can(\&cva_idnew);
 490     $i->{X}= can(\&cva_len);
 491     $i->{Y}= can(\&cva_len);
 492     $i->{A}= can(\&cva_ang);
 493     ev_compose($nl, $ctx->{Trans}, $i);
 494 }
 495 sub cmd_rel {
 496     my ($from,$to,$len,$right,$turn);
 497     $from= can(\&cva_idex);
 498     $to= can(\&cva_idnew);
 499     $len= cano(\&cva_len,0);
 500     $right= cano(\&cva_len,0) * $ctx->{Trans}{R};
 501     $turn= cano(\&cva_ang, 0) * $ctx->{Trans}{R};
 502     my ($u)= ev_compose({}, $from, { X => $len, Y => -$right, A => 0 });
 503     ev_compose($to, $u, { X => 0, Y => 0, A => $turn });
 504 }
 505
 506 sub dv__evreff ($) {
 507     my ($pfx) = @_;
 508     $pfx . ($pfx =~ m/\}$|\]$/ ? '' : '->');
 509 }
 510 sub dv__evr ($) {
 511     my ($v) = @_;
 512     return 'undef' if !defined $v;
 513     return $v if $v !~ m/\W/ && $v =~ m/[A-Z]/ && $v =~ m/^[a-z_]/i;
 514     return $v if $v =~ m/^[0-9.]+/;
 515     $v =~ s/[\\\']/\\$&/g;
 516     return "'$v'";
 517 }
 518 sub dv1 ($$$);
 519 sub dv1_kind ($$$$$$$) {
 520     my ($pfx,$expr,$ref,$ref_exp,$ixfmt,$ixesfn,$ixmapfn) = @_;
 521     my ($ix,$any);
 522     return 0 if $ref ne $ref_exp;
 523     $any=0;
 524     foreach $ix (&$ixesfn) {
 525         $any=1;
 526         my ($v)= &$ixmapfn($ix);
 527 #print STDERR "dv1_kind($pfx,$expr,$ref,$ref_exp,$ixmapfn) ix=$ix v=$v\n";
 528         dv1($pfx,$expr.sprintf($ixfmt,dv__evr($ix)),$v);
 529     }
 530     if (!$any) {
 531         printf DEBUG "%s%s= $ixfmt\n", $pfx, $expr, ' ';
 532     }
 533     1;
 534 }
 535 sub dv1 ($$$) {
 536     return 0 unless $debug;
 537     my ($pfx,$expr,$v) = @_;
 538     my ($ref);
 539     $ref= ref $v;
 540 #print STDERR "dv1 >$pfx|$ref<\n";
 541     if (!$ref) {
 542         printf DEBUG "%s%s= %s\n", $pfx,$expr, dv__evr($v);
 543         return;
 544     } elsif ($ref eq 'SCALAR') {
 545         dv1($pfx, ($expr =~ m/^\$/ ? "\$$expr" : '${'.$expr.'}'), $$v);
 546         return;
 547     }
 548     $expr.='->' unless $expr =~ m/\]$|\}$/;
 549     return if dv1_kind($pfx,$expr,$ref,'ARRAY','[%s]',
 550                        sub { ($[ .. $#$v) },
 551                        sub { $v->[$_[0]] });
 552     return if dv1_kind($pfx,$expr,$ref,'HASH','{%s}',
 553                        sub { sort keys %$v },
 554                        sub { $v->{$_[0]} });
 555     printf DEBUG "%s%s is %s\n", $pfx, $expr, $ref;
 556 }
 557
 558 sub dv {
 559     my ($pfx,@l) = @_;
 560     my ($expr,$v,$ref);
 561     while (@l) {
 562         ($expr,$v,@l)=@l;
 563         dv1($pfx,$expr,$v);
 564     }
 565 }
 566
 567 sub o ($) { $o .= $_[0]; }
 568 sub ol ($) { $ol .= $_[0]; }
 569 sub oflushpage () {
 570     return if $subsegcmapreq;
 571     print $o, $ol, "  showpage\n"
 572         or die $!;
 573     $o=$ol='';
 574 }
 575
 576 our $o_path_verb;
 577
 578 sub o_path_begin () {
 579     o("      newpath\n");
 580     $o_path_verb= 'moveto';
 581 }
 582 sub o_path_point ($) {
 583     my ($pt)=@_;
 584     o("        $pt $o_path_verb\n");
 585     $o_path_verb= 'lineto';
 586 }
 587 sub o_path_stroke ($) {
 588     my ($width)=@_;
 589     o("        $width setlinewidth stroke\n");
 590 }
 591 sub o_path_strokeonly () {
 592     o("      stroke\n");
 593 }
 594
 595 sub o_line ($$$) {
 596     my ($a,$b,$width)=@_;
 597     o_path_begin();
 598     o_path_point($a);
 599     o_path_point($b);
 600     o_path_stroke($width);
 601 }
 602
 603 sub current_draw () {
 604     my ($r);
 605     $r= $ctx->{Draw} =~ m/X/ ? '' : $ctx->{Draw};
 606     $r;
 607 }
 608
 609 sub psu_coords ($$$) {
 610     my ($ends,$inunit,$across)=@_;
 611     # $ends->[0]{X} etc.; $inunit 0 to 1 (but go to 1.5);
 612     # $across in mm, +ve to right.
 613     my (%ea_zo, $zo, $prop);
 614     $ea_zo{X}=$ea_zo{Y}=0;
 615     foreach $zo (qw(0 1)) {
 616         $prop= $zo ? $inunit : (1.0 - $inunit);
 617         $ea_zo{X} += $prop * ($ends->[$zo]{X} - $across * sin($ends->[0]{A}));
 618         $ea_zo{Y} += $prop * ($ends->[$zo]{Y} + $across * cos($ends->[0]{A}));
 619     }
 620 #    dv("psu_coords ", '$ends',$ends, '$inunit',$inunit, '$across',$across,
 621 #       '\\%ea_zo', \%ea_zo);
 622     return $ea_zo{X}." ".$ea_zo{Y};
 623 }
 624
 625 sub parametric__o_pt ($) {
 626     my ($pt)=@_;
 627     o_path_point("$pt->{X} $pt->{Y}");
 628 }
 629
 630 our $segused_incurrent;
 631 our $segused_currentpt;
 632 our $segmentpart_counter=0;
 633 our $segused_restorecounter;
 634
 635 sub segment_used__print ($) {
 636     my ($pt) = @_;
 637     if ($segused_incurrent > 0 && $segused_restorecounter==1) {
 638         o("%L segmentpart ".
 639           $segmentpart_counter++." ".
 640           $ctx->{Layer}{Level}.$ctx->{Layer}{Kind}." ".
 641           $segments[0]." ".
 642           $segused_incurrent." ".
 643           loc2dbg($segused_currentpt)." ".
 644           loc2dbg($pt)."\n");
 645     }
 646     $segused_incurrent= undef;
 647     $segused_currentpt= undef;
 648 }
 649
 650 sub segment_used__len ($$) {
 651     my ($used,$pt) = @_;
 652     $segused_incurrent++;
 653
 654     return if @segments < 3;
 655     $segments[1] -= $used;
 656     return if $segments[1] > 0;
 657
 658     segment_used__print($pt);
 659     segment_used_begin($pt);
 660
 661     @segments= @segments[2..$#segments];
 662     o("% segments @segments\n");
 663 }
 664
 665 sub segment_state_save () {
 666     return [ 0, $segused_incurrent, $segused_currentpt,
 667              $segmentpart_counter, @segments ];
 668 }
 669 sub segment_state_restore ($) {
 670     my ($r) = @_;
 671     ($segused_restorecounter, $segused_incurrent, $segused_currentpt,
 672      $segmentpart_counter, @segments) = @$r;
 673     $r->[0]++;
 674 }
 675
 676 sub segment_used_begin ($) {
 677     $segused_incurrent= 0;
 678     $segused_currentpt= $_[0];
 679 }
 680 sub segment_used_middle ($$) {
 681     my ($used,$pt) = @_;
 682     segment_used__len($used,$pt);
 683 }
 684 sub segment_used_end ($$) {
 685     my ($used,$pt) = @_;
 686     segment_used__len($used,$pt);
 687     segment_used__print($pt);
 688 }
 689 sub parametric_segment ($$$$$) {
 690     my ($p0,$p1,$lenperp,$minradius,$calcfn) = @_;
 691     # makes $param (global) go from $p0 to $p1  ($p1>$p0)
 692     # $lenperp is the length of one unit p, ie the curve
 693     # must have a uniform `density' in parameter space
 694     # $calcfn is invoked with $param set and should return a loc
 695     # (ie, ref to X =>, Y =>, A =>).
 696     my ($pa,$pb,@ends,$side,$ppu,$e,$v,$tick,$draw,$allwidth);
 697     return unless $ctx->{Draw} =~ m/[ARSCG]/;
 698     $ppu= $psu_ulen/$lenperp;
 699     $allwidth= allwidth($minradius);
 700     my ($railctr)=($psu_gauge + $psu_raillw)*0.5;
 701     my ($tickend)=($allwidth - $psu_ticklen);
 702     my ($tickpitch)=($psu_ulen / $psu_ticksperu);
 703     my ($sleeperctr)=($psu_ulen*0.5);
 704     my ($sleeperend)=($psu_sleeperlen*0.5);
 705 print DEBUG "ps $p0 $p1 $lenperp ($ppu)\n";
 706     $draw= current_draw();
 707     if ($draw =~ m/G/) {
 708         my ($pt,$going,$red,$csegbare,$movfeat,$movstroke);
 709         my ($used_last,$me,$segsave);
 710         $segsave= segment_state_save();
 711         foreach $me (qw(e m)) {
 712             segment_state_restore($segsave);
 713             $going=0;
 714             o("% segments @segments\n");
 715             $param=$p0;
 716             $pt= &$calcfn;
 717             segment_used_begin($pt);
 718             for (;;) {
 719                 $movstroke= "      cmapreq-stroke\n";
 720                 $csegbare= $segments[0];
 721                 $csegbare =~ s/^\-//;
 722                 if ($subsegcmapreq) {
 723                     if (!exists $subsegcmap{$csegbare}) {
 724                         print "$csegbare\n" or die $!;
 725                         $subsegcmap{$csegbare}++;
 726                     }
 727                 } else {
 728                     $movfeat= $csegbare =~ s,(/\D+)(\d+)$,$1, ? $2 : 'f';
 729                     die "unknown subsegment colour for $csegbare\n"
 730                         unless exists $subsegcmap{$csegbare};
 731                     $red= $pt->{A} / (2*$pi);
 732                     $red *= $subsegcmapangscale;
 733                     $red += $subsegcmapangscale*2;
 734                     $red += $subsegcmapangscale/2 if $segments[0] =~ m/^\-/;
 735                     $red %= $subsegcmapangscale;
 736                     $red += $subsegcmapangscale if $me eq 'e';
 737                     $red= sprintf("%f", $red / 255.0);
 738                     $movstroke=
 739                         ("    $red $subsegcmap{$csegbare} setrgbcolor\n".
 740                          "    $psu_subseglw{$me} setlinewidth stroke\n");
 741                     if ($subsegmovfeatpos ne $movfeat ||
 742                         ($me eq 'e' && $csegbare =~ m,^/,)) {
 743                         $movstroke= "%     no-stroke\n";
 744                     }
 745                 }
 746                 o_path_begin();
 747                 parametric__o_pt($pt);
 748
 749                 $param += $ppu;
 750                 last if $param>=$p1;
 751                 $pt= &$calcfn;
 752                 segment_used_middle($psu_ulen,$pt);
 753                 parametric__o_pt($pt);
 754                 o($movstroke);
 755             }
 756             $used_last= $p1-($param-$ppu);
 757             $param=$p1;
 758             $pt= &$calcfn;
 759             segment_used_end($used_last * $lenperp, $pt);
 760             parametric__o_pt($pt);
 761             o($movstroke);
 762         }
 763     }
 764     if ($draw =~ m/C/) {
 765         my ($pt);
 766         o("    $psu_thinlw setlinewidth\n");
 767         o_path_begin();
 768         for ($param=$p0; $param<$p1; $param += $ppu) {
 769             parametric__o_pt(&$calcfn);
 770         }
 771         $param=$p1;
 772         parametric__o_pt(&$calcfn);
 773         o("      stroke\n");
 774     }
 775     if ($draw =~ m/D/) {
 776         my ($pt,$ad,$len,$off);
 777         $param= ($p0+$p1)*0.5;
 778         $pt= &$calcfn;
 779         $ad= ang2deg($pt->{A});
 780         $len= sprintf "%.0f", $lenperp * abs($p1-$p0);
 781         $off= $draw =~ m/C/ ? $lmu_lenlabeloff : $lmu_lenlabeloffctr;
 782         ol("      gsave\n".
 783            "        $pt->{X} $pt->{Y} translate\n".
 784            "        $ad rotate\n".
 785            "        lf setfont\n".
 786            "        0 $off moveto\n".
 787            "        ($len) show\n".
 788            "      grestore\n");
 789     }
 790     return unless $draw =~ m/[ARS]/;
 791     for ($pa= $p0; $pa<$p1; $pa=$pb) {
 792         $pb= $pa + $ppu;
 793         $param= $pa; $ends[0]= @ends ? $ends[1] : &$calcfn;
 794         $param= $pb; $ends[1]= &$calcfn;
 795 #print DEBUG "pa $pa $ends[0]{X} $ends[0]{Y} $ends[0]{A}\n";
 796 #print DEBUG "pb $pb $ends[1]{X} $ends[1]{Y} $ends[1]{A}\n";
 797         $e= $pb<=$p1 ? 1.0 : ($p1-$pa)/$ppu;
 798         o("    gsave\n");
 799         o_path_begin();
 800         o_path_point(psu_coords(\@ends,0,-$allwidth));
 801         o_path_point(psu_coords(\@ends,0,$allwidth));
 802         o_path_point(psu_coords(\@ends,$e,$allwidth));
 803         o_path_point(psu_coords(\@ends,$e,-$allwidth));
 804         o("        closepath clip\n");
 805         foreach $side qw(-1 1) {
 806             if ($draw =~ m/R/) {
 807                 o_line(psu_coords(\@ends,0,$side*$railctr),
 808                        psu_coords(\@ends,1.5,$side*$railctr),
 809                        $psu_raillw);
 810             }
 811         }
 812         if ($draw =~ m/S/) {
 813             o_line(psu_coords(\@ends,$sleeperctr,-$sleeperend),
 814                    psu_coords(\@ends,$sleeperctr,+$sleeperend),
 815                    $psu_sleeperlw);
 816         }
 817         if ($draw =~ m/A/) {
 818             o("        0.5 setgray\n");
 819             foreach $side qw(-1 1) {
 820                 o_line(psu_coords(\@ends,0,$side*$allwidth),
 821                        psu_coords(\@ends,1.5,$side*$allwidth),
 822                        $psu_edgelw);
 823                 for ($tick=0; $tick<1.5; $tick+=$tickpitch/$psu_ulen) {
 824                     o_line(psu_coords(\@ends,$tick,$side*$allwidth),
 825                            psu_coords(\@ends,$tick,$side*$tickend),
 826                            $psu_ticklw);
 827                 }
 828             }
 829         }
 830         o("      grestore\n");
 831     }
 832 }
 833
 834 sub arc ($$$$$) {
 835     my ($to, $ctr,$from, $radius,$delta) = @_;
 836     # does parametric_segment to draw an arc centred on $ctr
 837     # ($ctr->{A} ignored)
 838     # from $from with radius $radius (this must be consistent!)
 839     # and directionally-subtending an angle $delta.
 840     # sets $to->... to be the other end, and returns $to
 841     my ($beta);
 842     $to->{A}= $beta= $from->{A} + $delta;
 843     $to->{X}= $ctr->{X} - $radius * sin($beta);
 844     $to->{Y}= $ctr->{Y} + $radius * cos($beta);
 845     return if abs($delta*$radius) < 1e-9;
 846     parametric_segment(0.0,1.0, abs($radius*$delta), $radius, sub {
 847         my ($beta) = $from->{A} + $delta * $param;
 848         return { X => $ctr->{X} - $radius * sin($beta),
 849                  Y => $ctr->{Y} + $radius * cos($beta),
 850                  A => $beta }
 851     });
 852 }
 853
 854 # joins_xxx all take $results, $from, $to, $minradius
 855 # where $results->[]{Path}{K} etc. and $results->[]{SolKinds}[]
 856
 857 sub joins_twoarcs ($$$$) {
 858     my ($results, $from,$to,$minradius) = @_;
 859     # two circular arcs of equal maximum possible radius
 860     # algorithm courtesy of Simon Tatham (`Railway problem',
 861     # pers.comm. to ijackson@chiark 23.1.2004)
 862     my ($sigma,$distfact, $theta,$phi, $a,$b,$c,$d, $m,$r, $radius);
 863     my ($cvec,$cfrom,$cto,$midpt, $delta1,$delta2, $path,$reverse);
 864     $sigma= ev_bearing($from,$to);
 865     $distfact= v_dist($from,$to);
 866     $theta= 0.5 * $pi - ($from->{A} - $sigma);
 867     $phi=   0.5 * $pi - ($to->{A} + $pi - $sigma);
 868     $a= 2 * (1 + cos($theta - $phi));
 869     $b= 2 * (cos($theta) - cos($phi));
 870     $c= -1;
 871     $d= sqrt($b*$b - 4*$a*$c);
 872     o("%     twoarcs theta=".ang2deg($theta)." phi=".ang2deg($phi).
 873       " ${a}r^2 + ${b}r + ${c} = 0\n");
 874     foreach $m (qw(-1 1)) {
 875         if ($a < 1e-6) {
 876             o("%     twoarcs $m insoluble\n");
 877             next;
 878         }
 879         $r= -0.5 * (-$b + $m*$d) / $a;
 880         $radius= -$r * $distfact;
 881         o("%     twoarcs $m radius $radius ");
 882         if (abs($radius) < $minradius) { o("too-small\n"); next; }
 883         $cfrom=  ev_compose({}, $from, { X=>0, Y=>-$radius, A=>-0.5*$pi });
 884         $cto=    ev_compose({}, $to,   { X=>0, Y=> $radius, A=> 0.5*$pi });
 885         $midpt=  ev_lincomb({}, $cfrom, $cto, 0.5);
 886         $reverse= signum($r);
 887         if ($reverse<0) {
 888             $cfrom->{A} += $pi;
 889             $cto->{A} += $pi;
 890         }
 891         $delta1= ev_bearing($cfrom, $midpt) - $cfrom->{A};
 892         $delta2= ev_bearing($cto,   $midpt) - $cto->{A};
 893         o("ok deltas ".ang2deg($delta1)." ".ang2deg($delta2)."\n");
 894         if ($reverse<0) {
 895             $delta1 -= 2*$pi;
 896             $delta2 -= 2*$pi;
 897         }
 898         my ($fs);
 899         $path= [{ T=>Arc, F=>$from, C=>$cfrom, R=> $radius, D=>$delta1 },
 900                 { T=>Arc, F=>$to,   C=>$cto,   R=>-$radius, D=>$delta2 }];
 901         push @$results, { Path => $path,
 902                           SolKinds =>  [ 'twoarcs', 'cross' ] };
 903     }
 904 }
 905
 906 sub joins_arcsline ($$$$) {
 907     my ($results, $from,$to,$minradius) = @_;
 908     # two circular arcs of specified radius
 909     # with an intervening straight
 910     my ($lr,$inv, $c,$d,$alpha,$t,$k,$l,$rpmsina,$rcosa,$linelen, $path);
 911     if ($minradius<=1e-6) { o("%     arcsline no-radius\n"); return; }
 912     foreach $lr (qw(-1 +1)) {
 913         foreach $inv (qw(-1 +1)) {
 914             $c=ev_compose({},$from,{X=>0,Y=>-$lr*$minradius, A=>0 });
 915             $d=ev_compose({},$to,{X=>0, Y=>-$inv*$lr*$minradius, A=>$pi });
 916             $t= v_dist($c,$d);
 917             o("%     arcsline $lr $inv t=$t ");
 918             if ($t < 1e-6) { o("concentric"); next; }
 919             $c->{A}= $d->{A}= ev_bearing($c,$d);
 920             o("bearing ".ang2deg($c->{A}));
 921             if ($inv>0) {
 922                 o("\n");
 923                 $k= ev_compose({}, $c, { X=>0, Y=>$lr*$minradius, A=>0 });
 924                 $l= ev_compose({}, $d, { X=>0, Y=>$lr*$minradius, A=>0 });
 925                 $linelen= $t;
 926             } else {
 927                 my ($cosalpha) = 2.0 * $minradius / $t;
 928                 if ($cosalpha > (1.0 - 1e-6)) { o(" too-close\n"); next; }
 929                 $alpha= acos($cosalpha);
 930                 $rpmsina= $lr * $minradius * sin($alpha);
 931                 $rcosa= $minradius * $cosalpha;
 932                 $k= ev_compose({}, $c, { X=>$rcosa, Y=>$rpmsina, A=>0 });
 933                 $l= ev_compose({}, $d, { X=>-$rcosa, Y=>-$rpmsina, A=>0 });
 934                 $k->{A}= $l->{A}= ev_bearing($k,$l);
 935                 o(" alpha=".ang2deg($alpha)." kl^=".ang2deg($k->{A})."\n");
 936                 $linelen= v_dist($k,$l);
 937             }
 938             $path= [{ T => Arc, F => $from, C => $c,
 939                       R =>$lr*$minradius,
 940                       D => -$lr * a_normalise
 941                           ($lr * ($from->{A} - $k->{A}), 0) },
 942                     { T => Line, A => $k, B => $l, L => $linelen },
 943                     { T => Arc, F => $l, C => $d,
 944                       R => $inv*$lr*$minradius,
 945                       D => -$lr*$inv * a_normalise
 946                           (-$lr*$inv * ($to->{A} - $l->{A}), 0) }];
 947             push @$results,
 948             { Path => $path,
 949               SolKinds => [ 'arcsline', ($inv<0 ? 'cross' : 'loop') ] };
 950         }
 951     }
 952 }
 953
 954 sub joins_arcline ($$$$) {
 955     my ($results, $from,$to,$minradius) = @_;
 956     # one circular arc and a straight line
 957     my ($swap,$echoice,$path, $ap,$bp,$av,$bv, $e,$f, $ae,$af,$afae);
 958     my ($dak,$ak,$kj,$k,$j,$aja,$jl,$l,$jc,$lc,$c,$rj,$rb);
 959     foreach $swap (qw(-1 +1)) {
 960         foreach $echoice (qw(0 1)) {
 961             $ap= $from; $bp= { %$to }; $bp->{A} += $pi;
 962             ($ap,$bp)= ($bp,$ap) if $swap<0;
 963             $av= ev_byang({}, $ap->{A});
 964             $bv= ev_byang({}, $bp->{A});
 965             $e= ev_byang({}, 0.5 * ($ap->{A} + $bp->{A} + $echoice * $pi));
 966             $f= v_rotateright($e);
 967             o("%     arcline $swap $echoice e ".loc2dbg($e)."\n");
 968             $ae= v_dotproduct($av,$e);
 969             $af= v_dotproduct($av,$f);
 970             o("%     arcline $swap $echoice a.e=$ae a.f=$af ");
 971             if (abs($ae) < 1e-6) { o(" singular\n"); next; }
 972             $afae= $af/$ae;
 973             o("a.f/a.e=$afae\n");
 974             $dak= v_dotproduct(v_subtract($ap,$bp), $e);
 975             $ak= v_scalarmult($dak, $e);
 976             $kj= v_scalarmult($dak * $afae, $f);
 977             $k= v_add($ap, $ak);
 978             $j= v_add($k, $kj);
 979             $aja= v_dotproduct(v_subtract($ap,$j), $av);
 980             o("%     arcline $swap $echoice d_ak=$dak aj.a=$aja ");
 981             if ($aja < 0) { o(" backwards aj\n"); next; }
 982             $jl= v_scalarmult(0.5, v_subtract($j, $bp));
 983             $lc= v_scalarmult(-v_dotproduct($jl, $f) * $afae, $e);
 984             $l= v_add($j, $jl);
 985             $c= v_add($l, $lc);
 986             $rj= v_dotproduct(v_subtract($j,$c), v_rotateright($av));
 987             $rb= v_dotproduct(v_subtract($c,$bp), v_rotateright($bv));
 988             o("r_j=$rj r_b=$rb ");
 989             if ($rj * $rb < 0) { o(" backwards b\n"); next; }
 990             if (abs($rj) < $minradius) { o(" too-small\n"); next; }
 991             o("ok\n");
 992             $j->{A}= $ap->{A};
 993             $c->{A}= 0;
 994             $path= [{ T => Line, A => $ap, B => $j, L => $aja },
 995                     { T => Arc, F => $j, C => $c, R => $rj,
 996                       D => -signum($rj) * a_normalise
 997                           (-signum($rj) * ($bp->{A} + $pi - $j->{A}), 0) }];
 998             $path= [ reverse @$path ] if $swap<0;
 999             push @$results, { Path => $path, SolKinds =>  [ 'arcline' ] };
1000         }
1001     }
1002 }
1003
1004 sub cmd_join {
1005     my ($from,$to,$minradius);
1006     my (@results,$result);
1007     my ($path,$segment,$bestpath,$len,$scores,$bestscores,@bends,$skl);
1008     my ($crit,$cs,$i,$cmp);
1009     $from= can(\&cva_idex);
1010     $to= can(\&cva_idex);
1011     $minradius= can(\&cva_len);
1012     o("%   join ".loc2dbg($from)."..".loc2dbg($to)." $minradius\n");
1013     joins_twoarcs(\@results, $from,$to,$minradius);
1014     joins_arcsline(\@results, $from,$to,$minradius);
1015     joins_arcline(\@results, $from,$to,$minradius);
1016     foreach $result (@results) {
1017         $path= $result->{Path};
1018         $skl= $result->{SolKinds};
1019         o("%   possible path @$skl $path\n");
1020         $len= 0;
1021         @bends= ();
1022         foreach $segment (@$path) {
1023             if ($segment->{T} eq Arc) {
1024                 o("%     Arc C ".loc2dbg($segment->{C}).
1025                   " R $segment->{R} D ".ang2deg($segment->{D})."\n");
1026                 $len += abs($segment->{R} * $segment->{D});
1027                 push @bends, -abs($segment->{R}) * $segment->{D}; # right +ve
1028             } elsif ($segment->{T} eq Line) {
1029                 o("%     Line A ".loc2dbg($segment->{A}).
1030                   " B ".loc2dbg($segment->{A})." L $segment->{L}\n");
1031                 $len += abs($segment->{L});
1032             } else {
1033                 die "unknown segment $segment->{T}";
1034             }
1035         }
1036         o("%    length $len bends @bends.\n");
1037         $scores= [];
1038         foreach $crit (@al, 'short') {
1039             if ($crit eq 'long') { $cs= $len; }
1040             elsif ($crit eq 'short') { $cs= -$len; }
1041             elsif ($crit =~ m/^(begin|end|)(left|right)$/) {
1042                 if ($1 eq 'begin') { $cs= $bends[0]; }
1043                 elsif ($1 eq 'end') { $cs= $bends[$#bends]; }
1044                 else { $cs=0; map { $cs += $_ } @bends; }
1045                 $cs= -$cs if $2 eq 'left';
1046             } elsif ($crit =~ m/^(\!?)(twoarcs|arcs?line|cross|loop)$/) {
1047                 $cs= !!(grep { $2 eq $_ } @$skl) != ($1 eq '!');
1048             } else {
1049                 die "unknown sort criterion $crit";
1050             }
1051             push @$scores, $cs;
1052         }
1053         o("%    scores @$scores\n");
1054         if (defined $bestpath) {
1055             for ($i=0,$cmp=0; !$cmp && $i<@$scores; $i++) {
1056                 $cmp= $scores->[$i] <=> $bestscores->[$i];
1057             }
1058             next if $cmp < 0;
1059         }
1060         $bestpath= $path;
1061         $bestscores= $scores;
1062     }
1063     die "no solution" unless defined $bestpath;
1064     o("%   chose path $bestpath @al\n");
1065     @al= ();
1066     foreach $segment (@$bestpath) {
1067         if ($segment->{T} eq 'Arc') {
1068             arc({}, $segment->{C},$segment->{F},$segment->{R},$segment->{D});
1069         } elsif ($segment->{T} eq 'Line') {
1070             line($segment->{A}, $segment->{B}, $segment->{L});
1071         } else {
1072             die "unknown segment";
1073         }
1074     }
1075 }
1076
1077 sub line ($$$) {
1078     my ($from,$to,$len) = @_;
1079     if ($len < 0) {
1080         ($from,$to,$len) = ($to,$from,-$len);
1081     }
1082     parametric_segment(0.0, 1.0, $len + 1e-6, undef, sub {
1083         ev_lincomb({}, $from, $to, $param);
1084     });
1085 }
1086
1087 sub cmd_extend {
1088     my ($from,$to,$radius,$len,$upto,$ctr,$beta,$ang,$how,$sign_r);
1089     $from= can(\&cva_idex);
1090     $to= can(\&cva_idnew);
1091     printf DEBUG "from $from->{X} $from->{Y} $from->{A}\n";
1092     $how= can(cvam_enum(qw(len upto ang uptoang parallel)));
1093     if ($how eq 'len') { $len= can(\&cva_len); }
1094     elsif ($how =~ m/ang$/) { $ang= can(\&cva_ang); }
1095     elsif ($how eq 'parallel' || $how eq 'upto') { $upto= can(\&cva_idex); }
1096     $radius= cano(\&cva_len, 'Inf'); # +ve is right hand bend
1097     if ($radius eq 'Inf') {
1098 #       print DEBUG "extend inf $len\n";
1099         if ($how eq 'upto') {
1100             $len= ($upto->{X} - $from->{X}) * cos($from->{A})
1101                 + ($upto->{Y} - $from->{Y}) * sin($from->{A});
1102         } elsif ($how eq 'len') {
1103         } else {
1104             die "len of straight spec by angle";
1105         }
1106         printf DEBUG "len $len\n";
1107         $to->{X}= $from->{X} + $len * cos($from->{A});
1108         $to->{Y}= $from->{Y} + $len * sin($from->{A});
1109         $to->{A}= $from->{A};
1110         line($from,$to,$len);
1111     } else {
1112         my ($sign_r, $sign_ang, $ctr, $beta_interval, $beta, $delta);
1113         print DEBUG "radius >$radius<\n";
1114         $radius *= $ctx->{Trans}{R};
1115         $sign_r= signum($radius);
1116         $sign_ang= 1;
1117         $ctr->{X}= $from->{X} + $radius * sin($from->{A});
1118         $ctr->{Y}= $from->{Y} - $radius * cos($from->{A});
1119         if ($how eq 'upto') {
1120             $beta= atan2(-$sign_r * ($upto->{X} - $ctr->{X}),
1121                          $sign_r * ($upto->{Y} - $ctr->{Y}));
1122             $beta_interval= 1.0;
1123         } elsif ($how eq 'parallel') {
1124             $beta= $upto->{A};
1125             $beta_interval= 1.0;
1126         } elsif ($how eq 'uptoang') {
1127             $beta= input_absang($ang);
1128             $beta_interval= 2.0;
1129         } elsif ($how eq 'len') {
1130             $sign_ang= signum($len);
1131             $beta= $from->{A} - $sign_r * $len / abs($radius);
1132             $beta_interval= 2.0;
1133         } else {
1134             $sign_ang= signum($ang);
1135             $beta= $from->{A} - $sign_r * $ang;
1136             $beta_interval= 2.0;
1137         }
1138     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1139         $beta += $sign_ang * $sign_r * 4.0 * $pi;
1140         for (;;) {
1141             $delta= $beta - $from->{A};
1142             last if $sign_ang * $sign_r * $delta <= 0;
1143             $beta -= $sign_ang * $sign_r * $beta_interval * $pi;
1144         }
1145     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1146         arc($to, ,$ctr,$from, $radius,$delta);
1147     }
1148     printf DEBUG "to $to->{X} $to->{Y} $to->{A}\n";
1149 }
1150
1151 sub loc2dbg ($) {
1152     my ($loc) = @_;
1153     return "$loc->{X} $loc->{Y} ".ang2deg($loc->{A});
1154 }
1155 sub ang2deg ($) {
1156     return $_[0] * 180 / $pi;
1157 }
1158 sub input_absang ($) {
1159     return $_[0] * $ctx->{Trans}{R} + $ctx->{Trans}{A};
1160 }
1161 sub input_abscoords ($$) {
1162     my ($in,$out);
1163     ($in->{X}, $in->{Y}) = @_;
1164     $in->{A}= 0.0;
1165     $out= ev_compose({}, $ctx->{Trans}, $in);
1166     return ($out->{X}, $out->{Y});
1167 }
1168
1169 sub newctx (;$) {
1170     my ($ctx_save) = @_;
1171     $ctx= {
1172         Trans => { X => 0.0, Y => 0.0, A => 0.0, R => 1.0 },
1173         InRunObj => "",
1174         DrawMap => sub { $_[0]; },
1175         SegMapN => { },
1176         SegMapNM => { }
1177         };
1178     if (defined $ctx_save) {
1179         %{ $ctx->{Layer} }= %{ $ctx_save->{Layer} };
1180         $ctx->{Parent}= $ctx_save;
1181     }
1182 }
1183
1184 our $defobj_save;
1185 our $defobj_ispart;
1186
1187 sub cmd_defobj { cmd__defobj(0); }
1188 sub cmd_defpart { cmd__defobj(1); }
1189 sub cmd__defobj ($) {
1190     my ($ispart) = @_;
1191     my ($id);
1192     $id= can(\&cva_idstr);
1193     die "nested defobj" if $defobj_save;
1194     die "repeated defobj" if exists $objs{$id};
1195     $defobj_save= $ctx;
1196     $defobj_ispart= $ispart;
1197     newctx($defobj_save);
1198     $ctx->{CmdLog}= [ ];
1199     $ctx->{InDefObj}= $id;
1200     $ctx->{Draw}= $defobj_save->{Draw}.'X';
1201     $ctx->{DrawMap}= sub { ''; };
1202     $ctx->{Layer}= { Level => 5, Kind => '' };
1203 }
1204
1205 sub cmd_enddef {
1206     my ($bit,$id);
1207     $id= $ctx->{InDefObj};
1208     die "unmatched enddef" unless defined $id;
1209     foreach $bit (qw(CmdLog Loc)) {
1210         $objs{$id}{$bit}= $ctx->{$bit};
1211     }
1212     $objs{$id}{Part}= $defobj_ispart;
1213     $ctx= $defobj_save;
1214     $defobj_save= undef;
1215     $defobj_ispart= undef;
1216 }
1217
1218 sub cmd__runobj ($) {
1219     my ($obj_id)=@_;
1220     my ($c);
1221     local (@al);
1222     dv("cmd__runobj $obj_id ",'$ctx',$ctx);
1223     foreach $c (@{ $objs{$obj_id}{CmdLog} }) {
1224         @al= @$c;
1225         next if $al[0] eq 'enddef';
1226         cmd__one();
1227     }
1228 }
1229
1230 sub cva_subsegspec ($) {
1231     my ($sp)=@_;
1232     die "invalid subsegment spec" unless
1233         $sp =~ m,^(\-?)([0-9A-Za-z_]*)(?:/(?:([A-Za-z_]+)(\d+))?)?$,;
1234     my ($sign,$segname,$movfeat,$movconf)=($1,$2,$3,$4);
1235
1236     if (!exists $ctx->{SegName}) {
1237         $segname= '';
1238         $sign= '';
1239     } else {
1240         my ($map_ctx);
1241
1242         $ctx->{SegName} =~ m/^\-?/ or die;
1243         $sign .= $&;
1244         $segname= $'.$segname;
1245
1246         for ($map_ctx= $ctx;
1247              defined $map_ctx;
1248              $map_ctx= $map_ctx->{Parent}) {
1249             if (defined $movfeat &&
1250                 exists $map_ctx->{SegMapNM}{"$segname/$movfeat"}) {
1251                 $movfeat= $map_ctx->{SegMapNM}{"$segname/$movfeat"};
1252             }
1253             if (exists $map_ctx->{SegMapN}{$segname}) {
1254                 $map_ctx->{SegMapN}{$segname} =~ m/^\-?/ or die;
1255                 $sign .= $&;
1256                 $segname= $';
1257             }
1258         }
1259         $sign =~ s/\-\-//g;
1260     }
1261
1262     return $sign.$segname.'/'.
1263         (defined $movfeat ? sprintf "%s%d", $movfeat, $movconf : '');
1264 }
1265
1266 sub cmd_segment {
1267     my ($csss,$length);
1268     $ctx->{SavedSegment}= pop @segments
1269         unless exists $ctx->{SavedSegment};
1270     @segments= ();
1271     while (@al>1) {
1272         $csss= can(\&cva_subsegspec);
1273         $length= can(\&cva_len);
1274         push @segments, $csss, $length;
1275     }
1276     $csss= can(\&cva_subsegspec);
1277     push @segments, $csss;
1278 }
1279
1280 sub cva_segmap_s {
1281     my ($sp) = @_;
1282     $sp =~ m,^\w+(?:/[a-zA-Z_]+)?$,
1283         or die "invalid (sub)segment mapping S \`$sp'";
1284     return $sp;
1285 }
1286
1287 sub cva_segmap_n {
1288     my ($sp) = @_;
1289     $sp =~ m,^\-?\w+$, or die "invalid segment mapping N' \`$sp'";
1290     return $sp;
1291 }
1292
1293 sub cva_segmap_m {
1294     my ($sp) = @_;
1295     $sp =~ m,^[a-zA-Z_]+$, or die "invalid segment mapping M' \`$sp'";
1296     return $sp;
1297 }
1298
1299 sub cmd_segmap {
1300     my ($s,$d);
1301     while (@al) {
1302         $s= can(\&cva_segmap_s);
1303         if ($s =~ m,/,) {
1304             $ctx->{SegMapNM}{$s}= can(\&cva_segmap_m);
1305         } else {
1306             $ctx->{SegMapN}{$s}= can(\&cva_segmap_n);
1307         }
1308     }
1309 }
1310
1311 sub layer_draw ($$) {
1312     my ($k,$l) = @_;
1313     my ($eo,$cc, $r);
1314     if ($k eq '') {
1315         $r= 'RLMN';
1316     } elsif ($k eq 's') {
1317         $r= '';
1318     } elsif ($k eq 'l') {
1319         $r= 'CLMN';
1320     } else {
1321         $r= 'ARSCLMNO';
1322     }
1323     foreach $eo (@eopts) {
1324 #print STDERR "$. layer $k$l eo $eo re $eo->{GlobRe} then $eo->{DrawMods} now $r\n";
1325         next unless $k =~ m/^$eo->{GlobRe}$/;
1326 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} match\n";
1327         next unless &{ $eo->{LayerCheck} }($l);
1328 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} checked\n";
1329         foreach $cc (split //, $eo->{DrawMods}) {
1330             $r =~ s/$cc//ig;
1331             $r .= $cc if $cc =~ m/[A-Z]/;
1332         }
1333     }
1334 #print STDERR "layer $k$l gives $r (before map)\n";
1335     $r= &{ $ctx->{DrawMap} }($r);
1336     return $r;
1337 }
1338
1339 sub cmd_layer {
1340     my ($kl, $k,$l);
1341     $kl= can(\&cva_identity);
1342     $kl =~ m/^([A-Za-z_]*)(\d*|\=|\*)$/ or die "invalid layer spec";
1343     ($k,$l)=($1,$2);
1344     $l= $output_layer if $l eq '*';
1345     $l= $ctx->{Layer}{Level} if $l =~ m/^\=?$/;
1346     $ctx->{Layer}{Kind}= $k;
1347     $ctx->{Layer}{Level}= $l;
1348     $ctx->{Draw}= layer_draw($k,$l);
1349 }
1350
1351 sub cmd_part { cmd__obj(Part); }
1352 sub cmd_obj { cmd__obj(1); }
1353 sub cmd_objflip { cmd__obj(-1); }
1354
1355 sub cmd__obj ($) {
1356     my ($how)=@_;
1357     my ($obj_id, $ctx_save, $pfx, $actual, $formal_id, $formal, $formcv);
1358     my ($part_name, $ctx_inobj, $obj, $id, $newid, $newpt);
1359     if ($how eq Part) {
1360         $part_name= can(\&cva_idstr);
1361         $how= (@al && $al[0] =~ s/^\^//) ? -1 : +1;
1362     }
1363     $obj_id= can(\&cva_idstr);
1364     if (defined $part_name) {
1365         $formal_id= can(\&cva_idstr);
1366         $actual= cano(\&cva_idex, undef);
1367         if (!defined $actual) {
1368             $actual= cva_idex("${part_name}_${formal_id}");
1369         }
1370     } else {
1371         $actual= can(\&cva_idex);
1372         $formal_id= can(\&cva_idstr);
1373     }
1374     $obj= $objs{$obj_id};
1375     dv("cmd__obj ",'$obj',$obj);
1376     die "unknown obj $obj_id" unless $obj;
1377     $formal= $obj->{Loc}{$formal_id};
1378     die "unknown formal $formal_id" unless $formal;
1379     $ctx_save= $ctx;
1380     newctx($ctx_save);
1381     $how *= $ctx_save->{Trans}{R};
1382     $ctx->{Trans}{R}= $how;
1383     $ctx->{Trans}{A}= $actual->{A} - $formal->{A}/$how;
1384     $formcv= ev_compose({}, $ctx->{Trans},$formal);
1385     $ctx->{Trans}{X}= $actual->{X} - $formcv->{X};
1386     $ctx->{Trans}{Y}= $actual->{Y} - $formcv->{Y};
1387     if (defined $part_name) {
1388         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${part_name}:";
1389     } else {
1390         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}::";
1391     }
1392     if ($segments[0] =~ m,(.*[^-]+)/,) {
1393         $ctx->{SegName}= $1;
1394     }
1395     $ctx->{DrawMap}= sub {
1396         my ($i) = @_;
1397         $i= &{ $ctx_save->{DrawMap} }($i);
1398         if ($obj->{Part}) {
1399             $i =~ s/[LMN]//g;
1400             $i =~ s/O/MNO/;
1401         } else {
1402             $i =~ s/[LM]//g;
1403             $i =~ s/N/MN/;
1404         }
1405         return $i;
1406     };
1407     $ctx->{Draw}= &{ $ctx->{DrawMap} }($ctx_save->{Draw});
1408     cmd__runobj($obj_id);
1409     if (defined $part_name) {
1410         $pfx= $part_name.'_';
1411     } else {
1412         if (@al && $al[0] eq '=') {
1413             $pfx= ''; shift @al;
1414         } else {
1415             $pfx= cano(\&cva_idstr,undef);
1416         }
1417     }
1418     if (exists $ctx->{SavedSegment}) {
1419         @segments= ($ctx->{SavedSegment});
1420     }
1421     $ctx_inobj= $ctx;
1422     $ctx= $ctx_save;
1423     if (defined $pfx) {
1424         foreach $id (keys %{ $ctx_inobj->{Loc} }) {
1425             next if $id eq $formal_id;
1426             $newid= $pfx.$id;
1427             next if exists $ctx_save->{Loc}{$newid};
1428             $newpt= cva_idnew($newid);
1429             %$newpt= %{ $ctx_inobj->{Loc}{$id} };
1430         }
1431     }
1432     if (defined $part_name) {
1433         my ($formalr_id, $actualr_id, $formalr, $actualr);
1434         while (@al) {
1435             die "part results come in pairs\n" unless @al>=2;
1436             ($formalr_id, $actualr_id, @al) = @al;
1437             if ($actualr_id =~ s/^\-//) {
1438                 $formalr_id= "-$formalr_id";
1439                 $formalr_id =~ s/^\-\-//;
1440             }
1441             {
1442                 local ($ctx) = $ctx_inobj;
1443                 $formalr= cva_idex($formalr_id);
1444             }
1445             $actualr= cva_idnew($actualr_id);
1446             %$actualr= %$formalr;
1447         }
1448     }
1449 }
1450
1451 sub cmd__do {
1452     my ($cmd);
1453 dv("cmd__do $ctx @al ",'$ctx',$ctx);
1454     $cmd= can(\&cva_cmd);
1455     my ($lm,$id,$loc,$io,$ad,$draw,$thendrawre);
1456     $io= defined $ctx->{InDefObj} ? "$ctx->{InDefObj}!" : $ctx->{InRunObj};
1457     o("%L cmd   $io $cmd @al\n");
1458     $ctx->{LocsMade}= [ ];
1459     {
1460         no strict 'refs';
1461         &{ "cmd_$cmd" };
1462     };
1463     die "too many args" if @al;
1464     foreach $lm (@{ $ctx->{LocsMade} }) {
1465         $id= $lm->{Id};
1466         $loc= $ctx->{Loc}{$id};
1467         $loc->{A} += $pi if $lm->{Neg};
1468         $ad= ang2deg($loc->{A});
1469         ol("%L point $io$id ".loc2dbg($loc)." ($lm->{Neg})\n");
1470         $draw= layer_draw($loc->{LayerKind}, $ctx->{Layer}{Level});
1471         if ($draw =~ m/[LM]/) {
1472             ol("    gsave\n".
1473                "      $loc->{X} $loc->{Y} translate $ad rotate\n");
1474             if ($draw =~ m/M/) {
1475                 ol("      0 $allwidthmin newpath moveto\n".
1476                    "      0 -$allwidthmin lineto\n".
1477                    "      $lmu_marklw setlinewidth stroke\n");
1478             }
1479             if ($draw =~ m/L/) {
1480                 ol("      /s ($id) def\n".
1481                    "      lf setfont\n".
1482                    "      /sx5  s stringwidth pop\n".
1483                    "      0.5 mul $lmu_txtboxpadx add def\n".
1484                    "      -90 rotate  0 $lmu_txtboxoff translate  newpath\n".
1485                    "      sx5 neg  0             moveto\n".
1486                    "      sx5 neg  $lmu_txtboxh  lineto\n".
1487                    "      sx5      $lmu_txtboxh  lineto\n".
1488                    "      sx5      0             lineto closepath\n".
1489                    "      gsave  1 setgray fill  grestore\n".
1490                    "      $lmu_txtboxlw setlinewidth stroke\n".
1491                    "      sx5 neg $lmu_txtboxpadx add  $lmu_txtboxtxty\n".
1492                    "      moveto s show\n");
1493             }
1494             ol("      grestore\n");
1495         }
1496     }
1497 }
1498
1499 sub cmd_showlibrary {
1500     my ($obj_id, $y, $x, $ctx_save, $width, $height);
1501     my ($max_x, $min_x, $max_y, $min_y, $nxty, $obj, $loc, $pat, $got, $glob);
1502     my ($adj);
1503     $x=$olu_left; $y=$olu_bottom; undef $nxty;
1504     $ctx_save= $ctx;
1505     foreach $obj_id (sort keys %objs) {
1506         $got= 1;
1507         foreach $glob (@al) {
1508             $pat= $glob;
1509             $got= !($pat =~ s/^\!//);
1510             die "bad pat" if $pat =~ m/[^0-9a-zA-Z_*?]/;
1511             $pat =~ s/\*/\.*/g; $pat =~ s/\?/./g;
1512             last if $obj_id =~ m/^$pat$/;
1513             $got= !$got;
1514         }
1515         next unless $got;
1516         $obj= $objs{$obj_id};
1517         next unless $obj->{Part};
1518         ($min_x, $max_x, $min_y, $max_y) = bbox($obj->{Loc});
1519         newctx($ctx_save);
1520
1521         for (;;) {
1522             $width= $max_x - $min_x;
1523             $height= $max_y - $min_y;
1524             if ($width < $height) {
1525                 $ctx->{Trans}{A}= 0;
1526                 $ctx->{Trans}{X}= $x - $min_x;
1527                 $ctx->{Trans}{Y}= $y - $min_y + $olu_textheight;
1528             } else {
1529                 ($width,$height)=($height,$width);
1530                 $ctx->{Trans}{A}= 0.5 * $pi;
1531                 $ctx->{Trans}{X}= $x + $max_y;
1532                 $ctx->{Trans}{Y}= $y - $min_x + $olu_textheight;
1533             }
1534             $adj= length($obj_id) * $olu_textallowperc - $width;
1535             $adj=0 if $adj<0;
1536             $width += $adj;
1537             $ctx->{Trans}{X} += 0.5 * $adj;
1538             if ($x + $width > $olu_right && defined $nxty) {
1539                 $x= $olu_left;
1540                 $y= $nxty;
1541                 undef $nxty;
1542             } elsif ($y + $height > $olu_top && $y > $olu_bottom) {
1543                 oflushpage();
1544                 $x= $olu_left; $y= $olu_bottom;
1545                 undef $nxty;
1546             } else {
1547                 last;
1548             }
1549         }
1550
1551         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}//";
1552         $ctx->{Draw}= $ctx_save->{Draw};
1553         cmd__runobj($obj_id);
1554         ol("    gsave\n".
1555            "      /s ($obj_id) def\n".
1556            "      lf setfont\n      ".
1557            ($x + 0.5*$width)." ".($y - $olu_textheight)." moveto\n".
1558            "      s stringwidth pop -0.5 mul  0  rmoveto\n".
1559            "      s show grestore\n");
1560         $x += $width + $olu_gap_x;
1561         upd_max(\$nxty, $y + $height + $olu_gap_y + $olu_textheight);
1562     }
1563     @al= ();
1564     $ctx= $ctx_save;
1565 }
1566
1567 sub cmd__one {
1568     cmd__do();
1569 }
1570
1571 o("%!\n".
1572   "  /lf /Courier-New findfont $lmu_marktpt scalefont def\n".
1573   "  $ps_page_shift 0 translate 90 rotate\n");
1574
1575 if ($page_x || $page_y) {
1576     o("  /Courier-New findfont 15 scalefont setfont\n".
1577       "  30 30 moveto (${page_x}x${page_y}) show\n");
1578 }
1579
1580 o("  -$ps_page_xmul $page_x mul  -$ps_page_ymul $page_y mul  translate\n".
1581   "  $ptscale $ptscale scale\n");
1582
1583 newctx();
1584
1585 open DEBUG, ($debug ? ">&2" : ">/dev/null") or die $!;
1586
1587 if ($debug) {
1588     select(DEBUG); $|=1;
1589     select(STDOUT); $|=1;
1590 }
1591
1592 $ctx->{Draw}= '';
1593 $ctx->{SegName}= '';
1594
1595 @al= qw(layer 5);
1596 cmd__one();
1597
1598 while (<>) {
1599     next if m/^\s*\#/;
1600     chomp; s/^\s+//; s/\s+$//;
1601     @al= split /\s+/, $_;
1602     next unless @al;
1603     print DEBUG "=== @al\n";
1604     last if $al[0] eq 'eof';
1605     push @{ $ctx->{CmdLog} }, [ @al ] if exists $ctx->{CmdLog};
1606     cmd__one();
1607 }
1608
1609 {
1610     my ($min_x, $max_x, $min_y, $max_y) = bbox($ctx->{Loc});
1611     my ($bboxstr);
1612     if (defined $min_x) {
1613         $bboxstr= sprintf("width  %.2d (%.2d..%2.d)\n".
1614                           "height %.2d (%.2d..%2.d)\n",
1615                           $max_x - $min_x, $min_x, $max_x,
1616                           $max_y - $min_y, $min_y, $max_y);
1617     } else {
1618         $bboxstr= "no locs, no bbox\n";
1619     }
1620     if (!$quiet) { print STDERR $bboxstr; }
1621     $bboxstr =~ s/^/\%L bbox /mg;
1622     o($bboxstr) or die $!;
1623
1624     if ($scale < 1.5) {
1625         my ($tick_x, $tick_y, $ticklen);
1626         $ticklen= 10;
1627         printf("    gsave 0.5 setgray 0.33 setlinewidth\n".
1628                "      /regmark {\n".
1629                "        newpath moveto\n".
1630                "        -%d 0 rmoveto %d 0 rlineto\n".
1631                "        -%d -%d rmoveto 0 %d rlineto stroke\n".
1632                "      } def\n",
1633                $ticklen, $ticklen*2, $ticklen, $ticklen, $ticklen*2)
1634             or die $!;
1635         for ($tick_x= $min_x; $tick_x < $max_x; $tick_x += 150) {
1636             for ($tick_y= $min_y; $tick_y < $max_y; $tick_y += 150) {
1637                 printf("      %f %f regmark\n",
1638                        $tick_x, $tick_y)
1639                     or die $!;
1640             }
1641         }
1642         printf("    grestore\n")
1643             or die $!;
1644     }
1645 }
1646
1647 oflushpage();