detpic/mascan.asm

   1 ;======================================================================
   2 ; MASTER - SCANNING ETC.
   3
   4  include common.inc
   5
   6 ;----------------------------------------------------------------------
   7  udata_acs
   8
   9 ; for reading and detection:
  10 b       res     1       ; byte just read
  11 cslot   res     1       ; current slave in slave table, points to flags byte
  12 cbyte   res     1
  13         ; one of the following:
  14         ;       0000 0000       we're expecting the first byte
  15         ;       M0B1 0000       we're expecting more detection byte 1
  16         ;       M010 0000       we're expecting more detection byte 2
  17         ;       1000 0000       we're expecting an extra byte
  18         ;       ???? ???1       reading halted due to lack of buffer space:
  19 cbyte_halted equ 0 ; also set briefly while we decide what to do next
  20
  21 wslave                  res 1 ; slave we need to write to
  22 outmsg_targetlen        res 1 ;
  23
  24 ;======================================================================
  25 ; HANDLING OF I2C EVENTS
  26
  27 near_getwritebyteyes code
  28 ;----------------------------------------
  29 i2c_getwritebyte_yes
  30         pop             ; we don't care where we were in i2cmu_write_next_byte
  31         bc_f    STATUS, Z       ; yes, we want to write this byte
  32         return          ; from i2cmu_write_next_byte
  33
  34  code
  35 ;----------------------------------------
  36 i2cmu_write_next_byte
  37         ; add calls to getwritebyte_<foo> here:
  38         call    polarity_getwritebyte
  39         call    points_getwritebyte
  40         ; end of list of calls to getwritebyte_<foo>
  41         ; so, no-one wants this slave:
  42         bs_f    STATUS, Z
  43         return
  44
  45 ;----------------------------------------
  46 i2cm_intrl
  47 ; handles i2c interrupt using i2cm_interrupt[_definite],
  48 ; according to the rules for <something>_intrl.
  49         bt_f_if0 PIR1, SSPIF
  50         return
  51         call    i2cm_interrupt_definite
  52         intrl_handled_nostack
  53
  54 ;======================================================================
  55 ; PROCESSING OF INCOMING BYTES - CORE AND DETECTION
  56
  57 ;----------------------------------------
  58 i2cmu_read_got_byte
  59 ;               Beforehand      At call
  60 ;   State       Reading         Reading-Wait
  61 ;   W                           data from slave
  62 ;
  63 ; See detect.asm head comment for protocol info, in particular
  64 ; the meaning of these bytes.
  65                                 ; W =           received byte
  66         mov_wf  b               ; W = b =       received byte
  67
  68         mov_lfsr slavetable, 1
  69         mov_ff  cslot, FSR1L    ; FSR1 ->       slave's flags
  70
  71         tst_f_ifnz cbyte
  72         bra     read_got_notfirst
  73         ; this is a first (head) byte:
  74
  75         bt_f_if0 POSTINC1, stf_detect ; FSR1 -> detbasel
  76         bra     read_got_first_reversers
  77 read_got_first_detectors        ; b =           MdBBdddd
  78         and_lw  0xb0            ; W =           M0BB0000
  79         mov_wf  cbyte           ; cbyte =       M0BB0000
  80         mov_lw  0x4f            ; W =           01001111
  81         and_wff b               ; b =           0d00dddd
  82         mov_fw  POSTINC1        ; W = detbasel; FSR1 -> lastd0
  83         rcall   read_got_detectbyte_prep ; b =  0d00dddd
  84                                          ; u =  0C00CCCC
  85         bt_f_if1 b, 6           ; b bit         .d......
  86         bs_f    b, 4            ; b =           0d0ddddd
  87                                 ;                ^ ^ copies of same bit
  88                                 ; u = (still)   0C00CCCC
  89                                 ; or, using detection segment bit numbers:
  90                                 ; b =           z4z43210
  91                                 ; u =           z4zz3210
  92         goto    addmsgs_dethead
  93
  94 ;----------
  95 read_got_first_reversers
  96         bt_f_if1 b, 6
  97         bra     read_got_bad_first_reversers
  98         and_lw  0x80            ; W =           M0000000
  99         mov_wf  cbyte           ; cbyte =       M0000000
 100         bc_f    b, 7            ; b =           00dddddd
 101         mov_fw  POSTINC1        ; W = detbasel; FSR1 -> lastd0
 102         rcall   read_got_detectbyte_prep
 103         goto    addmsgs_revhead
 104
 105 ;-----
 106 read_got_bad_first_reversers panic morse_MR
 107
 108 ;----------
 109 read_got_detectors_b1           ; b =           dddddddd
 110         bc_f    cbyte, 4        ; cbyte =       M0B00000
 111         mov_fw  POSTINC1        ; W = detbasel; FSR1 -> lastd0
 112         inc_f   FSR1L           ; FSR1 -> lastd1
 113         add_lw  5               ; W = detbasel+8
 114         rcall   read_got_detectbyte_prep
 115         goto    addmsgs_all
 116
 117 ;----------
 118 read_got_detectors_b2           ; b =           dddddddd
 119         bc_f    cbyte,5         ; cbyte =       M0000000
 120         mov_fw  POSTDEC1        ; W = detbasel; FSR1 -> flags
 121         bs_f    FSR1L, 2        ; FSR1L ->      lastd2
 122         add_lw  13              ; W = detbasel+16
 123         rcall   read_got_detectbyte_prep
 124         goto    addmsgs_all
 125
 126 ;----------
 127 read_got_detectbyte_prep_ifsomething
 128 ;
 129 ; This is a branch of read_got_detectbyte_prep, called if we're doing
 130 ; `return' rather than `pop+return'.  For conditions on return, see
 131 ; read_got_detectbyte_prep; these are supposed to be (basically) the
 132 ; same as the entry conditions for addmsgs_<kind>.
 133 ;
 134 ;               on entry
 135 ;  W            [C0]*
 136 ;  t            adjdetbasel
 137 ;  u            undefined
 138 ;  b            [d0]*
 139 ;  lastd<n>     [o0]*
 140 ;  FSR1 ->      lastd<n>
 141 ;
 142         mov_wf  u               ; u =           [C0]*
 143         xor_wfw INDF1           ; lastd<n> =    [d0]*
 144         mov_lw  0x07
 145         ior_wff FSR1L           ; FSR1L ->      detmsgh
 146         return ; to addmsgs_<something>, very shortly
 147
 148 ;----------------------------------------
 149 read_got_notfirst
 150         bt_f_if1 cbyte, 4
 151         bra     read_got_detectors_b1
 152         bt_f_if1 cbyte, 5
 153         bra     read_got_detectors_b2
 154         ; it must be an extra byte
 155
 156         bt_f_if0 b, 7           ; any more ?
 157         bc_f    cbyte, 7
 158         bc_f    b, 7
 159         call    process_got_extra
 160         bra     i2c_arrange_next_byte
 161
 162 ;----------
 163 read_got_detectbyte_prep
 164 ;
 165 ; Sees if anything has changed.  If no changes pops one return address
 166 ; and branches to i2c_arrange_next_byte; if some changes, returns to
 167 ; calling point.
 168 ;
 169 ; So, caller should be i2cmu_read_got_byte, and next stuff
 170 ; should basically be a call to addmsg_<something> (perhaps preceded
 171 ; by a bit of fiddling of b).  addmsg_<something> will finish
 172 ; by branching to i2c_arrange_next_byte.
 173 ;
 174 ;               call                    return          pop+return
 175 ;  W            adjdetbasel             preserved       undefined
 176 ;  b            [d0]*                   preserved       preserved
 177 ;  FSR1 ->      lastd<n>                detmsgh         preserved
 178 ;  cbyte        set for next read etc.  preserved       preserved
 179 ;  u            undefined               [C0]*           preserved
 180 ;  lastd<n>     [o0]*                   [d0]*           preserved = [d0]*
 181 ;
 182 ;  TOS ->       (optionally, fiddle b, and then:) goto addmsgs_<something>
 183 ;  NOS          return address for i2cmu_read_got_byte
 184 ;
 185         mov_wf  t               ; t =           adjdetbasel
 186         mov_fw  b               ; W =           [d0]*
 187         xor_wfw INDF1           ; W =           [C0]*, Z iff same
 188                         ;  where C set iff change to that detection segment
 189         bra_nz  read_got_detectbyte_prep_ifsomething
 190         ; there's nothing to do
 191         pop
 192 ;...
 193 ;----------------------------------------
 194 i2c_arrange_next_byte
 195         tst_f_ifnz cbyte
 196         goto    i2cm_read_another
 197 ;...
 198 ;======================================================================
 199 ; DECIDING WHICH SLAVE TO ADDRESS
 200 ;...
 201 i2c_arrange_something
 202 ; figure out what to do next - which pic to address, etc.
 203         bs_f    cbyte, cbyte_halted
 204
 205         tst_f_ifnz wslave       ; anyone asked to write ?
 206         bra     arrange_write
 207 nextslave_nowrite
 208         ; no writing needed, we consider reading:
 209         bt_f_if1 flags, flags_polarising
 210         return  ; do not scan while booster PWM is off while polarising
 211                 ; to avoid all trains disappearing and reappearing
 212
 213         neg_fw  outmsg_begin
 214         add_wfw outmsg_end
 215         and_lw  outbuf_size - 1
 216         cmp_fw_ifle outmsg_targetlen
 217         return ; target len < actual len, do not add anything
 218         ; ok, there's space, go ahead:
 219         bc_f    cbyte, cbyte_halted
 220
 221         mov_lw  ste_size
 222         add_wff cslot           ; cslot -> next ste_flags
 223         mov_lfsr slavetable, 1  ; FSR1H -> slavetable
 224         mov_ff  cslot, FSR1L    ; FSR1 -> new ste_flags
 225
 226         bt_f_if1 POSTDEC1, stf_sentinel ; FSR1 -> ste_slave
 227         bra     nextslave_looparound
 228         ; Ok, we have a slave:
 229
 230         mov_fw  INDF1           ; W = new slave number
 231         goto    i2cm_read_start
 232
 233 nextslave_looparound
 234         ; now we do our own detection
 235         mov_lw  (slavetable + ste_flags) & 0xff ; select our own slot
 236         mov_wf  cslot
 237         call    read_detection_head_master
 238         goto    i2cmu_read_got_byte
 239
 240 ;----------------------------------------
 241 i2cmu_done
 242         ; So we've done one write.
 243         bs_f    cbyte, cbyte_halted
 244
 245         tst_f_ifnz wslave       ; anyone asked in the meantime ?
 246         bra     arrange_write
 247
 248         ; Anyone else to write to ?
 249         ; add calls to needwrite_<foo> here:
 250         call    polarity_needwrite
 251         call    points_needwrite
 252         ; end of list of calls to needwrite_<foo>
 253
 254         ; no, if we're here, no-one wants to write
 255         bra     nextslave_nowrite
 256
 257 ;----------------------------------------
 258 i2c_needwrite
 259 ; Informs mascan that we need to write to some slave.
 260 ; Some time after this, mascan will call getwritebyte_<everything>
 261 ; and this must yield at least one byte to write.
 262 ;  W            slave that we must write to
 263         mov_wf  wslave
 264         bt_f_if0 cbyte, cbyte_halted
 265         return ; we're currently doing something
 266 ;...
 267 ;----------
 268 arrange_write
 269 ;  wslave       slave to write to
 270         bc_f    cbyte, cbyte_halted
 271         mov_fw  wslave
 272         mov_wf  cwslave
 273         clr_f   wslave
 274         goto    i2cm_write_start
 275
 276 ;----------------------------------------
 277 i2c_consider_restartread
 278         bt_f_if0 cbyte, cbyte_halted
 279         return
 280         bra     nextslave_nowrite
 281
 282 ;======================================================================
 283 ; INITIALISATION
 284
 285 mascan_init
 286         mov_lw  (slavetable + ste_flags + ste_size) & 0xff
 287                  ; start with 1st actual slave
 288         mov_wf  cslot
 289         clr_f   cbyte
 290         bs_f    cbyte, cbyte_halted ; serial output of `hello' will start us up
 291         clr_f   wslave
 292
 293         mov_lw  2
 294         mov_lfsr slavetable, 0          ; FSR0 -> slavetable
 295         load_tblptr pic2detinfo         ; TBLPTR* -> pic2detinfo
 296         clr_f   t                       ; t = loop counter
 297 mascan_init_loop
 298         tblrd_postinc_fixup             ; TABLAT = EOOOOSSS
 299         mov_fw  TABLAT                  ; W = EOOOOSSS, N = E
 300
 301         tblrd_postinc_fixup             ; TABLAT = DSSSSSSS, N (still) = E
 302         bra_nn  mascan_init_ifabsent
 303
 304         mov_ff  t, POSTINC0             ; ste_slave = slave
 305         mov_wf  u                       ; u = 1OOOOSSS
 306         and_lw  0x78
 307         bra_nz  mascan_bad_detinfo0
 308         ; ok                            ; u = 10000SSS
 309
 310         mov_fw  TABLAT                  ; W = DSSSSSSS
 311         and_lw  0x80                    ; W = D0000000
 312         mov_wf  POSTINC0                ; ste_flags = D0000000
 313
 314         mov_fw  TABLAT                  ; W = DSSSSSSS
 315         bc_w    7                       ; W = 0SSSSSSS = first
 316         add_lw  -0xf8                   ; W = first - 0xf8 = detbasel
 317         mov_wf  POSTINC0                ; detbasel
 318
 319         clr_f   POSTINC0                ; lastd0
 320         clr_f   POSTINC0                ; lastd1
 321         clr_f   POSTINC0                ; lastd2
 322         set_f   POSTINC0                ; unused
 323
 324         mov_fw  u                       ; W = 10000SSS
 325         xor_lw  b'10011000' ^ 0x80      ; W = detmsgh
 326         mov_wf  POSTINC0                ; detmsgh
 327
 328 mascan_init_ifabsent
 329         inc_f   t                       ; next slave
 330         bt_f_if0 t, maxpics_ln2
 331         bra     mascan_init_loop
 332         ; we've read the whole flash table
 333
 334  if slavetable == 0x400
 335         bt_f_if1 FSR0H, 0
 336         bra     mascan_bad_toomany
 337  endif
 338
 339         clr_f   POSTINC0                ; ste_slave
 340         mov_lw  (1<<stf_detect)|(1<<stf_sentinel)
 341         mov_wf  POSTINC0                ; ste_flags
 342         ; rest of final entry, and rest of table, is undefined
 343
 344         ; at 9600, it's about 1ms per char.
 345         ; we allow 1ms to scan 2 pics via i2c.
 346         ; so our target len is (no of pics)/2
 347         ; plus 2 bytes of slop
 348         rl_fw   t
 349         add_lw  2
 350         mov_wf  outmsg_targetlen
 351
 352         return
 353
 354 mascan_bad_detinfo0 panic morse_DF
 355 mascan_bad_toomany panic morse_DG
 356
 357 ;======================================================================
 358 ; PROCESSING OF INCOMING BYTES - EXTRA (NON-DETECTION)
 359
 360 near_gots code
 361 ;----------------------------------------
 362 process_got_extra
 363         mov_fw  b
 364 loopback_read_byte
 365 ;...
 366 ;  W            message
 367         xor_lw  0x00 ^ 0x20
 368         bra_z   got_pointed
 369         xor_lw  0x20 ^ 0xb0
 370         bra_z   got_aargh
 371         panic   morse_MX
 372
 373 ;======================================================================
 374 ; GENERATION OF DETECTION MESSAGES FOR HOST - MAD BT_F_IF1 TABLES
 375
 376 addmsg_testbit macro bit
 377         bt_f_if1 u, bit
 378         rcall   addmsg_one
 379         endm
 380
 381 addmsg_return macro dummy_bit
 382         goto    i2c_arrange_next_byte
 383         endm
 384
 385 addmsg_ignore macro dummy_bit
 386         nop
 387         nop
 388         endm
 389
 390 addmsg_padding macro dummy_bit
 391         nop
 392         mov_lw  dummy_bit
 393         endm
 394
 395 ;----------------------------------------
 396 ;addmsgs_<kind>
 397 ;
 398 ;                       on entry        after first addmsg_one, or when done
 399 ;  W, STATUS, v, FSR0   undefined       trashed
 400 ;  t                    adjdetbasel     not modified by addmsgs_<kind> or _one
 401 ;  u                    [C0]*           not modified by addmsgs_<kind> or _one
 402 ;  b                    [d0]*           not modified by addmsgs_<kind> or _one
 403 ;  lastd<n>             [d0]* (new)     not modified by addmsgs_<kind> or _one
 404 ;  FSR1 ->              detmsgh         not modified by addmsgs_<kind> or _one
 405 ;  outbuf, outmsg_*     not full, updated appropriately
 406 ;  all others           any             not interfered with
 407 ;
 408 ; (this is all set up by read_prep_detectbyte and
 409 ;  read_got_detectbyte_prep_ifsomething)
 410 ; when done, branches to i2c_arrange_next_byte, rather than returning
 411
 412 addmsgs_section code (          7       )*4 + 0x2100
 413 ;
 414 ;                               A
 415 ;                               |- PCL bbb value after macro - number in this
 416 ;                               V       column should increment 1 each line
 417 ;
 418 addmsgs_revhead addmsg_testbit  0
 419                 addmsg_testbit  1
 420                 addmsg_testbit  2
 421                 addmsg_testbit  3
 422                 addmsg_testbit  4
 423                 addmsg_testbit  5
 424                 addmsg_return   6
 425
 426 addmsgs_all     addmsg_testbit  7
 427                 addmsg_testbit  0
 428                 addmsg_testbit  1
 429                 addmsg_testbit  2
 430                 addmsg_testbit  3
 431                 addmsg_testbit  4
 432                 addmsg_testbit  5
 433                 addmsg_testbit  6
 434                 addmsg_return   7
 435
 436 addmsgs_dethead addmsg_testbit  0
 437                 addmsg_testbit  1
 438                 addmsg_testbit  2
 439                 addmsg_testbit  3
 440                 addmsg_testbit  6 ; bit 6 was copied to 4 but only in b, not u
 441                 addmsg_return   5
 442
 443 ;----------
 444 addmsg_one
 445 ;  TOS - 4 ->   bt_f_if1 w, b'bbb'
 446 ;  TOSL         ???bbb00
 447 ; other conditions on entry and exit as for entry to addmsgs_<kind>, above
 448         rr_fw   TOSL            ; W =           0???bbb0
 449         rr_w                    ; W =           00???bbb
 450         ior_wfw 0xf8            ; W =           11111bbb
 451         mov_wf  FSR0L           ; FSR0L =       11111bbb
 452         clr_f   FSR0H           ; FSR0 ->       bitnum2bit[bbb]
 453         add_wfw t               ; W =           adjdetbasel + 11111bbb
 454                                 ;  ie =         0 SSSSSSS (det msg low byte)
 455         mov_wf  v               ; v =           0 SSSSSSS (det msg low byte)
 456
 457         mov_fw  b               ; W =           [d0]*
 458         and_wfw INDF0           ; train: W = 0x00, Z=1; none: W = 0*d0*, Z=0
 459         bt_f_if0 STATUS, Z
 460         mov_lw  0x08            ; train: W = 0 000 0 000; none: W = 0 000 1 000
 461         xor_wfw INDF1           ; W =           1 001 Y SSS (det msg high byte)
 462         call    serial_addbyte
 463
 464         mov_fw  v               ; W =           0 SSSSSSS (det msg low byte)
 465         goto    serial_addbyte_another
 466
 467 ;======================================================================
 468  include final.inc