hostside/gui

   1 #!/usr/bin/wishx
   2
   3 load chiark_tcl_hbytes-1.so
   4
   5 #---------- general utilities ----------
   6
   7 set tk_strictMotif 1
   8
   9 tk_setPalette background black foreground white
  10
  11 source lib.tcl
  12
  13 set default_speedstep_list {0 1 10 20 35 50 65 80 95 110 126}
  14
  15 set picturepadx 10
  16 set picturepady 10
  17
  18 proc pagew {page} { return ".picture-$page" }
  19 proc debug {m} { puts $m }
  20
  21 proc sconn {m} {
  22     global sconn
  23     debug "=> $m"
  24     puts $sconn $m
  25 }
  26
  27 proc widgets-dgram {} {
  28     global cpage geometry picturepadx picturepady
  29     if {[string length $geometry]} { wm geometry . $geometry }
  30     set sizes [exec ./gui-plan-$cpage --sizes]
  31     set w [pagew $cpage]
  32     frame $w
  33     frame $w.picture -background {} \
  34             -width [lindex $sizes 0] \
  35             -height [lindex $sizes 1]
  36     pack $w.picture -padx $picturepadx -pady $picturepady
  37     pack $w
  38 }
  39
  40 proc widgets-fullscreen-nowm {} {
  41     pack propagate . false
  42     foreach wh {width height} {
  43         . configure -$wh [winfo screen$wh .]
  44     }
  45 }
  46
  47 proc bgerror {emsg} {
  48     global errorCode errorInfo
  49     catch {
  50         puts stderr "UNEXPECTED BACKGROUND ERROR\n"
  51         puts stderr "$errorCode\n$errorInfo\n$emsg"
  52     }
  53     exit 16
  54 }
  55
  56 #---------- train set event registraton ----------
  57
  58 set event_dispatch_body {
  59     append l " "
  60 }
  61 set event_selections {}
  62
  63 proc register-event {selections args re body} {
  64     global event_dispatch_body event_selections
  65
  66     eval lappend event_selections $selections
  67
  68     foreach selection $selections {
  69         if {[regexp {^\w} $selection]} {
  70             error "selection $selection lacks context char"
  71         }
  72     }
  73     if {[regexp {^\^\w} $re]} {
  74         error "re $re never matches context char"
  75     }
  76
  77     regsub -all {\W+} $re - proc
  78     set proc "event/$proc/[join $args -]"
  79     set suffix {}
  80     set number 0
  81     while {![catch { info args $proc$suffix }]} { set suffix [incr number] }
  82     append proc $suffix
  83
  84     proc $proc [concat l $args] $body
  85     set al ""
  86     foreach a $args { append al " \$$a" }
  87
  88     append event_dispatch_body \
  89             "    if {\[regexp [list $re] \$l dummy $args]} {\n" \
  90             "        debug \"$proc$al\"\n" \
  91             "        eval [list $proc] \[list \$l$al]\n" \
  92             "        return\n" \
  93             "    }\n"
  94 }
  95
  96 #---------- handling of commands we issue ----------
  97
  98 proc scmd {onresult ctrlr commandstr args} {
  99     # later, calls
 100     #   eval [list $onresult-ok|nak|error $ackornakmessage] $args
 101     global commands_queued
 102     sconn $commandstr
 103     lappend commands_queued [list $ctrlr $onresult $args]
 104 }
 105
 106 proc scmd_result {oknakerr message reporterrmsg} {
 107     global commands_queued
 108     manyset [lindex $commands_queued 0] ctrlr onresult args
 109     set commands_queued [lrange $commands_queued 1 end]
 110     if {[string length $reporterrmsg]} {
 111         report-problem "$ctrlr: $reporterrmsg"
 112     }
 113     set proc "$onresult-$oknakerr"
 114     if {![string compare $oknakerr nak] && [catch { info args $proc }]} {
 115         set proc "$onresult-err"
 116     }
 117     eval [list $proc $message] $args
 118 }
 119
 120 register-event {} {} {^\+ack \S+ ok } { scmd_result ok $l "" }
 121 register-event {} {train segment error} \
 122         {^\+ack \S+ SignallingPredictedProblem (\S+) (\S+) \: (.*) $} {
 123     set m $train
 124     if {[string compare - $segment]} { append m " @$segment" }
 125     append m ": $error"
 126     scmd_result err $l $m
 127 }
 128 register-event {} {} {^\+ack } { scmd_result err $l $l }
 129 register-event {} {} {^\+nack \S+ } { scmd_result nak $l $l }
 130
 131 proc routinecmd-nak {m args} { error "got nak to routine command: $m" }
 132 proc routinecmd-err {m args} { }
 133 proc routinecmd-ok {m args} { }
 134
 135 proc mustsucceed-err {m args} { error "unexpected error: $m" }
 136 proc mustsucceed-ok {m args} { }
 137
 138 proc report-problem-report-stderr {m} { puts stderr "*** $m" }
 139 set report_problem_report report-problem-report-stderr
 140
 141 proc report-problem {message} {
 142     global report_problem_report
 143     eval $report_problem_report [list $message]
 144 }
 145
 146 proc widget-problem-report {} {
 147     global problem_reports report_problem_report
 148     set problem_reports "\n\n\n\n\n"
 149     label .problem-report -anchor w -justify left -takefocus 0 \
 150             -border 2 -relief sunken -width 80 -textvariable problem_reports
 151     pack .problem-report -side top
 152     set report_problem_report report-problem-report-widget
 153 }
 154
 155 proc report-problem-report-widget {m} {
 156     global problem_reports
 157     set problem_reports [join [concat \
 158                 [lrange [split $problem_reports "\n"] 1 end] \
 159                 [list $m] \
 160             ] "\n"]
 161 }
 162
 163 #---------- movpos (overlay buttons, keybindings, execution) ----------
 164
 165 proc movpos-button-gvars {mid} {
 166     upvar #0 mp_details($mid) details
 167     if {![info exists details]} { return 0 }
 168     uplevel 1 [list manyset $details cpage key seg feat poslocs]
 169     uplevel 1 { set w [pagew $cpage].movpos-$mid }
 170     upvar #0 mp_state($mid) state
 171     uplevel 1 [list manyset $state posn]
 172     return 1
 173 }
 174
 175 proc movpos-button-sstate {mid posn} {
 176     upvar #0 mp_state($mid) state
 177     set state $posn
 178     movpos-button-setdisplay $mid
 179 }
 180
 181 proc movpos-all-unknown {} {
 182     global mp_details
 183     foreach mid [array names mp_details] {
 184         movpos-button-sstate $mid ?
 185     }
 186 }
 187
 188 proc widgets-movpos {} {
 189     global mp_details
 190     foreach mid [array names mp_details] {
 191         upvar #0 mp_state($mid) state
 192         set state {?}
 193         movpos-button-gvars $mid
 194         set w [pagew $cpage].movpos-$mid
 195         button $w -text $key -padx 0 -pady 0 -borderwidth 0 \
 196                 -command [list movpos-invoked $mid "plan $cpage"]
 197         movpos-button-setdisplay $mid
 198     }
 199 }
 200
 201 proc movpos-button-setdisplay {mid} {
 202     # we want to display as much of these as possible:
 203     #   position known ?   (actual position is done by button location)
 204     #   moving or stable
 205     #   whether a train's plan includes a different position
 206     #   whether autopoint
 207     movpos-button-gvars $mid
 208     switch -exact $posn {
 209         ?       { set poslocn 2;     set fg black; set bg white }
 210         default { set poslocn $posn; set fg white; set bg black }
 211     }
 212     $w configure -background $bg -foreground $fg \
 213             -activebackground $bg -activeforeground $fg
 214     manyset [lindex $poslocs $poslocn] x y
 215     place $w -anchor center -x $x -y $y
 216 }
 217
 218 proc movpos-invoked {mid ctrlr} {
 219     global movfeatcommand
 220     movpos-button-gvars $mid
 221     switch -exact $posn {
 222         0 { set new_posn 1 }
 223         default { set new_posn 0 }
 224     }
 225     scmd routinecmd $ctrlr "$movfeatcommand $seg $feat $new_posn"
 226 }
 227
 228 register-event ?movpos_*_feat {seg feat posn_new} \
 229         {^.movpos (\w+) feat (\w+) ([01]|\?) } {
 230     set mid $seg/$feat
 231     if {![movpos-button-gvars $mid]} return
 232     set posn $posn_new
 233     movpos-button-sstate $mid $posn
 234 }
 235
 236 proc movpos-bindkey-1 {cpage key seg feat adj0x adj0y adj1x adj1y} {
 237     global posdeviation picturepadx picturepady
 238     manyset [subseg-end-get-centroid $cpage $seg $feat {}] mx my
 239     set mid $seg/$feat
 240     foreach posn {0 1} {
 241         manyset [subseg-end-get-centroid $cpage $seg $feat $posn] x y
 242         set dx [expr {$x-$mx}]; set dy [expr {$y-$my}]
 243         set d [expr {sqrt($dx*$dx + $dy*$dy)}]
 244         set mul [expr {$posdeviation / ($d + 1e-6)}]
 245         set x [expr {$mx + $mul*$dx + $picturepadx + [set adj${posn}x]}]
 246         set y [expr {$my + $mul*$dy + $picturepady + [set adj${posn}y]}]
 247         lappend poslocs [list $x $y]
 248     }
 249     lappend poslocs [list [expr {$mx + $picturepadx + ($adj0x+$adj1x)*0.5}] \
 250                           [expr {$my + $picturepady + ($adj0y+$adj1y)*0.5}]]
 251     upvar #0 mp_details($mid) details
 252     set details [list $cpage $key $seg $feat $poslocs]
 253
 254     bind . <Key-[string tolower $key]> [list movpos-invoked $mid "keyboard"]
 255 }
 256
 257 #---------- computation of movpos button locations
 258
 259 proc layout-subseg-featmap {seg concfeatpos args} {
 260     global subsegfeatmap
 261     set subsegfeatmap($concfeatpos) $args
 262 }
 263
 264 proc layout-subseg-end {seg feat posn x y} {
 265     global cpage
 266     upvar #0 subsegfeatmap($feat$posn) mapped
 267     if {[info exists mapped]} {
 268         foreach {feat posn} $mapped {
 269             layout-subseg-end $seg $feat $posn $x $y
 270         }
 271         return
 272     }
 273     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 274     if {![info exists sse]} { set sse {{} {}} }
 275     manyset $sse lx ly
 276     lappend lx $x
 277     lappend ly $y
 278     set sse [list $lx $ly]
 279     if {[string length $posn]} { layout-subseg-end $seg $feat {} $x $y }
 280 }
 281
 282 proc subseg-end-get-centroid {cpage seg feat posn} {
 283     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 284     if {![info exists sse]} {
 285         puts "skipping binding of unknown $seg/$feat$posn"
 286         return -code return
 287     }
 288     manyset $sse lx ly
 289     set sx 0; set sy 0; set n [llength $lx]
 290     foreach x $lx y $ly { addexpr sx {$x}; addexpr sy {$y} }
 291     return [list [expr {$sx * 1.0 / $n}] [expr {$sy * 1.0 / $n}]]
 292 }
 293
 294 proc layout-data {} {
 295     global cpage
 296     upvar #0 ld_sse/$cpage sse
 297     catch { unset sse }
 298     source ../layout/ours.dgram.segmap-info
 299     source ../layout/ours.dgram-$cpage.overlay-info
 300
 301     upvar #0 movpos_bindings($cpage) bindings
 302     if {![info exists bindings]} {
 303         puts "no movpos bindings for $cpage"
 304         return
 305     }
 306     foreach binding $bindings {
 307         if {[regexp \
 308    {^([A-Z])([-+]\d*)?([-+]\d*)?([-+]\d*)?([-+]\d*)?\=(\w+)/([A-Z]+)$} \
 309                  $binding dummy key adj0x adj0y adj1x adj1y seg feat]} {
 310             if {![string length $adj1x]} { set adj1x $adj0x; set adj1y $adj0y }
 311             movpos-bindkey-1 $cpage $key $seg $feat \
 312                 $adj0x.0 $adj0y.0 $adj1x.0 $adj1y.0
 313         } elseif {[regexp {^[A-Z]$} $binding] || [regexp {~} $binding]} {
 314         } else {
 315             error "incomprehensible binding $binding on page $cpage"
 316         }
 317     }
 318 }
 319
 320 #---------- speed ----------
 321
 322 # variables:
 323 #   $train_commanded($train)    $speed_step
 324 #   $train_direction($train)    forwards|backwards or unset
 325 #   $speedws                    [list $w ...]
 326 #
 327 # speed/${w}(...) aka s(...):
 328 #   $s(ctrlr)                   controller
 329 #   $s(train)                   train selected, or something not \w+
 330 #   $s(optionmenu)              optionmenu widget name
 331 #   $s(kind)                    abs or rel
 332 #   $s(commanding)              step of command we have scmd'd, or unset
 333 #   $s(queued)                  step of command we would like to queue
 334 #                                or unset if n/a
 335 #   $s(inhibit)   0   all is well, can command any speed
 336 #                 1   train newly selected, only rel can command higher speed
 337 #                 2   can only command same or lower speed
 338 #
 339 # We don't worry too much about races: in particular, we don't mind
 340 # racing with other things trying to command the speed, and losing
 341 # the odd increment/decrement.  But since we thread the requested
 342 # speed via realtime, we do queue up our own increments/decrements
 343 # while we're executing a speed command, to avoid loss of steps during
 344 # quick motions.
 345
 346 # Interfaces for concrete controllers:
 347 #   speedw-new $w $ctrlr
 348 #   speedw-setstate $w disabled|normal        controller appears/disappears
 349 #   speedw-userinput-abs $w $step
 350 #   speedw-userinput-rel $w $stepmap
 351 # where
 352 #   eval {stepmap} [list $oldstep] => $newstep
 353
 354 set speedws {}
 355
 356 proc speedws-forall {command args} {
 357     global speedws
 358     foreach w $speedws { eval [list $command $w] $args }
 359 }
 360
 361 proc speedws-fortrain {train command args} {
 362     global speedws
 363     foreach w $speedws {
 364         upvar #0 speed/$w s
 365         if {[string compare $s(train) $train]} continue
 366         eval [list $command $w] $args
 367     }
 368 }
 369
 370 proc speedw-new {w ctrlr} {
 371     upvar #0 speed/$w s
 372     global speedws
 373
 374     lappend speedws $w
 375     set s(ctrlr) $ctrlr
 376     set s(inhibit) 0
 377
 378     frame $w -relief sunken -border 2
 379     label $w.ctrlr -state disabled -text $s(ctrlr)
 380     set s(optionmenu) [tk_optionMenu $w.train speed/${w}(train) {}]
 381     $w.train configure -textvariable {} -width 15
 382     label $w.speed -state disabled -width 4 \
 383             -font -*-courier-bold-r-*-*-20-*-*-*-*-*-*-* \
 384             -background black -foreground white
 385     pack $w.ctrlr $w.train $w.speed -side left
 386
 387     speedw-notrains $w "(starting)"
 388 }
 389 proc speedw-notrains {w whystr} {
 390     $w.train configure -state disabled
 391     speedw-train-noneselected $w $whystr
 392 }
 393 proc speedw-train-noneselected {w whystr} {
 394     upvar #0 speed/$w s
 395     tractbrake-detach $s(train)
 396     set s(train) {}
 397     $w.train configure -text $whystr
 398     $w.speed configure -text -
 399     speedw-inhibit $w
 400 }
 401
 402 proc speedw-inhibit {w} {
 403     upvar #0 speed/$w s
 404     set s(inhibit) 2
 405     $w.speed configure -foreground red
 406 }
 407 proc speedw-uninhibit {w max} {
 408     upvar #0 speed/$w s
 409     set r $s(inhibit)
 410     if {$r>$max} { return -1 }
 411     set s(inhibit) 0
 412     $w.speed configure -foreground white
 413     return $r
 414 }
 415
 416 proc speedw-setstate {w disnorm} {
 417     $w.ctrlr configure -state $disnorm
 418     $w.speed configure -state $disnorm
 419 }
 420
 421 proc speedw-train-selectnext {w} {
 422     upvar #0 speed/$w s
 423     set max [$s(optionmenu) index end]
 424     for {set ix 0} {$ix <= $max} {incr ix} {
 425         set v [$s(optionmenu) entrycget $ix -value]
 426         if {![string compare $v $s(train)]} break
 427     }
 428     set activate [expr {($ix+1) % ($max+1)}]
 429     $s(optionmenu) invoke $activate
 430 }
 431
 432 proc speedw-train-selected {w t} {
 433     upvar #0 speed/$w s
 434     if {![string compare $t $s(train)]} return
 435     tractbrake-detach $s(train)
 436     $w.train configure -text $t
 437     set s(inhibit) 1
 438     set s(train) $t
 439     $w.speed configure -foreground white
 440     speedw-redisplay-speed $w
 441 }
 442
 443 proc speedw-redisplay-speed {w} {
 444     upvar #0 speed/$w s
 445     upvar #0 train_commanded($s(train)) gcommanded
 446     upvar #0 train_direction($s(train)) gdirection
 447     set t $gcommanded
 448     if {[info exists gdirection]} {
 449         switch -exact $gdirection {
 450             forwards { set t "$t>" }
 451             backwards { set t "<$t" }
 452         }
 453     }
 454     $w.speed configure -text $t
 455 }
 456
 457 proc speedw-train-direction {w dirchange} {
 458     upvar #0 speed/$w s
 459     if {![string length $s(train)]} return
 460     scmd routinecmd $s(ctrlr) "direction $s(train) $dirchange"
 461 }
 462
 463 proc speedw-trains-available {w l} {
 464     upvar #0 speed/$w s
 465     if {![llength $l]} { speedw-train-noneselected $w "(no trains)"; return }
 466     $s(optionmenu) delete 0 end
 467     $s(optionmenu) add radiobutton -label "(none)" -value {} \
 468             -command [list speedw-train-noneselected $w "(no train selected)"]
 469     set l [lsort $l]
 470     foreach t $l {
 471         $s(optionmenu) add radiobutton -label $t -value $t \
 472                 -command [list speedw-train-selected $w $t]
 473     }
 474     $w.train configure -state normal
 475     if {[llength $l]==1} {
 476         $s(optionmenu) invoke 1
 477     } elseif {[set ix [lsearch -exact $l $s(train)]] >= 0} {
 478         $s(optionmenu) invoke [expr {$ix+1}]
 479     } elseif {![string length $s(train)]} {
 480         $s(optionmenu) invoke 0
 481     } else {
 482         $w.train configure -text "$s(train) (not present)"
 483     }
 484 }
 485
 486 proc speedw-userinput-abs {w speed} {
 487     upvar #0 speed/$w s
 488     if {![string length $s(train)]} return
 489     tractbrake-detach $s(train)
 490     if {!$speed} { speedw-uninhibit $w 2 }
 491     speedw-do-abs $w $speed
 492 }
 493
 494 proc speedw-userinput-tractbrake {w tract brake} {
 495     upvar #0 speed/$w s
 496     if {![string length $s(train)]} return
 497     if {$s(inhibit)} return
 498     tractbrake-userinput $s(train) $tract $brake $w
 499 }
 500
 501 proc speedw-do-abs {w speed} {
 502     upvar #0 speed/$w s
 503     if {$speed == [speedw-currentspeed $w]} return
 504     set s(queued) $speed
 505     speedw-check $w
 506 }
 507
 508 proc speedw-check {w} {
 509     upvar #0 speed/$w s
 510     if {![string length $s(train)]} return
 511     upvar #0 train_commanded($s(train)) gcommanded
 512     upvar #0 train_direction($s(train)) gdirection
 513     if {[info exists s(commanding)]} return
 514     if {![info exists s(queued)]} return
 515     set newspeed $s(queued)
 516     unset s(queued)
 517     if {$s(inhibit) && $newspeed > $gcommanded} return
 518     set s(commanding) $newspeed
 519     scmd speedw-commanded $s(ctrlr) "speed $s(train) $newspeed $gdirection" $w
 520 }
 521
 522 proc speedw-commanded-nak {m args} { error "got nak from speed: $m" }
 523 proc speedw-commanded-ok {m w} {
 524     upvar #0 speed/$w s
 525     unset s(commanding)
 526     speedw-check $w
 527 }
 528 proc speedw-commanded-err {m w} {
 529     upvar #0 speed/$w s
 530     unset s(commanding)
 531     speedw-inhibit $w
 532     speedw-check $w
 533 }
 534
 535 proc speedw-currentspeed {w} {
 536     upvar #0 speed/$w s
 537     upvar #0 train_commanded($s(train)) gcommanded
 538     if {[info exists s(queued)]} {
 539         return $s(queued)
 540     } elseif {[info exists s(commanding)]} {
 541         return $s(commanding)
 542     } else {
 543         return $gcommanded
 544     }
 545 }
 546
 547 proc speedw-userinput-rel {w stepmap} {
 548     upvar #0 speed/$w s
 549     if {![string length $s(train)]} return
 550     set oldspeed [speedw-currentspeed $w]
 551     set newspeed [eval $stepmap [list $oldspeed]]
 552     speedw-userinput-abs $w $newspeed
 553 }
 554
 555 proc speedw-userinput-rel-steps {w delta steplist} {
 556     if {$delta<0} {
 557         if {[speedw-uninhibit $w 2]>1} { incr delta 1 }
 558         if {!$delta} return
 559     } else {
 560         speedw-uninhibit $w 1
 561     }
 562     speedw-userinput-rel $w [list speedw-stepmap-fromlist $steplist $delta]
 563 }
 564
 565 proc speedw-userinput-tractbrake {w tract brake} {
 566     upvar #0 speed/$w s
 567     if {![string length $s(train)]} return
 568     debug [format "speedw-userinput-tractbrake %s %6.4f %6.4f" \
 569                $s(train) $tract $brake]
 570     speedw-uninhibit $w 1
 571     if {$s(inhibit)} { set tract 0 }
 572     tractbrake-userinput $s(train) $tract $brake $w
 573 }
 574
 575 proc speedws-train-problem {train} {
 576     speedws-fortrain $train speedw-inhibit
 577 }
 578
 579 register-event ?train_*_at {train direction} \
 580         {^.train (\w+) at \S+ (forwards|backwards) } {
 581     upvar #0 train_direction($train) dirn
 582     set dirn $direction
 583     speedws-fortrain $train speedw-redisplay-speed
 584     tractbrake-ensure $train
 585 }
 586
 587 register-event ?train_*_speed_commanding {train speed} \
 588         {^.train (\w+) speed commanding (\d+) } {
 589     upvar #0 train_commanded($train) cmd
 590     set cmd $speed
 591     speedws-fortrain $train speedw-redisplay-speed
 592 }
 593
 594 proc speedws-stastate-hook {} {
 595     global train_direction stastate
 596     switch -exact -- $stastate {
 597         Run {
 598             set trains [array names train_direction]
 599             speedws-forall speedw-trains-available $trains
 600         }
 601         Resolving {
 602             movpos-all-unknown
 603         }
 604         Finalising {
 605             speedws-forall speedw-notrains "($stastate)"
 606         }
 607         default {
 608             catch { unset train_commanded }
 609             speedws-forall speedw-notrains "($stastate)"
 610         }
 611     }
 612 }
 613
 614 register-event &train_*_signalling-problem {train problem} \
 615         {^\&train (\w+) signalling-problem (.*) $} {
 616     global speedws
 617     regsub {^(\S+) (\S+) \: } $problem {\1 @\2: } problem
 618     report-problem "event: $problem"
 619     speedws-train-problem $train
 620 }
 621
 622 proc speedw-new-cooked {wunique desc} {
 623     set w .inputs.$wunique
 624     speedw-new $w $desc
 625     pack $w -side left -padx 10
 626     return $w
 627 }
 628
 629 proc speedw-stepmap-fromlist {speedlist offset oldspeed} {
 630     if {![llength $speedlist]} {
 631         unset speedlist
 632         upvar #0 default_speedstep_list speedlist
 633     }
 634     set ixabove 0
 635     foreach entry $speedlist {
 636         if {$entry==$oldspeed} { set ixbelow $ixabove; break }
 637         if {$entry>$oldspeed} break
 638         set ixbelow $ixabove
 639         incr ixabove
 640     }
 641     set ix [expr {($offset>0 ? $ixbelow : $ixabove) + $offset}]
 642     if {$ix<0} { return 0 }
 643     if {$ix>=[llength $speedlist]} { return [lindex $speedlist end] }
 644     return [lindex $speedlist $ix]
 645 }
 646
 647 #----- traction / brake (hidden behind speedw) ----------
 648
 649 proc tractbrake-queue-update {train} {
 650     upvar #0 tractbrake/$train tb
 651     set tb(queued) [after $tb(updms) \
 652                         [list tractbrake-update $train]]
 653 }
 654
 655 proc tractbrake-attach {train speedw} {
 656     # can safely be called when already attached
 657     upvar #0 tractbrake/$train tb
 658     upvar #0 speedcurve/$train sc
 659     set tb(speedw) $speedw
 660     if {[info exists tb(queued)]} return
 661     upvar #0 train_commanded($train) gcommanded
 662     setexpr tb(v) {[lindex $sc $gcommanded] / [lindex $sc 126]}
 663     tractbrake-queue-update $train
 664 }
 665 proc tractbrake-detach {train} {
 666     # can safely be called when already detached
 667     upvar #0 tractbrake/$train tb
 668     catch { after cancel $tb(queued) }
 669     catch { unset tb(queued) }
 670     tractbrake-reset $train
 671 }
 672 proc tractbrake-reset {train} {
 673     upvar #0 tractbrake/$train tb
 674     if {![info exists tb]} return
 675     set tb(A) 0
 676     set tb(B) 0
 677     set tb(a) 0
 678     set tb(b) 0
 679 }
 680
 681 proc tractbrake-update {train} {
 682     upvar #0 tractbrake/$train tb
 683     upvar #0 tractbrake-params/$train pa
 684     unset tb(queued)
 685     foreach AB {A B} ab {a b} lm {lambda mu} {
 686         addexpr tb($ab) { $tb(updfact_$lm) * ( $tb($AB) - $tb($ab) ) - 1e-5 }
 687     }
 688     addexpr tb(v) {
 689         + $tb(perupd_alpha) * $tb(a)
 690         - $tb(perupd_beta) * $tb(b)
 691         - $tb(perupd_omega) * $tb(v) * $tb(v)
 692         - $tb(perupd_phi)
 693     }
 694     set m "tractbrake $train"
 695     foreach v {A a B b v} { append m [format " %s=%6.4f" $v $tb($v)] }
 696     debug $m
 697     if {$tb(v) <= 0} {
 698         # stopped
 699         set tb(v) 0
 700         speedw-do-abs $tb(speedw) 0
 701         if {$tb(A) <= 0 && $tb(a) <= 0 &&
 702             $tb(B) <= 0 && $tb(b) <= 0} {
 703             # no throttle or brake, no need to requeue
 704             return
 705         }
 706     } else {
 707         if {$tb(v) > 1.0} { set tb(v) 1.0 }
 708         upvar #0 speedcurve/$train sc
 709         upvar #0 train_commanded($train) gcommanded
 710         set step $gcommanded
 711         setexpr targetvel {$tb(v) * [lindex $sc 126]}
 712         while 1 {
 713             set vel [lindex $sc $step]
 714             if {$vel > $targetvel && $step > 0} {
 715                 setexpr nextstep {$step - 1}
 716             } elseif {$vel < $targetvel && $step < 126} {
 717                 setexpr nextstep {$step + 1}
 718             } else {
 719                 break
 720             }
 721             set nextvel [lindex $sc $nextstep]
 722             if {abs($nextvel-$targetvel) >= abs($vel-$targetvel)} {
 723                 break
 724             }
 725             set step $nextstep
 726         }
 727         speedw-do-abs $tb(speedw) $step
 728     }
 729     tractbrake-queue-update $train
 730 }
 731
 732 proc tractbrake-userinput {train tract brake speedw} {
 733     upvar #0 tractbrake/$train tb
 734     if {![info exists tb]} {
 735         report-problem "event: no traction/brake parameters for $train"
 736         return
 737     }
 738     if {[string length $tract]} { set tb(A) $tract }
 739     if {[string length $brake]} { set tb(B) $brake }
 740     if {$tract || $brake} {
 741         tractbrake-attach $train $speedw
 742     }
 743 }
 744
 745 proc tractbrake-ensure {train} {
 746     upvar #0 speedcurve/$train sc
 747     if {[info exists sc]} return ;# try this only once
 748     set sc 0
 749
 750     if {[regexp {[^-+._0-9a-z]} $train]} { error "bad train $train ?" }
 751
 752     if {[catch { set f [open $train.speeds.record] } emsg]} {
 753         global errorCode errorInfo
 754         switch -glob $errorCode {POSIX ENOENT *} {
 755             report-problem "train $train: no traction/braking (no speed table)"
 756             return
 757         }
 758         error $emsg $errorInfo $errorCode
 759     }
 760     while {[llength $sc] <= 126} { lappend sc x }
 761     while {[gets $f l] >= 0} {
 762         if {![regexp {^train (\S+) step (\d+)=([0-9.]+)$} $l \
 763                   dummy tr step velocity]} continue
 764         if {[string compare $tr $train] || $step<=0 || $step>126} {
 765             error "bad velocity line $l ?" {} {TRACTBRAKE SKIP}
 766         }
 767         set sc [lreplace $sc $step $step $velocity]
 768     }
 769     close $f
 770     if {[lsearch -exact $sc x]>=0} {
 771         report-problem "train $train: no traction/braking\
 772             (incomplete speed table"
 773         return
 774     }
 775
 776     upvar #0 tractbrake/$train tb
 777     defset tb(deadzone) 0.2
 778     defset tb(updms)    20
 779     defset tb(lambda)   0.600  ;# time constant for adj throttle
 780     defset tb(mu)       0.300  ;# time constant for apply/release breaks
 781     defset tb(inv_alpha)   20  ;# time constant for accelerate to max
 782     defset tb(omegaphi)    50  ;# (air resistance) / (rolling res) at max spd
 783     defset tb(inv_beta)    10  ;# time constant for service brake (over-est'd)
 784     defset tb(overpower) 1.03  ;# factor by which we are overpowered for max spd
 785     foreach lm {lambda mu} {
 786         setexpr tb(updfact_$lm) { $tb(updms) * 0.001 / $tb($lm) }
 787     }
 788
 789     setexpr tb(alpha) { 1.0 / $tb(inv_alpha) }
 790     setexpr tb(beta) { 1.0 / $tb(inv_beta) }
 791     setexpr tb(phi) { $tb(alpha) / ($tb(omegaphi) + 1.0) / $tb(overpower) }
 792     setexpr tb(omega) { $tb(omegaphi) * $tb(phi) }
 793
 794     foreach p {alpha beta omega phi} {
 795         setexpr tb(perupd_$p) { $tb($p) * 0.001 * $tb(updms) }
 796     }
 797
 798     tractbrake-reset $train
 799 }
 800
 801 #---------- concrete input bindings ----------
 802
 803 proc ib-suppressions {args} {
 804     set l {}
 805     foreach supp $args {
 806         set l [concat $l --redaction $supp --suppress]
 807     }
 808     return $l
 809 }
 810
 811 proc ib-speedw-new {devid wunique desc} {
 812     upvar #0 input/$devid in
 813     set in(speedw) [speedw-new-cooked $wunique $desc]
 814 }
 815
 816 #----- wheelmouse
 817
 818 proc ib-ev/wheelmouse/EV_REL/REL_WHEEL {devid value} {
 819     upvar #0 input/$devid in
 820     speedw-userinput-rel-steps $in(speedw) [expr {-$value}] {}
 821 }
 822
 823 proc ib-selectnext {devid value} {
 824     if {$value!=1} return
 825     upvar #0 input/$devid in
 826     speedw-train-selectnext $in(speedw)
 827 }
 828 proc ib-changedirection {devid value} {
 829     upvar #0 input/$devid in
 830     if {!$value} return
 831     speedw-train-direction $in(speedw) change
 832 }
 833
 834 proc ib-ev/wheelmouse/EV_KEY/BTN_LEFT {devid value} {
 835     ib-selectnext $devid $value
 836 }
 837 proc ib-ev/wheelmouse/EV_KEY/BTN_RIGHT {devid value} {
 838     ib-changedirection $devid $value
 839 }
 840
 841 proc ib-create/wheelmouse {devid wunique desc} {
 842     ib-speedw-new $devid $wunique $desc
 843 }
 844
 845 proc ib-wheelmouse-redactions {} {
 846     return [ib-suppressions  \
 847             {EV REL REL X} \
 848             {EV REL REL Y}]
 849 }
 850
 851 proc ib-evcmd/wheelmouse {devid target} {
 852     return [ib-evcmd-construct $devid $target [concat \
 853             [list --grab] [ib-wheelmouse-redactions]]]
 854 }
 855
 856 #----- gamepad
 857
 858 proc ib-create/gamepad {devid wunique desc} {
 859     ib-speedw-new $devid $wunique $desc
 860     upvar #0 input/$devid in
 861     set in(tractbrake_deadzone) 0.2
 862 }
 863
 864 proc ib-ev/tractbrake/init {devid} {
 865     upvar #0 input-params/$devid pa
 866 }
 867
 868 proc ib-ev/gamepad/EV_ABS/ABS_THROTTLE {devid value} {
 869     upvar #0 input/$devid in
 870     if {abs($value) < $in(tractbrake_deadzone)} {
 871         speedw-userinput-tractbrake $in(speedw) 0 0
 872         return
 873     }
 874     if {$value < 0} {
 875         speedw-userinput-tractbrake $in(speedw) [expr {-$value}] 0
 876     } {
 877         speedw-userinput-tractbrake $in(speedw) 0 $value
 878     }
 879 }
 880
 881 #----- ebuyer wireless keyboard
 882
 883 proc ib-create/ebwikeb {devid wunique} {
 884     upvar #0 input/$devid in
 885     set in(desc) "main keyboard"
 886     ib-create/wheelmouse $devid $wunique $in(desc)
 887     set in(modifiers) 0
 888 }
 889
 890 proc ib-evcmd/ebwikeb {devid target} {
 891     return [concat \
 892             [list ./evdev-manip-ebwikeb --redact --stdin-monitor] \
 893             [ib-wheelmouse-redactions] \
 894             [ib-suppressions \
 895                 {0x01 02} \
 896                 {EV MSC} \
 897                 {0x0c 01} \
 898                 {0xffbc 88 0xffbc 00}]]
 899 }
 900
 901 proc ib-ev/ebwikeb/EV_REL/REL_WHEEL {devid value} {
 902     ib-ev/wheelmouse/EV_REL/REL_WHEEL $devid $value
 903 }
 904
 905 proc ib-ebwikeb-modifier {devid value bitval} {
 906     upvar #0 input/${devid}(modifiers) mod
 907     if {$value} {
 908         set mod [expr {$mod | $bitval}]
 909     } else {
 910         set mod [expr {$mod & ~$bitval}]
 911     }
 912 }
 913 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTSHIFT {devid value} {
 914     ib-ebwikeb-modifier $devid $value 0x0001
 915 }
 916 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTSHIFT {devid value} {
 917     ib-ebwikeb-modifier $devid $value 0x0002
 918 }
 919 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTCTRL {devid value} {
 920     ib-ebwikeb-modifier $devid $value 0x0100
 921 }
 922 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTCTRL {devid value} {
 923     ib-ebwikeb-modifier $devid $value 0x0200
 924 }
 925 proc ib-ev/ebwikeb/EV_KEY/KEY_CAPSLOCK {devid value} {
 926     ib-ebwikeb-modifier $devid $value 0x0400
 927 }
 928
 929 proc ib-ev/ebwikeb/0xffbc_88/0xffbc_0d {devid value} {
 930     upvar #0 input/$devid in
 931     if {!$value} return
 932     if {$in(modifiers) & 0x00ff} {
 933         ib-selectnext $devid $value
 934     } else {
 935         ib-changedirection $devid $value
 936     }
 937 }
 938
 939 proc ib-ev/ebwikeb/EV_KEY/KEY_BOOKMARKS {devid value} {
 940     upvar #0 input/$devid in
 941     if {!$value} return
 942     if {!($in(modifiers) & 0xff00)} return
 943     if {$in(modifiers) & 0x00ff} {
 944         set how stop
 945     } else {
 946         set how auto
 947     }
 948     scmd routinecmd $in(desc) "!realtime $how"
 949 }
 950
 951 #----- static keybindings speed `controller'
 952
 953 proc bind-keyboard-speed {kslow kfast kseltrain kreverse desc} {
 954     set wunique [get-unique keyboardspeed]
 955     set w [speedw-new-cooked $wunique $desc]
 956     foreach delta {-1 +1} sf {slow fast} {
 957         bind . <Key-[set k$sf]> [list speedw-userinput-rel-steps $w $delta {}]
 958     }
 959     bind . <Key-$kseltrain> [list speedw-train-selectnext $w]
 960     bind . <Key-$kreverse> [list speedw-train-direction $w change]
 961     speedw-setstate $w normal
 962 }
 963
 964 #----- Joytech "Neo S" USB PC gamepad
 965
 966 proc hidraw-descriptors/gamepad-neo-s {} {
 967     return xx
 968 }
 969
 970 #proc hidraw-readable/gamepad-neo-s {chan hidraw devid} {
 971 #    upvar #0 hidraw/$hidraw raw
 972 #    # In my tests with tcl8.3 and tcl8.5, "read chan numbytes"
 973 #    # on a nonblocking binary channel does only one read(2)
 974 #    # provided that read(2) returns less than requested
 975 #    while 1 {
 976 #       set msg [hbytes raw2h [read $chan 256]]
 977 #       if {![hbytes
 978 #       switch -glob [bhtes $msg {
 979 #           4a* { set want 8 }
 980 #           {} { set want 64 }
 981 #           * { error "unknown report number $raw(buf)" }
 982 #       }
 983 #       if {$want > $sofar} {
 984 #           set got [read $chan [expr {$want - $sofar}]]
 985 #
 986 #       }
 987 #
 988 #       set sofar [hbytes length $raw(buf)]
 989 #       if {!$sofar} {
 990 #           set got [read $chan 64]
 991 #       } else {
 992 #
 993 #       }
 994
 995
 996 #---------- input device evdev binding ----------
 997
 998 proc ib-evcmd-construct {devid target xargs} {
 999     upvar #0 input/$devid in
1000     if {[llength $target] > 1} {
1001         debug "ib $devid - multiple devices, not supported"
1002         return {}
1003     }
1004     manyset [lindex $target 0] ev sysfs
1005     if {[regexp { } $ev]} { error "event device `$ev' contains space" }
1006     return [concat \
1007             [list ./evdev-manip --redact] $xargs \
1008             [list --stdin-monitor \
1009                   --expect-sysfs /sys$sysfs/$ev/dev \
1010                   /dev/input/$ev]]
1011 }
1012
1013 proc bind-input-core {devid devkind devinfo concrete concargs} {
1014     global input_bindings
1015     lappend input_bindings [list $devkind $devid $devinfo $concrete $concargs]
1016 }
1017
1018 proc bind-input {bus vendor product version concrete args} {
1019     bind-input-core evdev:$bus:$vendor:$product:$version \
1020         evdev [list $bus $vendor $product $version] \
1021         $concrete $args
1022 }
1023
1024 proc bind-input-static {event sysfs concrete args} {
1025     bind-input-core [get-unique static] \
1026         static [list $event $sysfs] \
1027         $concrete $args
1028 }
1029
1030 proc bind-input-raw {devtype concrete args} {
1031     set descriptors [exec ./hidrawconv-$devtype -d]
1032     bind-input-core hidraw:[get-unique $devtype] \
1033         hidraw [list $devtype $descriptors] \
1034         $concrete $args
1035 }
1036
1037 proc widgets-input-bindings {} {
1038     global input_bindings
1039     foreach binding $input_bindings {
1040         manyset $binding devkind devid devinfo concrete concargs
1041         set cid [get-unique $concrete]
1042         upvar #0 input/$devid in
1043         set in(laststart) 0
1044         set in(concrete) $concrete
1045         eval [list ib-create/$concrete $devid $cid] $concargs
1046     }
1047     pack .inputs -side top -fill x
1048 }
1049
1050 # input/$devid becomes `in' via upvar:
1051 #  $in(chan)        channel open onto evdev-manip;
1052 #                   unset if none, or hidraw, or something
1053 #  $in(laststart)   last start time, [clock seconds]
1054 #                      at every event we set this the current time
1055 #                      but we insist on adding at least 5s
1056 #                      and if that would make it > current time +15s
1057 #                      we don't start
1058 #  $in(speedw)      optional, may be set by ib-create
1059
1060 # hidraw/hidrawN becomes `hr' via upvar:
1061 #  $raw(devid)      $devid (see above)
1062 #  $raw(chan)       channel open onto /dev/hidrawN
1063
1064 proc input-concrete-start-try {devid concrete} {
1065     global inputretryadd inputretrymax
1066     upvar #0 input/$devid in
1067     set now [clock seconds]
1068     set newlast [expr {$in(laststart) + $inputretryadd}]
1069     if {$newlast > $now + $inputretrymax} { return 0 }
1070     if {$newlast < $now} { set newlast $now }
1071     set in(laststart) $newlast
1072 }
1073
1074 proc input-bindings-list {devkind} {
1075     global input_bindings
1076     set o {}
1077     foreach b $input_bindings {
1078         manyset $b dk
1079         if {[string compare $dk $devkind]} continue
1080         lappend o $b
1081     }
1082     return $o
1083 }
1084
1085 proc scan-input-bindings {} {
1086     global errorInfo errorCode unmatched_notified old_hidraws
1087     global input_bindings scaninputinterval
1088     global input_rawbindings
1089
1090     after $scaninputinterval scan-input-bindings
1091
1092     # scan /proc/bus/input/devices for appropriate evdevs
1093     # results go in $target($devid)
1094     if {[catch {
1095         set f [open /proc/bus/input/devices]
1096     } emsg]} {
1097         if {[string match {POSIX ENOENT *} $errorCode]} return
1098         error $emsg $errorInfo $errorCode
1099     }
1100     while 1 {
1101         set r [gets $f l]
1102         if {$r <= 0} {
1103             if {[info exists v(devid)] &&
1104                 [info exists v(sysfs)] &&
1105                 [info exists v(event)]} {
1106                 lappend target(evdev:$v(devid)) [list $v(event) $v(sysfs)]
1107             }
1108             catch { unset v }
1109         }
1110         if {$r < 0} {
1111             break
1112         }
1113         append l "\n"
1114         if {[regexp \
1115  {^I: Bus=(\w+) Vendor=(\w+) Product=(\w+) Version=(\w+)\s} \
1116                  $l dummy bus vendor product version]} {
1117             set v(devid) $bus:$vendor:$product:$version
1118         } elseif {[regexp {^S: Sysfs=(\S+)\s} $l dummy sysfs]} {
1119             set v(sysfs) $sysfs
1120         } elseif {[regexp {^H: Handlers=(?:.*\s)?(event\d+)\s} $l dummy ev]} {
1121             set v(event) $ev
1122         } else {
1123             # ignored
1124         }
1125     }
1126     close $f
1127
1128     # add as-if-scanned entries for static bindings to target
1129     # also check to see if we want hidraw
1130     foreach binding $input_bindings {
1131         manyset $binding devkind devid devinfo concrete concargs
1132         switch -exact $devkind static { } default continue
1133         lappend target($devid) [list $event $sysfs]
1134     }
1135
1136     # scan /dev/hidraw*
1137     foreach binding [input-bindings-list hidraw] {
1138         manyset $binding devkind devid devinfo concrete concargs
1139         switch -exact $devkind hidraw { } default continue
1140         manyset $devinfo devtype descriptors
1141         set rawmap($descriptors) [list $devid $devtype $concrete]
1142     }
1143     if {[array exists rawmap]} {
1144         set new_hidraws [lsort [glob -nocomplain -directory /dev hidraw*]]
1145         foreach hidraw $new_hidraws {
1146             upvar #0 hidraw/$hidraw raw
1147             if {[info exists raw(chan)]} {
1148                 set found($raw(devid)) 1
1149                 continue
1150             }
1151             if {[lsearch -exact $old_hidraws $hidraw] >= 0} continue
1152             if {[catch {
1153                 set chan [open $hidraw r+]
1154                 set descriptors [exec ./hidraw-ioctl -d <@ $chan]
1155                 if {![info exists rawmap($descriptors)]} {
1156                     set m [exec ./hidraw-ioctl -i <@ $chan]
1157                     error "unknown descriptors (unmatched device) $hidraw $m >$descriptors<"
1158                 }
1159             } emsg]} {
1160                 upvar #0 hidraw_notified($hidraw) notified
1161                 if {![info exists notified] ||
1162                      [string compare $notified $emsg]} {
1163                     debug "ir $hidraw $emsg"
1164                     set notified $emsg
1165                 }
1166                 catch { close $chan }
1167                 catch { unset chan }
1168                 continue
1169             }
1170             manyset $rawmap($descriptors) devid devtype concrete
1171             set found($devid) 1
1172             if {![input-concrete-start-try $devid $concrete]} {
1173                 catch { close $chan }
1174                 continue
1175             }
1176             set raw(devid) $devid
1177             set cmdl [list ./hidrawconv-$devtype -e <@ $chan 2>@ stderr]
1178             set evch [open |$cmdl r]
1179             set raw(chan) $evch
1180             fconfigure $evch -blocking 0 -buffering line
1181             fileevent $evch readable \
1182                 [list catch-for-input-binding hidraw $hidraw \
1183                      [list readable input-binding-raw $evch $hidraw $devid]]
1184             input-binding-present $devid 1 "hidraw $hidraw"
1185         }
1186         set old_hidraws $new_hidraws
1187     }
1188
1189     # try to start the input binding for all the unstarted found targets
1190     foreach devid [array names target] {
1191         upvar #0 input/$devid in
1192         if {![info exists in(concrete)]} {
1193             if {![info exists unmatched_notified($devid)]} {
1194                 debug "ib $devid unmatched, ignored"
1195                 set unmatched_notified($devid) 1
1196             }
1197             continue
1198         }
1199         set found($devid) 1
1200         if {[info exists in(chan)]} continue
1201         if {![input-concrete-start-try $devid $concrete]} continue
1202
1203         set cmdl [ib-evcmd/$in(concrete) $devid $target($devid)]
1204         if {![llength $cmdl]} {
1205             unset target($devid)
1206             continue
1207         }
1208         lappend cmdl 2>@ stderr
1209         catch-for-input-binding evdev $devid {
1210             debug "ib $devid running $cmdl"
1211             set in(chan) [open |$cmdl r+]
1212             fconfigure $in(chan) -blocking 0 -buffering line
1213             fileevent $in(chan) readable \
1214                 [list catch-for-input-binding evdev $devid \
1215                     [list readable input-binding $in(chan) $devid]]
1216         }
1217     }
1218
1219     # anything not found, not present
1220     foreach binding $input_bindings {
1221         manyset $binding devkind devid devinfo concrete concargs
1222         switch -exact $devkind evdev - raw { } default continue
1223         upvar #0 input/$devid in
1224         if {![info exists in(concrete)]} continue
1225         if {[info exists found($devid)]} continue
1226         input-binding-present $devid 0 absent
1227     }
1228 }
1229
1230 proc input-binding-present {devid yes why} {
1231     upvar #0 input/$devid in
1232     if {[info exists in(speedw)]} {
1233         speedw-setstate $in(speedw) [lindex {disabled normal} $yes]
1234     }
1235     set call "ib-[lindex {absent present} $yes]/$in(concrete)"
1236     if {![catch { info args $call }]} {
1237         $call $devid $why
1238     }
1239 }
1240
1241 proc input-binding-eof {chan devid} {
1242     upvar #0 input/$devid in
1243     input-binding-eof-core $in(chan) "evdev-manip exited"
1244 }
1245
1246 proc input-binding-eof-core {chan msg} {
1247     fconfigure $chan -blocking 1
1248     close $chan
1249     error $msg {} {CHILDSTATUS ? 0}
1250 }
1251
1252 proc input-binding-raw-eof {chan hidraw devid} {
1253     upvar #0 hidraw/$hidraw raw
1254     input-binding-eof-core $raw(chan) "hidrawconv-* exited"
1255 }
1256
1257 proc input-binding-inputline {chan l devid} {
1258     upvar #0 input/$devid in
1259     if {[input-binding-inputline-core-ib $devid $l]} return
1260     regsub {^[^ ]+ } $l {} lr
1261     switch -glob -- $lr {
1262         {opened *} {
1263             debug "ib $devid start << $l"
1264             input-binding-present $devid 1 "evdev open"
1265         }
1266         {[-0-9]*} {
1267             manyset [split $lr] value kindl kindr codel coder
1268             input-binding-inputline-core-ev $devid \
1269                 ${kindl}_${kindr}/${codel}_${coder} $value $l
1270         }
1271         * {
1272             debug "ib $devid ignored << $l"
1273         }
1274     }
1275 }
1276
1277 proc input-binding-inputline-core-ib {devid l} {
1278     # give the input binding first dibs
1279     upvar #0 input/$devid in
1280     if {[catch { info args ib-inputline/$in(concrete) }]} { return 0 }
1281     return [ib-inputline/$in(concrete) $devid $l]
1282 }
1283
1284 proc input-binding-inputline-core-ev {devid kindcode value l} {
1285     global showunbound
1286     upvar #0 input/$devid in
1287     set proc ib-ev/$in(concrete)/$kindcode
1288     if {[catch { info args $proc }]} {
1289         if {$showunbound} {
1290             debug "ib $devid unbound $proc << $l"
1291         }
1292         return
1293     }
1294     $proc $devid $value
1295 }
1296
1297 proc input-binding-raw-inputline {chan l hidraw devid} {
1298     upvar #0 hidraw/$hidraw raw
1299     if {[input-binding-inputline-core-ib $devid $l]} return
1300     manyset [split $l] kind code value
1301     input-binding-inputline-core-ev $devid $kind/$code $value $l
1302 }
1303
1304 proc catch-for-input-binding {devkind ident body} {
1305     global errorInfo errorCode
1306     set r [catch { uplevel 1 $body } rv]
1307     if {$r!=1} { return -code $r $rv }
1308     switch -glob $errorCode {
1309         {CHILDSTATUS *} { set m "exited with status [lindex $errorCode 2]" }
1310         {CHILDKILLED *} { set m "killed by signal [lindex $errorCode 3]" }
1311         {POSIX *} { set m "communication error: [lindex $errorCode 1]" }
1312         * { error $rv $errorInfo $errorCode }
1313     }
1314     debug "ib $devkind $ident died $m"
1315     input-binding-destroy/$devkind $ident $m
1316 }
1317
1318 proc input-binding-destroy/evdev {devid m} {
1319     upvar #0 input/$devid in
1320     catch { close $in(chan) }
1321     catch { unset in(chan) }
1322     input-binding-present $devid 0 "died $m"
1323 }
1324
1325 proc input-binding-destroy/hidraw {hidraw m} {
1326     upvar #0 hidraw/$hidraw raw
1327     catch { close $raw(chan) }
1328     catch { unset raw(chan) }
1329     input-binding-present $raw(devid) 0 "died $m"
1330 }
1331
1332 proc engage-input-bindings {} {
1333     scan-input-bindings
1334 }
1335
1336 #---------- plan background (gui-plan subprocess) ----------
1337
1338 proc gui-pipe-readable {args} {
1339     global gui_pipe
1340     while {[gets $gui_pipe l] >= 0} {
1341         debug "<gui-plan $l"
1342     }
1343     if {[eof $gui_pipe]} {
1344         close $gui_pipe
1345         error "gui-plan crashed"
1346     }
1347 }
1348
1349 #---------- train set events of general interest, and setup ----------
1350
1351 proc train-event-eof {args} {
1352     error "lost connection to train set"
1353 }
1354
1355 register-event ?stastate {ctxch state} {^(.)stastate (\w+|\-) } {
1356     global ctrain trains stastate
1357     set stastate $state
1358     report-problem "stastate: $state"
1359     if {[string compare $ctxch |]} speedws-stastate-hook
1360 }
1361
1362 register-event ?resolution {message} \
1363         {^.resolution (\S+ .*)$} {
1364     if {[string match "problems *" $message]} return
1365     report-problem "resolution: $message"
1366 }
1367
1368 register-event ?warning {message} {^.warning (\S+ .*)$} {
1369     report-problem "warning: $message"
1370 }
1371
1372 register-event {} {} {^=connected } {
1373     global pages gui_pipe server port event_selections
1374
1375     scmd replayed {} "select-replay [concat $event_selections]"
1376
1377     foreach page $pages {
1378         set w [pagew $page]
1379         tkwait visibility $w.picture
1380
1381         set cmdl [list ./gui-plan-$page [winfo id $w.picture] @$server,$port]
1382         lappend cmdl 2>@ stderr
1383         set gui_pipe [open |$cmdl r]
1384
1385         puts stderr "running $cmdl"
1386         fconfigure $gui_pipe -blocking no
1387         fileevent $gui_pipe readable gui-pipe-readable
1388     }
1389 }
1390 proc replayed-err {m args} { error "replay failed: $m" }
1391 proc replayed-ok {m args} {
1392     speedws-stastate-hook
1393 }
1394
1395 register-event {} {} {^=failed } { error "multiplexer failed: $l" }
1396 register-event {} {} {^=denied } { error "multiplexer denied us: $l" }
1397 register-event {} {} {^\+nack } { error "multiplexer does not understand" }
1398
1399 #---------- main program ----------
1400
1401 append event_dispatch_body {
1402     debug "ignored $l"
1403 }
1404 proc train-event-inputline {sconn l} $event_dispatch_body
1405 proc register-event {args} { error "too late!" }
1406
1407 proc engage-server {} {
1408     global server port sconn
1409
1410     set sconn [socket $server $port]
1411     fconfig-trainproto $sconn
1412     fileevent $sconn readable {readable train-event $sconn}
1413 }
1414
1415 proc main {} {
1416     global pages cpage configfile input_bindings old_hidraws
1417     setting server railway {[[0-9a-z:].*}
1418     setting geometry {} {[-+]\d+[-+]\d+}
1419     setting posdeviation 5 {\d+}
1420     setting movfeatcommand {movfeat+} {(?:!movfeat|movfeat\+?\+?)}
1421     setting problemdisplayms 1000 {\d+}
1422     setting inputretryadd 5 {\d+}
1423     setting inputretrymax 15 {\d+}
1424     setting scaninputinterval 500 {\d+}
1425     setting showunbound 0 {[01]}
1426
1427     set hostname [lindex [split [info hostname] .] 0]
1428     setting configfile gui-$hostname.config {.+}
1429     parse-argv {}
1430
1431     frame .inputs
1432     if {![info exists input_bindings]} { set input_bindings {} }
1433     set old_hidraws {}
1434
1435     uplevel #0 source gui-layout.config
1436     uplevel #0 source $configfile
1437     foreach cpage $pages {
1438         layout-data
1439         widgets-dgram
1440     }
1441     unset cpage
1442     widgets-movpos
1443     widgets-input-bindings
1444     widget-problem-report
1445     engage-server
1446     engage-input-bindings
1447     start_commandloop
1448 }
1449
1450 main