hostside/gui

   1 #!/usr/bin/wishx
   2
   3 load chiark_tcl_hbytes-1.so
   4
   5 #---------- general utilities ----------
   6
   7 set tk_strictMotif 1
   8
   9 tk_setPalette background black foreground white
  10
  11 source lib.tcl
  12
  13 set default_speedstep_list {0 1 10 20 35 50 65 80 95 110 126}
  14
  15 set picturepadx 10
  16 set picturepady 10
  17
  18 proc pagew {page} { return ".picture-$page" }
  19 proc debug {m} { puts $m }
  20
  21 proc sconn {m} {
  22     global sconn
  23     debug "=> $m"
  24     puts $sconn $m
  25 }
  26
  27 proc widgets-dgram {} {
  28     global cpage geometry picturepadx picturepady
  29     if {[string length $geometry]} { wm geometry . $geometry }
  30     set sizes [exec ./gui-plan-$cpage --sizes]
  31     set w [pagew $cpage]
  32     frame $w
  33     frame $w.picture -background {} \
  34             -width [lindex $sizes 0] \
  35             -height [lindex $sizes 1]
  36     pack $w.picture -padx $picturepadx -pady $picturepady
  37     pack $w
  38 }
  39
  40 proc widgets-fullscreen-nowm {} {
  41     pack propagate . false
  42     foreach wh {width height} {
  43         . configure -$wh [winfo screen$wh .]
  44     }
  45 }
  46
  47 proc bgerror {emsg} {
  48     global errorCode errorInfo
  49     catch {
  50         puts stderr "UNEXPECTED BACKGROUND ERROR\n"
  51         puts stderr "$errorCode\n$errorInfo\n$emsg"
  52     }
  53     exit 16
  54 }
  55
  56 #---------- train set event registraton ----------
  57
  58 set event_dispatch_body {
  59     append l " "
  60 }
  61 set event_selections {}
  62
  63 proc register-event {selections args re body} {
  64     global event_dispatch_body event_selections
  65
  66     eval lappend event_selections $selections
  67
  68     foreach selection $selections {
  69         if {[regexp {^\w} $selection]} {
  70             error "selection $selection lacks context char"
  71         }
  72     }
  73     if {[regexp {^\^\w} $re]} {
  74         error "re $re never matches context char"
  75     }
  76
  77     regsub -all {\W+} $re - proc
  78     set proc "event/$proc/[join $args -]"
  79     set suffix {}
  80     set number 0
  81     while {![catch { info args $proc$suffix }]} { set suffix [incr number] }
  82     append proc $suffix
  83
  84     proc $proc [concat l $args] $body
  85     set al ""
  86     foreach a $args { append al " \$$a" }
  87
  88     append event_dispatch_body \
  89             "    if {\[regexp [list $re] \$l dummy $args]} {\n" \
  90             "        debug \"$proc$al\"\n" \
  91             "        eval [list $proc] \[list \$l$al]\n" \
  92             "        return\n" \
  93             "    }\n"
  94 }
  95
  96 #---------- handling of commands we issue ----------
  97
  98 proc scmd {onresult ctrlr commandstr args} {
  99     # later, calls
 100     #   eval [list $onresult-ok|nak|error $ackornakmessage] $args
 101     global commands_queued
 102     sconn $commandstr
 103     lappend commands_queued [list $ctrlr $onresult $args]
 104 }
 105
 106 proc scmd_result {oknakerr message reporterrmsg} {
 107     global commands_queued
 108     manyset [lindex $commands_queued 0] ctrlr onresult args
 109     set commands_queued [lrange $commands_queued 1 end]
 110     if {[string length $reporterrmsg]} {
 111         report-problem "$ctrlr: $reporterrmsg"
 112     }
 113     set proc "$onresult-$oknakerr"
 114     if {![string compare $oknakerr nak] && [catch { info args $proc }]} {
 115         set proc "$onresult-err"
 116     }
 117     eval [list $proc $message] $args
 118 }
 119
 120 register-event {} {} {^\+ack \S+ ok } { scmd_result ok $l "" }
 121 register-event {} {train segment error} \
 122         {^\+ack \S+ SignallingPredictedProblem (\S+) (\S+) \: (.*) $} {
 123     set m $train
 124     if {[string compare - $segment]} { append m " @$segment" }
 125     append m ": $error"
 126     scmd_result err $l $m
 127 }
 128 register-event {} {} {^\+ack } { scmd_result err $l $l }
 129 register-event {} {} {^\+nack \S+ } { scmd_result nak $l $l }
 130
 131 proc routinecmd-nak {m args} { error "got nak to routine command: $m" }
 132 proc routinecmd-err {m args} { }
 133 proc routinecmd-ok {m args} { }
 134
 135 proc mustsucceed-err {m args} { error "unexpected error: $m" }
 136 proc mustsucceed-ok {m args} { }
 137
 138 proc report-problem-report-stderr {m} { puts stderr "*** $m" }
 139 set report_problem_report report-problem-report-stderr
 140
 141 proc report-problem {message} {
 142     global report_problem_report
 143     eval $report_problem_report [list $message]
 144 }
 145
 146 proc widget-problem-report {} {
 147     global problem_reports report_problem_report
 148     set problem_reports "\n\n\n\n\n"
 149     label .problem-report -anchor w -justify left -takefocus 0 \
 150             -border 2 -relief sunken -width 80 -textvariable problem_reports
 151     pack .problem-report -side top
 152     set report_problem_report report-problem-report-widget
 153 }
 154
 155 proc report-problem-report-widget {m} {
 156     global problem_reports
 157     set problem_reports [join [concat \
 158                 [lrange [split $problem_reports "\n"] 1 end] \
 159                 [list $m] \
 160             ] "\n"]
 161 }
 162
 163 #---------- movpos (overlay buttons, keybindings, execution) ----------
 164
 165 proc movpos-button-gvars {mid} {
 166     upvar #0 mp_details($mid) details
 167     if {![info exists details]} { return 0 }
 168     uplevel 1 [list manyset $details cpage key seg feat poslocs]
 169     uplevel 1 { set w [pagew $cpage].movpos-$mid }
 170     upvar #0 mp_state($mid) state
 171     uplevel 1 [list manyset $state posn]
 172     return 1
 173 }
 174
 175 proc movpos-button-sstate {mid posn} {
 176     upvar #0 mp_state($mid) state
 177     set state $posn
 178     movpos-button-setdisplay $mid
 179 }
 180
 181 proc movpos-all-unknown {} {
 182     global mp_details
 183     foreach mid [array names mp_details] {
 184         movpos-button-sstate $mid ?
 185     }
 186 }
 187
 188 proc widgets-movpos {} {
 189     global mp_details
 190     foreach mid [array names mp_details] {
 191         upvar #0 mp_state($mid) state
 192         set state {?}
 193         movpos-button-gvars $mid
 194         set w [pagew $cpage].movpos-$mid
 195         button $w -text $key -padx 0 -pady 0 -borderwidth 0 \
 196                 -command [list movpos-invoked $mid "plan $cpage"]
 197         movpos-button-setdisplay $mid
 198     }
 199 }
 200
 201 proc movpos-button-setdisplay {mid} {
 202     # we want to display as much of these as possible:
 203     #   position known ?   (actual position is done by button location)
 204     #   moving or stable
 205     #   whether a train's plan includes a different position
 206     #   whether autopoint
 207     movpos-button-gvars $mid
 208     switch -exact $posn {
 209         ?       { set poslocn 2;     set fg black; set bg white }
 210         default { set poslocn $posn; set fg white; set bg black }
 211     }
 212     $w configure -background $bg -foreground $fg \
 213             -activebackground $bg -activeforeground $fg
 214     manyset [lindex $poslocs $poslocn] x y
 215     place $w -anchor center -x $x -y $y
 216 }
 217
 218 proc movpos-invoked {mid ctrlr} {
 219     global movfeatcommand
 220     movpos-button-gvars $mid
 221     switch -exact $posn {
 222         0 { set new_posn 1 }
 223         default { set new_posn 0 }
 224     }
 225     scmd routinecmd $ctrlr "$movfeatcommand $seg $feat $new_posn"
 226 }
 227
 228 register-event ?movpos_*_feat {seg feat posn_new} \
 229         {^.movpos (\w+) feat (\w+) ([01]|\?) } {
 230     set mid $seg/$feat
 231     if {![movpos-button-gvars $mid]} return
 232     set posn $posn_new
 233     movpos-button-sstate $mid $posn
 234 }
 235
 236 proc movpos-bindkey-1 {cpage key seg feat adj0x adj0y adj1x adj1y} {
 237     global posdeviation picturepadx picturepady
 238     manyset [subseg-end-get-centroid $cpage $seg $feat {}] mx my
 239     set mid $seg/$feat
 240     foreach posn {0 1} {
 241         manyset [subseg-end-get-centroid $cpage $seg $feat $posn] x y
 242         set dx [expr {$x-$mx}]; set dy [expr {$y-$my}]
 243         set d [expr {sqrt($dx*$dx + $dy*$dy)}]
 244         set mul [expr {$posdeviation / ($d + 1e-6)}]
 245         set x [expr {$mx + $mul*$dx + $picturepadx + [set adj${posn}x]}]
 246         set y [expr {$my + $mul*$dy + $picturepady + [set adj${posn}y]}]
 247         lappend poslocs [list $x $y]
 248     }
 249     lappend poslocs [list [expr {$mx + $picturepadx + ($adj0x+$adj1x)*0.5}] \
 250                           [expr {$my + $picturepady + ($adj0y+$adj1y)*0.5}]]
 251     upvar #0 mp_details($mid) details
 252     set details [list $cpage $key $seg $feat $poslocs]
 253
 254     bind . <Key-[string tolower $key]> [list movpos-invoked $mid "keyboard"]
 255 }
 256
 257 #---------- computation of movpos button locations
 258
 259 proc layout-subseg-featmap {seg concfeatpos args} {
 260     global subsegfeatmap
 261     set subsegfeatmap($concfeatpos) $args
 262 }
 263
 264 proc layout-subseg-end {seg feat posn x y} {
 265     global cpage
 266     upvar #0 subsegfeatmap($feat$posn) mapped
 267     if {[info exists mapped]} {
 268         foreach {feat posn} $mapped {
 269             layout-subseg-end $seg $feat $posn $x $y
 270         }
 271         return
 272     }
 273     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 274     if {![info exists sse]} { set sse {{} {}} }
 275     manyset $sse lx ly
 276     lappend lx $x
 277     lappend ly $y
 278     set sse [list $lx $ly]
 279     if {[string length $posn]} { layout-subseg-end $seg $feat {} $x $y }
 280 }
 281
 282 proc subseg-end-get-centroid {cpage seg feat posn} {
 283     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 284     if {![info exists sse]} {
 285         puts "skipping binding of unknown $seg/$feat$posn"
 286         return -code return
 287     }
 288     manyset $sse lx ly
 289     set sx 0; set sy 0; set n [llength $lx]
 290     foreach x $lx y $ly { addexpr sx {$x}; addexpr sy {$y} }
 291     return [list [expr {$sx * 1.0 / $n}] [expr {$sy * 1.0 / $n}]]
 292 }
 293
 294 proc layout-data {} {
 295     global cpage
 296     upvar #0 ld_sse/$cpage sse
 297     catch { unset sse }
 298     source ../layout/ours.dgram.segmap-info
 299     source ../layout/ours.dgram-$cpage.overlay-info
 300
 301     upvar #0 movpos_bindings($cpage) bindings
 302     if {![info exists bindings]} {
 303         puts "no movpos bindings for $cpage"
 304         return
 305     }
 306     foreach binding $bindings {
 307         if {[regexp \
 308    {^([A-Z])([-+]\d*)?([-+]\d*)?([-+]\d*)?([-+]\d*)?\=(\w+)/([A-Z]+)$} \
 309                  $binding dummy key adj0x adj0y adj1x adj1y seg feat]} {
 310             if {![string length $adj1x]} { set adj1x $adj0x; set adj1y $adj0y }
 311             movpos-bindkey-1 $cpage $key $seg $feat \
 312                 $adj0x.0 $adj0y.0 $adj1x.0 $adj1y.0
 313         } elseif {[regexp {^[A-Z]$} $binding] || [regexp {~} $binding]} {
 314         } else {
 315             error "incomprehensible binding $binding on page $cpage"
 316         }
 317     }
 318 }
 319
 320 #---------- speed ----------
 321
 322 # variables:
 323 #   $train_commanded($train)    $speed_step
 324 #   $train_direction($train)    forwards|backwards or unset
 325 #   $speedws                    [list $w ...]
 326 #
 327 # speed/${w}(...) aka s(...):
 328 #   $s(ctrlr)                   controller
 329 #   $s(train)                   train selected, or something not \w+
 330 #   $s(optionmenu)              optionmenu widget name
 331 #   $s(kind)                    abs or rel
 332 #   $s(commanding)              step of command we have scmd'd, or unset
 333 #   $s(queued)                  step of command we would like to queue
 334 #                                or unset if n/a
 335 #   $s(inhibit)   0   all is well, can command any speed
 336 #                 1   train newly selected, only rel can command higher speed
 337 #                 2   can only command same or lower speed
 338 #
 339 # We don't worry too much about races: in particular, we don't mind
 340 # racing with other things trying to command the speed, and losing
 341 # the odd increment/decrement.  But since we thread the requested
 342 # speed via realtime, we do queue up our own increments/decrements
 343 # while we're executing a speed command, to avoid loss of steps during
 344 # quick motions.
 345
 346 # Interfaces for concrete controllers:
 347 #   speedw-new $w $ctrlr
 348 #   speedw-setstate $w disabled|normal        controller appears/disappears
 349 #   speedw-userinput-abs $w $step
 350 #   speedw-userinput-rel $w $stepmap
 351 # where
 352 #   eval {stepmap} [list $oldstep] => $newstep
 353
 354 set speedws {}
 355
 356 proc speedws-forall {command args} {
 357     global speedws
 358     foreach w $speedws { eval [list $command $w] $args }
 359 }
 360
 361 proc speedws-fortrain {train command args} {
 362     global speedws
 363     foreach w $speedws {
 364         upvar #0 speed/$w s
 365         if {[string compare $s(train) $train]} continue
 366         eval [list $command $w] $args
 367     }
 368 }
 369
 370 proc speedw-new {w ctrlr} {
 371     upvar #0 speed/$w s
 372     global speedws
 373
 374     lappend speedws $w
 375     set s(ctrlr) $ctrlr
 376     set s(inhibit) 0
 377
 378     frame $w -relief sunken -border 2
 379     label $w.ctrlr -state disabled -text $s(ctrlr)
 380     set s(optionmenu) [tk_optionMenu $w.train speed/${w}(train) {}]
 381     $w.train configure -textvariable {} -width 15
 382     label $w.speed -state disabled -width 4 \
 383             -font -*-courier-bold-r-*-*-20-*-*-*-*-*-*-* \
 384             -background black -foreground white
 385     pack $w.ctrlr $w.train $w.speed -side left
 386
 387     speedw-notrains $w "(starting)"
 388 }
 389 proc speedw-notrains {w whystr} {
 390     $w.train configure -state disabled
 391     speedw-train-noneselected $w $whystr
 392 }
 393 proc speedw-train-noneselected {w whystr} {
 394     upvar #0 speed/$w s
 395     tractbrake-detach $s(train)
 396     set s(train) {}
 397     $w.train configure -text $whystr
 398     $w.speed configure -text -
 399     speedw-inhibit $w
 400 }
 401
 402 proc speedw-inhibit {w} {
 403     upvar #0 speed/$w s
 404     set s(inhibit) 2
 405     $w.speed configure -foreground red
 406 }
 407 proc speedw-uninhibit {w max} {
 408     upvar #0 speed/$w s
 409     set r $s(inhibit)
 410     if {$r>$max} { return -1 }
 411     set s(inhibit) 0
 412     $w.speed configure -foreground white
 413     return $r
 414 }
 415
 416 proc speedw-setstate {w disnorm} {
 417     $w.ctrlr configure -state $disnorm
 418     $w.speed configure -state $disnorm
 419 }
 420
 421 proc speedw-train-selectnext {w} {
 422     upvar #0 speed/$w s
 423     set max [$s(optionmenu) index end]
 424     for {set ix 0} {$ix <= $max} {incr ix} {
 425         set v [$s(optionmenu) entrycget $ix -value]
 426         if {![string compare $v $s(train)]} break
 427     }
 428     set activate [expr {($ix+1) % ($max+1)}]
 429     $s(optionmenu) invoke $activate
 430 }
 431
 432 proc speedw-train-selected {w t} {
 433     upvar #0 speed/$w s
 434     if {![string compare $t $s(train)]} return
 435     tractbrake-detach $s(train)
 436     $w.train configure -text $t
 437     set s(inhibit) 1
 438     set s(train) $t
 439     $w.speed configure -foreground white
 440     speedw-redisplay-speed $w
 441 }
 442
 443 proc speedw-redisplay-speed {w} {
 444     upvar #0 speed/$w s
 445     upvar #0 train_commanded($s(train)) gcommanded
 446     upvar #0 train_direction($s(train)) gdirection
 447     set t $gcommanded
 448     if {[info exists gdirection]} {
 449         switch -exact $gdirection {
 450             forwards { set t "$t>" }
 451             backwards { set t "<$t" }
 452         }
 453     }
 454     $w.speed configure -text $t
 455 }
 456
 457 proc speedw-train-direction {w dirchange} {
 458     upvar #0 speed/$w s
 459     if {![string length $s(train)]} return
 460     scmd routinecmd $s(ctrlr) "direction $s(train) $dirchange"
 461 }
 462
 463 proc speedw-trains-available {w l} {
 464     upvar #0 speed/$w s
 465     if {![llength $l]} { speedw-train-noneselected $w "(no trains)"; return }
 466     $s(optionmenu) delete 0 end
 467     $s(optionmenu) add radiobutton -label "(none)" -value {} \
 468             -command [list speedw-train-noneselected $w "(no train selected)"]
 469     set l [lsort $l]
 470     foreach t $l {
 471         $s(optionmenu) add radiobutton -label $t -value $t \
 472                 -command [list speedw-train-selected $w $t]
 473     }
 474     $w.train configure -state normal
 475     if {[llength $l]==1} {
 476         $s(optionmenu) invoke 1
 477     } elseif {[set ix [lsearch -exact $l $s(train)]] >= 0} {
 478         $s(optionmenu) invoke [expr {$ix+1}]
 479     } elseif {![string length $s(train)]} {
 480         $s(optionmenu) invoke 0
 481     } else {
 482         $w.train configure -text "$s(train) (not present)"
 483     }
 484 }
 485
 486 proc speedw-userinput-abs {w speed} {
 487     upvar #0 speed/$w s
 488     if {![string length $s(train)]} return
 489     tractbrake-detach $s(train)
 490     if {!$speed} { speedw-uninhibit $w 2 }
 491     speedw-do-abs $w $speed
 492 }
 493
 494 proc speedw-userinput-tractbrake {w tract brake} {
 495     upvar #0 speed/$w s
 496     if {![string length $s(train)]} return
 497     if {$s(inhibit)} return
 498     tractbrake-userinput $s(train) $tract $brake $w
 499 }
 500
 501 proc speedw-do-abs {w speed} {
 502     upvar #0 speed/$w s
 503     set s(queued) $speed
 504     speedw-check $w
 505 }
 506
 507 proc speedw-check {w} {
 508     upvar #0 speed/$w s
 509     if {![string length $s(train)]} return
 510     upvar #0 train_commanded($s(train)) gcommanded
 511     upvar #0 train_direction($s(train)) gdirection
 512     if {[info exists s(commanding)]} return
 513     if {![info exists s(queued)]} return
 514     set newspeed $s(queued)
 515     unset s(queued)
 516     if {$s(inhibit) && $newspeed > $gcommanded} return
 517     set s(commanding) $newspeed
 518     scmd speedw-commanded $s(ctrlr) "speed $s(train) $newspeed $gdirection" $w
 519 }
 520
 521 proc speedw-commanded-nak {m args} { error "got nak from speed: $m" }
 522 proc speedw-commanded-ok {m w} {
 523     upvar #0 speed/$w s
 524     unset s(commanding)
 525     speedw-check $w
 526 }
 527 proc speedw-commanded-err {m w} {
 528     upvar #0 speed/$w s
 529     unset s(commanding)
 530     speedw-inhibit $w
 531     speedw-check $w
 532 }
 533
 534 proc speedw-currentspeed {w} {
 535     upvar #0 speed/$w s
 536     upvar #0 train_commanded($s(train)) gcommanded
 537     if {[info exists s(queued)]} {
 538         return $s(queued)
 539     } elseif {[info exists s(commanding)]} {
 540         return $s(commanding)
 541     } else {
 542         return $gcommanded
 543     }
 544 }
 545
 546 proc speedw-userinput-rel {w stepmap} {
 547     upvar #0 speed/$w s
 548     if {![string length $s(train)]} return
 549     set oldspeed [speedw-currentspeed $w]
 550     set newspeed [eval $stepmap [list $oldspeed]]
 551     speedw-userinput-abs $w $newspeed
 552 }
 553
 554 proc speedw-userinput-rel-steps {w delta steplist} {
 555     if {$delta<0} {
 556         if {[speedw-uninhibit $w 2]>1} { incr delta 1 }
 557         if {!$delta} return
 558     } else {
 559         speedw-uninhibit $w 1
 560     }
 561     speedw-userinput-rel $w [list speedw-stepmap-fromlist $steplist $delta]
 562 }
 563
 564 proc speedw-userinput-tractbrake {w tract brake} {
 565     upvar #0 speed/$w s
 566     if {![string length $s(train)]} return
 567     speedw-uninhibit $w 1
 568     tractbrake-userinput $s(train) $tract $brake $w
 569 }
 570
 571 proc speedws-train-problem {train} {
 572     speedws-fortrain $train speedw-inhibit
 573 }
 574
 575 register-event ?train_*_at {train direction} \
 576         {^.train (\w+) at \S+ (forwards|backwards) } {
 577     upvar #0 train_direction($train) dirn
 578     set dirn $direction
 579     speedws-fortrain $train speedw-redisplay-speed
 580     tractbrake-ensure $train
 581 }
 582
 583 register-event ?train_*_speed_commanding {train speed} \
 584         {^.train (\w+) speed commanding (\d+) } {
 585     upvar #0 train_commanded($train) cmd
 586     set cmd $speed
 587     speedws-fortrain $train speedw-redisplay-speed
 588 }
 589
 590 proc speedws-stastate-hook {} {
 591     global train_direction stastate
 592     switch -exact -- $stastate {
 593         Run {
 594             set trains [array names train_direction]
 595             speedws-forall speedw-trains-available $trains
 596         }
 597         Resolving {
 598             movpos-all-unknown
 599         }
 600         Finalising {
 601             speedws-forall speedw-notrains "($stastate)"
 602         }
 603         default {
 604             catch { unset train_commanded }
 605             speedws-forall speedw-notrains "($stastate)"
 606         }
 607     }
 608 }
 609
 610 register-event &train_*_signalling-problem {train problem} \
 611         {^\&train (\w+) signalling-problem (.*) $} {
 612     global speedws
 613     regsub {^(\S+) (\S+) \: } $problem {\1 @\2: } problem
 614     report-problem "event: $problem"
 615     speedws-train-problem $train
 616 }
 617
 618 proc speedw-new-cooked {wunique desc} {
 619     set w .inputs.$wunique
 620     speedw-new $w $desc
 621     pack $w -side left -padx 10
 622     return $w
 623 }
 624
 625 proc speedw-stepmap-fromlist {speedlist offset oldspeed} {
 626     if {![llength $speedlist]} {
 627         unset speedlist
 628         upvar #0 default_speedstep_list speedlist
 629     }
 630     set ixabove 0
 631     foreach entry $speedlist {
 632         if {$entry==$oldspeed} { set ixbelow $ixabove; break }
 633         if {$entry>$oldspeed} break
 634         set ixbelow $ixabove
 635         incr ixabove
 636     }
 637     set ix [expr {($offset>0 ? $ixbelow : $ixabove) + $offset}]
 638     if {$ix<0} { return 0 }
 639     if {$ix>=[llength $speedlist]} { return [lindex $speedlist end] }
 640     return [lindex $speedlist $ix]
 641 }
 642
 643 #----- traction / brake (hidden behind speedw) ----------
 644
 645 proc tractbrake-queue-update {train} {
 646     upvar #0 tractbrake/$train tb
 647     set tb(queued) [after $tb(updms) \
 648                         [list tractbrake-update $train]]
 649 }
 650
 651 proc tractbrake-attach {train speedw} {
 652     # can safely be called when already attached
 653     upvar #0 tractbrake/$train tb
 654     upvar #0 speedcurve/$train sc
 655     set tb(speedw) $speedw
 656     if {[info exists tb(queued)]} return
 657     upvar #0 train_commanded($train) gcommanded
 658     setexpr tb(v) {[lindex $sc $gcommanded] / [lindex $sc 126]}
 659     tractbrake-queue-update $train
 660 }
 661 proc tractbrake-detach {train} {
 662     # can safely be called when already detached
 663     upvar #0 tractbrake/$train tb
 664     catch { after cancel $tb(queued) }
 665     catch { unset tb(queued) }
 666     tractbrake-reset $train
 667 }
 668 proc tractbrake-reset {train} {
 669     upvar #0 tractbrake/$train tb
 670     if {![info exists tb]} return
 671     set tb(A) 0
 672     set tb(B) 0
 673     set tb(a) 0
 674     set tb(b) 0
 675 }
 676
 677 proc tractbrake-update {train} {
 678     upvar #0 tractbrake/$train tb
 679     upvar #0 tractbrake-params/$train pa
 680     unset tb(queued)
 681     foreach AB {A B} ab {a b} lm {lambda mu} {
 682         addexpr tb($ab) { $tb(updfact_$lm) * ( $tb($AB) - $tb($ab) ) - 1e-5 }
 683     }
 684     addexpr tb(v) {
 685         + $tb(perupd_alpha) * $tb(a)
 686         - $tb(perupd_beta) * $tb(b)
 687         - $tb(perupd_omega) * $tb(v) * $tb(v)
 688         - $tb(perupd_phi)
 689     }
 690     set m "tractbrake $train"
 691     foreach v {A a B b v} { append m [format " %s=%6.4f" $v $tb($v)] }
 692     debug $m
 693     if {$tb(v) <= 0} {
 694         # stopped
 695         set tb(v) 0
 696         speedw-do-abs $tb(speedw) 0
 697         if {$tb(A) <= 0 && $tb(a) <= 0 &&
 698             $tb(B) <= 0 && $tb(b) <= 0} {
 699             # no throttle or brake, no need to requeue
 700             return
 701         }
 702     } else {
 703         if {$tb(v) > 1.0} { set tb(v) 1.0 }
 704         upvar #0 speedcurve/$train sc
 705         upvar #0 train_commanded($train) gcommanded
 706         set step $gcommanded
 707         setexpr targetvel {$tb(v) * [lindex $sc 126]}
 708         while 1 {
 709             set vel [lindex $sc $step]
 710             if {$vel > $targetvel && $step > 0} {
 711                 setexpr nextstep {$step - 1}
 712             } elseif {$vel < $targetvel && $step < 126} {
 713                 setexpr nextstep {$step + 1}
 714             } else {
 715                 break
 716             }
 717             set nextvel [lindex $sc $nextstep]
 718             if {abs($nextvel-$targetvel) >= abs($vel-$targetvel)} {
 719                 break
 720             }
 721             set step $nextstep
 722         }
 723         if {$step != $gcommanded} {
 724             speedw-do-abs $tb(speedw) $step
 725         }
 726     }
 727     tractbrake-queue-update $train
 728 }
 729
 730 proc tractbrake-userinput {train tract brake speedw} {
 731     upvar #0 tractbrake/$train tb
 732     if {![info exists tb]} {
 733         report-problem "event: no traction/brake parameters for $train"
 734         return
 735     }
 736     if {[string length $tract]} { set tb(A) $tract }
 737     if {[string length $brake]} { set tb(B) $brake }
 738     if {$tract || $brake} {
 739         tractbrake-attach $train $speedw
 740     }
 741 }
 742
 743 proc tractbrake-ensure {train} {
 744     upvar #0 speedcurve/$train sc
 745     if {[info exists sc]} return ;# try this only once
 746     set sc 0
 747
 748     if {[regexp {[^-+._0-9a-z]} $train]} { error "bad train $train ?" }
 749
 750     if {[catch { set f [open $train.speeds.record] } emsg]} {
 751         global errorCode errorInfo
 752         switch -glob $errorCode {POSIX ENOENT *} {
 753             report-problem "train $train: no traction/braking (no speed table)"
 754             return
 755         }
 756         error $emsg $errorInfo $errorCode
 757     }
 758     while {[llength $sc] <= 126} { lappend sc x }
 759     while {[gets $f l] >= 0} {
 760         if {![regexp {^train (\S+) step (\d+)=([0-9.]+)$} $l \
 761                   dummy tr step velocity]} continue
 762         if {[string compare $tr $train] || $step<=0 || $step>126} {
 763             error "bad velocity line $l ?" {} {TRACTBRAKE SKIP}
 764         }
 765         set sc [lreplace $sc $step $step $velocity]
 766     }
 767     close $f
 768     if {[lsearch -exact $sc x]>=0} {
 769         report-problem "train $train: no traction/braking\
 770             (incomplete speed table"
 771         return
 772     }
 773
 774     upvar #0 tractbrake/$train tb
 775     defset tb(deadzone) 0.2
 776     defset tb(updms)    20
 777     defset tb(lambda)   0.600  ;# time constant for adj throttle
 778     defset tb(mu)       0.300  ;# time constant for apply/release breaks
 779     defset tb(inv_alpha)   20  ;# time constant for accelerate to max
 780     defset tb(omegaphi)    50  ;# (air resistance) / (rolling res) at max spd
 781     defset tb(inv_beta)    10  ;# time constant for service brake (over-est'd)
 782     defset tb(overpower) 1.03  ;# factor by which we are overpowered for max spd
 783     foreach lm {lambda mu} {
 784         setexpr tb(updfact_$lm) { $tb(updms) * 0.001 / $tb($lm) }
 785     }
 786
 787     setexpr tb(alpha) { 1.0 / $tb(inv_alpha) }
 788     setexpr tb(beta) { 1.0 / $tb(inv_beta) }
 789     setexpr tb(phi) { $tb(alpha) / ($tb(omegaphi) + 1.0) / $tb(overpower) }
 790     setexpr tb(omega) { $tb(omegaphi) * $tb(phi) }
 791
 792     foreach p {alpha beta omega phi} {
 793         setexpr tb(perupd_$p) { $tb($p) * 0.001 * $tb(updms) }
 794     }
 795
 796     tractbrake-reset $train
 797 }
 798
 799 #---------- concrete input bindings ----------
 800
 801 proc ib-suppressions {args} {
 802     set l {}
 803     foreach supp $args {
 804         set l [concat $l --redaction $supp --suppress]
 805     }
 806     return $l
 807 }
 808
 809 proc ib-speedw-new {devid wunique desc} {
 810     upvar #0 input/$devid in
 811     set in(speedw) [speedw-new-cooked $wunique $desc]
 812 }
 813
 814 #----- wheelmouse
 815
 816 proc ib-ev/wheelmouse/EV_REL/REL_WHEEL {devid value} {
 817     upvar #0 input/$devid in
 818     speedw-userinput-rel-steps $in(speedw) [expr {-$value}] {}
 819 }
 820
 821 proc ib-selectnext {devid value} {
 822     if {$value!=1} return
 823     upvar #0 input/$devid in
 824     speedw-train-selectnext $in(speedw)
 825 }
 826 proc ib-changedirection {devid value} {
 827     upvar #0 input/$devid in
 828     if {!$value} return
 829     speedw-train-direction $in(speedw) change
 830 }
 831
 832 proc ib-ev/wheelmouse/EV_KEY/BTN_LEFT {devid value} {
 833     ib-selectnext $devid $value
 834 }
 835 proc ib-ev/wheelmouse/EV_KEY/BTN_RIGHT {devid value} {
 836     ib-changedirection $devid $value
 837 }
 838
 839 proc ib-create/wheelmouse {devid wunique desc} {
 840     ib-speedw-new $devid $wunique $desc
 841 }
 842
 843 proc ib-wheelmouse-redactions {} {
 844     return [ib-suppressions  \
 845             {EV REL REL X} \
 846             {EV REL REL Y}]
 847 }
 848
 849 proc ib-evcmd/wheelmouse {devid target} {
 850     return [ib-evcmd-construct $devid $target [concat \
 851             [list --grab] [ib-wheelmouse-redactions]]]
 852 }
 853
 854 #----- gamepad
 855
 856 proc ib-create/gamepad {devid wunique desc} {
 857     ib-speedw-new $devid $wunique $desc
 858     upvar #0 input/$devid in
 859     set in(tractbrake_deadzone) 0.2
 860 }
 861
 862 proc ib-ev/tractbrake/init {devid} {
 863     upvar #0 input-params/$devid pa
 864 }
 865
 866 proc ib-ev/gamepad/EV_ABS/ABS_THROTTLE {devid value} {
 867     upvar #0 input/$devid in
 868     if {abs($value) < $in(tractbrake_deadzone)} {
 869         speedw-userinput-tractbrake $in(speedw) 0 0
 870         return
 871     }
 872     if {$value > 0} {
 873         speedw-userinput-tractbrake $in(speedw) $value 0
 874     } {
 875         speedw-userinput-tractbrake $in(speedw) 0 [expr {-$value}]
 876     }
 877 }
 878
 879 #----- ebuyer wireless keyboard
 880
 881 proc ib-create/ebwikeb {devid wunique} {
 882     upvar #0 input/$devid in
 883     set in(desc) "main keyboard"
 884     ib-create/wheelmouse $devid $wunique $in(desc)
 885     set in(modifiers) 0
 886 }
 887
 888 proc ib-evcmd/ebwikeb {devid target} {
 889     return [concat \
 890             [list ./evdev-manip-ebwikeb --redact --stdin-monitor] \
 891             [ib-wheelmouse-redactions] \
 892             [ib-suppressions \
 893                 {0x01 02} \
 894                 {EV MSC} \
 895                 {0x0c 01} \
 896                 {0xffbc 88 0xffbc 00}]]
 897 }
 898
 899 proc ib-ev/ebwikeb/EV_REL/REL_WHEEL {devid value} {
 900     ib-ev/wheelmouse/EV_REL/REL_WHEEL $devid $value
 901 }
 902
 903 proc ib-ebwikeb-modifier {devid value bitval} {
 904     upvar #0 input/${devid}(modifiers) mod
 905     if {$value} {
 906         set mod [expr {$mod | $bitval}]
 907     } else {
 908         set mod [expr {$mod & ~$bitval}]
 909     }
 910 }
 911 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTSHIFT {devid value} {
 912     ib-ebwikeb-modifier $devid $value 0x0001
 913 }
 914 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTSHIFT {devid value} {
 915     ib-ebwikeb-modifier $devid $value 0x0002
 916 }
 917 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTCTRL {devid value} {
 918     ib-ebwikeb-modifier $devid $value 0x0100
 919 }
 920 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTCTRL {devid value} {
 921     ib-ebwikeb-modifier $devid $value 0x0200
 922 }
 923 proc ib-ev/ebwikeb/EV_KEY/KEY_CAPSLOCK {devid value} {
 924     ib-ebwikeb-modifier $devid $value 0x0400
 925 }
 926
 927 proc ib-ev/ebwikeb/0xffbc_88/0xffbc_0d {devid value} {
 928     upvar #0 input/$devid in
 929     if {!$value} return
 930     if {$in(modifiers) & 0x00ff} {
 931         ib-selectnext $devid $value
 932     } else {
 933         ib-changedirection $devid $value
 934     }
 935 }
 936
 937 proc ib-ev/ebwikeb/EV_KEY/KEY_BOOKMARKS {devid value} {
 938     upvar #0 input/$devid in
 939     if {!$value} return
 940     if {!($in(modifiers) & 0xff00)} return
 941     if {$in(modifiers) & 0x00ff} {
 942         set how stop
 943     } else {
 944         set how auto
 945     }
 946     scmd routinecmd $in(desc) "!realtime $how"
 947 }
 948
 949 #----- static keybindings speed `controller'
 950
 951 proc bind-keyboard-speed {kslow kfast kseltrain kreverse desc} {
 952     set wunique [get-unique keyboardspeed]
 953     set w [speedw-new-cooked $wunique $desc]
 954     foreach delta {-1 +1} sf {slow fast} {
 955         bind . <Key-[set k$sf]> [list speedw-userinput-rel-steps $w $delta {}]
 956     }
 957     bind . <Key-$kseltrain> [list speedw-train-selectnext $w]
 958     bind . <Key-$kreverse> [list speedw-train-direction $w change]
 959     speedw-setstate $w normal
 960 }
 961
 962 #----- Joytech "Neo S" USB PC gamepad
 963
 964 proc hidraw-descriptors/gamepad-neo-s {} {
 965     return xx
 966 }
 967
 968 #proc hidraw-readable/gamepad-neo-s {chan hidraw devid} {
 969 #    upvar #0 hidraw/$hidraw raw
 970 #    # In my tests with tcl8.3 and tcl8.5, "read chan numbytes"
 971 #    # on a nonblocking binary channel does only one read(2)
 972 #    # provided that read(2) returns less than requested
 973 #    while 1 {
 974 #       set msg [hbytes raw2h [read $chan 256]]
 975 #       if {![hbytes
 976 #       switch -glob [bhtes $msg {
 977 #           4a* { set want 8 }
 978 #           {} { set want 64 }
 979 #           * { error "unknown report number $raw(buf)" }
 980 #       }
 981 #       if {$want > $sofar} {
 982 #           set got [read $chan [expr {$want - $sofar}]]
 983 #
 984 #       }
 985 #
 986 #       set sofar [hbytes length $raw(buf)]
 987 #       if {!$sofar} {
 988 #           set got [read $chan 64]
 989 #       } else {
 990 #
 991 #       }
 992
 993
 994 #---------- input device evdev binding ----------
 995
 996 proc ib-evcmd-construct {devid target xargs} {
 997     upvar #0 input/$devid in
 998     if {[llength $target] > 1} {
 999         debug "ib $devid - multiple devices, not supported"
1000         return {}
1001     }
1002     manyset [lindex $target 0] ev sysfs
1003     if {[regexp { } $ev]} { error "event device `$ev' contains space" }
1004     return [concat \
1005             [list ./evdev-manip --redact] $xargs \
1006             [list --stdin-monitor \
1007                   --expect-sysfs /sys$sysfs/$ev/dev \
1008                   /dev/input/$ev]]
1009 }
1010
1011 proc bind-input-core {devid devkind devinfo concrete concargs} {
1012     global input_bindings
1013     lappend input_bindings [list $devkind $devid $devinfo $concrete $concargs]
1014 }
1015
1016 proc bind-input {bus vendor product version concrete args} {
1017     bind-input-core evdev:$bus:$vendor:$product:$version \
1018         evdev [list $bus $vendor $product $version] \
1019         $concrete $args
1020 }
1021
1022 proc bind-input-static {event sysfs concrete args} {
1023     bind-input-core [get-unique static] \
1024         static [list $event $sysfs] \
1025         $concrete $args
1026 }
1027
1028 proc bind-input-raw {devtype concrete args} {
1029     set descriptors [exec ./hidrawconv-$devtype -d]
1030     bind-input-core hidraw:[get-unique $devtype] \
1031         hidraw [list $devtype $descriptors] \
1032         $concrete $args
1033 }
1034
1035 proc widgets-input-bindings {} {
1036     global input_bindings
1037     foreach binding $input_bindings {
1038         manyset $binding devkind devid devinfo concrete concargs
1039         set cid [get-unique $concrete]
1040         upvar #0 input/$devid in
1041         set in(laststart) 0
1042         set in(concrete) $concrete
1043         eval [list ib-create/$concrete $devid $cid] $concargs
1044     }
1045     pack .inputs -side top -fill x
1046 }
1047
1048 # input/$devid becomes `in' via upvar:
1049 #  $in(chan)        channel open onto evdev-manip;
1050 #                   unset if none, or hidraw, or something
1051 #  $in(laststart)   last start time, [clock seconds]
1052 #                      at every event we set this the current time
1053 #                      but we insist on adding at least 5s
1054 #                      and if that would make it > current time +15s
1055 #                      we don't start
1056 #  $in(speedw)      optional, may be set by ib-create
1057
1058 # hidraw/hidrawN becomes `hr' via upvar:
1059 #  $raw(devid)      $devid (see above)
1060 #  $raw(chan)       channel open onto /dev/hidrawN
1061
1062 proc input-concrete-start-try {devid concrete} {
1063     global inputretryadd inputretrymax
1064     upvar #0 input/$devid in
1065     set now [clock seconds]
1066     set newlast [expr {$in(laststart) + $inputretryadd}]
1067     if {$newlast > $now + $inputretrymax} { return 0 }
1068     if {$newlast < $now} { set newlast $now }
1069     set in(laststart) $newlast
1070 }
1071
1072 proc input-bindings-list {devkind} {
1073     global input_bindings
1074     set o {}
1075     foreach b $input_bindings {
1076         manyset $b dk
1077         if {[string compare $dk $devkind]} continue
1078         lappend o $b
1079     }
1080     return $o
1081 }
1082
1083 proc scan-input-bindings {} {
1084     global errorInfo errorCode unmatched_notified old_hidraws
1085     global input_bindings scaninputinterval
1086     global input_rawbindings
1087
1088     after $scaninputinterval scan-input-bindings
1089
1090     # scan /proc/bus/input/devices for appropriate evdevs
1091     # results go in $target($devid)
1092     if {[catch {
1093         set f [open /proc/bus/input/devices]
1094     } emsg]} {
1095         if {[string match {POSIX ENOENT *} $errorCode]} return
1096         error $emsg $errorInfo $errorCode
1097     }
1098     while 1 {
1099         set r [gets $f l]
1100         if {$r <= 0} {
1101             if {[info exists v(devid)] &&
1102                 [info exists v(sysfs)] &&
1103                 [info exists v(event)]} {
1104                 lappend target(evdev:$v(devid)) [list $v(event) $v(sysfs)]
1105             }
1106             catch { unset v }
1107         }
1108         if {$r < 0} {
1109             break
1110         }
1111         append l "\n"
1112         if {[regexp \
1113  {^I: Bus=(\w+) Vendor=(\w+) Product=(\w+) Version=(\w+)\s} \
1114                  $l dummy bus vendor product version]} {
1115             set v(devid) $bus:$vendor:$product:$version
1116         } elseif {[regexp {^S: Sysfs=(\S+)\s} $l dummy sysfs]} {
1117             set v(sysfs) $sysfs
1118         } elseif {[regexp {^H: Handlers=(?:.*\s)?(event\d+)\s} $l dummy ev]} {
1119             set v(event) $ev
1120         } else {
1121             # ignored
1122         }
1123     }
1124     close $f
1125
1126     # add as-if-scanned entries for static bindings to target
1127     # also check to see if we want hidraw
1128     foreach binding $input_bindings {
1129         manyset $binding devkind devid devinfo concrete concargs
1130         switch -exact $devkind static { } default continue
1131         lappend target($devid) [list $event $sysfs]
1132     }
1133
1134     # scan /dev/hidraw*
1135     foreach binding [input-bindings-list hidraw] {
1136         manyset $binding devkind devid devinfo concrete concargs
1137         switch -exact $devkind hidraw { } default continue
1138         manyset $devinfo devtype descriptors
1139         set rawmap($descriptors) [list $devid $devtype $concrete]
1140     }
1141     if {[array exists rawmap]} {
1142         set new_hidraws [lsort [glob -nocomplain -directory /dev hidraw*]]
1143         foreach hidraw $new_hidraws {
1144             upvar #0 hidraw/$hidraw raw
1145             if {[info exists raw(chan)]} {
1146                 set found($raw(devid)) 1
1147                 continue
1148             }
1149             if {[lsearch -exact $old_hidraws $hidraw] >= 0} continue
1150             if {[catch {
1151                 set chan [open $hidraw r+]
1152                 set descriptors [exec ./hidraw-ioctl -d <@ $chan]
1153                 if {![info exists rawmap($descriptors)]} {
1154                     set m [exec ./hidraw-ioctl -i <@ $chan]
1155                     error "unknown descriptors (unmatched device) $hidraw $m >$descriptors<"
1156                 }
1157             } emsg]} {
1158                 upvar #0 hidraw_notified($hidraw) notified
1159                 if {![info exists notified] ||
1160                      [string compare $notified $emsg]} {
1161                     debug "ir $hidraw $emsg"
1162                     set notified $emsg
1163                 }
1164                 catch { close $chan }
1165                 catch { unset chan }
1166                 continue
1167             }
1168             manyset $rawmap($descriptors) devid devtype concrete
1169             set found($devid) 1
1170             if {![input-concrete-start-try $devid $concrete]} {
1171                 catch { close $chan }
1172                 continue
1173             }
1174             set raw(devid) $devid
1175             set cmdl [list ./hidrawconv-$devtype -e <@ $chan 2>@ stderr]
1176             set evch [open |$cmdl r]
1177             set raw(chan) $evch
1178             fconfigure $evch -blocking 0 -buffering line
1179             fileevent $evch readable \
1180                 [list catch-for-input-binding hidraw $hidraw \
1181                      [list readable input-binding-raw $evch $hidraw $devid]]
1182             input-binding-present $devid 1 "hidraw $hidraw"
1183         }
1184         set old_hidraws $new_hidraws
1185     }
1186
1187     # try to start the input binding for all the unstarted found targets
1188     foreach devid [array names target] {
1189         upvar #0 input/$devid in
1190         if {![info exists in(concrete)]} {
1191             if {![info exists unmatched_notified($devid)]} {
1192                 debug "ib $devid unmatched, ignored"
1193                 set unmatched_notified($devid) 1
1194             }
1195             continue
1196         }
1197         set found($devid) 1
1198         if {[info exists in(chan)]} continue
1199         if {![input-concrete-start-try $devid $concrete]} continue
1200
1201         set cmdl [ib-evcmd/$in(concrete) $devid $target($devid)]
1202         if {![llength $cmdl]} {
1203             unset target($devid)
1204             continue
1205         }
1206         lappend cmdl 2>@ stderr
1207         catch-for-input-binding evdev $devid {
1208             debug "ib $devid running $cmdl"
1209             set in(chan) [open |$cmdl r+]
1210             fconfigure $in(chan) -blocking 0 -buffering line
1211             fileevent $in(chan) readable \
1212                 [list catch-for-input-binding evdev $devid \
1213                     [list readable input-binding $in(chan) $devid]]
1214         }
1215     }
1216
1217     # anything not found, not present
1218     foreach binding $input_bindings {
1219         manyset $binding devkind devid devinfo concrete concargs
1220         switch -exact $devkind evdev - raw { } default continue
1221         upvar #0 input/$devid in
1222         if {![info exists in(concrete)]} continue
1223         if {[info exists found($devid)]} continue
1224         input-binding-present $devid 0 absent
1225     }
1226 }
1227
1228 proc input-binding-present {devid yes why} {
1229     upvar #0 input/$devid in
1230     if {[info exists in(speedw)]} {
1231         speedw-setstate $in(speedw) [lindex {disabled normal} $yes]
1232     }
1233     set call "ib-[lindex {absent present} $yes]/$in(concrete)"
1234     if {![catch { info args $call }]} {
1235         $call $devid $why
1236     }
1237 }
1238
1239 proc input-binding-eof {chan devid} {
1240     upvar #0 input/$devid in
1241     input-binding-eof-core $in(chan) "evdev-manip exited"
1242 }
1243
1244 proc input-binding-eof-core {chan msg} {
1245     fconfigure $chan -blocking 1
1246     close $chan
1247     error $msg {} {CHILDSTATUS ? 0}
1248 }
1249
1250 proc input-binding-raw-eof {chan hidraw devid} {
1251     upvar #0 hidraw/$hidraw raw
1252     input-binding-eof-core $raw(chan) "hidrawconv-* exited"
1253 }
1254
1255 proc input-binding-inputline {chan l devid} {
1256     upvar #0 input/$devid in
1257     if {[input-binding-inputline-core-ib $devid $l]} return
1258     regsub {^[^ ]+ } $l {} lr
1259     switch -glob -- $lr {
1260         {opened *} {
1261             debug "ib $devid start << $l"
1262             input-binding-present $devid 1 "evdev open"
1263         }
1264         {[-0-9]*} {
1265             manyset [split $lr] value kindl kindr codel coder
1266             input-binding-inputline-core-ev $devid \
1267                 ${kindl}_${kindr}/${codel}_${coder} $value $l
1268         }
1269         * {
1270             debug "ib $devid ignored << $l"
1271         }
1272     }
1273 }
1274
1275 proc input-binding-inputline-core-ib {devid l} {
1276     # give the input binding first dibs
1277     upvar #0 input/$devid in
1278     if {[catch { info args ib-inputline/$in(concrete) }]} { return 0 }
1279     return [ib-inputline/$in(concrete) $devid $l]
1280 }
1281
1282 proc input-binding-inputline-core-ev {devid kindcode value l} {
1283     global showunbound
1284     upvar #0 input/$devid in
1285     set proc ib-ev/$in(concrete)/$kindcode
1286     if {[catch { info args $proc }]} {
1287         if {$showunbound} {
1288             debug "ib $devid unbound $proc << $l"
1289         }
1290         return
1291     }
1292     $proc $devid $value
1293 }
1294
1295 proc input-binding-raw-inputline {chan l hidraw devid} {
1296     upvar #0 hidraw/$hidraw raw
1297     if {[input-binding-inputline-core-ib $devid $l]} return
1298     manyset [split $l] kind code value
1299     input-binding-inputline-core-ev $devid $kind/$code $value $l
1300 }
1301
1302 proc catch-for-input-binding {devkind ident body} {
1303     global errorInfo errorCode
1304     set r [catch { uplevel 1 $body } rv]
1305     if {$r!=1} { return -code $r $rv }
1306     switch -glob $errorCode {
1307         {CHILDSTATUS *} { set m "exited with status [lindex $errorCode 2]" }
1308         {CHILDKILLED *} { set m "killed by signal [lindex $errorCode 3]" }
1309         {POSIX *} { set m "communication error: [lindex $errorCode 1]" }
1310         * { error $rv $errorInfo $errorCode }
1311     }
1312     debug "ib $devkind $ident died $m"
1313     input-binding-destroy/$devkind $ident $m
1314 }
1315
1316 proc input-binding-destroy/evdev {devid m} {
1317     upvar #0 input/$devid in
1318     catch { close $in(chan) }
1319     catch { unset in(chan) }
1320     input-binding-present $devid 0 "died $m"
1321 }
1322
1323 proc input-binding-destroy/hidraw {hidraw m} {
1324     upvar #0 hidraw/$hidraw raw
1325     catch { close $raw(chan) }
1326     catch { unset raw(chan) }
1327     input-binding-present $raw(devid) 0 "died $m"
1328 }
1329
1330 proc engage-input-bindings {} {
1331     scan-input-bindings
1332 }
1333
1334 #---------- plan background (gui-plan subprocess) ----------
1335
1336 proc gui-pipe-readable {args} {
1337     global gui_pipe
1338     while {[gets $gui_pipe l] >= 0} {
1339         debug "<gui-plan $l"
1340     }
1341     if {[eof $gui_pipe]} {
1342         close $gui_pipe
1343         error "gui-plan crashed"
1344     }
1345 }
1346
1347 #---------- train set events of general interest, and setup ----------
1348
1349 proc train-event-eof {args} {
1350     error "lost connection to train set"
1351 }
1352
1353 register-event ?stastate {ctxch state} {^(.)stastate (\w+|\-) } {
1354     global ctrain trains stastate
1355     set stastate $state
1356     report-problem "stastate: $state"
1357     if {[string compare $ctxch |]} speedws-stastate-hook
1358 }
1359
1360 register-event ?resolution {message} \
1361         {^.resolution (\S+ .*)$} {
1362     if {[string match "problems *" $message]} return
1363     report-problem "resolution: $message"
1364 }
1365
1366 register-event ?warning {message} {^.warning (\S+ .*)$} {
1367     report-problem "warning: $message"
1368 }
1369
1370 register-event {} {} {^=connected } {
1371     global pages gui_pipe server port event_selections
1372
1373     scmd replayed {} "select-replay [concat $event_selections]"
1374
1375     foreach page $pages {
1376         set w [pagew $page]
1377         tkwait visibility $w.picture
1378
1379         set cmdl [list ./gui-plan-$page [winfo id $w.picture] @$server,$port]
1380         lappend cmdl 2>@ stderr
1381         set gui_pipe [open |$cmdl r]
1382
1383         puts stderr "running $cmdl"
1384         fconfigure $gui_pipe -blocking no
1385         fileevent $gui_pipe readable gui-pipe-readable
1386     }
1387 }
1388 proc replayed-err {m args} { error "replay failed: $m" }
1389 proc replayed-ok {m args} {
1390     speedws-stastate-hook
1391 }
1392
1393 register-event {} {} {^=failed } { error "multiplexer failed: $l" }
1394 register-event {} {} {^=denied } { error "multiplexer denied us: $l" }
1395 register-event {} {} {^\+nack } { error "multiplexer does not understand" }
1396
1397 #---------- main program ----------
1398
1399 append event_dispatch_body {
1400     debug "ignored $l"
1401 }
1402 proc train-event-inputline {sconn l} $event_dispatch_body
1403 proc register-event {args} { error "too late!" }
1404
1405 proc engage-server {} {
1406     global server port sconn
1407
1408     set sconn [socket $server $port]
1409     fconfig-trainproto $sconn
1410     fileevent $sconn readable {readable train-event $sconn}
1411 }
1412
1413 proc main {} {
1414     global pages cpage configfile input_bindings old_hidraws
1415     setting server railway {[[0-9a-z:].*}
1416     setting geometry {} {[-+]\d+[-+]\d+}
1417     setting posdeviation 5 {\d+}
1418     setting movfeatcommand {movfeat+} {(?:!movfeat|movfeat\+?\+?)}
1419     setting problemdisplayms 1000 {\d+}
1420     setting inputretryadd 5 {\d+}
1421     setting inputretrymax 15 {\d+}
1422     setting scaninputinterval 500 {\d+}
1423     setting showunbound 0 {[01]}
1424
1425     set hostname [lindex [split [info hostname] .] 0]
1426     setting configfile gui-$hostname.config {.+}
1427     parse-argv {}
1428
1429     frame .inputs
1430     if {![info exists input_bindings]} { set input_bindings {} }
1431     set old_hidraws {}
1432
1433     uplevel #0 source gui-layout.config
1434     uplevel #0 source $configfile
1435     foreach cpage $pages {
1436         layout-data
1437         widgets-dgram
1438     }
1439     unset cpage
1440     widgets-movpos
1441     widgets-input-bindings
1442     widget-problem-report
1443     engage-server
1444     engage-input-bindings
1445     start_commandloop
1446 }
1447
1448 main