detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12         clr_f   INTCON
  13         bs_f    RCON, IPEN      ; interrupt priorities
  14
  15         call    idlocs_init
  16
  17         bt_f_if0 idloc1,idloc1_master
  18         call    slave_init
  19
  20         bt_f_if1 idloc1,idloc1_master
  21         call    master_init
  22
  23         bs_f    INTCON, GIEH
  24         bs_f    INTCON, GIEL
  25
  26         bt_f_if1 idloc1,idloc1_master
  27         goto    backgroundloop_master
  28         bt_f_if1 idloc1,idloc1_boarddet
  29         goto    backgroundloop_detectors
  30         goto    backgroundloop_reversers
  31
  32 ;----------
  33 common_local_init
  34 ; called by {master,slave}_init immediately after they've init'd i2c.
  35         clr_f   PCLATU
  36         call    bitnum2bit_init
  37
  38         call    points_local_init
  39         call    polarity_local_init
  40         call    detect_local_init
  41         return
  42
  43 ;----------------------------------------
  44 panic_kill_hook @
  45         call    power_panichook
  46         call    cdu_panichook
  47         return
  48
  49 ;----------
  50 intrl_handled_routine @
  51         mov_ff  isr_low_save_stkptr, STKPTR
  52         intrl_handled_core
  53
  54 ;======================================================================
  55 ; MASTER
  56
  57 ;----------------------------------------
  58 master_init
  59 ; Master-specific initialisation.
  60         call    memory_erase
  61         clr_f   flags
  62         call    serial_init
  63         call    i2cm_init
  64         call    serialtxbuf_init
  65         call    polarity_master_init
  66         call    points_master_init
  67         call    common_local_init
  68         call    nmra_init
  69         call    serialtxfc_init
  70         call    mascan_init
  71         call    tick_init
  72         call    cdu_init
  73         call    power_polarising_init
  74         call    power_fault_init
  75         call    watchdog_init
  76         return
  77
  78 ;----------------------------------------
  79 master_interrupt_low @
  80         enter_interrupt_low
  81         Dl 0x80
  82         Df      INTCON
  83         Df      INTCON2
  84         Df      INTCON3
  85         Df      PIR1
  86         Df      PIR2
  87         Df      PIR3
  88         Dl 0x8d
  89         call    tick_intrl
  90         call    nmra_serialrx_intrl
  91         call    power_fault_intrl
  92         call    serialtxfc_intrl
  93         call    serialtx_intrl
  94         call    points_local_intrl
  95         call    i2cm_intrl
  96         Dl 0x8e
  97         Df      INTCON
  98         Df      INTCON2
  99         Df      INTCON3
 100         Df      PIR1
 101         Df      PIR2
 102         Df      PIR3
 103         Dl 0x8f
 104         panic   morse_IL
 105
 106 ;----------------------------------------------------------------------
 107 serialrx_table_section  code    0x2000
 108
 109 ;--------------------
 110 command_tellmode
 111         mov_lw  0x09
 112         goto    serial_addbyte
 113
 114 ;--------------------
 115 serialrx_generalmsg @
 116 ;command_<something>  has same calling convention:
 117 ;
 118 ;  FSR0 ->      start of message                undefined
 119 ;  *FSR0        message                         undefined
 120 ;
 121         mov_fw  INDF0
 122         bra_n   serialrx_if_multibyte
 123         bra_z   command_crashed
 124
 125         xor_lw  0x11
 126         bra_z   command_power_on
 127         xor_lw  0x10 ^ 0x11
 128         bra_z   command_power_off
 129         xor_lw  0x0a ^ 0x10
 130         bra_z   command_tellmode
 131         bra     serialrx_bad
 132
 133 ;-----
 134 serialrx_if_multibyte
 135         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 136         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 137         bt_f_if0 PCL, 0 ; always true, but reads PCL
 138         add_wff PCL
 139         ; <--- here is zero
 140
 141         goto    serialrx_bad            ; 1 0000 xxx
 142         goto    command_ping            ; 1 0001 xxx
 143         goto    command_polarity        ; 1 0010 xxx
 144         goto    command_watchdog        ; 1 0011 xxx
 145         goto    command_point           ; 1 0100 xxx
 146         goto    serialrx_bad            ; 1 0101 xxx
 147         goto    serialrx_bad            ; 1 0110 xxx
 148         goto    serialrx_bad            ; 1 0111 xxx
 149         goto    serialrx_bad            ; 1 1000 xxx
 150         goto    serialrx_bad            ; 1 1001 xxx
 151         goto    serialrx_bad            ; 1 1010 xxx
 152         goto    serialrx_bad            ; 1 1011 xxx
 153         goto    serialrx_bad            ; 1 1100 xxx
 154         goto    serialrx_bad            ; 1 1101 xxx
 155         goto    serialrx_bad            ; 1 1110 xxx
 156         goto    serialrx_bad            ; 1 1111 xxx
 157
 158 ;-----
 159 serialrx_bad
 160         mov_ff  INDF0, t
 161         panic   morse_HX
 162
 163 code2 code
 164 ;--------------------
 165 command_ping
 166         mov_fw  POSTINC0
 167         mov_ff  INDF0, t
 168         call    serial_addbyte
 169         mov_fw  t
 170         bra_n   command_ping_bad
 171         goto    serial_addbyte_another
 172
 173 command_ping_bad panic morse_HP
 174
 175 ;======================================================================
 176 ; SLAVE
 177
 178 ;----------------------------------------
 179 slave_init
 180 ; Slave-specific initialisation.
 181         clr_f   flags
 182
 183         mov_fw  picno
 184         call    i2cs_init
 185
 186         bc_f    T0CON, TMR0ON
 187
 188         call    common_local_init
 189         call    detect_slave_init
 190         return
 191
 192 ;----------------------------------------
 193 slave_interrupt_low @
 194         enter_interrupt_low
 195         call    points_local_intrl
 196         panic   morse_IL
 197
 198 ;----------------------------------------
 199 i2csu_write_begin
 200         return
 201
 202 near_local_do code
 203 ;----------------------------------------
 204 i2csu_write_data
 205         call    led_green
 206
 207         bt_w_if0 7
 208         bra     i2csu_write_if_special
 209         bt_w_if1 6
 210         bra     polarity_local_do
 211         bt_w_if0 5
 212         bra     point_local_do
 213 i2csu_write_if_bad
 214         mov_wf  t
 215         panic   morse_DX
 216
 217 i2csu_write_if_special
 218         tst_w_ifnz
 219         bra     i2csu_write_if_bad
 220         goto    panic_crashread_commanded
 221
 222 code3 code
 223 ;======================================================================
 224 ; MASTER/SLAVE deviations
 225
 226 ;----------
 227 message_for_master @
 228 ; Either transmits the message to the master, or if we are the master,
 229 ; handles it as an incoming message from the notional `slave 0'.
 230 ;  W            message         unchanged
 231 ;  GIEH         set             set
 232         bt_f_if0 idloc1,idloc1_master
 233         goto    slave_add_short_message
 234         goto    loopback_read_byte
 235
 236 ;======================================================================
 237   include final.inc