hostside/gui

   1 #!/usr/bin/wishx
   2
   3 #---------- general utilities ----------
   4
   5 set tk_strictMotif 1
   6
   7 tk_setPalette background black foreground white
   8
   9 source lib.tcl
  10
  11 set default_speedstep_list {0 1 10 20 35 50 65 80 95 110 126}
  12
  13 set picturepadx 10
  14 set picturepady 10
  15
  16 proc pagew {page} { return ".picture-$page" }
  17 proc debug {m} { puts $m }
  18
  19 proc sconn {m} {
  20     global sconn
  21     debug "=> $m"
  22     puts $sconn $m
  23 }
  24
  25 proc widgets-dgram {} {
  26     global cpage geometry picturepadx picturepady
  27     if {[string length $geometry]} { wm geometry . $geometry }
  28     set sizes [exec ./gui-plan-$cpage --sizes]
  29     set w [pagew $cpage]
  30     frame $w
  31     frame $w.picture -background {} \
  32             -width [lindex $sizes 0] \
  33             -height [lindex $sizes 1]
  34     pack $w.picture -padx $picturepadx -pady $picturepady
  35     pack $w
  36 }
  37
  38 proc widgets-fullscreen-nowm {} {
  39     pack propagate . false
  40     foreach wh {width height} {
  41         . configure -$wh [winfo screen$wh .]
  42     }
  43 }
  44
  45 proc bgerror {emsg} {
  46     global errorCode errorInfo
  47     catch {
  48         puts stderr "UNEXPECTED BACKGROUND ERROR\n"
  49         puts stderr "$errorCode\n$errorInfo\n$emsg"
  50     }
  51     exit 16
  52 }
  53
  54 #---------- train set event registraton ----------
  55
  56 set event_dispatch_body {
  57     append l " "
  58 }
  59 set event_selections {}
  60
  61 proc register-event {selections args re body} {
  62     global event_dispatch_body event_selections
  63
  64     eval lappend event_selections $selections
  65
  66     foreach selection $selections {
  67         if {[regexp {^\w} $selection]} {
  68             error "selection $selection lacks context char"
  69         }
  70     }
  71     if {[regexp {^\^\w} $re]} {
  72         error "re $re never matches context char"
  73     }
  74
  75     regsub -all {\W+} $re - proc
  76     set proc "event/$proc/[join $args -]"
  77     set suffix {}
  78     set number 0
  79     while {![catch { info args $proc$suffix }]} { set suffix [incr number] }
  80     append proc $suffix
  81
  82     proc $proc [concat l $args] $body
  83     set al ""
  84     foreach a $args { append al " \$$a" }
  85
  86     append event_dispatch_body \
  87             "    if {\[regexp [list $re] \$l dummy $args]} {\n" \
  88             "        debug \"$proc$al\"\n" \
  89             "        eval [list $proc] \[list \$l$al]\n" \
  90             "        return\n" \
  91             "    }\n"
  92 }
  93
  94 #---------- handling of commands we issue ----------
  95
  96 proc scmd {onresult ctrlr commandstr args} {
  97     # later, calls
  98     #   eval [list $onresult-ok|nak|error $ackornakmessage] $args
  99     global commands_queued
 100     sconn $commandstr
 101     lappend commands_queued [list $ctrlr $onresult $args]
 102 }
 103
 104 proc scmd_result {oknakerr message reporterrmsg} {
 105     global commands_queued
 106     manyset [lindex $commands_queued 0] ctrlr onresult args
 107     set commands_queued [lrange $commands_queued 1 end]
 108     if {[string length $reporterrmsg]} {
 109         report-problem "$ctrlr: $reporterrmsg"
 110     }
 111     set proc "$onresult-$oknakerr"
 112     if {![string compare $oknakerr nak] && [catch { info args $proc }]} {
 113         set proc "$onresult-err"
 114     }
 115     eval [list $proc $message] $args
 116 }
 117
 118 register-event {} {} {^\+ack \S+ ok } { scmd_result ok $l "" }
 119 register-event {} {train segment error} \
 120         {^\+ack \S+ SignallingPredictedProblem (\S+) (\S+) \: (.*) $} {
 121     set m $train
 122     if {[string compare - $segment]} { append m " @$segment" }
 123     append m ": $error"
 124     scmd_result err $l $m
 125 }
 126 register-event {} {} {^\+ack } { scmd_result err $l $l }
 127 register-event {} {} {^\+nack \S+ } { scmd_result nak $l $l }
 128
 129 proc routinecmd-nak {m args} { error "got nak to routine command: $m" }
 130 proc routinecmd-err {m args} { }
 131 proc routinecmd-ok {m args} { }
 132
 133 proc mustsucceed-err {m args} { error "unexpected error: $m" }
 134 proc mustsucceed-ok {m args} { }
 135
 136 proc report-problem-report-stderr {m} { puts stderr "*** $m" }
 137 set report_problem_report report-problem-report-stderr
 138
 139 proc report-problem {message} {
 140     global report_problem_report
 141     eval $report_problem_report [list $message]
 142 }
 143
 144 proc widget-problem-report {} {
 145     global problem_reports report_problem_report
 146     set problem_reports "\n\n\n\n\n"
 147     label .problem-report -anchor w -justify left -takefocus 0 \
 148             -border 2 -relief sunken -width 80 -textvariable problem_reports
 149     pack .problem-report -side top
 150     set report_problem_report report-problem-report-widget
 151 }
 152
 153 proc report-problem-report-widget {m} {
 154     global problem_reports
 155     set problem_reports [join [concat \
 156                 [lrange [split $problem_reports "\n"] 1 end] \
 157                 [list $m] \
 158             ] "\n"]
 159 }
 160
 161 #---------- movpos (overlay buttons, keybindings, execution) ----------
 162
 163 proc movpos-button-gvars {mid} {
 164     upvar #0 mp_details($mid) details
 165     if {![info exists details]} { return 0 }
 166     uplevel 1 [list manyset $details cpage key seg feat poslocs]
 167     uplevel 1 { set w [pagew $cpage].movpos-$mid }
 168     upvar #0 mp_state($mid) state
 169     uplevel 1 [list manyset $state posn]
 170     return 1
 171 }
 172
 173 proc movpos-button-sstate {mid posn} {
 174     upvar #0 mp_state($mid) state
 175     set state $posn
 176     movpos-button-setdisplay $mid
 177 }
 178
 179 proc movpos-all-unknown {} {
 180     global mp_details
 181     foreach mid [array names mp_details] {
 182         movpos-button-sstate $mid ?
 183     }
 184 }
 185
 186 proc widgets-movpos {} {
 187     global mp_details
 188     foreach mid [array names mp_details] {
 189         upvar #0 mp_state($mid) state
 190         set state {?}
 191         movpos-button-gvars $mid
 192         set w [pagew $cpage].movpos-$mid
 193         button $w -text $key -padx 0 -pady 0 -borderwidth 0 \
 194                 -command [list movpos-invoked $mid "plan $cpage"]
 195         movpos-button-setdisplay $mid
 196     }
 197 }
 198
 199 proc movpos-button-setdisplay {mid} {
 200     # we want to display as much of these as possible:
 201     #   position known ?   (actual position is done by button location)
 202     #   moving or stable
 203     #   whether a train's plan includes a different position
 204     #   whether autopoint
 205     movpos-button-gvars $mid
 206     set fg white
 207     set bg black
 208     $w configure -background $bg -foreground $fg \
 209             -activebackground $bg -activeforeground $fg
 210     switch -exact $posn {
 211         ? { manyset [lindex $poslocs 2] x y }
 212         default { manyset [lindex $poslocs $posn] x y }
 213     }
 214     place $w -anchor center -x $x -y $y
 215 }
 216
 217 proc movpos-invoked {mid ctrlr} {
 218     global movfeatcommand
 219     movpos-button-gvars $mid
 220     switch -exact $posn {
 221         0 { set new_posn 1 }
 222         default { set new_posn 0 }
 223     }
 224     scmd routinecmd $ctrlr "$movfeatcommand $seg $feat $new_posn"
 225 }
 226
 227 register-event ?movpos_*_feat {seg feat posn_new} \
 228         {^.movpos (\w+) feat (\w+) ([01]|\?) } {
 229     set mid $seg/$feat
 230     if {![movpos-button-gvars $mid]} return
 231     set posn $posn_new
 232     movpos-button-sstate $mid $posn
 233 }
 234
 235 proc movpos-bindkey-1 {cpage key seg feat adj0x adj0y adj1x adj1y} {
 236     global posdeviation picturepadx picturepady
 237     manyset [subseg-end-get-centroid $cpage $seg $feat {}] mx my
 238     set mid $seg/$feat
 239     foreach posn {0 1} {
 240         manyset [subseg-end-get-centroid $cpage $seg $feat $posn] x y
 241         set dx [expr {$x-$mx}]; set dy [expr {$y-$my}]
 242         set d [expr {sqrt($dx*$dx + $dy*$dy)}]
 243         set mul [expr {$posdeviation / ($d + 1e-6)}]
 244         set x [expr {$mx + $mul*$dx + $picturepadx + [set adj${posn}x]}]
 245         set y [expr {$my + $mul*$dy + $picturepady + [set adj${posn}y]}]
 246         lappend poslocs [list $x $y]
 247     }
 248     lappend poslocs [list [expr {$mx + $picturepadx + ($adj0x+$adj1x)*0.5}] \
 249                           [expr {$my + $picturepady + ($adj0y+$adj1y)*0.5}]]
 250     upvar #0 mp_details($mid) details
 251     set details [list $cpage $key $seg $feat $poslocs]
 252
 253     bind . <Key-[string tolower $key]> [list movpos-invoked $mid "keyboard"]
 254 }
 255
 256 #---------- computation of movpos button locations
 257
 258 proc layout-subseg-featmap {seg concfeatpos args} {
 259     global subsegfeatmap
 260     set subsegfeatmap($concfeatpos) $args
 261 }
 262
 263 proc layout-subseg-end {seg feat posn x y} {
 264     global cpage
 265     upvar #0 subsegfeatmap($feat$posn) mapped
 266     if {[info exists mapped]} {
 267         foreach {feat posn} $mapped {
 268             layout-subseg-end $seg $feat $posn $x $y
 269         }
 270         return
 271     }
 272     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 273     if {![info exists sse]} { set sse {{} {}} }
 274     manyset $sse lx ly
 275     lappend lx $x
 276     lappend ly $y
 277     set sse [list $lx $ly]
 278     if {[string length $posn]} { layout-subseg-end $seg $feat {} $x $y }
 279 }
 280
 281 proc subseg-end-get-centroid {cpage seg feat posn} {
 282     upvar #0 ld_sse/${cpage}($seg/$feat$posn) sse
 283     if {![info exists sse]} {
 284         puts "skipping binding of unknown $seg/$feat$posn"
 285         return -code return
 286     }
 287     manyset $sse lx ly
 288     set sx 0; set sy 0; set n [llength $lx]
 289     foreach x $lx y $ly { addexpr sx {$x}; addexpr sy {$y} }
 290     return [list [expr {$sx * 1.0 / $n}] [expr {$sy * 1.0 / $n}]]
 291 }
 292
 293 proc layout-data {} {
 294     global cpage
 295     upvar #0 ld_sse/$cpage sse
 296     catch { unset sse }
 297     source ../layout/ours.dgram.segmap-info
 298     source ../layout/ours.dgram-$cpage.overlay-info
 299
 300     upvar #0 movpos_bindings($cpage) bindings
 301     if {![info exists bindings]} {
 302         puts "no movpos bindings for $cpage"
 303         return
 304     }
 305     foreach binding $bindings {
 306         if {[regexp \
 307    {^([A-Z])([-+]\d*)?([-+]\d*)?([-+]\d*)?([-+]\d*)?\=(\w+)/([A-Z]+)$} \
 308                  $binding dummy key adj0x adj0y adj1x adj1y seg feat]} {
 309             if {![string length $adj1x]} { set adj1x $adj0x; set adj1y $adj0y }
 310             movpos-bindkey-1 $cpage $key $seg $feat \
 311                 $adj0x.0 $adj0y.0 $adj1x.0 $adj1y.0
 312         } elseif {[regexp {^[A-Z]$} $binding] || [regexp {~} $binding]} {
 313         } else {
 314             error "incomprehensible binding $binding on page $cpage"
 315         }
 316     }
 317 }
 318
 319 #---------- speed ----------
 320
 321 # variables:
 322 #   $train_commanded($train)    $speed_step
 323 #   $train_direction($train)    forwards|backwards or unset
 324 #   $speedws                    [list $w ...]
 325 #
 326 # speed/${w}(...) aka s(...):
 327 #   $s(ctrlr)                   controller
 328 #   $s(train)                   train selected, or something not \w+
 329 #   $s(optionmenu)              optionmenu widget name
 330 #   $s(kind)                    abs or rel
 331 #   $s(commanding)              step of command we have scmd'd, or unset
 332 #   $s(queued)                  step of command we would like to queue
 333 #                                or unset if n/a
 334 #   $s(inhibit)   0   all is well, can command any speed
 335 #                 1   train newly selected, only rel can command higher speed
 336 #                 2   can only command same or lower speed
 337 #
 338 # We don't worry too much about races: in particular, we don't mind
 339 # racing with other things trying to command the speed, and losing
 340 # the odd increment/decrement.  But since we thread the requested
 341 # speed via realtime, we do queue up our own increments/decrements
 342 # while we're executing a speed command, to avoid loss of steps during
 343 # quick motions.
 344
 345 # Interfaces for concrete controllers:
 346 #   speedw-new $w $ctrlr
 347 #   speedw-setstate $w disabled|normal        controller appears/disappears
 348 #   speedw-userinput-abs $w $step
 349 #   speedw-userinput-rel $w $stepmap
 350 # where
 351 #   eval {stepmap} [list $oldstep] => $newstep
 352
 353 set speedws {}
 354
 355 proc speedws-forall {command args} {
 356     global speedws
 357     foreach w $speedws { eval [list $command $w] $args }
 358 }
 359
 360 proc speedws-fortrain {train command args} {
 361     global speedws
 362     foreach w $speedws {
 363         upvar #0 speed/$w s
 364         if {[string compare $s(train) $train]} continue
 365         eval [list $command $w] $args
 366     }
 367 }
 368
 369 proc speedw-new {w ctrlr} {
 370     upvar #0 speed/$w s
 371     global speedws
 372
 373     lappend speedws $w
 374     set s(ctrlr) $ctrlr
 375     set s(inhibit) 0
 376
 377     frame $w -relief sunken -border 2
 378     label $w.ctrlr -state disabled -text $s(ctrlr)
 379     set s(optionmenu) [tk_optionMenu $w.train speed/${w}(train) {}]
 380     $w.train configure -textvariable {} -width 15
 381     label $w.speed -state disabled -width 4 \
 382             -font -*-courier-bold-r-*-*-20-*-*-*-*-*-*-* \
 383             -background black -foreground white
 384     pack $w.ctrlr $w.train $w.speed -side left
 385
 386     speedw-notrains $w "(starting)"
 387 }
 388 proc speedw-notrains {w whystr} {
 389     $w.train configure -state disabled
 390     speedw-train-noneselected $w $whystr
 391 }
 392 proc speedw-train-noneselected {w whystr} {
 393     upvar #0 speed/$w s
 394     set s(train) {}
 395     $w.train configure -text $whystr
 396     $w.speed configure -text -
 397     speedw-inhibit $w
 398 }
 399
 400 proc speedw-inhibit {w} {
 401     upvar #0 speed/$w s
 402     set s(inhibit) 2
 403     $w.speed configure -foreground red
 404 }
 405 proc speedw-uninhibit {w max} {
 406     upvar #0 speed/$w s
 407     set r $s(inhibit)
 408     if {$r>$max} { return -1 }
 409     set s(inhibit) 0
 410     $w.speed configure -foreground white
 411     return $r
 412 }
 413
 414 proc speedw-setstate {w disnorm} {
 415     $w.ctrlr configure -state $disnorm
 416     $w.speed configure -state $disnorm
 417 }
 418
 419 proc speedw-train-selectnext {w} {
 420     upvar #0 speed/$w s
 421     set max [$s(optionmenu) index end]
 422     for {set ix 0} {$ix <= $max} {incr ix} {
 423         set v [$s(optionmenu) entrycget $ix -value]
 424         if {![string compare $v $s(train)]} break
 425     }
 426     set activate [expr {($ix+1) % ($max+1)}]
 427     $s(optionmenu) invoke $activate
 428 }
 429
 430 proc speedw-train-selected {w t} {
 431     upvar #0 speed/$w s
 432     $w.train configure -text $t
 433     set s(inhibit) 1
 434     set s(train) $t
 435     $w.speed configure -foreground white
 436     speedw-redisplay-speed $w
 437 }
 438
 439 proc speedw-redisplay-speed {w} {
 440     upvar #0 speed/$w s
 441     upvar #0 train_commanded($s(train)) gcommanded
 442     upvar #0 train_direction($s(train)) gdirection
 443     set t $gcommanded
 444     if {[info exists gdirection]} {
 445         switch -exact $gdirection {
 446             forwards { set t "$t>" }
 447             backwards { set t "<$t" }
 448         }
 449     }
 450     $w.speed configure -text $t
 451 }
 452
 453 proc speedw-train-direction {w dirchange} {
 454     upvar #0 speed/$w s
 455     if {![string length $s(train)]} return
 456     scmd routinecmd $s(ctrlr) "direction $s(train) $dirchange"
 457 }
 458
 459 proc speedw-trains-available {w l} {
 460     upvar #0 speed/$w s
 461     if {![llength $l]} { speedw-train-noneselected $w "(no trains)"; return }
 462     $s(optionmenu) delete 0 end
 463     $s(optionmenu) add radiobutton -label "(none)" -value {} \
 464             -command [list speedw-train-noneselected $w "(no train selected)"]
 465     set l [lsort $l]
 466     foreach t $l {
 467         $s(optionmenu) add radiobutton -label $t -value $t \
 468                 -command [list speedw-train-selected $w $t]
 469     }
 470     $w.train configure -state normal
 471     if {[llength $l]==1} {
 472         $s(optionmenu) invoke 1
 473     } elseif {[set ix [lsearch -exact $l $s(train)]] >= 0} {
 474         $s(optionmenu) invoke [expr {$ix+1}]
 475     } elseif {![string length $s(train)]} {
 476         $s(optionmenu) invoke 0
 477     } else {
 478         $w.train configure -text "$s(train) (not present)"
 479     }
 480 }
 481
 482 proc speedw-userinput-abs {w speed} {
 483     upvar #0 speed/$w s
 484     if {![string length $s(train)]} return
 485     set s(queued) $speed
 486     speedw-check $w
 487 }
 488
 489 proc speedw-check {w} {
 490     upvar #0 speed/$w s
 491     if {![string length $s(train)]} return
 492     upvar #0 train_commanded($s(train)) gcommanded
 493     upvar #0 train_direction($s(train)) gdirection
 494     if {[info exists s(commanding)]} return
 495     if {![info exists s(queued)]} return
 496     set newspeed $s(queued)
 497     unset s(queued)
 498     if {$s(inhibit)} {
 499         if {$newspeed > $gcommanded} return
 500         speedw-uninhibit $w 2
 501     }
 502     set s(commanding) $newspeed
 503     scmd speedw-commanded $s(ctrlr) "speed $s(train) $newspeed $gdirection" $w
 504 }
 505
 506 proc speedw-commanded-nak {m args} { error "got nak from speed: $m" }
 507 proc speedw-commanded-ok {m w} {
 508     upvar #0 speed/$w s
 509     unset s(commanding)
 510     speedw-check $w
 511 }
 512 proc speedw-commanded-err {m w} {
 513     upvar #0 speed/$w s
 514     unset s(commanding)
 515     speedw-inhibit $w
 516     speedw-check $w
 517 }
 518
 519 proc speedw-userinput-rel {w stepmap} {
 520     upvar #0 speed/$w s
 521     if {![string length $s(train)]} return
 522     upvar #0 train_commanded($s(train)) gcommanded
 523     if {[info exists s(queued)]} {
 524         set oldspeed $s(queued)
 525     } elseif {[info exists s(commanding)]} {
 526         set oldspeed $s(commanding)
 527     } else {
 528         set oldspeed $gcommanded
 529     }
 530     set newspeed [eval $stepmap [list $oldspeed]]
 531     speedw-userinput-abs $w $newspeed
 532 }
 533
 534 proc speedw-userinput-rel-steps {w delta steplist} {
 535     if {$delta<0} {
 536         if {[speedw-uninhibit $w 2]>1} { incr delta 1 }
 537         if {!$delta} return
 538     } else {
 539         speedw-uninhibit $w 1
 540     }
 541     speedw-userinput-rel $w [list speedw-stepmap-fromlist $steplist $delta]
 542 }
 543
 544 proc speedws-train-problem {train} {
 545     speedws-fortrain $train speedw-inhibit
 546 }
 547
 548 register-event ?train_*_at {train direction} \
 549         {^.train (\w+) at \S+ (forwards|backwards) } {
 550     upvar #0 train_direction($train) dirn
 551     set dirn $direction
 552     speedws-fortrain $train speedw-redisplay-speed
 553 }
 554
 555 register-event ?train_*_speed_commanding {train speed} \
 556         {^.train (\w+) speed commanding (\d+) } {
 557     upvar #0 train_commanded($train) cmd
 558     set cmd $speed
 559     speedws-fortrain $train speedw-redisplay-speed
 560 }
 561
 562 proc speedws-stastate-hook {} {
 563     global train_commanded stastate
 564     switch -exact -- $stastate {
 565         Run {
 566             set trains [array names train_commanded]
 567             speedws-forall speedw-trains-available $trains
 568         }
 569         Resolving {
 570             movpos-all-unknown
 571         }
 572         Finalising {
 573             speedws-forall speedw-notrains "($stastate)"
 574         }
 575         default {
 576             catch { unset train_commanded }
 577             speedws-forall speedw-notrains "($stastate)"
 578         }
 579     }
 580 }
 581
 582 register-event &train_*_signalling-problem {train problem} \
 583         {^\&train (\w+) signalling-problem (.*) $} {
 584     global speedws
 585     regsub {^(\S+) (\S+) \: } $problem {\1 @\2: } problem
 586     report-problem "event: $problem"
 587     speedws-train-problem $train
 588 }
 589
 590 proc speedw-new-cooked {wunique desc} {
 591     set w .inputs.$wunique
 592     speedw-new $w $desc
 593     pack $w -side left -padx 10
 594     return $w
 595 }
 596
 597 proc speedw-stepmap-fromlist {speedlist offset oldspeed} {
 598     if {![llength $speedlist]} {
 599         unset speedlist
 600         upvar #0 default_speedstep_list speedlist
 601     }
 602     set ixabove 0
 603     foreach entry $speedlist {
 604         if {$entry==$oldspeed} { set ixbelow $ixabove; break }
 605         if {$entry>$oldspeed} break
 606         set ixbelow $ixabove
 607         incr ixabove
 608     }
 609     set ix [expr {($offset>0 ? $ixbelow : $ixabove) + $offset}]
 610     if {$ix<0} { return 0 }
 611     if {$ix>=[llength $speedlist]} { return [lindex $speedlist end] }
 612     return [lindex $speedlist $ix]
 613 }
 614
 615 #---------- concrete input bindings ----------
 616
 617 proc ib-suppressions {args} {
 618     set l {}
 619     foreach supp $args {
 620         set l [concat $l --redaction $supp --suppress]
 621     }
 622     return $l
 623 }
 624
 625 proc ib-speedw-new {devid wunique desc} {
 626     upvar #0 input/$devid in
 627     set in(speedw) [speedw-new-cooked $wunique $desc]
 628 }
 629
 630 #----- wheelmouse
 631
 632 proc ib-ev/wheelmouse/EV_REL/REL_WHEEL {devid value} {
 633     upvar #0 input/$devid in
 634     speedw-userinput-rel-steps $in(speedw) [expr {-$value}] {}
 635 }
 636
 637 proc ib-selectnext {devid value} {
 638     if {$value!=1} return
 639     upvar #0 input/$devid in
 640     speedw-train-selectnext $in(speedw)
 641 }
 642 proc ib-changedirection {devid value} {
 643     upvar #0 input/$devid in
 644     if {!$value} return
 645     speedw-train-direction $in(speedw) change
 646 }
 647
 648 proc ib-ev/wheelmouse/EV_KEY/BTN_LEFT {devid value} {
 649     ib-selectnext $devid $value
 650 }
 651 proc ib-ev/wheelmouse/EV_KEY/BTN_RIGHT {devid value} {
 652     ib-changedirection $devid $value
 653 }
 654
 655 proc ib-create/wheelmouse {devid wunique desc} {
 656     ib-speedw-new $devid $wunique $desc
 657 }
 658
 659 proc ib-wheelmouse-redactions {} {
 660     return [ib-suppressions  \
 661             {EV REL REL X} \
 662             {EV REL REL Y}]
 663 }
 664
 665 proc ib-evcmd/wheelmouse {devid target} {
 666     return [ib-evcmd-construct $devid $target [concat \
 667             [list --grab] [ib-wheelmouse-redactions]]]
 668 }
 669
 670 #----- ebuyer wireless keyboard
 671
 672 proc ib-create/ebwikeb {devid wunique} {
 673     upvar #0 input/$devid in
 674     set in(desc) "main keyboard"
 675     ib-create/wheelmouse $devid $wunique $in(desc)
 676     set in(modifiers) 0
 677 }
 678
 679 proc ib-evcmd/ebwikeb {devid target} {
 680     return [concat \
 681             [list ./evdev-manip-ebwikeb --redact --stdin-monitor] \
 682             [ib-wheelmouse-redactions] \
 683             [ib-suppressions \
 684                 {0x01 02} \
 685                 {EV MSC} \
 686                 {0x0c 01} \
 687                 {0xffbc 88 0xffbc 00}]]
 688 }
 689
 690 proc ib-ev/ebwikeb/EV_REL/REL_WHEEL {devid value} {
 691     ib-ev/wheelmouse/EV_REL/REL_WHEEL $devid $value
 692 }
 693
 694 proc ib-ebwikeb-modifier {devid value bitval} {
 695     upvar #0 input/${devid}(modifiers) mod
 696     if {$value} {
 697         set mod [expr {$mod | $bitval}]
 698     } else {
 699         set mod [expr {$mod & ~$bitval}]
 700     }
 701 }
 702 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTSHIFT {devid value} {
 703     ib-ebwikeb-modifier $devid $value 0x0001
 704 }
 705 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTSHIFT {devid value} {
 706     ib-ebwikeb-modifier $devid $value 0x0002
 707 }
 708 proc ib-ev/ebwikeb/EV_KEY/KEY_LEFTCTRL {devid value} {
 709     ib-ebwikeb-modifier $devid $value 0x0100
 710 }
 711 proc ib-ev/ebwikeb/EV_KEY/KEY_RIGHTCTRL {devid value} {
 712     ib-ebwikeb-modifier $devid $value 0x0200
 713 }
 714 proc ib-ev/ebwikeb/EV_KEY/KEY_CAPSLOCK {devid value} {
 715     ib-ebwikeb-modifier $devid $value 0x0400
 716 }
 717
 718 proc ib-ev/ebwikeb/0xffbc_88/0xffbc_0d {devid value} {
 719     upvar #0 input/$devid in
 720     if {!$value} return
 721     if {$in(modifiers) & 0x00ff} {
 722         ib-selectnext $devid $value
 723     } else {
 724         ib-changedirection $devid $value
 725     }
 726 }
 727
 728 proc ib-ev/ebwikeb/EV_KEY/KEY_BOOKMARKS {devid value} {
 729     upvar #0 input/$devid in
 730     if {!$value} return
 731     if {!($in(modifiers) & 0xff00)} return
 732     if {$in(modifiers) & 0x00ff} {
 733         set how stop
 734     } else {
 735         set how auto
 736     }
 737     scmd routinecmd $in(desc) "!realtime $how"
 738 }
 739
 740 #----- static keybindings speed `controller'
 741
 742 proc bind-keyboard-speed {kslow kfast kseltrain kreverse desc} {
 743     set wunique [get-unique keyboardspeed]
 744     set w [speedw-new-cooked $wunique $desc]
 745     foreach delta {-1 +1} sf {slow fast} {
 746         bind . <Key-[set k$sf]> [list speedw-userinput-rel-steps $w $delta {}]
 747     }
 748     bind . <Key-$kseltrain> [list speedw-train-selectnext $w]
 749     bind . <Key-$kreverse> [list speedw-train-direction $w change]
 750     speedw-setstate $w normal
 751 }
 752
 753 #---------- input device evdev binding ----------
 754
 755 proc ib-evcmd-construct {devid target xargs} {
 756     upvar #0 input/$devid in
 757     if {[llength $target] > 1} {
 758         debug "ib $devid - multiple devices, not supported"
 759         return {}
 760     }
 761     manyset [lindex $target 0] ev sysfs
 762     if {[regexp { } $ev]} { error "event device `$ev' contains space" }
 763     return [concat \
 764             [list ./evdev-manip --redact] $xargs \
 765             [list --stdin-monitor \
 766                   --expect-sysfs /sys$sysfs/$ev/dev \
 767                   /dev/input/$ev]]
 768 }
 769
 770 proc bind-input {bus vendor product version concrete args} {
 771     global input_bindings
 772     set devid $bus:$vendor:$product:$version
 773     lappend input_bindings [list $devid $concrete $args]
 774 }
 775
 776 proc bind-input-static {event sysfs concrete args} {
 777     global input_bindings input_statics
 778     set devid [get-unique static]
 779     lappend input_statics [list $devid $event $sysfs]
 780     lappend input_bindings [list $devid $concrete $args]
 781 }
 782
 783 proc widgets-input-bindings {} {
 784     global input_bindings
 785     foreach binding $input_bindings {
 786         manyset $binding devid concrete xa
 787         set cid [get-unique $concrete]
 788         upvar #0 input/$devid in
 789         set in(laststart) 0
 790         set in(concrete) $concrete
 791         eval [list ib-create/$concrete $devid $cid] $xa
 792     }
 793     pack .inputs -side top -fill x
 794 }
 795
 796 # input/$bus:$vendor:$product:$version becomes `in' via upvar
 797 #  $in(chan)        channel open onto evdev-manip; unset if none
 798 #  $in(laststart)   last start time, [clock seconds]
 799 #                      at every event we set this the current time
 800 #                      but we insist on adding at least 5s
 801 #                      and if that would make it > current time +15s
 802 #                      we don't start
 803 #  $in(speedw)      optional, may be set by ib-create
 804
 805 proc scan-input-bindings {} {
 806     global errorInfo errorCode unmatched_notified
 807     global input_bindings inputretryadd inputretrymax scaninputinterval
 808     global input_statics
 809     if {[catch {
 810         set f [open /proc/bus/input/devices]
 811     } emsg]} {
 812         if {[string match {POSIX ENOENT *} $errorCode]} return
 813         error $emsg $errorInfo $errorCode
 814     }
 815     while 1 {
 816         set r [gets $f l]
 817         if {$r <= 0} {
 818             if {[info exists v(devid)] &&
 819                 [info exists v(sysfs)] &&
 820                 [info exists v(event)]} {
 821                 lappend target($v(devid)) [list $v(event) $v(sysfs)]
 822             }
 823             catch { unset v }
 824         }
 825         if {$r < 0} {
 826             break
 827         }
 828         append l "\n"
 829         if {[regexp \
 830  {^I: Bus=(\w+) Vendor=(\w+) Product=(\w+) Version=(\w+)\s} \
 831                  $l dummy bus vendor product version]} {
 832             set v(devid) $bus:$vendor:$product:$version
 833         } elseif {[regexp {^S: Sysfs=(\S+)\s} $l dummy sysfs]} {
 834             set v(sysfs) $sysfs
 835         } elseif {[regexp {^H: Handlers=(?:.*\s)?(event\d+)\s} $l dummy ev]} {
 836             set v(event) $ev
 837         } else {
 838             # ignored
 839         }
 840     }
 841     close $f
 842     foreach static $input_statics {
 843         manyset $static devid event sysfs
 844         lappend target($devid) [list $event $sysfs]
 845     }
 846     foreach devid [array names target] {
 847         upvar #0 input/$devid in
 848         if {![info exists in(concrete)]} {
 849             if {![info exists unmatched_notified($devid)]} {
 850                 debug "ib $devid unmatched, ignored"
 851                 set unmatched_notified($devid) 1
 852             }
 853             continue
 854         }
 855         if {[info exists in(chan)]} continue
 856         set now [clock seconds]
 857         set newlast [expr {$in(laststart) + $inputretryadd}]
 858         if {$newlast > $now + $inputretrymax} continue
 859         if {$newlast < $now} { set newlast $now }
 860         set cmdl [ib-evcmd/$in(concrete) $devid $target($devid)]
 861         if {![llength $cmdl]} {
 862             unset target($devid)
 863             continue
 864         }
 865         lappend cmdl 2>@ stderr
 866         set in(laststart) $newlast
 867         catch-for-input-binding $devid {
 868             debug "ib $devid running $cmdl"
 869             set in(chan) [open |$cmdl r+]
 870             fconfigure $in(chan) -blocking 0 -buffering line
 871             fileevent $in(chan) readable [list catch-for-input-binding $devid \
 872                     [list readable input-binding $in(chan) $devid]]
 873         }
 874     }
 875     foreach binding $input_bindings {
 876         manyset $binding devid concrete ctrlr
 877         upvar #0 input/$devid in
 878         if {![info exists in(concrete)]} continue
 879         if {[info exists target($devid)]} continue
 880         input-binding-notpresent $devid absent
 881     }
 882     after $scaninputinterval scan-input-bindings
 883 }
 884
 885 proc input-binding-notpresent {devid why} {
 886     upvar #0 input/$devid in
 887     if {[info exists in(speedw)]} {
 888         speedw-setstate $in(speedw) disabled
 889     }
 890     if {![catch { info args ib-absent/$in(concret) }]} {
 891         ib-absent/$in(concrete) $devid $why
 892     }
 893 }
 894
 895 proc input-binding-eof {chan devid} {
 896     upvar #0 input/$devid in
 897     fconfigure $in(chan) -blocking 1
 898     close $in(chan)
 899     error "evdev-manip exited" {} {CHILDSTATUS ? 0}
 900 }
 901
 902 proc input-binding-inputline {chan l devid} {
 903     global showunbound
 904     upvar #0 input/$devid in
 905     if {![catch { info args ib-inputline/$in(concrete) }]} {
 906         # give the input binding first dibs
 907         if {[ib-inputline/$in(concrete) $devid $l]} return
 908     }
 909     regsub {^[^ ]+ } $l {} lr
 910     switch -glob -- $lr {
 911         {opened *} {
 912             debug "ib $devid start << $l"
 913             if {[info exists in(speedw)]} {
 914                 speedw-setstate $in(speedw) normal
 915             }
 916         }
 917         {[-0-9]*} {
 918             manyset [split $lr] value kindl kindr codel coder
 919             set proc ib-ev/$in(concrete)/${kindl}_${kindr}/${codel}_${coder}
 920             if {[catch { info args $proc }]} {
 921                 if {$showunbound} {
 922                     debug "ib $devid unbound $proc << $l"
 923                 }
 924                 return
 925             }
 926             $proc $devid $value
 927         }
 928         * {
 929             debug "ib $devid ignored << $l"
 930         }
 931     }
 932 }
 933
 934 proc catch-for-input-binding {devid body} {
 935     upvar #0 input/$devid in
 936     global errorInfo errorCode
 937     set r [catch { uplevel 1 $body } rv]
 938     if {$r!=1} { return -code $r $rv }
 939     switch -glob $errorCode {
 940         {CHILDSTATUS *} { set m "exited with status [lindex $errorCode 2]" }
 941         {CHILDKILLED *} { set m "killed by signal [lindex $errorCode 3]" }
 942         {POSIX *} { set m "communication error: [lindex $errorCode 1]" }
 943         * { error $rv $errorInfo $errorCode }
 944     }
 945     debug "ib $devid died $m"
 946     catch { close $in(chan) }
 947     catch { unset in(chan) }
 948
 949     input-binding-notpresent $devid "died $m"
 950 }
 951
 952 proc engage-input-bindings {} {
 953     scan-input-bindings
 954 }
 955
 956 #---------- plan background (gui-plan subprocess) ----------
 957
 958 proc gui-pipe-readable {args} {
 959     global gui_pipe
 960     while {[gets $gui_pipe l] >= 0} {
 961         debug "<gui-plan $l"
 962     }
 963     if {[eof $gui_pipe]} {
 964         close $gui_pipe
 965         error "gui-plan crashed"
 966     }
 967 }
 968
 969 #---------- train set events of general interest, and setup ----------
 970
 971 proc train-event-eof {args} {
 972     error "lost connection to train set"
 973 }
 974
 975 register-event ?stastate {ctxch state} {^(.)stastate (\w+|\-) } {
 976     global ctrain trains stastate
 977     set stastate $state
 978     report-problem "stastate: $state"
 979     if {[string compare $ctxch |]} speedws-stastate-hook
 980 }
 981
 982 register-event ?resolution {message} \
 983         {^.resolution (\S+ .*)$} {
 984     if {[string match "problems *" $message]} return
 985     report-problem "resolution: $message"
 986 }
 987
 988 register-event ?warning {message} {^.warning (\S+ .*)$} {
 989     report-problem "warning: $message"
 990 }
 991
 992 register-event {} {} {^=connected } {
 993     global pages gui_pipe server port event_selections
 994
 995     scmd replayed {} "select-replay [concat $event_selections]"
 996
 997     foreach page $pages {
 998         set w [pagew $page]
 999         tkwait visibility $w.picture
1000
1001         set cmdl [list ./gui-plan-$page [winfo id $w.picture] @$server,$port]
1002         lappend cmdl 2>@ stderr
1003         set gui_pipe [open |$cmdl r]
1004
1005         puts stderr "running $cmdl"
1006         fconfigure $gui_pipe -blocking no
1007         fileevent $gui_pipe readable gui-pipe-readable
1008     }
1009 }
1010 proc replayed-err {m args} { error "replay failed: $m" }
1011 proc replayed-ok {m args} {
1012     speedws-stastate-hook
1013 }
1014
1015 register-event {} {} {^=failed } { error "multiplexer failed: $l" }
1016 register-event {} {} {^=denied } { error "multiplexer denied us: $l" }
1017 register-event {} {} {^\+nack } { error "multiplexer does not understand" }
1018
1019 #---------- main program ----------
1020
1021 append event_dispatch_body {
1022     debug "ignored $l"
1023 }
1024 proc train-event-inputline {sconn l} $event_dispatch_body
1025 proc register-event {args} { error "too late!" }
1026
1027 proc engage-server {} {
1028     global server port sconn
1029
1030     set sconn [socket $server $port]
1031     fconfig-trainproto $sconn
1032     fileevent $sconn readable {readable train-event $sconn}
1033 }
1034
1035 proc main {} {
1036     global pages cpage configfile input_bindings input_statics
1037     setting server railway {[[0-9a-z:].*}
1038     setting geometry {} {[-+]\d+[-+]\d+}
1039     setting posdeviation 5 {\d+}
1040     setting movfeatcommand {movfeat+} {(?:!movfeat|movfeat\+?\+?)}
1041     setting problemdisplayms 1000 {\d+}
1042     setting inputretryadd 5 {\d+}
1043     setting inputretrymax 15 {\d+}
1044     setting scaninputinterval 500 {\d+}
1045     setting showunbound 0 {[01]}
1046
1047     set hostname [lindex [split [info hostname] .] 0]
1048     setting configfile gui-$hostname.config {.+}
1049     parse-argv {}
1050
1051     frame .inputs
1052     if {![info exists input_bindings]} { set input_bindings {} }
1053     if {![info exists input_statics]} { set input_statics {} }
1054
1055     uplevel #0 source gui-layout.config
1056     uplevel #0 source $configfile
1057     foreach cpage $pages {
1058         layout-data
1059         widgets-dgram
1060     }
1061     unset cpage
1062     widgets-movpos
1063     widgets-input-bindings
1064     widget-problem-report
1065     engage-server
1066     engage-input-bindings
1067     start_commandloop
1068 }
1069
1070 main