hostside/gui

   1 #!/usr/bin/wishx
   2
   3 load chiark_tcl_hbytes-1.so
   4
   5 #---------- general utilities ----------
   6
   7 set tk_strictMotif 1
   8
   9 tk_setPalette background black foreground white
  10
  11 source lib.tcl
  12
  13 set default_speedstep_list {0 1 10 20 35 50 65 80 95 110 126}
  14
  15 set picturepadx 10
  16 set picturepady 10
  17
  18 proc pagew {page} { return ".picture-$page" }
  19 proc debug {m} { puts $m }
  20
  21 proc sconn {m} {
  22     global sconn
  23     debug "=> $m"
  24     puts $sconn $m
  25 }
  26
  27 proc widgets-dgram {} {
  28     global cpage geometry picturepadx picturepady
  29     if {[string length $geometry]} { wm geometry . $geometry }
  30     set sizes [exec ./gui-plan-$cpage --sizes]
  31     set w [pagew $cpage]
  32     frame $w
  33     frame $w.picture -background {} \
  34             -width [lindex $sizes 0] \
  35             -height [lindex $sizes 1]
  36     pack $w.picture -padx $picturepadx -pady $picturepady
  37     pack $w
  38 }
  39
  40 proc widgets-fullscreen-nowm {} {
  41     pack propagate . false
  42     foreach wh {width height} {
  43         . configure -$wh [winfo screen$wh .]
  44     }
  45 }
  46
  47 proc bgerror {emsg} {
  48     global errorCode errorInfo
  49     catch {
  50         puts stderr "UNEXPECTED BACKGROUND ERROR\n"
  51         puts stderr "$errorCode\n$errorInfo\n$emsg"
  52     }
  53     exit 16
  54 }
  55
  56 #---------- train set event registraton ----------
  57
  58 set event_dispatch_body {
  59     append l " "
  60 }
  61 set event_selections {}
  62
  63 proc register-event {selections args re body} {
  64     global event_dispatch_body event_selections
  65
  66     eval lappend event_selections $selections
  67
  68     foreach selection $selections {
  69         if {[regexp {^\w} $selection]} {
  70             error "selection $selection lacks context char"
  71         }
  72     }
  73     if {[regexp {^\^\w} $re]} {
  74         error "re $re never matches context char"
  75     }
  76
  77     regsub -all {\W+} $re - proc
  78     set proc "event/$proc/[join $args -]"
  79     set suffix {}
  80     set number 0
  81     while {![catch { info args $proc$suffix }]} { set suffix [incr number] }
  82     append proc $suffix
  83
  84     proc $proc [concat l $args] $body
  85     set al ""
  86     foreach a $args { append al " \$$a" }
  87
  88     append event_dispatch_body \
  89             "    if {\[regexp [list $re] \$l dummy $args]} {\n" \
  90             "        debug \"$proc$al\"\n" \
  91             "        eval [list $proc] \[list \$l$al]\n" \
  92             "        return\n" \
  93             "    }\n"
  94 }
  95
  96 #---------- handling of commands we issue ----------
  97
  98 proc scmd {onresult ctrlr commandstr args} {
  99     # later, calls
 100     #   eval [list $onresult-ok|nak|error $ackornakmessage] $args
 101     global commands_queued
 102     sconn $commandstr
 103     lappend commands_queued [list $ctrlr $onresult $args]
 104 }
 105
 106 proc scmd_result {oknakerr message reporterrmsg} {
 107     global commands_queued
 108     manyset [lindex $commands_queued 0] ctrlr onresult args
 109     set commands_queued [lrange $commands_queued 1 end]
 110     if {[string length $reporterrmsg]} {
 111         report-problem "$ctrlr: $reporterrmsg"
 112     }
 113     set proc "$onresult-$oknakerr"
 114     if {![string compare $oknakerr nak] && [catch { info args $proc }]} {
 115         set proc "$onresult-err"
 116     }
 117     eval [list $proc $message] $args
 118 }
 119
 120 register-event {} {} {^\+ack \S+ ok } { scmd_result ok $l "" }
 121 register-event {} {train segment error} \
 122         {^\+ack \S+ SignallingPredictedProblem (\S+) (\S+) \: (.*) $} {
 123     set m $train
 124     if {[string compare - $segment]} { append m " @$segment" }
 125     append m ": $error"
 126     scmd_result err $l $m
 127 }
 128 register-event {} {} {^\+ack } { scmd_result err $l $l }
 129 register-event {} {} {^\+nack \S+ } { scmd_result nak $l $l }
 130
 131 proc routinecmd-nak {m args} { error "got nak to routine command: $m" }
 132 proc routinecmd-err {m args} { }
 133 proc routinecmd-ok {m args} { }
 134
 135 proc mustsucceed-err {m args} { error "unexpected error: $m" }
 136 proc mustsucceed-ok {m args} { }
 137
 138 proc report-problem-report-stderr {m} { puts stderr "*** $m" }
 139 set report_problem_report report-problem-report-stderr
 140
 141 proc report-problem {message} {
 142     global report_problem_report
 143     eval $report_problem_report [list $message]
 144 }
 145
 146 proc widget-problem-report {} {
 147     global problem_reports report_problem_report
 148     set problem_reports "\n\n\n\n\n"
 149     label .problem-report -anchor w -justify left -takefocus 0 \
 150             -border 2 -relief sunken -width 80 -textvariable problem_reports
 151     pack .problem-report -side top
 152     set report_problem_report report-problem-report-widget
 153 }
 154
 155 proc report-problem-report-widget {m} {
 156     global problem_reports
 157     set problem_reports [join [concat \
 158                 [lrange [split $problem_reports "\n"] 1 end] \
 159                 [list $m] \
 160             ] "\n"]
 161 }
 162
 163 #---------- movpos (overlay buttons, keybindings, execution) ----------
 164
 165 proc movpos-button-gvars {mid} {
 166     upvar #0 mp_details($mid) details
 167     if {![info exists details]} { return 0 }
 168     uplevel 1 [list manyset $details cpage key seg feat poslocs]
 169     uplevel 1 { set w [pagew $cpage].movpos-$mid }
 170     upvar #0 mp_state($mid) state
 171     uplevel 1 [list manyset $state posn]
 172     return 1
 173 }
 174
 175 proc movpos-button-sstate {mid posn} {
 176     upvar #0 mp_state($mid) state
 177     set state $posn
 178     movpos-button-setdisplay $mid
 179 }
 180
 181 proc movpos-all-unknown {} {
 182     global mp_details
 183     foreach mid [array names mp_details] {
 184         movpos-button-sstate $mid ?
 185     }
 186 }
 187
 188 proc widgets-movpos {} {
 189     global mp_details
 190     foreach mid [array names mp_details] {
 191         upvar #0 mp_state($mid) state
 192         set state {?}
 193         movpos-button-gvars $mid
 194         set w [pagew $cpage].movpos-$mid
 195         button $w -text $key -padx 0 -pady 0 -borderwidth 0 \
 196                 -command [list movpos-invoked $mid "plan $cpage"]
 197         movpos-button-setdisplay $mid
 198     }
 199 }
 200
 201 proc movpos-button-setdisplay {mid} {
 202     # we want to display as much of these as possible:
 203     #   position known ?   (actual position is done by button location)
 204     #   moving or stable
 205     #   whether a train's plan includes a different position
 206     #   whether autopoint
 207     movpos-button-gvars $mid
 208     switch -exact $posn {
 209         ?       { set poslocn 2;     set fg black; set bg white }
 210         default { set poslocn $posn; set fg white; set bg black }
 211     }
 212     $w configure -background $bg -foreground $fg \
 213             -activebackground $bg -activeforeground $fg
 214     manyset [lindex $poslocs $poslocn] x y
 215     place $w -anchor center -x $x -y $y
 216 }
 217
 218 proc movpos-invoked {mid ctrlr} {
 219     global movfeatcommand
 220     movpos-button-gvars $mid
 221     switch -exact $posn {
 222         0 { set new_posn 1 }
 223         default { set new_posn 0 }
 224     }
 225     scmd routinecmd $ctrlr "$movfeatcommand $seg $feat $new_posn"
 226 }
 227
 228 register-event ?movpos_*_feat {seg feat posn_new} \
 229         {^.movpos (\w+) feat (\w+) ([01]|\?) } {
 230     set mid $seg/$feat
 231     if {![movpos-button-gvars $mid]} return
 232     set posn $posn_new
 233     movpos-button-sstate $mid $posn
 234 }
 235
 236 proc movpos-bindkey-1 {cpage key seg feat adj0x adj0y adj1x adj1y} {
 237     global posdeviation picturepadx picturepady
 238     manyset [subseg-end-get-centroid $cpage $seg $feat {}] mx my
 239     set mid $seg/$feat
 240     foreach posn {0 1} {
 241         manyset [subseg-end-get-centroid $cpage $seg $feat $posn] x y
 242         set dx [expr {$x-$mx}]; set dy [expr {$y-$my}]
 243         set d [expr {sqrt($dx*$dx + $dy*$dy)}]
 244         set mul [expr {$posdeviation / ($d + 1e-6)}]
 245         set x [expr {$mx + $mul*$dx + $picturepadx + [set adj${posn}x]}]
 246         set y [expr {$my + $mul*$dy + $picturepady + [set adj${posn}y]}]
 247         lappend poslocs [list $x $y]
 248     }
 249     lappend poslocs [list [expr {$mx + $picturepadx + ($adj0x+$adj1x)*0.5}] \
 250                           [expr {$my + $picturepady + ($adj0y+$adj1y)*0.5}]]
 251     upvar #0 mp_details($mid) details
 252     set details [list $cpage $key $seg $feat $poslocs]
 253
 254     bind . <Key-[string tolower $key]> [list movpos-invoked $mid "keyboard"]
 255 }
 256
 257 #---------- computation of movpos button locations
 258
 259 proc layout-subseg-featmap {seg concfeatpos args} {
 260     global subsegfeatmap
 261     set subsegfeatmap($concfeatpos) $args
 262 }
 263
 264 proc layout-subseg-end {seg feat posn x y} {
 265     global cpage
 266     upvar #0 subsegfeatmap($feat$posn) mapped
 267     if {[info exists mapped]} {
 268         foreach {feat posn} $mapped {
 269             layout-subseg-end $seg $feat $posn $x $y
 270         }
 271         return
 272     }
 273     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 274     if {![info exists sse]} { set sse {{} {}} }
 275     manyset $sse lx ly
 276     lappend lx $x
 277     lappend ly $y
 278     set sse [list $lx $ly]
 279     if {[string length $posn]} { layout-subseg-end $seg $feat {} $x $y }
 280 }
 281
 282 proc subseg-end-get-centroid {cpage seg feat posn} {
 283     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 284     if {![info exists sse]} {
 285         puts "skipping binding of unknown $seg/$feat$posn"
 286         return -code return
 287     }
 288     manyset $sse lx ly
 289     set sx 0; set sy 0; set n [llength $lx]
 290     foreach x $lx y $ly { addexpr sx {$x}; addexpr sy {$y} }
 291     return [list [expr {$sx * 1.0 / $n}] [expr {$sy * 1.0 / $n}]]
 292 }
 293
 294 proc layout-data {} {
 295     global cpage
 296     upvar #0 ld_sse/$cpage sse
 297     catch { unset sse }
 298     source ../layout/ours.dgram.segmap-info
 299     source ../layout/ours.dgram-$cpage.overlay-info
 300
 301     upvar #0 movpos_bindings($cpage) bindings
 302     if {![info exists bindings]} {
 303         puts "no movpos bindings for $cpage"
 304         return
 305     }
 306     foreach binding $bindings {
 307         if {[regexp \
 308    {^([A-Z])([-+]\d*)?([-+]\d*)?([-+]\d*)?([-+]\d*)?\=(\w+)/([A-Z]+)$} \
 309                  $binding dummy key adj0x adj0y adj1x adj1y seg feat]} {
 310             if {![string length $adj1x]} { set adj1x $adj0x; set adj1y $adj0y }
 311             movpos-bindkey-1 $cpage $key $seg $feat \
 312                 $adj0x.0 $adj0y.0 $adj1x.0 $adj1y.0
 313         } elseif {[regexp {^[A-Z]$} $binding] || [regexp {~} $binding]} {
 314         } else {
 315             error "incomprehensible binding $binding on page $cpage"
 316         }
 317     }
 318 }
 319
 320 #---------- speed ----------
 321
 322 # variables:
 323 #   $train_commanded($train)    $speed_step
 324 #   $train_direction($train)    forwards|backwards or unset
 325 #   $speedws                    [list $w ...]
 326 #
 327 # speed/${w}(...) aka s(...):
 328 #   $s(ctrlr)                   controller
 329 #   $s(train)                   train selected, or something not \w+
 330 #   $s(optionmenu)              optionmenu widget name
 331 #   $s(kind)                    abs or rel
 332 #   $s(commanding)              step of command we have scmd'd, or unset
 333 #   $s(queued)                  step of command we would like to queue
 334 #                                or unset if n/a
 335 #   $s(inhibit)   0   all is well, can command any speed
 336 #                 1   train newly selected, only rel can command higher speed
 337 #                 2   can only command same or lower speed
 338 #
 339 # We don't worry too much about races: in particular, we don't mind
 340 # racing with other things trying to command the speed, and losing
 341 # the odd increment/decrement.  But since we thread the requested
 342 # speed via realtime, we do queue up our own increments/decrements
 343 # while we're executing a speed command, to avoid loss of steps during
 344 # quick motions.
 345
 346 # Interfaces for concrete controllers:
 347 #   speedw-new $w $ctrlr
 348 #   speedw-setstate $w disabled|normal        controller appears/disappears
 349 #   speedw-userinput-abs $w $step
 350 #   speedw-userinput-rel $w $stepmap
 351 # where
 352 #   eval {stepmap} [list $oldstep] => $newstep
 353
 354 set speedws {}
 355
 356 proc speedws-forall {command args} {
 357     global speedws
 358     foreach w $speedws { eval [list $command $w] $args }
 359 }
 360
 361 proc speedws-fortrain {train command args} {
 362     global speedws
 363     foreach w $speedws {
 364         upvar #0 speed/$w s
 365         if {[string compare $s(train) $train]} continue
 366         eval [list $command $w] $args
 367     }
 368 }
 369
 370 proc speedw-new {w ctrlr} {
 371     upvar #0 speed/$w s
 372     global speedws
 373
 374     lappend speedws $w
 375     set s(ctrlr) $ctrlr
 376     set s(inhibit) 0
 377
 378     frame $w -relief sunken -border 2
 379     label $w.ctrlr -state disabled -text $s(ctrlr)
 380     set s(optionmenu) [tk_optionMenu $w.train speed/${w}(train) {}]
 381     $w.train configure -textvariable {} -width 15
 382     label $w.speed -state disabled -width 4 \
 383             -font -*-courier-bold-r-*-*-20-*-*-*-*-*-*-* \
 384             -background black -foreground white
 385     pack $w.ctrlr $w.train $w.speed -side left
 386
 387     speedw-notrains $w "(starting)"
 388 }
 389 proc speedw-notrains {w whystr} {
 390     $w.train configure -state disabled
 391     speedw-train-noneselected $w $whystr
 392 }
 393 proc speedw-train-noneselected {w whystr} {
 394     upvar #0 speed/$w s
 395     tractbrake-detach $s(train)
 396     set s(train) {}
 397     $w.train configure -text $whystr
 398     $w.speed configure -text -
 399     speedw-inhibit $w
 400 }
 401
 402 proc speedw-inhibit {w} {
 403     upvar #0 speed/$w s
 404     set s(inhibit) 2
 405     $w.speed configure -foreground red
 406 }
 407 proc speedw-uninhibit {w max} {
 408     upvar #0 speed/$w s
 409     set r $s(inhibit)
 410     if {$r>$max} { return -1 }
 411     set s(inhibit) 0
 412     $w.speed configure -foreground white
 413     return $r
 414 }
 415
 416 proc speedw-setstate {w disnorm} {
 417     $w.ctrlr configure -state $disnorm
 418     $w.speed configure -state $disnorm
 419 }
 420
 421 proc speedw-train-selectnext {w} {
 422     upvar #0 speed/$w s
 423     set max [$s(optionmenu) index end]
 424     for {set ix 0} {$ix <= $max} {incr ix} {
 425         set v [$s(optionmenu) entrycget $ix -value]
 426         if {![string compare $v $s(train)]} break
 427     }
 428     set activate [expr {($ix+1) % ($max+1)}]
 429     $s(optionmenu) invoke $activate
 430 }
 431
 432 proc speedw-train-selected {w t} {
 433     upvar #0 speed/$w s
 434     if {![string compare $t $s(train)]} return
 435     tractbrake-detach $s(train)
 436     $w.train configure -text $t
 437     set s(inhibit) 1
 438     set s(train) $t
 439     $w.speed configure -foreground white
 440     speedw-redisplay-speed $w
 441 }
 442
 443 proc speedw-redisplay-speed {w} {
 444     upvar #0 speed/$w s
 445     upvar #0 train_commanded($s(train)) gcommanded
 446     upvar #0 train_direction($s(train)) gdirection
 447     set t $gcommanded
 448     if {[info exists gdirection]} {
 449         switch -exact $gdirection {
 450             forwards { set t "$t>" }
 451             backwards { set t "<$t" }
 452         }
 453     }
 454     $w.speed configure -text $t
 455 }
 456
 457 proc speedw-train-direction {w dirchange} {
 458     upvar #0 speed/$w s
 459     if {![string length $s(train)]} return
 460     scmd routinecmd $s(ctrlr) "direction $s(train) $dirchange"
 461 }
 462
 463 proc speedw-trains-available {w l} {
 464     upvar #0 speed/$w s
 465     if {![llength $l]} { speedw-train-noneselected $w "(no trains)"; return }
 466     $s(optionmenu) delete 0 end
 467     $s(optionmenu) add radiobutton -label "(none)" -value {} \
 468             -command [list speedw-train-noneselected $w "(no train selected)"]
 469     set l [lsort $l]
 470     foreach t $l {
 471         $s(optionmenu) add radiobutton -label $t -value $t \
 472                 -command [list speedw-train-selected $w $t]
 473     }
 474     $w.train configure -state normal
 475     if {[llength $l]==1} {
 476         $s(optionmenu) invoke 1
 477     } elseif {[set ix [lsearch -exact $l $s(train)]] >= 0} {
 478         $s(optionmenu) invoke [expr {$ix+1}]
 479     } elseif {![string length $s(train)]} {
 480         $s(optionmenu) invoke 0
 481     } else {
 482         $w.train configure -text "$s(train) (not present)"
 483     }
 484 }
 485
 486 proc speedw-userinput-abs {w speed} {
 487     upvar #0 speed/$w s
 488     if {![string length $s(train)]} return
 489     tractbrake-detach $s(train)
 490     if {!$speed} { speedw-uninhibit $w 2 }
 491     speedw-do-abs $w $speed
 492 }
 493
 494 proc speedw-userinput-tractbrake {w tract brake} {
 495     upvar #0 speed/$w s
 496     if {![string length $s(train)]} return
 497     if {$s(inhibit)} return
 498     tractbrake-userinput $s(train) $tract $brake $w
 499 }
 500
 501 proc speedw-do-abs {w speed} {
 502     upvar #0 speed/$w s
 503     if {$speed == [speedw-currentspeed $w]} return
 504     set s(queued) $speed
 505     speedw-check $w
 506 }
 507
 508 proc speedw-check {w} {
 509     upvar #0 speed/$w s
 510     if {![string length $s(train)]} return
 511     upvar #0 train_commanded($s(train)) gcommanded
 512     upvar #0 train_direction($s(train)) gdirection
 513     if {[info exists s(commanding)]} return
 514     if {![info exists s(queued)]} return
 515     set newspeed $s(queued)
 516     unset s(queued)
 517     if {$s(inhibit) && $newspeed > $gcommanded} return
 518     set s(commanding) $newspeed
 519     scmd speedw-commanded $s(ctrlr) "speed $s(train) $newspeed $gdirection" $w
 520 }
 521
 522 proc speedw-commanded-nak {m args} { error "got nak from speed: $m" }
 523 proc speedw-commanded-ok {m w} {
 524     upvar #0 speed/$w s
 525     unset s(commanding)
 526     speedw-check $w
 527 }
 528 proc speedw-commanded-err {m w} {
 529     upvar #0 speed/$w s
 530     unset s(commanding)
 531     speedw-inhibit $w
 532     speedw-check $w
 533 }
 534
 535 proc speedw-currentspeed {w} {
 536     upvar #0 speed/$w s
 537     upvar #0 train_commanded($s(train)) gcommanded
 538     if {[info exists s(queued)]} {
 539         return $s(queued)
 540     } elseif {[info exists s(commanding)]} {
 541         return $s(commanding)
 542     } else {
 543         return $gcommanded
 544     }
 545 }
 546
 547 proc speedw-userinput-rel {w stepmap} {
 548     upvar #0 speed/$w s
 549     if {![string length $s(train)]} return
 550     set oldspeed [speedw-currentspeed $w]
 551     set newspeed [eval $stepmap [list $oldspeed]]
 552     speedw-userinput-abs $w $newspeed
 553 }
 554
 555 proc speedw-userinput-rel-steps {w delta steplist} {
 556     if {$delta<0} {
 557         if {[speedw-uninhibit $w 2]>1} { incr delta 1 }
 558         if {!$delta} return
 559     } else {
 560         speedw-uninhibit $w 1
 561     }
 562     speedw-userinput-rel $w [list speedw-stepmap-fromlist $steplist $delta]
 563 }
 564
 565 proc speedw-userinput-tractbrake {w tract brake} {
 566     upvar #0 speed/$w s
 567     if {![string length $s(train)]} return
 568     debug [format "speedw-userinput-tractbrake %s %6.4f %6.4f" \
 569                $s(train) $tract $brake]
 570     speedw-uninhibit $w 1
 571     if {$s(inhibit)} { set tract 0 }
 572     tractbrake-userinput $s(train) $tract $brake $w
 573 }
 574
 575 proc speedw-uninhibit-tractbrake {w} {
 576     upvar #0 speed/$w s
 577     speedw-uninhibit $w 2
 578     if {![string length $s(train)]} return
 579     tractbrake-reset-speed $s(train)
 580 }
 581
 582 proc speedws-train-problem {train} {
 583     speedws-fortrain $train speedw-inhibit
 584 }
 585
 586 register-event ?train_*_at {train direction} \
 587         {^.train (\w+) at \S+ (forwards|backwards) } {
 588     upvar #0 train_direction($train) dirn
 589     set dirn $direction
 590     speedws-fortrain $train speedw-redisplay-speed
 591     tractbrake-ensure $train
 592 }
 593
 594 register-event ?train_*_speed_commanding {train speed} \
 595         {^.train (\w+) speed commanding (\d+) } {
 596     upvar #0 train_commanded($train) cmd
 597     set cmd $speed
 598     speedws-fortrain $train speedw-redisplay-speed
 599 }
 600
 601 proc speedws-stastate-hook {} {
 602     global train_direction stastate
 603     switch -exact -- $stastate {
 604         Run {
 605             set trains [array names train_direction]
 606             speedws-forall speedw-trains-available $trains
 607         }
 608         Resolving {
 609             movpos-all-unknown
 610         }
 611         Finalising {
 612             speedws-forall speedw-notrains "($stastate)"
 613         }
 614         default {
 615             catch { unset train_commanded }
 616             speedws-forall speedw-notrains "($stastate)"
 617         }
 618     }
 619 }
 620
 621 register-event &train_*_signalling-problem {train problem} \
 622         {^\&train (\w+) signalling-problem (.*) $} {
 623     global speedws
 624     regsub {^(\S+) (\S+) \: } $problem {\1 @\2: } problem
 625     report-problem "event: $problem"
 626     speedws-train-problem $train
 627 }
 628
 629 proc speedw-new-cooked {wunique desc} {
 630     set w .inputs.$wunique
 631     speedw-new $w $desc
 632     pack $w -side left -padx 10
 633     return $w
 634 }
 635
 636 proc speedw-stepmap-fromlist {speedlist offset oldspeed} {
 637     if {![llength $speedlist]} {
 638         unset speedlist
 639         upvar #0 default_speedstep_list speedlist
 640     }
 641     set ixabove 0
 642     foreach entry $speedlist {
 643         if {$entry==$oldspeed} { set ixbelow $ixabove; break }
 644         if {$entry>$oldspeed} break
 645         set ixbelow $ixabove
 646         incr ixabove
 647     }
 648     set ix [expr {($offset>0 ? $ixbelow : $ixabove) + $offset}]
 649     if {$ix<0} { return 0 }
 650     if {$ix>=[llength $speedlist]} { return [lindex $speedlist end] }
 651     return [lindex $speedlist $ix]
 652 }
 653
 654 #----- traction / brake (hidden behind speedw) ----------
 655
 656 proc tractbrake-queue-update {train} {
 657     upvar #0 tractbrake/$train tb
 658     set tb(queued) [after $tb(updms) \
 659                         [list tractbrake-update $train]]
 660 }
 661
 662 proc tractbrake-reset-speed {train} {
 663     upvar #0 tractbrake/$train tb
 664     if {![info exists tb]} return
 665     upvar #0 speedcurve/$train sc
 666     upvar #0 train_commanded($train) gcommanded
 667     setexpr tb(v) {[lindex $sc $gcommanded] / [lindex $sc 126]}
 668 }
 669 proc tractbrake-attach {train speedw} {
 670     # can safely be called when already attached
 671     upvar #0 tractbrake/$train tb
 672     set tb(speedw) $speedw
 673     if {[info exists tb(queued)]} return
 674     tractbrake-reset-speed $train
 675     tractbrake-queue-update $train
 676 }
 677 proc tractbrake-detach {train} {
 678     # can safely be called when already detached
 679     upvar #0 tractbrake/$train tb
 680     catch { after cancel $tb(queued) }
 681     catch { unset tb(queued) }
 682     tractbrake-reset $train
 683 }
 684 proc tractbrake-reset {train} {
 685     upvar #0 tractbrake/$train tb
 686     if {![info exists tb]} return
 687     set tb(A) 0
 688     set tb(B) 0
 689     set tb(a) 0
 690     set tb(b) 0
 691 }
 692
 693 proc tractbrake-update {train} {
 694     upvar #0 tractbrake/$train tb
 695     upvar #0 tractbrake-params/$train pa
 696     unset tb(queued)
 697     foreach AB {A B} ab {a b} lm {lambda mu} {
 698         addexpr tb($ab) { $tb(updfact_$lm) * ( $tb($AB) - $tb($ab) ) - 1e-5 }
 699     }
 700     addexpr tb(v) {
 701         + $tb(perupd_alpha) * $tb(a)
 702         - $tb(perupd_beta) * $tb(b)
 703         - $tb(perupd_omega) * $tb(v) * $tb(v)
 704         - $tb(perupd_phi)
 705     }
 706     set m "tractbrake $train"
 707     foreach v {A a B b v} { append m [format " %s=%6.4f" $v $tb($v)] }
 708     debug $m
 709     if {$tb(v) <= 0} {
 710         # stopped
 711         set tb(v) 0
 712         speedw-do-abs $tb(speedw) 0
 713         if {$tb(A) <= 0 && $tb(a) <= 0 &&
 714             $tb(B) <= 0 && $tb(b) <= 0} {
 715             # no throttle or brake, no need to requeue
 716             return
 717         }
 718     } else {
 719         if {$tb(v) > 1.0} { set tb(v) 1.0 }
 720         upvar #0 speedcurve/$train sc
 721         upvar #0 train_commanded($train) gcommanded
 722         set step $gcommanded
 723         setexpr targetvel {$tb(v) * [lindex $sc 126]}
 724         while 1 {
 725             set vel [lindex $sc $step]
 726             if {$vel > $targetvel && $step > 0} {
 727                 setexpr nextstep {$step - 1}
 728             } elseif {$vel < $targetvel && $step < 126} {
 729                 setexpr nextstep {$step + 1}
 730             } else {
 731                 break
 732             }
 733             set nextvel [lindex $sc $nextstep]
 734             if {abs($nextvel-$targetvel) >= abs($vel-$targetvel)} {
 735                 break
 736             }
 737             set step $nextstep
 738         }
 739         speedw-do-abs $tb(speedw) $step
 740     }
 741     tractbrake-queue-update $train
 742 }
 743
 744 proc tractbrake-userinput {train tract brake speedw} {
 745     upvar #0 tractbrake/$train tb
 746     if {![info exists tb]} {
 747         report-problem "event: no traction/brake parameters for $train"
 748         return
 749     }
 750     if {[string length $tract]} { set tb(A) $tract }
 751     if {[string length $brake]} { set tb(B) $brake }
 752     if {$tract || $brake} {
 753         tractbrake-attach $train $speedw
 754     }
 755 }
 756
 757 proc tractbrake-ensure {train} {
 758     upvar #0 speedcurve/$train sc
 759     global trainnum2train
 760     if {[info exists sc]} return ;# try this only once
 761     set sc 0
 762
 763     if {[regexp {[^-+._0-9a-z]} $train]} { error "bad train $train ?" }
 764
 765     if {[catch { set f [open $train.speeds.record] } emsg]} {
 766         global errorCode errorInfo
 767         switch -glob $errorCode {POSIX ENOENT *} {
 768             report-problem "train $train: no traction/braking (no speed table)"
 769             return
 770         }
 771         error $emsg $errorInfo $errorCode
 772     }
 773     while {[llength $sc] <= 126} { lappend sc x }
 774     while {[gets $f l] >= 0} {
 775         if {[regexp {^train (\S+) step (\d+)=([0-9.]+)$} $l \
 776                  dummy tr step velocity]} {
 777             if {[string compare $tr $train] || $step<=0 || $step>126} {
 778                 error "bad velocity line $train $l ?"
 779             }
 780             set sc [lreplace $sc $step $step $velocity]
 781         } elseif {[regexp {^train (\S+) is (\d+) } $l \
 782                        dummy tr trainnum]} {
 783             if {[string compare $tr $train]} {
 784                 error "bad train line $train $l ?"
 785             }
 786             set trainnum2train($trainnum) $tr
 787         } else {
 788             # fine, whatever
 789         }
 790     }
 791     close $f
 792     if {[lsearch -exact $sc x]>=0} {
 793         report-problem "train $train: no traction/braking\
 794             (incomplete speed table"
 795         return
 796     }
 797
 798     upvar #0 tractbrake/$train tb
 799     defset tb(deadzone) 0.2
 800     defset tb(updms)    20
 801     defset tb(lambda)   0.600  ;# time constant for adj throttle
 802     defset tb(mu)       0.300  ;# time constant for apply/release breaks
 803     defset tb(inv_alpha)   20  ;# time constant for accelerate to max
 804     defset tb(omegaphi)    50  ;# (air resistance) / (rolling res) at max spd
 805     defset tb(inv_beta)    10  ;# time constant for service brake (over-est'd)
 806     defset tb(overpower) 1.03  ;# factor by which we are overpowered for max spd
 807     foreach lm {lambda mu} {
 808         setexpr tb(updfact_$lm) { $tb(updms) * 0.001 / $tb($lm) }
 809     }
 810
 811     setexpr tb(alpha) { 1.0 / $tb(inv_alpha) }
 812     setexpr tb(beta) { 1.0 / $tb(inv_beta) }
 813     setexpr tb(phi) { $tb(alpha) / ($tb(omegaphi) + 1.0) / $tb(overpower) }
 814     setexpr tb(omega) { $tb(omegaphi) * $tb(phi) }
 815
 816     foreach p {alpha beta omega phi} {
 817         setexpr tb(perupd_$p) { $tb($p) * 0.001 * $tb(updms) }
 818     }
 819
 820     tractbrake-reset $train
 821 }
 822
 823 #---------- concrete input bindings ----------
 824
 825 proc ib-suppressions {args} {
 826     set l {}
 827     foreach supp $args {
 828         set l [concat $l --redaction $supp --suppress]
 829     }
 830     return $l
 831 }
 832
 833 proc ib-speedw-new {devid wunique desc} {
 834     upvar #0 input/$devid in
 835     set in(speedw) [speedw-new-cooked $wunique $desc]
 836 }
 837
 838 #----- wheelmouse
 839
 840 proc ib-ev/wheelmouse/EV_REL/REL_WHEEL {devid value} {
 841     upvar #0 input/$devid in
 842     speedw-userinput-rel-steps $in(speedw) [expr {-$value}] {}
 843 }
 844
 845 proc ib-selectnext {devid value} {
 846     if {$value!=1} return
 847     upvar #0 input/$devid in
 848     speedw-train-selectnext $in(speedw)
 849 }
 850 proc ib-changedirection {devid value} {
 851     upvar #0 input/$devid in
 852     if {!$value} return
 853     speedw-train-direction $in(speedw) change
 854 }
 855
 856 proc ib-ev/wheelmouse/EV_KEY/BTN_LEFT {devid value} {
 857     ib-selectnext $devid $value
 858 }
 859 proc ib-ev/wheelmouse/EV_KEY/BTN_RIGHT {devid value} {
 860     ib-changedirection $devid $value
 861 }
 862
 863 proc ib-create/wheelmouse {devid wunique desc} {
 864     ib-speedw-new $devid $wunique $desc
 865 }
 866
 867 proc ib-wheelmouse-redactions {} {
 868     return [ib-suppressions  \
 869             {EV REL REL X} \
 870             {EV REL REL Y}]
 871 }
 872
 873 proc ib-evcmd/wheelmouse {devid target} {
 874     return [ib-evcmd-construct $devid $target [concat \
 875             [list --grab] [ib-wheelmouse-redactions]]]
 876 }
 877
 878 #----- gamepad
 879
 880 proc ib-create/gamepad {devid wunique desc} {
 881     ib-speedw-new $devid $wunique $desc
 882     upvar #0 input/$devid in
 883     set in(main_deadzone_y) 0.2
 884     set in(main_deadzone_x) 0.5
 885     set in(main_x) 0
 886     set in(main_y) 0
 887     set in(main_active) {}
 888 }
 889
 890 proc ib-ev/gamepad/EV_ABS/ABS_THROTTLE {d v} { ib-gamepad-main $d y $v }
 891 proc ib-ev/gamepad/EV_ABS/ABS_RUDDER {d v} { ib-gamepad-main $d x $v }
 892
 893 proc ib-gamepad-main {devid xy value} {
 894     upvar #0 input/$devid in
 895     if { abs($value) < $in(main_deadzone_$xy) } { set value 0 }
 896     set last $in(main_$xy)
 897     set in(main_$xy) $value
 898
 899     set active {}
 900     foreach txy {x y} {
 901         if { $in(main_$txy) } {
 902             if {[string length $active]} return
 903             set active $txy
 904         }
 905     }
 906     debug [format "ib-gamepad-main %s %s %6.4f,%6.4f %s %s" \
 907                $devid $xy $in(main_x) $in(main_y) $in(main_active) $active]
 908     if {![string length $active]} {
 909         if {[string length $in(main_active)]} {
 910             speedw-userinput-tractbrake $in(speedw) 0 0
 911         }
 912     } else {
 913         if {[string length $in(main_active)] &&
 914             [string compare $active $in(main_active)]} {
 915             return
 916         }
 917         set value $in(main_$active)
 918         switch -exact $active {
 919             y {
 920                 if {$value < 0} {
 921                     speedw-userinput-tractbrake $in(speedw) [expr {-$value}] 0
 922                 } {
 923                     speedw-userinput-tractbrake $in(speedw) 0 $value
 924                 }
 925             }
 926             x {
 927                 if { abs($value) < 0.75 } return
 928                 if {[string length $in(main_active)]} return
 929                 speedw-train-direction $in(speedw) \
 930                     [expr { $value < 0 ? "backwards" : "forwards" }]
 931             }
 932             default {
 933                 error "$active ?"
 934             }
 935         }
 936     }
 937     set in(main_active) $active
 938 }
 939
 940 proc ib-ev/gamepad/EV_KEY/BTN_TOP2 {devid value} {
 941     upvar #0 input/$devid in
 942     if {!$value} return
 943     if {[string length $in(main_active)]} return
 944     speedw-uninhibit-tractbrake $in(speedw)
 945 }
 946
 947 #----- ebuyer wireless keyboard
 948
 949 proc ib-create/ebwikeb {devid wunique} {
 950     upvar #0 input/$devid in
 951     set in(desc) "main keyboard"
 952     ib-create/wheelmouse $devid $wunique $in(desc)
 953     set in(modifiers) 0
 954 }
 955
 956 proc ib-evcmd/ebwikeb {devid target} {
 957     return [concat \
 958             [list ./evdev-manip-ebwikeb --redact --stdin-monitor] \
 959             [ib-wheelmouse-redactions] \
 960             [ib-suppressions \
 961                 {0x01 02} \
 962                 {EV MSC} \
 963                 {0x0c 01} \
 964                 {0xffbc 88 0xffbc 00}]]
 965 }
 966
 967 proc ib-ev/ebwikeb/EV_REL/REL_WHEEL {devid value} {
 968     ib-ev/wheelmouse/EV_REL/REL_WHEEL $devid $value
 969 }
 970
 971 proc ib-ebwikeb-modifier {devid value bitval} {
 972     upvar #0 input/${devid}(modifiers) mod
 973     if {$value} {
 974         set mod [expr {$mod | $bitval}]
 975     } else {
 976         set mod [expr {$mod & ~$bitval}]
 977     }
 978 }
 979 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTSHIFT {devid value} {
 980     ib-ebwikeb-modifier $devid $value 0x0001
 981 }
 982 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTSHIFT {devid value} {
 983     ib-ebwikeb-modifier $devid $value 0x0002
 984 }
 985 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTCTRL {devid value} {
 986     ib-ebwikeb-modifier $devid $value 0x0100
 987 }
 988 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTCTRL {devid value} {
 989     ib-ebwikeb-modifier $devid $value 0x0200
 990 }
 991 proc ib-ev/ebwikeb/EV_KEY/KEY_CAPSLOCK {devid value} {
 992     ib-ebwikeb-modifier $devid $value 0x0400
 993 }
 994
 995 proc ib-ev/ebwikeb/0xffbc_88/0xffbc_0d {devid value} {
 996     upvar #0 input/$devid in
 997     if {!$value} return
 998     if {$in(modifiers) & 0x00ff} {
 999         ib-selectnext $devid $value
1000     } else {
1001         ib-changedirection $devid $value
1002     }
1003 }
1004
1005 proc ib-ev/ebwikeb/EV_KEY/KEY_BOOKMARKS {devid value} {
1006     upvar #0 input/$devid in
1007     if {!$value} return
1008     if {!($in(modifiers) & 0xff00)} return
1009     if {$in(modifiers) & 0x00ff} {
1010         set how stop
1011     } else {
1012         set how auto
1013     }
1014     scmd routinecmd $in(desc) "!realtime $how"
1015 }
1016
1017 #----- static keybindings speed `controller'
1018
1019 proc bind-keyboard-speed {kslow kfast kseltrain kreverse desc} {
1020     set wunique [get-unique keyboardspeed]
1021     set w [speedw-new-cooked $wunique $desc]
1022     foreach delta {-1 +1} sf {slow fast} {
1023         bind . <Key-[set k$sf]> [list speedw-userinput-rel-steps $w $delta {}]
1024     }
1025     bind . <Key-$kseltrain> [list speedw-train-selectnext $w]
1026     bind . <Key-$kreverse> [list speedw-train-direction $w change]
1027     speedw-setstate $w normal
1028 }
1029
1030 #----- Joytech "Neo S" USB PC gamepad
1031
1032 proc hidraw-descriptors/gamepad-neo-s {} {
1033     return xx
1034 }
1035
1036 #proc hidraw-readable/gamepad-neo-s {chan hidraw devid} {
1037 #    upvar #0 hidraw/$hidraw raw
1038 #    # In my tests with tcl8.3 and tcl8.5, "read chan numbytes"
1039 #    # on a nonblocking binary channel does only one read(2)
1040 #    # provided that read(2) returns less than requested
1041 #    while 1 {
1042 #       set msg [hbytes raw2h [read $chan 256]]
1043 #       if {![hbytes
1044 #       switch -glob [bhtes $msg {
1045 #           4a* { set want 8 }
1046 #           {} { set want 64 }
1047 #           * { error "unknown report number $raw(buf)" }
1048 #       }
1049 #       if {$want > $sofar} {
1050 #           set got [read $chan [expr {$want - $sofar}]]
1051 #
1052 #       }
1053 #
1054 #       set sofar [hbytes length $raw(buf)]
1055 #       if {!$sofar} {
1056 #           set got [read $chan 64]
1057 #       } else {
1058 #
1059 #       }
1060
1061
1062 #---------- input device evdev binding ----------
1063
1064 proc ib-evcmd-construct {devid target xargs} {
1065     upvar #0 input/$devid in
1066     if {[llength $target] > 1} {
1067         debug "ib $devid - multiple devices, not supported"
1068         return {}
1069     }
1070     manyset [lindex $target 0] ev sysfs
1071     if {[regexp { } $ev]} { error "event device `$ev' contains space" }
1072     return [concat \
1073             [list ./evdev-manip --redact] $xargs \
1074             [list --stdin-monitor \
1075                   --expect-sysfs /sys$sysfs/$ev/dev \
1076                   /dev/input/$ev]]
1077 }
1078
1079 proc bind-input-core {devid devkind devinfo concrete concargs} {
1080     global input_bindings
1081     lappend input_bindings [list $devkind $devid $devinfo $concrete $concargs]
1082 }
1083
1084 proc bind-input {bus vendor product version concrete args} {
1085     bind-input-core evdev:$bus:$vendor:$product:$version \
1086         evdev [list $bus $vendor $product $version] \
1087         $concrete $args
1088 }
1089
1090 proc bind-input-static {event sysfs concrete args} {
1091     bind-input-core [get-unique static] \
1092         static [list $event $sysfs] \
1093         $concrete $args
1094 }
1095
1096 proc bind-input-raw {devtype concrete args} {
1097     set descriptors [exec ./hidrawconv-$devtype -d]
1098     bind-input-core hidraw:[get-unique $devtype] \
1099         hidraw [list $devtype $descriptors] \
1100         $concrete $args
1101 }
1102
1103 proc widgets-input-bindings {} {
1104     global input_bindings
1105     foreach binding $input_bindings {
1106         manyset $binding devkind devid devinfo concrete concargs
1107         set cid [get-unique $concrete]
1108         upvar #0 input/$devid in
1109         set in(laststart) 0
1110         set in(concrete) $concrete
1111         eval [list ib-create/$concrete $devid $cid] $concargs
1112     }
1113     pack .inputs -side top -fill x
1114 }
1115
1116 # input/$devid becomes `in' via upvar:
1117 #  $in(chan)        channel open onto evdev-manip;
1118 #                   unset if none, or hidraw, or something
1119 #  $in(laststart)   last start time, [clock seconds]
1120 #                      at every event we set this the current time
1121 #                      but we insist on adding at least 5s
1122 #                      and if that would make it > current time +15s
1123 #                      we don't start
1124 #  $in(speedw)      optional, may be set by ib-create
1125
1126 # hidraw/hidrawN becomes `hr' via upvar:
1127 #  $raw(devid)      $devid (see above)
1128 #  $raw(chan)       channel open onto /dev/hidrawN
1129
1130 proc input-concrete-start-try {devid concrete} {
1131     global inputretryadd inputretrymax
1132     upvar #0 input/$devid in
1133     set now [clock seconds]
1134     set newlast [expr {$in(laststart) + $inputretryadd}]
1135     if {$newlast > $now + $inputretrymax} { return 0 }
1136     if {$newlast < $now} { set newlast $now }
1137     set in(laststart) $newlast
1138 }
1139
1140 proc input-bindings-list {devkind} {
1141     global input_bindings
1142     set o {}
1143     foreach b $input_bindings {
1144         manyset $b dk
1145         if {[string compare $dk $devkind]} continue
1146         lappend o $b
1147     }
1148     return $o
1149 }
1150
1151 proc scan-input-bindings {} {
1152     global errorInfo errorCode unmatched_notified old_hidraws
1153     global input_bindings scaninputinterval
1154     global input_rawbindings
1155
1156     after $scaninputinterval scan-input-bindings
1157
1158     # scan /proc/bus/input/devices for appropriate evdevs
1159     # results go in $target($devid)
1160     if {[catch {
1161         set f [open /proc/bus/input/devices]
1162     } emsg]} {
1163         if {[string match {POSIX ENOENT *} $errorCode]} return
1164         error $emsg $errorInfo $errorCode
1165     }
1166     while 1 {
1167         set r [gets $f l]
1168         if {$r <= 0} {
1169             if {[info exists v(devid)] &&
1170                 [info exists v(sysfs)] &&
1171                 [info exists v(event)]} {
1172                 lappend target(evdev:$v(devid)) [list $v(event) $v(sysfs)]
1173             }
1174             catch { unset v }
1175         }
1176         if {$r < 0} {
1177             break
1178         }
1179         append l "\n"
1180         if {[regexp \
1181  {^I: Bus=(\w+) Vendor=(\w+) Product=(\w+) Version=(\w+)\s} \
1182                  $l dummy bus vendor product version]} {
1183             set v(devid) $bus:$vendor:$product:$version
1184         } elseif {[regexp {^S: Sysfs=(\S+)\s} $l dummy sysfs]} {
1185             set v(sysfs) $sysfs
1186         } elseif {[regexp {^H: Handlers=(?:.*\s)?(event\d+)\s} $l dummy ev]} {
1187             set v(event) $ev
1188         } else {
1189             # ignored
1190         }
1191     }
1192     close $f
1193
1194     # add as-if-scanned entries for static bindings to target
1195     # also check to see if we want hidraw
1196     foreach binding $input_bindings {
1197         manyset $binding devkind devid devinfo concrete concargs
1198         switch -exact $devkind static { } default continue
1199         lappend target($devid) [list $event $sysfs]
1200     }
1201
1202     # scan /dev/hidraw*
1203     foreach binding [input-bindings-list hidraw] {
1204         manyset $binding devkind devid devinfo concrete concargs
1205         switch -exact $devkind hidraw { } default continue
1206         manyset $devinfo devtype descriptors
1207         set rawmap($descriptors) [list $devid $devtype $concrete]
1208     }
1209     if {[array exists rawmap]} {
1210         set new_hidraws [lsort [glob -nocomplain -directory /dev hidraw*]]
1211         foreach hidraw $new_hidraws {
1212             upvar #0 hidraw/$hidraw raw
1213             if {[info exists raw(chan)]} {
1214                 set found($raw(devid)) 1
1215                 continue
1216             }
1217             if {[lsearch -exact $old_hidraws $hidraw] >= 0} continue
1218             if {[catch {
1219                 set chan [open $hidraw r+]
1220                 set descriptors [exec ./hidraw-ioctl -d <@ $chan]
1221                 if {![info exists rawmap($descriptors)]} {
1222                     set m [exec ./hidraw-ioctl -i <@ $chan]
1223                     error "unknown descriptors (unmatched device) $hidraw $m >$descriptors<"
1224                 }
1225             } emsg]} {
1226                 upvar #0 hidraw_notified($hidraw) notified
1227                 if {![info exists notified] ||
1228                      [string compare $notified $emsg]} {
1229                     debug "ir $hidraw $emsg"
1230                     set notified $emsg
1231                 }
1232                 catch { close $chan }
1233                 catch { unset chan }
1234                 continue
1235             }
1236             manyset $rawmap($descriptors) devid devtype concrete
1237             set found($devid) 1
1238             if {![input-concrete-start-try $devid $concrete]} {
1239                 catch { close $chan }
1240                 continue
1241             }
1242             set raw(devid) $devid
1243             set cmdl [list ./hidrawconv-$devtype -e <@ $chan 2>@ stderr]
1244             set evch [open |$cmdl r]
1245             set raw(chan) $evch
1246             fconfigure $evch -blocking 0 -buffering line
1247             fileevent $evch readable \
1248                 [list catch-for-input-binding hidraw $hidraw \
1249                      [list readable input-binding-raw $evch $hidraw $devid]]
1250             input-binding-present $devid 1 "hidraw $hidraw"
1251         }
1252         set old_hidraws $new_hidraws
1253     }
1254
1255     # try to start the input binding for all the unstarted found targets
1256     foreach devid [array names target] {
1257         upvar #0 input/$devid in
1258         if {![info exists in(concrete)]} {
1259             if {![info exists unmatched_notified($devid)]} {
1260                 debug "ib $devid unmatched, ignored"
1261                 set unmatched_notified($devid) 1
1262             }
1263             continue
1264         }
1265         set found($devid) 1
1266         if {[info exists in(chan)]} continue
1267         if {![input-concrete-start-try $devid $concrete]} continue
1268
1269         set cmdl [ib-evcmd/$in(concrete) $devid $target($devid)]
1270         if {![llength $cmdl]} {
1271             unset target($devid)
1272             continue
1273         }
1274         lappend cmdl 2>@ stderr
1275         catch-for-input-binding evdev $devid {
1276             debug "ib $devid running $cmdl"
1277             set in(chan) [open |$cmdl r+]
1278             fconfigure $in(chan) -blocking 0 -buffering line
1279             fileevent $in(chan) readable \
1280                 [list catch-for-input-binding evdev $devid \
1281                     [list readable input-binding $in(chan) $devid]]
1282         }
1283     }
1284
1285     # anything not found, not present
1286     foreach binding $input_bindings {
1287         manyset $binding devkind devid devinfo concrete concargs
1288         switch -exact $devkind evdev - raw { } default continue
1289         upvar #0 input/$devid in
1290         if {![info exists in(concrete)]} continue
1291         if {[info exists found($devid)]} continue
1292         input-binding-present $devid 0 absent
1293     }
1294 }
1295
1296 proc input-binding-present {devid yes why} {
1297     upvar #0 input/$devid in
1298     if {[info exists in(speedw)]} {
1299         speedw-setstate $in(speedw) [lindex {disabled normal} $yes]
1300     }
1301     set call "ib-[lindex {absent present} $yes]/$in(concrete)"
1302     if {![catch { info args $call }]} {
1303         $call $devid $why
1304     }
1305 }
1306
1307 proc input-binding-eof {chan devid} {
1308     upvar #0 input/$devid in
1309     input-binding-eof-core $in(chan) "evdev-manip exited"
1310 }
1311
1312 proc input-binding-eof-core {chan msg} {
1313     fconfigure $chan -blocking 1
1314     close $chan
1315     error $msg {} {CHILDSTATUS ? 0}
1316 }
1317
1318 proc input-binding-raw-eof {chan hidraw devid} {
1319     upvar #0 hidraw/$hidraw raw
1320     input-binding-eof-core $raw(chan) "hidrawconv-* exited"
1321 }
1322
1323 proc input-binding-inputline {chan l devid} {
1324     upvar #0 input/$devid in
1325     if {[input-binding-inputline-core-ib $devid $l]} return
1326     regsub {^[^ ]+ } $l {} lr
1327     switch -glob -- $lr {
1328         {opened *} {
1329             debug "ib $devid start << $l"
1330             input-binding-present $devid 1 "evdev open"
1331         }
1332         {[-0-9]*} {
1333             manyset [split $lr] value kindl kindr codel coder
1334             input-binding-inputline-core-ev $devid \
1335                 ${kindl}_${kindr}/${codel}_${coder} $value $l
1336         }
1337         * {
1338             debug "ib $devid ignored << $l"
1339         }
1340     }
1341 }
1342
1343 proc input-binding-inputline-core-ib {devid l} {
1344     # give the input binding first dibs
1345     upvar #0 input/$devid in
1346     if {[catch { info args ib-inputline/$in(concrete) }]} { return 0 }
1347     return [ib-inputline/$in(concrete) $devid $l]
1348 }
1349
1350 proc input-binding-inputline-core-ev {devid kindcode value l} {
1351     global showunbound
1352     upvar #0 input/$devid in
1353     set proc ib-ev/$in(concrete)/$kindcode
1354     if {[catch { info args $proc }]} {
1355         if {$showunbound} {
1356             debug "ib $devid unbound $proc << $l"
1357         }
1358         return
1359     }
1360     $proc $devid $value
1361 }
1362
1363 proc input-binding-raw-inputline {chan l hidraw devid} {
1364     upvar #0 hidraw/$hidraw raw
1365     if {[input-binding-inputline-core-ib $devid $l]} return
1366     manyset [split $l] kind code value
1367     input-binding-inputline-core-ev $devid $kind/$code $value $l
1368 }
1369
1370 proc catch-for-input-binding {devkind ident body} {
1371     global errorInfo errorCode
1372     set r [catch { uplevel 1 $body } rv]
1373     if {$r!=1} { return -code $r $rv }
1374     switch -glob $errorCode {
1375         {CHILDSTATUS *} { set m "exited with status [lindex $errorCode 2]" }
1376         {CHILDKILLED *} { set m "killed by signal [lindex $errorCode 3]" }
1377         {POSIX *} { set m "communication error: [lindex $errorCode 1]" }
1378         * { error $rv $errorInfo $errorCode }
1379     }
1380     debug "ib $devkind $ident died $m"
1381     input-binding-destroy/$devkind $ident $m
1382 }
1383
1384 proc input-binding-destroy/evdev {devid m} {
1385     upvar #0 input/$devid in
1386     catch { close $in(chan) }
1387     catch { unset in(chan) }
1388     input-binding-present $devid 0 "died $m"
1389 }
1390
1391 proc input-binding-destroy/hidraw {hidraw m} {
1392     upvar #0 hidraw/$hidraw raw
1393     catch { close $raw(chan) }
1394     catch { unset raw(chan) }
1395     input-binding-present $raw(devid) 0 "died $m"
1396 }
1397
1398 proc engage-input-bindings {} {
1399     scan-input-bindings
1400 }
1401
1402 #---------- plan background (gui-plan subprocess) ----------
1403
1404 proc gui-pipe-readable {args} {
1405     global gui_pipe
1406     while {[gets $gui_pipe l] >= 0} {
1407         debug "<gui-plan $l"
1408     }
1409     if {[eof $gui_pipe]} {
1410         close $gui_pipe
1411         error "gui-plan crashed"
1412     }
1413 }
1414
1415 #---------- train set events of general interest, and setup ----------
1416
1417 proc train-event-eof {args} {
1418     error "lost connection to train set"
1419 }
1420
1421 register-event ?stastate {ctxch state} {^(.)stastate (\w+|\-) } {
1422     global ctrain trains stastate
1423     set stastate $state
1424     report-problem "stastate: $state"
1425     if {[string compare $ctxch |]} speedws-stastate-hook
1426 }
1427
1428 register-event ?resolution {message} \
1429         {^.resolution (\S+ .*)$} {
1430     if {[string match "problems *" $message]} return
1431     report-problem "resolution: $message"
1432 }
1433
1434 register-event ?warning {message} {^.warning (\S+ .*)$} {
1435     report-problem "warning: $message"
1436 }
1437
1438 register-event {} {} {^=connected } {
1439     global pages gui_pipe server port event_selections
1440
1441     scmd replayed {} "select-replay [concat $event_selections]"
1442
1443     foreach page $pages {
1444         set w [pagew $page]
1445         tkwait visibility $w.picture
1446
1447         set cmdl [list ./gui-plan-$page [winfo id $w.picture] @$server,$port]
1448         lappend cmdl 2>@ stderr
1449         set gui_pipe [open |$cmdl r]
1450
1451         puts stderr "running $cmdl"
1452         fconfigure $gui_pipe -blocking no
1453         fileevent $gui_pipe readable gui-pipe-readable
1454     }
1455 }
1456 proc replayed-err {m args} { error "replay failed: $m" }
1457 proc replayed-ok {m args} {
1458     speedws-stastate-hook
1459 }
1460
1461 register-event {} {} {^=failed } { error "multiplexer failed: $l" }
1462 register-event {} {} {^=denied } { error "multiplexer denied us: $l" }
1463 register-event {} {} {^\+nack } { error "multiplexer does not understand" }
1464
1465 #---------- main program ----------
1466
1467 append event_dispatch_body {
1468     debug "ignored $l"
1469 }
1470 proc train-event-inputline {sconn l} $event_dispatch_body
1471 proc register-event {args} { error "too late!" }
1472
1473 proc engage-server {} {
1474     global server port sconn
1475
1476     set sconn [socket $server $port]
1477     fconfig-trainproto $sconn
1478     fileevent $sconn readable {readable train-event $sconn}
1479 }
1480
1481 proc main {} {
1482     global pages cpage configfile input_bindings old_hidraws
1483     setting server railway {[[0-9a-z:].*}
1484     setting geometry {} {[-+]\d+[-+]\d+}
1485     setting posdeviation 5 {\d+}
1486     setting movfeatcommand {movfeat+} {(?:!movfeat|movfeat\+?\+?)}
1487     setting problemdisplayms 1000 {\d+}
1488     setting inputretryadd 5 {\d+}
1489     setting inputretrymax 15 {\d+}
1490     setting scaninputinterval 500 {\d+}
1491     setting showunbound 0 {[01]}
1492
1493     set hostname [lindex [split [info hostname] .] 0]
1494     setting configfile gui-$hostname.config {.+}
1495     parse-argv {}
1496
1497     frame .inputs
1498     if {![info exists input_bindings]} { set input_bindings {} }
1499     set old_hidraws {}
1500
1501     uplevel #0 source gui-layout.config
1502     uplevel #0 source $configfile
1503     foreach cpage $pages {
1504         layout-data
1505         widgets-dgram
1506     }
1507     unset cpage
1508     widgets-movpos
1509     widgets-input-bindings
1510     widget-problem-report
1511     engage-server
1512     engage-input-bindings
1513     start_commandloop
1514 }
1515
1516 main