detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12         clr_f   INTCON
  13         bs_f    RCON, IPEN      ; interrupt priorities
  14
  15         call    idlocs_init
  16
  17         bt_f_if0 idloc1,idloc1_master
  18         call    slave_init
  19
  20         bt_f_if1 idloc1,idloc1_master
  21         call    master_init
  22
  23         bs_f    INTCON, GIEH
  24         bs_f    INTCON, GIEL
  25
  26         bt_f_if1 idloc1,idloc1_master
  27         goto    backgroundloop_master
  28         bt_f_if1 idloc1,idloc1_boarddet
  29         goto    backgroundloop_detectors
  30         goto    backgroundloop_reversers
  31
  32 ;----------
  33 common_local_init
  34 ; called by {master,slave}_init immediately after they've init'd i2c.
  35         clr_f   PCLATU
  36         call    bitnum2bit_init
  37
  38         call    points_local_init
  39         call    polarity_local_init
  40         call    detect_local_init
  41         return
  42
  43 ;----------------------------------------
  44 panic_kill_hook @
  45         call    power_panichook
  46         call    cdu_panichook
  47         return
  48
  49 ;----------
  50 intrl_handled_routine @
  51         mov_ff  isr_low_save_stkptr, STKPTR
  52         intrl_handled_core
  53
  54 ;======================================================================
  55 ; MASTER
  56
  57 ;----------------------------------------
  58 master_init
  59 ; Master-specific initialisation.
  60         call    memory_erase
  61         clr_f   flags
  62  set_f xdebug+7
  63  clr_f xdebug+6
  64         call    serial_init
  65         call    i2cm_init
  66         call    serialtxbuf_init
  67         call    polarity_master_init
  68         call    points_master_init
  69         call    common_local_init
  70         call    nmra_init
  71         call    serialtxfc_init
  72         call    mascan_init
  73         call    tick_init
  74         call    cdu_init
  75         call    power_polarising_init
  76         call    power_fault_init
  77         call    watchdog_init
  78  clr_f xdebug+0
  79         return
  80
  81 ;----------------------------------------
  82 master_interrupt_low @
  83         enter_interrupt_low
  84  D 0x80
  85         call    tick_intrl
  86  ;Dl 0x01
  87         call    nmra_serialrx_intrl
  88  ;Dl 0x02
  89         call    power_fault_intrl
  90  ;Dl 0x03
  91         call    serialtxfc_intrl
  92  ;Dl 0x04
  93         call    serialtx_intrl
  94  ;Dl 0x05
  95         call    points_local_intrl
  96  ;Dl 0x06
  97         call    i2cm_intrl
  98  bs_f   xdebug+0, 5
  99         panic   morse_IL
 100
 101 ;----------------------------------------------------------------------
 102 serialrx_table_section  code    0x2000
 103
 104 ;--------------------
 105 serialrx_generalmsg @
 106 ;command_<something>  has same calling convention:
 107 ;
 108 ;  FSR0 ->      start of message                undefined
 109 ;  *FSR0        message                         undefined
 110 ;
 111         mov_fw  INDF0
 112         bra_n   serialrx_if_multibyte
 113         bra_z   command_crashed
 114
 115         xor_lw  0x21
 116         bra_z   command_power_on
 117         xor_lw  0x01
 118         bra_z   command_power_off
 119         bra     serialrx_bad
 120
 121 ;-----
 122 serialrx_if_multibyte
 123         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 124         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 125         bt_f_if0 PCL, 0 ; always true, but reads PCL
 126         add_wff PCL
 127         ; <--- here is zero
 128
 129         goto    serialrx_bad            ; 1 0000 xxx
 130         goto    command_ping            ; 1 0001 xxx
 131         goto    command_polarity        ; 1 0010 xxx
 132         goto    command_watchdog        ; 1 0011 xxx
 133         goto    command_point           ; 1 0100 xxx
 134         goto    serialrx_bad            ; 1 0101 xxx
 135         goto    serialrx_bad            ; 1 0110 xxx
 136         goto    serialrx_bad            ; 1 0111 xxx
 137         goto    serialrx_bad            ; 1 1000 xxx
 138         goto    serialrx_bad            ; 1 1001 xxx
 139         goto    serialrx_bad            ; 1 1010 xxx
 140         goto    serialrx_bad            ; 1 1011 xxx
 141         goto    serialrx_bad            ; 1 1100 xxx
 142         goto    serialrx_bad            ; 1 1101 xxx
 143         goto    serialrx_bad            ; 1 1110 xxx
 144         goto    serialrx_bad            ; 1 1111 xxx
 145
 146 ;-----
 147 serialrx_bad
 148         mov_ff  INDF0, t
 149         panic   morse_HX
 150
 151 code2 code
 152 ;--------------------
 153 command_ping
 154         mov_fw  POSTINC0
 155         mov_ff  INDF0, t
 156         call    serial_addbyte
 157         mov_fw  t
 158         bra_n   command_ping_bad
 159  mov_wf xdebug+6
 160         goto    serial_addbyte_another
 161
 162 command_ping_bad panic morse_HP
 163
 164 ;======================================================================
 165 ; SLAVE
 166
 167 ;----------------------------------------
 168 slave_init
 169 ; Slave-specific initialisation.
 170         clr_f   flags
 171
 172         mov_fw  picno
 173         call    i2cs_init
 174
 175         bc_f    T0CON, TMR0ON
 176
 177         call    common_local_init
 178         call    detect_slave_init
 179         return
 180
 181 ;----------------------------------------
 182 slave_interrupt_low @
 183         enter_interrupt_low
 184         call    points_local_intrl
 185         panic   morse_IL
 186
 187 ;----------------------------------------
 188 i2csu_write_begin
 189         return
 190
 191 near_local_do code
 192 ;----------------------------------------
 193 i2csu_write_data
 194         call    led_green
 195
 196         bt_w_if0 7
 197         bra     i2csu_write_if_special
 198         bt_w_if1 6
 199         bra     polarity_local_do
 200         bt_w_if0 5
 201         bra     point_local_do
 202 i2csu_write_if_bad
 203         mov_wf  t
 204         panic   morse_DX
 205
 206 i2csu_write_if_special
 207         tst_w_ifnz
 208         bra     i2csu_write_if_bad
 209         goto    panic_crashread_commanded
 210
 211 code3 code
 212 ;======================================================================
 213 ; MASTER/SLAVE deviations
 214
 215 ;----------
 216 message_for_master @
 217 ; Either transmits the message to the master, or if we are the master,
 218 ; handles it as an incoming message from the notional `slave 0'.
 219 ;  W            message         unchanged
 220 ;  GIEH         set             set
 221         bt_f_if0 idloc1,idloc1_master
 222         goto    slave_add_short_message
 223         goto    loopback_read_byte
 224
 225 ;======================================================================
 226   include final.inc