detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12
  13  set_f qqTRISA
  14  set_f qqTRISB
  15  set_f qqTRISC
  16  set_f qqTRISD
  17  set_f qqTRISE
  18  mov_lw 0xaa
  19  mov_wf qqLATA
  20  mov_wf qqLATB
  21  mov_wf qqLATC
  22  mov_wf qqLATD
  23  mov_wf qqLATE
  24
  25         clr_f   INTCON
  26         bs_f    RCON, IPEN      ; interrupt priorities
  27
  28         call    idlocs_init
  29         clr_f   flags
  30
  31         bt_f_if0 idloc1,idloc1_master
  32         call    slave_init
  33
  34         bt_f_if1 idloc1,idloc1_master
  35         call    master_init
  36
  37         bs_f    INTCON, GIEH
  38         bs_f    INTCON, GIEL
  39
  40         bt_f_if1 idloc1,idloc1_master
  41         goto    backgroundloop_master
  42         bt_f_if1 idloc1,idloc1_boarddet
  43         goto    backgroundloop_detectors
  44         goto    backgroundloop_reversers
  45
  46 ;----------
  47 common_local_init
  48 ; called by {master,slave}_init immediately after they've init'd i2c.
  49         clr_f   PCLATU
  50         call    bitnum2bit_init
  51
  52         call    points_local_init
  53         call    polarity_local_init
  54         call    detect_local_init
  55         return
  56
  57 ;----------------------------------------
  58 panic_kill_hook @
  59         call    power_panichook
  60         call    cdu_panichook
  61         return
  62
  63 ;----------
  64 intrl_handled_routine @
  65         mov_ff  isr_low_save_stkptr, STKPTR
  66         intrl_handled_core
  67
  68 ;======================================================================
  69 ; MASTER
  70
  71 ;----------------------------------------
  72 master_init
  73 ; Master-specific initialisation.
  74         call    serial_init
  75         call    i2cm_init
  76         call    serialtxbuf_init
  77         call    polarity_master_init
  78         call    points_master_init
  79         call    common_local_init
  80         call    nmra_init
  81         call    serialtxfc_init
  82         call    mascan_init
  83         call    tick_init
  84         call    cdu_init
  85         call    power_polarising_init
  86         call    power_fault_init
  87         call    watchdog_init
  88  clr_f xdebug+0
  89         return
  90
  91 ;----------------------------------------
  92 master_interrupt_low @
  93         enter_interrupt_low
  94         call    tick_intrl
  95         call    nmra_serialrx_intrl
  96         call    power_fault_intrl
  97  mov_ff PIR1, xdebug+2
  98  mov_ff PIE1, xdebug+3
  99  mov_ff IPR1, xdebug+4
 100  mov_ff INTCON, xdebug+5
 101         call    serialtxfc_intrl
 102         call    serialtx_intrl
 103         call    points_local_intrl
 104         call    i2cm_intrl
 105  bs_f   xdebug+0, 5
 106         panic   morse_IL
 107
 108 ;----------------------------------------------------------------------
 109 serialrx_table_section  code    0x2000
 110
 111 ;--------------------
 112 serialrx_generalmsg @
 113 ;command_<something>  has same calling convention:
 114 ;
 115 ;  FSR0 ->      start of message                undefined
 116 ;  *FSR0        message                         undefined
 117 ;
 118         mov_fw  INDF0
 119         bra_n   serialrx_if_multibyte
 120         bra_z   command_crashed
 121
 122         xor_lw  0x21
 123         bra_z   command_power_on
 124         xor_lw  0x01
 125         bra_z   command_power_off
 126         bra     serialrx_bad
 127
 128 ;-----
 129 serialrx_if_multibyte
 130         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 131         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 132         bt_f_if0 PCL, 0 ; always true, but reads PCL
 133         add_wff PCL
 134         ; <--- here is zero
 135
 136         goto    serialrx_bad            ; 1 0000 xxx
 137         goto    command_ping            ; 1 0001 xxx
 138         goto    command_polarity        ; 1 0010 xxx
 139         goto    serialrx_bad            ; 1 0011 xxx
 140         goto    command_point           ; 1 0100 xxx
 141         goto    serialrx_bad            ; 1 0101 xxx
 142         goto    serialrx_bad            ; 1 0110 xxx
 143         goto    serialrx_bad            ; 1 0111 xxx
 144         goto    serialrx_bad            ; 1 1000 xxx
 145         goto    serialrx_bad            ; 1 1001 xxx
 146         goto    serialrx_bad            ; 1 1010 xxx
 147         goto    serialrx_bad            ; 1 1011 xxx
 148         goto    serialrx_bad            ; 1 1100 xxx
 149         goto    serialrx_bad            ; 1 1101 xxx
 150         goto    serialrx_bad            ; 1 1110 xxx
 151         goto    serialrx_bad            ; 1 1111 xxx
 152
 153 ;-----
 154 serialrx_bad
 155         mov_ff  INDF0, t
 156         panic   morse_HX
 157
 158 code2 code
 159 ;--------------------
 160 command_ping
 161         mov_fw  POSTINC0
 162         mov_ff  INDF0, t
 163         call    serial_addbyte
 164         mov_fw  t
 165         bra_n   command_ping_bad
 166         goto    serial_addbyte_another
 167
 168 command_ping_bad panic morse_HP
 169
 170 ;======================================================================
 171 ; SLAVE
 172
 173 ;----------------------------------------
 174 slave_init
 175 ; Slave-specific initialisation.
 176         mov_fw  picno
 177         call    i2cs_init
 178
 179         bc_f    T0CON, TMR0ON
 180
 181         call    common_local_init
 182         call    detect_slave_init
 183         return
 184
 185 ;----------------------------------------
 186 slave_interrupt_low @
 187         enter_interrupt_low
 188         call    points_local_intrl
 189         panic   morse_IL
 190
 191 ;----------------------------------------
 192 i2csu_write_begin
 193         return
 194
 195 near_local_do code
 196 ;----------------------------------------
 197 i2csu_write_data
 198         call    led_green
 199
 200         bt_w_if0 7
 201         bra     i2csu_write_if_special
 202         bt_w_if1 6
 203         bra     polarity_local_do
 204         bt_w_if0 5
 205         bra     point_local_do
 206 i2csu_write_if_bad
 207         mov_wf  t
 208         panic   morse_DX
 209
 210 i2csu_write_if_special
 211         tst_w_ifnz
 212         bra     i2csu_write_if_bad
 213         goto    panic_crashread_commanded
 214
 215 code3 code
 216 ;======================================================================
 217 ; MASTER/SLAVE deviations
 218
 219 ;----------
 220 message_for_master @
 221 ; Either transmits the message to the master, or if we are the master,
 222 ; handles it as an incoming message from the notional `slave 0'.
 223 ;  W            message         unchanged
 224 ;  GIEH         set             set
 225         bt_f_if0 idloc1,idloc1_master
 226         goto    slave_add_short_message
 227         goto    loopback_read_byte
 228
 229 ;======================================================================
 230   include final.inc