detpic/panic.asm

   1 ;======================================================================
   2 ; panic.asm
   3 ;
   4 ; This file implements panic_routine, which is called by the
   5 ; `panic' macro in panic.inc.  See panic.inc for the functionality
   6 ; of `panic'.
   7
   8         include common.inc
   9
  10 ;---------------------------------------------------------------------------
  11 ; reserved access bank locations
  12
  13  udata_acs
  14
  15 psave_intcon    res     1
  16 psave_bsr       res     1
  17
  18 panicst                         res     1
  19 panicst_restart_i2c             equ     7
  20 panicst_acked                   equ     5
  21 panicst_ferroerr                equ     4
  22 panicst_writeslave              equ     3
  23
  24 panic_valcount                  res     1
  25
  26 panic_vars_section udata 0x060 + maxpics ; not available via access bank
  27 ; used in panic routine for temporary storage:
  28
  29 flash_pattern           res     1
  30 morse_counter           res     1
  31 register_counter        res     1
  32 bit_counter             res     1
  33
  34 panic_address   res     1       ; condensed form of message start addr.
  35 panic_morse     res     1       ; # bytes of morse msg in panic readout
  36 panic_regs      res     1       ; # registers in panic readout
  37
  38 t0l_count       res     1
  39 t0h_count       res     1
  40
  41 psave_latc      res     1
  42 psave_t         res     1
  43 psave_tablat    res     1
  44 psave_tblptr    res     3
  45 psave_fsr0      res     2
  46 psave_fsr1      res     2
  47 psave_prod      res     2
  48 psave_stkptr    res     1
  49
  50 stack_depth     equ     31
  51 panic_stack     res     stack_depth*3
  52
  53 ;****************************************************************************
  54
  55 pan_ code
  56
  57 ;****************************************************************************
  58
  59
  60 panic_routine
  61 ; switch off interrupts and power
  62 ; reconfigure timer0 for writing diagnostic msg to the LED
  63
  64         mov_ff  INTCON, psave_intcon
  65         bc_f    INTCON, GIEH   ; disable all interrupts
  66
  67         mov_ff  BSR, psave_bsr
  68         banksel flash_pattern
  69
  70         mov_ff  LATC, psave_latc
  71
  72 ; now we have time to save registers etc
  73 ; (turning off interrupts is urgent (we might get interrupted while
  74 ;  panicing which would be bad because we might forget to panic).
  75
  76         mov_wf   panic_address
  77
  78         mov_ff  t, psave_t
  79         mov_ff  TABLAT, psave_tablat
  80         mov_ff  TBLPTRL, psave_tblptr
  81         mov_ff  TBLPTRH, psave_tblptr+1
  82         mov_ff  TBLPTRU, psave_tblptr+2
  83         mov_ff  FSR0L, psave_fsr0
  84         mov_ff  FSR0H, psave_fsr0+1
  85         mov_ff  FSR1L, psave_fsr1
  86         mov_ff  FSR1H, psave_fsr1+1
  87         mov_ff  PRODL, psave_prod
  88         mov_ff  PRODH, psave_prod+1
  89         mov_ff  STKPTR, psave_stkptr
  90
  91         mov_lfsr panic_stack + stack_depth*3 - 1, 0
  92         mov_lw  stack_depth
  93         mov_wf  STKPTR
  94 stacksave_loop
  95         mov_ff  TOSU, POSTDEC0
  96         mov_ff  TOSH, POSTDEC0
  97         mov_ff  TOSL, POSTDEC0
  98         dec_f_ifnz STKPTR
  99         bra     stacksave_loop
 100
 101         clr_f    STKPTR         ; avoids stack overruns
 102         clr_f   panicst
 103
 104         call    panic_kill_hook
 105
 106 ; re-initialise timer0 config, etc.
 107         call    read_pic_no
 108         bra_z   panic_setup_if_master
 109 panic_setup_if_slave
 110         morse_t0setup sclock, (1<<TMR0ON), t0l_count, t0h_count
 111         bra     panic_setup_endif_masterslave
 112
 113 panic_setup_if_master
 114         mov_lw  0x0b ; AAARGH
 115         bt_f_if1 TXSTA, TXEN
 116         call    serial_write_char
 117         morse_t0setup mclock, (1<<TMR0ON), t0l_count, t0h_count
 118 panic_setup_endif_masterslave
 119
 120 ; get # bytes of morse msg, # registers in panic readout, message start addr.
 121 ; back from condensed message start addr. stored in panic_address
 122
 123 panic_loop
 124         mov_lw  4 ; size of each message's details
 125         mul_wf  panic_address
 126         mov_ff  PRODL,TBLPTRL
 127         mov_ff  PRODH,WREG
 128         add_lw  (morse_messages_start)/256
 129         mov_wf  TBLPTRH
 130         clr_f   TBLPTRU
 131
 132         tblrd   *+              ; read 1st byte of error message
 133                                 ; (gives # bytes morse, # bytes registers)
 134         dw      0xffff ; silicon errata: B4 issue 4
 135
 136         mov_ff  TABLAT,panic_morse
 137         mov_lw  00001111b
 138         and_wff panic_morse     ; panic_morse now contains # bytes of morse msgs
 139
 140         mov_ff  TABLAT,panic_regs
 141         mov_lw  01110000b
 142         and_wff panic_regs
 143         swap_f  panic_regs      ; panic_regs now contains # registers to read
 144
 145         call    led_black
 146         rcall   waiting16
 147         rcall   morsemsg        ; transmit morse in red
 148         call    led_black
 149         rcall   waiting8
 150         rcall   waiting4
 151         rcall   registermsg     ; transmit contents of registers in
 152                                 ; red(=low) and blue(=high)
 153         rcall   waiting16
 154         bra     panic_loop
 155
 156 ;****************************************************************************
 157 ; PANIC SUBROUTINES
 158
 159 morsemsg
 160 ; wrapper round morse_readout to flash the per-pic led red for a morse msg
 161
 162 morse_msg_start
 163         clr_f           morse_counter           ; clear loop counter
 164
 165 morse_loop
 166         mov_fw          panic_morse
 167         cmp_fw_ifge     morse_counter           ; if loop counter >=panic_morse
 168         return                                  ; return to panic
 169
 170         tblrd           *+
 171         mov_ff          TABLAT,flash_pattern
 172         rcall           morse_readout
 173         inc_f           morse_counter
 174         bra             morse_loop
 175
 176
 177 ;--------------------------
 178 morse_readout
 179
 180 ; Flashes the per-pic led and black in a specified pattern.
 181 ;
 182 ; The pattern is specified as the state for 8 identically-long time
 183 ; periods each as long as a morse `dot', encoded into a byte with
 184 ; most significant bit first.
 185 ;                       On entry                On exit
 186 ; W                     any                     undefined
 187 ; flash_pattern         flash pattern           preserved
 188 ; bit_counter           any                     undefined
 189
 190         mov_lw          9
 191         mov_wf          bit_counter
 192         rr_f            flash_pattern
 193
 194 morse_readout_loop
 195         dec_f_ifz       bit_counter             ; done all the bits yet ?
 196         return
 197         ; No:
 198
 199         rl_f            flash_pattern           ; top bit goes into N,
 200                                                 ;ie Negative if 1
 201         bra_n           morse_readout_if_led_1
 202
 203 morse_readout_if_led_0
 204         call            led_black
 205         bra             morse_readout_endif_led
 206
 207 morse_readout_if_led_1
 208         call            led_red
 209
 210 morse_readout_endif_led
 211         rcall           waiting
 212         bra             morse_readout_loop
 213
 214 ;--------------------------
 215 ;--------------------------
 216 registermsg
 217
 218 register_msg_start
 219         clr_f           register_counter        ; clear loop counter
 220
 221 register_loop
 222         mov_fw          panic_regs
 223         cmp_fw_ifge     register_counter        ; if loop counter >=panic_regs
 224         return                                  ; return to panic
 225
 226         tblrd           *+
 227
 228         mov_fw          TABLAT          ; TABLAT has the 8-bit version
 229         mov_wf          FSR0L           ; of the address.  So, 8 bits
 230                                         ; go straight into FSR0L.
 231
 232         mov_lw          0x0f            ; For FSR0H, we see if the
 233         mov_fw          FSR0H           ; address XX is >=0x60.
 234                                         ; If it is then we meant 0xfXX;
 235         mov_lw          0x5f            ; if not then we meant 0x0XX.
 236         cmp_fw_ifle     FSR0L           ; (This is just like PIC does
 237         clr_f           FSR0H           ; for insns using Access Bank)
 238
 239         mov_ff          INDF0,flash_pattern
 240         rcall           register_readout
 241
 242         inc_f           register_counter        ;increment loop counter
 243
 244         rcall           waiting8
 245         bra             register_loop
 246
 247 ;--------------------------
 248
 249 register_readout
 250
 251 ; Flashes the per-pic led red(0) and green(1) in a specified pattern.
 252 ; (black gap between each bit)
 253 ;
 254 ; The pattern is specified as the state for 8 identically-long time
 255 ; periods each as long as a morse `dot', encoded into a byte with
 256 ; most significant bit first.
 257 ;                       On entry                On exit
 258 ; W                     any                     undefined
 259 ; flash_pattern         flash pattern           preserved
 260 ; bit_counter           any                     undefined
 261
 262         clr_f   bit_counter             ; clear loop counter
 263         rr_f    flash_pattern
 264
 265
 266 register_readout_loop
 267         mov_lw          8
 268         cmp_fw_ifge     bit_counter             ; if loop counter >=8 (register
 269                                                 ; length), return
 270         return
 271
 272         mov_lw          4
 273         cmp_fw_ifne     bit_counter     ; if loop counter !=4 (nybble length),
 274                                         ; skip insertion of extra black space
 275         bra             not_nybble_boundary
 276         rcall           waiting4
 277
 278 not_nybble_boundary
 279         rl_f            flash_pattern           ; top bit goes into N flag,
 280                                                 ; ie Negative if 1
 281         bra_n           register_readout_if_led_1
 282
 283 register_readout_if_led_0
 284         call            led_red
 285         bra             register_readout_endif_led
 286
 287 register_readout_if_led_1
 288         call            led_green
 289
 290 register_readout_endif_led
 291         inc_f           bit_counter       ; increment loop counter
 292         rcall           waiting
 293         call            led_black
 294         rcall           waiting
 295         bra             register_readout_loop
 296
 297
 298 ;****************************************************************************
 299 ; GENERAL SUBROUTINES
 300
 301 ;----------------------------------------
 302 waiting16       rcall   waiting8
 303 waiting8        rcall   waiting4
 304 waiting4        rcall   waiting2
 305 waiting2        rcall   waiting
 306 waiting
 307 ; waits for a fixed interval, depending on the configuration of TMR0
 308
 309         bc_f    INTCON,2        ; clear timer0 interrupt bit (p109)
 310 ; Interrupt happens on overflow.  So start at 65535-morse_t0cycles:
 311         mov_fw  t0h_count
 312         mov_wf  TMR0H           ; p107 set high byte of timer0 (buffered,
 313                                 ; only actually set when write to tmr0l occurs)
 314         mov_fw  t0l_count
 315         mov_wf  TMR0L           ; set timer0 low byte - timer now set
 316 waiting_loop    ; wait for timer0 interrupt, or some other interrupt
 317         bt_f_if1 INTCON,TMR0IF
 318         return
 319
 320         bt_f_if1 idloc1, idloc1_master
 321         bra     waiting_master
 322         ; slave:
 323
 324         bt_f_if0 SSPCON1, SSPEN
 325         bra     waiting_loop    ; no readouts if i2c is disabled
 326         ; slave, i2c enabled:
 327
 328         bt_f_if1 PIR1, SSPIF
 329         call    pan_i2cs_interrupt
 330
 331         bra     waiting_loop
 332
 333 ;----------------------------------------
 334 ; MASTER'S PANIC SERIAL PORT HANDLING
 335
 336 ;--------------------
 337 waiting_master
 338         bt_f_if1 PIR1,RCIF ; host sent us something ?
 339         call    panicd_serialrx
 340
 341         bt_f_if0 SSPCON1, SSPEN
 342         bra     waiting_loop
 343         ; master, i2c enabled:
 344
 345         bt_f_if1 PIR1, SSPIF
 346         rcall   pan_i2cm_interrupt
 347
 348         bra     waiting_loop
 349
 350 ;----------
 351 panicst_oerrferr
 352         dec_fw  RCREG
 353         bra_nz  panicd_serialrx_err_loop
 354         ; yay! host ack'd ferr/oerr
 355         bc_f    panicst, panicst_ferroerr
 356         return ; return from panicd_serialrx
 357
 358 ;----------
 359 panicd_serialrx_err
 360         bs_f    panicst, panicst_ferroerr
 361         call    led_green
 362         bc_f    RCSTA, RCEN     ; disable       } to clear FERR/OERR
 363         mov_fw  RCREG           ; read RCREG    } (see PIC18FXX8 DS p182)
 364         bs_f    RCSTA, RCEN     ; reenable      }
 365 panicd_serialrx_err_loop
 366         bt_f_if0 PIR1, RCIF ; wait for a byte 0x01 to ack the overrun/error
 367         bra     panicd_serialrx_err_loop
 368 ;...
 369 ;----------
 370 panicd_serialrx
 371         bt_f_if1 RCSTA,FERR
 372         bra     panicd_serialrx_err
 373         bt_f_if1 RCSTA,OERR
 374         bra     panicd_serialrx_err
 375         bt_f_if1 panicst, panicst_ferroerr
 376         bra     panicst_oerrferr
 377
 378         mov_fw  RCREG
 379 ;...
 380 ;****************************************************************************
 381 ; MEMORY READOUT
 382
 383 ;----------
 384 pan_i2csu_write_data
 385 panicd_process_input_byte
 386 ;               W       instruction from host or master
 387         tst_w_ifnz
 388         bra     write_ifnot_00
 389         ; we've received 0x00:
 390
 391         mov_lfsr 0,1
 392         bs_f    panicst, panicst_acked
 393         return
 394
 395 ;----------
 396 write_ifnot_00
 397         bt_f_if0 panicst, panicst_acked ; well, ignore that !
 398         return
 399         ; OK, we have an instruction:
 400
 401         bt_w_if1 7 ; huh?
 402         bra     write_if_setbytetowrite
 403         bt_w_if1 6
 404         bra     panic_crashread_setpointer
 405         bt_f_if0 idloc1,idloc1_master
 406         return ; all the remaining options are for master only
 407         bt_w_if1 5
 408         bra     write_if_master_slaveselect
 409         bt_w_if1 4
 410         bra     write_if_master_masterread
 411         bra     write_if_master_slaveread
 412         return ; huh ?
 413
 414 ;----------
 415 panic_crashread_setpointer
 416 ;  W                    byte from master or host        undefined
 417 ;  FSR1*                crashread pointer               updated
 418 ;  t, STATUS, PROD*     any                             undefined
 419 ;  all others           any                             preserved
 420         mov_wf  t
 421         mov_lw  1<<6
 422         mul_wf  FSR1L
 423         mov_ff  PRODH, FSR1H
 424         mov_fw  t
 425         and_lw  0x3f
 426         ior_wfw PRODL
 427         mov_wf  FSR1L
 428         return
 429
 430 ;======================================================================
 431 ; MASTER READOUT AND MASTER READOUT OF SLAVES
 432
 433 ;----------
 434 write_if_setbytetowrite
 435         bt_f_if0 idloc1,idloc1_master
 436         return ; for master only
 437
 438         bc_w    7
 439         mov_wf  panic_valcount
 440         bs_f    panicst, panicst_writeslave
 441         return
 442
 443 ;----------
 444 write_if_master_slaveread
 445         mov_wf  panic_valcount
 446         bc_f    panicst, panicst_writeslave
 447         return
 448
 449 ;----------
 450 write_if_master_slaveselect
 451         bc_w    5
 452         bt_f_if1 panicst, panicst_writeslave
 453         bra     pan_i2cm_write_start
 454         bra     pan_i2cm_read_start
 455
 456 ;----------
 457 write_if_master_masterread
 458         bc_w    4
 459         mov_wf  panic_valcount
 460 write_if_master_masterread_loop
 461         mov_fw  POSTINC1
 462         call    serial_write_char
 463         dec_f_ifnz panic_valcount
 464         bra     write_if_master_masterread_loop
 465         return
 466
 467 ;----------
 468 pan_i2cmu_read_got_byte
 469         call    serial_write_char
 470         dec_fw_ifnz panic_valcount
 471         bra     pan_i2cm_read_another
 472         return
 473
 474 ;----------
 475 pan_i2cmu_write_next_byte
 476         mov_fw  panic_valcount
 477         bs_f    STATUS, Z
 478         bt_f_if1 panicst, panicst_writeslave
 479         bc_f    STATUS, Z
 480         bc_f    panicst, panicst_writeslave
 481         return
 482
 483 ;----------
 484 pan_i2cmu_done
 485         mov_lw  ' '
 486         goto    serial_write_char
 487
 488 ;======================================================================
 489 ; SLAVE I2C
 490
 491 pan_near_i2csu code
 492 ;----------
 493 pan_i2csu_write_begin
 494         return
 495
 496 ;----------
 497 pan_i2csu_read_begin
 498         mov_lw  0x80 ; M0000000
 499         bt_f_if0 panicst, panicst_acked
 500         goto    i2cs_read_data
 501 ;...
 502 i2csu_read_panicd_ok
 503         mov_fw  POSTINC1
 504         goto    i2cs_read_data
 505
 506 ;----------
 507 pan_i2csu_read_another
 508         bt_f_if1 panicst, panicst_acked
 509         bra     i2csu_read_panicd_ok
 510         ; not ok
 511         mov_lw  0x0b ; AARGH
 512         goto    i2cs_read_data
 513
 514 near_gots code
 515 ;----------
 516 got_aargh
 517         panic   morse_T
 518
 519 near_serialrx_table code 0x2100
 520 ;----------
 521 command_crashed
 522 panic_crashread_commanded
 523         bs_f    panicst, panicst_acked ; since we were asked to
 524         panic   morse_E
 525
 526 ;***************************************************************************
 527         include final.inc