detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12         clr_f   INTCON
  13         bs_f    RCON, IPEN      ; interrupt priorities
  14
  15         call    idlocs_init
  16
  17         bt_f_if0 idloc1,idloc1_master
  18         call    slave_init
  19
  20         bt_f_if1 idloc1,idloc1_master
  21         call    master_init
  22
  23         bs_f    INTCON, GIEH
  24         bs_f    INTCON, GIEL
  25
  26         bt_f_if1 idloc1,idloc1_master
  27         goto    backgroundloop_master
  28         bt_f_if1 idloc1,idloc1_boarddet
  29         goto    backgroundloop_detectors
  30         goto    backgroundloop_reversers
  31
  32 ;----------
  33 common_local_init
  34 ; called by {master,slave}_init immediately after they've init'd i2c.
  35         clr_f   PCLATU
  36         call    bitnum2bit_init
  37
  38         call    points_local_init
  39         call    polarity_local_init
  40         call    detect_local_init
  41         return
  42
  43 ;----------------------------------------
  44 panic_kill_hook @
  45         call    power_panichook
  46         call    cdu_panichook
  47         return
  48
  49 ;----------
  50 intrl_handled_routine @
  51         mov_ff  isr_low_save_stkptr, STKPTR
  52         intrl_handled_core
  53
  54 ;======================================================================
  55 ; MASTER
  56
  57 ;----------------------------------------
  58 master_init
  59 ; Master-specific initialisation.
  60         call    memory_erase
  61         clr_f   flags
  62  set_f xdebug+7
  63         call    serial_init
  64         call    i2cm_init
  65         call    serialtxbuf_init
  66         call    polarity_master_init
  67         call    points_master_init
  68         call    common_local_init
  69         call    nmra_init
  70         call    serialtxfc_init
  71         call    mascan_init
  72         call    tick_init
  73         call    cdu_init
  74         call    power_polarising_init
  75         call    power_fault_init
  76         call    watchdog_init
  77  clr_f xdebug+0
  78         return
  79
  80 ;----------------------------------------
  81 master_interrupt_low @
  82         enter_interrupt_low
  83  D 0x80
  84         call    tick_intrl
  85  D 0x01
  86         call    nmra_serialrx_intrl
  87  D 0x02
  88         call    power_fault_intrl
  89  D 0x03
  90         call    serialtxfc_intrl
  91  D 0x04
  92         call    serialtx_intrl
  93  D 0x05
  94         call    points_local_intrl
  95  D 0x06
  96         call    i2cm_intrl
  97  bs_f   xdebug+0, 5
  98         panic   morse_IL
  99
 100 ;----------------------------------------------------------------------
 101 serialrx_table_section  code    0x2000
 102
 103 ;--------------------
 104 serialrx_generalmsg @
 105 ;command_<something>  has same calling convention:
 106 ;
 107 ;  FSR0 ->      start of message                undefined
 108 ;  *FSR0        message                         undefined
 109 ;
 110         mov_fw  INDF0
 111         bra_n   serialrx_if_multibyte
 112         bra_z   command_crashed
 113
 114         xor_lw  0x21
 115         bra_z   command_power_on
 116         xor_lw  0x01
 117         bra_z   command_power_off
 118         bra     serialrx_bad
 119
 120 ;-----
 121 serialrx_if_multibyte
 122         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 123         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 124         bt_f_if0 PCL, 0 ; always true, but reads PCL
 125         add_wff PCL
 126         ; <--- here is zero
 127
 128         goto    serialrx_bad            ; 1 0000 xxx
 129         goto    command_ping            ; 1 0001 xxx
 130         goto    command_polarity        ; 1 0010 xxx
 131         goto    command_watchdog        ; 1 0011 xxx
 132         goto    command_point           ; 1 0100 xxx
 133         goto    serialrx_bad            ; 1 0101 xxx
 134         goto    serialrx_bad            ; 1 0110 xxx
 135         goto    serialrx_bad            ; 1 0111 xxx
 136         goto    serialrx_bad            ; 1 1000 xxx
 137         goto    serialrx_bad            ; 1 1001 xxx
 138         goto    serialrx_bad            ; 1 1010 xxx
 139         goto    serialrx_bad            ; 1 1011 xxx
 140         goto    serialrx_bad            ; 1 1100 xxx
 141         goto    serialrx_bad            ; 1 1101 xxx
 142         goto    serialrx_bad            ; 1 1110 xxx
 143         goto    serialrx_bad            ; 1 1111 xxx
 144
 145 ;-----
 146 serialrx_bad
 147         mov_ff  INDF0, t
 148         panic   morse_HX
 149
 150 code2 code
 151 ;--------------------
 152 command_ping
 153         mov_fw  POSTINC0
 154         mov_ff  INDF0, t
 155         call    serial_addbyte
 156         mov_fw  t
 157         bra_n   command_ping_bad
 158         goto    serial_addbyte_another
 159
 160 command_ping_bad panic morse_HP
 161
 162 ;======================================================================
 163 ; SLAVE
 164
 165 ;----------------------------------------
 166 slave_init
 167 ; Slave-specific initialisation.
 168         clr_f   flags
 169
 170         mov_fw  picno
 171         call    i2cs_init
 172
 173         bc_f    T0CON, TMR0ON
 174
 175         call    common_local_init
 176         call    detect_slave_init
 177         return
 178
 179 ;----------------------------------------
 180 slave_interrupt_low @
 181         enter_interrupt_low
 182         call    points_local_intrl
 183         panic   morse_IL
 184
 185 ;----------------------------------------
 186 i2csu_write_begin
 187         return
 188
 189 near_local_do code
 190 ;----------------------------------------
 191 i2csu_write_data
 192         call    led_green
 193
 194         bt_w_if0 7
 195         bra     i2csu_write_if_special
 196         bt_w_if1 6
 197         bra     polarity_local_do
 198         bt_w_if0 5
 199         bra     point_local_do
 200 i2csu_write_if_bad
 201         mov_wf  t
 202         panic   morse_DX
 203
 204 i2csu_write_if_special
 205         tst_w_ifnz
 206         bra     i2csu_write_if_bad
 207         goto    panic_crashread_commanded
 208
 209 code3 code
 210 ;======================================================================
 211 ; MASTER/SLAVE deviations
 212
 213 ;----------
 214 message_for_master @
 215 ; Either transmits the message to the master, or if we are the master,
 216 ; handles it as an incoming message from the notional `slave 0'.
 217 ;  W            message         unchanged
 218 ;  GIEH         set             set
 219         bt_f_if0 idloc1,idloc1_master
 220         goto    slave_add_short_message
 221         goto    loopback_read_byte
 222
 223 ;======================================================================
 224   include final.inc