detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4  include common.inc
   5  code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset
  12
  13  set_f qqTRISA
  14  set_f qqTRISB
  15  set_f qqTRISC
  16  set_f qqTRISD
  17  set_f qqTRISE
  18  mov_lw 0xaa
  19  mov_wf qqLATA
  20  mov_wf qqLATB
  21  mov_wf qqLATC
  22  mov_wf qqLATD
  23  mov_wf qqLATE
  24
  25         clr_f   INTCON
  26         bs_f    RCON, IPEN      ; interrupt priorities
  27
  28         call    idlocs_init
  29         clr_f   flags
  30
  31         bt_f_if0 idloc1,idloc1_master
  32         call    slave_init
  33
  34         bt_f_if1 idloc1,idloc1_master
  35         call    master_init
  36
  37         bs_f    INTCON, GIEH
  38         bs_f    INTCON, GIEL
  39
  40         bt_f_if1 idloc1,idloc1_master
  41         goto    backgroundloop_master
  42         bt_f_if1 idloc1,idloc1_boarddet
  43         goto    backgroundloop_detectors
  44         goto    backgroundloop_reversers
  45
  46 ;----------
  47 common_local_init
  48 ; called by {master,slave}_init immediately after they've init'd i2c.
  49         clr_f   PCLATU
  50         call    bitnum2bit_init
  51
  52         call    points_local_init
  53         call    polarity_local_init
  54         call    detect_local_init
  55         return
  56
  57 ;----------------------------------------
  58 panic_kill_hook
  59         call    power_panichook
  60         call    cdu_panichook
  61         return
  62
  63 ;----------
  64 intrl_handled_routine
  65         mov_ff  isr_low_save_stkptr, STKPTR
  66         intrl_handled_core
  67
  68 ;======================================================================
  69 ; MASTER
  70
  71 ;----------------------------------------
  72 master_init
  73 ; Master-specific initialisation.
  74         call    i2cm_init
  75         call    serialtxbuf_init
  76         call    polarity_master_init
  77         call    points_master_init
  78         call    common_local_init
  79         call    serial_init
  80         call    nmra_init
  81         call    serialtxfc_init
  82         call    mascan_init
  83         call    tick_init
  84         call    power_polarising_init
  85         return
  86
  87 ;----------------------------------------
  88 master_interrupt_low
  89         enter_interrupt_low
  90         call    tick_intrl
  91         call    nmra_serialrx_intrl
  92         call    serialtx_intrl
  93         call    points_local_intrl
  94         call    i2cm_intrl
  95         panic   morse_IL
  96
  97 ;----------
  98 near_interrupt_high code
  99 master_interrupt_high_notnmra
 100         panic   morse_IH
 101
 102 ;----------------------------------------------------------------------
 103 serialrx_table_section  code    0x2000
 104
 105 ;--------------------
 106 serialrx_generalmsg
 107 ;command_<something>  has same calling convention:
 108 ;
 109 ;  FSR0 ->      start of message                undefined
 110 ;  *FSR0        message                         undefined
 111 ;
 112 ;                               ; INDF0=MM ww ww ww ww ii ii ii
 113         rlc_fw  INDF0           ; W =   ww ww ww ww ii ii ii ??  C=MM Z=00
 114         bra_c   serialrx_if_multibyte
 115         bra_z   command_crashed
 116         ; single-byte non-0 command, has to be ON or OFF
 117         ;       ie supposedly   ; INDF0=zz zz II zz zz zz zz PP  C=zz
 118         rrc_fw  INDF0           ; W =   zz zz zz II zz zz zz zz  C=PP
 119         xor_lw  0x10            ; W =   zz zz zz zz zz zz zz zz  C=PP Z=OK
 120         bra_n   serialrx_bad
 121         goto    command_power
 122
 123 ;-----
 124 serialrx_if_multibyte
 125         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 126         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 127         bt_f_if0 PCL, 0 ; always true, but reads PCL
 128         add_wff PCL
 129         ; <--- here is zero
 130
 131         goto    serialrx_bad            ; 1 0000 xxx
 132         goto    command_ping            ; 1 0001 xxx
 133         goto    command_polarity        ; 1 0010 xxx
 134         goto    serialrx_bad            ; 1 0011 xxx
 135         goto    command_point           ; 1 0100 xxx
 136         goto    serialrx_bad            ; 1 0101 xxx
 137         goto    serialrx_bad            ; 1 0110 xxx
 138         goto    serialrx_bad            ; 1 0111 xxx
 139         goto    serialrx_bad            ; 1 1000 xxx
 140         goto    serialrx_bad            ; 1 1001 xxx
 141         goto    serialrx_bad            ; 1 1010 xxx
 142         goto    serialrx_bad            ; 1 1011 xxx
 143         goto    serialrx_bad            ; 1 1100 xxx
 144         goto    serialrx_bad            ; 1 1101 xxx
 145         goto    serialrx_bad            ; 1 1110 xxx
 146         goto    serialrx_bad            ; 1 1111 xxx
 147
 148         goto    serialrx_bad    ; 0 0000 xxx
 149         goto    serialrx_bad    ; 0 0001 xxx
 150         goto    serialrx_bad    ; 0 0000 xxx
 151
 152 ;-----
 153 serialrx_bad
 154         mov_ff  INDF0, t
 155         panic   morse_HX
 156
 157 ;--------------------
 158 command_ping
 159         mov_fw  POSTINC0
 160         mov_ff  INDF0, t
 161         call    serial_addbyte
 162         mov_fw  t
 163         bra_n   command_ping_bad
 164         goto    serial_addbyte_another
 165
 166 command_ping_bad panic morse_HP
 167
 168 code2 code
 169 ;======================================================================
 170 ; SLAVE
 171
 172 ;----------------------------------------
 173 slave_init
 174 ; Slave-specific initialisation.
 175         mov_fw  picno
 176         call    i2cs_init
 177
 178         bc_f    T0CON, TMR0ON
 179
 180         call    common_local_init
 181         call    detect_slave_init
 182         return
 183
 184 ;----------------------------------------
 185 slave_interrupt_low
 186         enter_interrupt_low
 187         call    points_local_intrl
 188         panic   morse_IL
 189
 190 ;----------------------------------------
 191 i2csu_write_begin
 192         return
 193
 194 near_local_do code
 195 ;----------------------------------------
 196 i2csu_write_data
 197         call    led_green
 198
 199         bt_w_if0 7
 200         bra     i2csu_write_if_special
 201         bt_w_if1 6
 202         bra     polarity_local_do
 203         bt_w_if0 5
 204         bra     point_local_do
 205 i2csu_write_if_bad
 206         mov_wf  t
 207         panic   morse_DX
 208
 209 i2csu_write_if_special
 210         tst_w_ifnz
 211         bra     i2csu_write_if_bad
 212         goto    panic_crashread_commanded
 213
 214 code3 code
 215 ;======================================================================
 216 ; MASTER/SLAVE deviations
 217
 218 ;----------
 219 message_for_master
 220 ; Either transmits the message to the master, or if we are the master,
 221 ; handles it as an incoming message from the notional `slave 0'.
 222 ;  W            message         unchanged
 223 ;  GIEH         set             set
 224         bt_f_if0 idloc1,idloc1_master
 225         goto    slave_add_short_message
 226         goto    loopback_read_byte
 227
 228 ;======================================================================
 229  include final.inc