detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12         clr_f   INTCON
  13         bs_f    RCON, IPEN      ; interrupt priorities
  14
  15         call    idlocs_init
  16
  17         bt_f_if0 idloc1,idloc1_master
  18         call    slave_init
  19
  20         bt_f_if1 idloc1,idloc1_master
  21         call    master_init
  22
  23         bs_f    INTCON, GIEH
  24         bs_f    INTCON, GIEL
  25
  26         bt_f_if1 idloc1,idloc1_master
  27         goto    backgroundloop_master
  28         bt_f_if1 idloc1,idloc1_boarddet
  29         goto    backgroundloop_detectors
  30         goto    backgroundloop_reversers
  31
  32 ;----------
  33 common_local_init
  34 ; called by {master,slave}_init immediately after they've init'd i2c.
  35         clr_f   PCLATU
  36         call    bitnum2bit_init
  37
  38         call    points_local_init
  39         call    polarity_local_init
  40         call    detect_local_init
  41         return
  42
  43 ;----------------------------------------
  44 panic_kill_hook @
  45         call    power_panichook
  46         call    cdu_panichook
  47         return
  48
  49 ;----------
  50 intrl_handled_routine @
  51         mov_ff  isr_low_save_stkptr, STKPTR
  52         intrl_handled_core
  53
  54 ;======================================================================
  55 ; MASTER
  56
  57 ;----------------------------------------
  58 master_init
  59 ; Master-specific initialisation.
  60         call    memory_erase
  61         clr_f   flags
  62         call    serial_init
  63         call    i2cm_init
  64         call    serialtxbuf_init
  65         call    polarity_master_init
  66         call    points_master_init
  67         call    common_local_init
  68         call    nmra_init
  69         call    serialtxfc_init
  70         call    mascan_init
  71         call    tick_init
  72         call    cdu_init
  73         call    power_polarising_init
  74         call    power_fault_init
  75         call    watchdog_init
  76         call    i2c_consider_restartread ; sends hello when all slaves ack'd
  77         return
  78
  79 ;----------------------------------------
  80 master_interrupt_low @
  81         enter_interrupt_low
  82         Dl 0x80
  83         Df      INTCON
  84         Df      INTCON2
  85         Df      INTCON3
  86         Df      PIR1
  87         Df      PIR2
  88         Dl 0x8d
  89         call    tick_intrl
  90         call    nmra_serialrx_intrl
  91         call    power_fault_intrl
  92         call    serialtxfc_intrl
  93         call    serialtx_intrl
  94         call    points_local_intrl
  95         call    i2cm_intrl
  96         Dl 0x8e
  97         Df      INTCON
  98         Df      INTCON2
  99         Df      INTCON3
 100         Df      PIR1
 101         Df      PIR2
 102         Dl 0x8f
 103         panic   morse_IL
 104
 105 ;----------------------------------------------------------------------
 106 serialrx_table_section  code    0x2000
 107
 108 ;--------------------
 109 command_tellmode
 110         mov_lw  0x09
 111         goto    serial_addbyte
 112
 113 ;--------------------
 114 serialrx_generalmsg @
 115 ;command_<something>  has same calling convention:
 116 ;
 117 ;  FSR0 ->      start of message                undefined
 118 ;  *FSR0        message                         undefined
 119 ;
 120         mov_fw  INDF0
 121         bra_n   serialrx_if_multibyte
 122         bra_z   command_crashed
 123
 124         xor_lw  0x11
 125         bra_z   command_power_on
 126         xor_lw  0x10 ^ 0x11
 127         bra_z   command_power_off
 128         xor_lw  0x0a ^ 0x10
 129         bra_z   command_tellmode
 130         bra     serialrx_bad
 131
 132 ;-----
 133 serialrx_if_multibyte
 134         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 135         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 136         bt_f_if0 PCL, 0 ; always true, but reads PCL
 137         add_wff PCL
 138         ; <--- here is zero
 139
 140         goto    serialrx_bad            ; 1 0000 xxx
 141         goto    command_ping            ; 1 0001 xxx
 142         goto    command_polarity        ; 1 0010 xxx
 143         goto    command_watchdog        ; 1 0011 xxx
 144         goto    command_point           ; 1 0100 xxx
 145         goto    serialrx_bad            ; 1 0101 xxx
 146         goto    serialrx_bad            ; 1 0110 xxx
 147         goto    serialrx_bad            ; 1 0111 xxx
 148         goto    serialrx_bad            ; 1 1000 xxx
 149         goto    serialrx_bad            ; 1 1001 xxx
 150         goto    serialrx_bad            ; 1 1010 xxx
 151         goto    serialrx_bad            ; 1 1011 xxx
 152         goto    serialrx_bad            ; 1 1100 xxx
 153         goto    serialrx_bad            ; 1 1101 xxx
 154         goto    serialrx_bad            ; 1 1110 xxx
 155         goto    serialrx_bad            ; 1 1111 xxx
 156
 157 ;-----
 158 serialrx_bad
 159         mov_ff  INDF0, t
 160         panic   morse_HX
 161
 162 code2 code
 163 ;--------------------
 164 command_ping
 165         mov_fw  POSTINC0
 166         mov_ff  INDF0, t
 167         call    serial_addbyte
 168         mov_fw  t
 169         bra_n   command_ping_bad
 170         goto    serial_addbyte_another
 171
 172 command_ping_bad panic morse_HP
 173
 174 ;======================================================================
 175 ; SLAVE
 176
 177 ;----------------------------------------
 178 slave_init
 179 ; Slave-specific initialisation.
 180         clr_f   flags
 181
 182         mov_fw  picno
 183         call    i2cs_init
 184
 185         bc_f    T0CON, TMR0ON
 186
 187         call    common_local_init
 188         call    detect_slave_init
 189         return
 190
 191 ;----------------------------------------
 192 slave_interrupt_low @
 193         enter_interrupt_low
 194         call    points_local_intrl
 195         panic   morse_IL
 196
 197 ;----------------------------------------
 198 i2csu_write_begin
 199         return
 200
 201 near_local_do code
 202 ;----------------------------------------
 203 i2csu_write_data
 204         call    led_green
 205
 206         bt_w_if0 7
 207         bra     i2csu_write_if_special
 208         bt_w_if1 6
 209         bra     polarity_local_do
 210         bt_w_if0 5
 211         bra     point_local_do
 212 i2csu_write_if_bad
 213         mov_wf  t
 214         panic   morse_DX
 215
 216 i2csu_write_if_special
 217         tst_w_ifnz
 218         bra     i2csu_write_if_bad
 219         goto    panic_crashread_commanded
 220
 221 code3 code
 222 ;======================================================================
 223 ; MASTER/SLAVE deviations
 224
 225 ;----------
 226 message_for_master @
 227 ; Either transmits the message to the master, or if we are the master,
 228 ; handles it as an incoming message from the notional `slave 0'.
 229 ;  W            message         unchanged
 230 ;  GIEH         set             set
 231         bt_f_if0 idloc1,idloc1_master
 232         goto    slave_add_short_message
 233         goto    loopback_read_byte
 234
 235 ;======================================================================
 236   include final.inc