detpic/energy.asm

   1 ;======================================================================
   2 ; TRACK POWER AND SHORT CIRCUIT
   3
   4   include common.inc
   5
   6 settling_timeout        equ      10000 ; us
   7
   8 stop_timeout            equ     500000 ; us
   9 stopflash_timeout       equ      50000 ; us
  10 retry_timeout           equ      50000 ; us
  11 persist_timeout         equ      90000 ; us
  12
  13   udata_acs
  14 settling        res     1 ; all counters are 0 if stopped
  15 stop_wait       res     1 ;  or otherwise count down
  16 retry_wait      res     1
  17
  18   code
  19
  20 ;======================================================================
  21 ;
  22 ; POLARISING/SETTLING:
  23 ;
  24 ;               NMRA            flag_p. settling        Booster PWM
  25 ;
  26 ; Normal        running         0       stopped         mark
  27 ; Polarising    paused          1       stopped         space
  28 ; Settling      paused          1       running         space
  29 ;
  30 ; NMRA is paused by disabling timer 0 intr; when we restart,
  31 ; we restart the current message.
  32 ;
  33 ;----------------------------------------------------------------------
  34
  35 ;--------------------
  36 power_polarising_init
  37         clr_f   settling
  38         pin_h   p0_booster_pwm
  39         return
  40
  41 ;--------------------
  42 power_polarising_begin
  43         pin_vl  p0_booster_pwm
  44         bc_f    INTCON, TMR0IE ; disables NMRA interrupt
  45         bs_f    flags, flags_polarising
  46         clr_f   settling
  47         return
  48
  49 ;--------------------
  50 power_polarising_settling
  51 ; idempotent
  52         tst_f_ifnz settling
  53         return
  54         mov_lw  settling_timeout / tick_us
  55         mov_wf  settling
  56         return
  57
  58 ;--------------------
  59 power_polarising_tick
  60         tst_f_ifnz settling
  61         dec_f_ifnz settling ; decrement if not zero
  62         return ; return if not dec'd, or if decrement didn't make zero
  63         ; settle timeout complete:
  64
  65         bc_f    flags, flags_polarising
  66         call    nmra_restartmessage
  67         bs_f    INTCON, TMR0IE ; reenables NMRA interrupt
  68         goto    i2c_consider_restartread
  69
  70 ;======================================================================
  71 ;
  72 ; FAULTS AND POWER:
  73 ;
  74 ;               Shutdown  CDU   Timeout User Fault      Next states
  75 ;
  76 ; Off           shutdown  off   none    off             *On (or +Fault)
  77 ; On            power-up  on    none    off             Fault, or *Off
  78 ; Stopping      shutdown  off   500ms   50% 1/100ms     ->Retry
  79 ; Retry         power-up  off   50ms    off             ->Off, or Persists
  80 ; Persists      shutdown  off   90ms    on              ->Retry
  81 ;                                                       * = when host instructs
  82 ;                                                       + = lost race, only
  83 ;                                                       -> = after timeout
  84 ;
  85 ;               shutdown LAT    stop_wait       retry_wait
  86 ;
  87 ; Off           H (shutdown)    stopped         stopped
  88 ; On            L (power-up)    stopped         stopped
  89 ; Stopping      H (shutdown)    before Retry    for LED flash
  90 ; Retry         L (power-up)    stopped         before Off
  91 ; Persists      H (shutdown)    stopped         before retry
  92 ;
  93 ;                               (uses tickdiv)  (uses tick)
  94
  95 ;--------------------
  96 power_fault_init
  97         bs_f    INTCON2, INTEDG1 ; rising edge
  98         bc_f    INTCON3, INT1IP
  99         bc_f    INTCON3, INT1IF
 100         bs_f    INTCON3, INT1IE
 101         clr_f   stop_wait
 102         clr_f   retry_wait
 103         pin_h   p0_booster_shutdown
 104         pin_h   p0_booster_userfault
 105         ; now we are Off
 106         return
 107
 108 ;--------------------
 109 command_power
 110         bra_nc  command_power_off
 111         ; command is ON:
 112
 113 ; Off -> On; noop in other states
 114         pinlat_ifl p0_booster_shutdown
 115         return  ; On or Retry
 116         ; might be Off, Stopping or Persists:
 117
 118         tst_f_ifnz retry_wait
 119         return  ; that deals with Stopping or Persists
 120         ; must be Off:
 121
 122         pin_vl  p0_booster_shutdown
 123         goto    cdu_on
 124
 125 ;----------
 126 command_power_off
 127 ; On -> Off; noop in other states
 128         pinlat_ifh p0_booster_shutdown
 129         return  ; Off, Stopping or Persists
 130         ; might be On or Retry:
 131
 132         tst_f_ifnz retry_wait
 133         return  ; that deals with Retry
 134         ; must be On:
 135 power_off_now
 136         pin_vh  p0_booster_shutdown
 137         goto    cdu_off
 138
 139 ;--------------------
 140 power_fault_intrl
 141         bt_f_if0 INTCON3, INT1IF
 142         return
 143         ; we have a fault:
 144
 145         bc_f    INTCON3, INT1IF
 146         rcall   power_off_now
 147
 148         mov_fw  retry_wait
 149         bra_z   power_fault_stop ; we were Off or On, goto Stopping
 150         ; must be Stopping, Retry or Persists:
 151
 152         tst_f_ifnz stop_wait
 153         bra     power_fault_stop ; we were already Stopping; restart timer
 154         ; might be Retry or Persists, goto Persists (restarting any timer):
 155
 156         mov_lw  persist_timeout / tick_us
 157         mov_wf  retry_wait
 158         pin_vl  p0_booster_userfault
 159         return
 160
 161 ;-----
 162 power_fault_stop
 163         mov_lw  stop_timeout / tickdiv_us
 164         mov_wf  stop_wait
 165         pin_vl  p0_booster_userfault
 166         mov_lw  b'00000111'
 167         call    serial_addbyte
 168         rcall   power_stop_doflash
 169         intrl_handled_nostack
 170
 171 ;--------------------
 172 power_fault_tick
 173         tst_f_ifnz retry_wait
 174         dec_f_ifnz retry_wait
 175         return
 176         ; retry_wait was running but has just reached zero;
 177         ; we were in Stopping, Retry or Persists:
 178
 179         tst_f_ifnz stop_wait
 180         bra     power_stop_doflash ; that was Stopping, just flash the LED
 181         ; must be Retry or Persists:
 182
 183         pinlat_ifh p0_booster_shutdown
 184         bra     power_retry ; we were in Persists, now we can try again
 185         ; we were in Retry and it worked.
 186 ; go to Off:
 187         pin_vh  p0_booster_shutdown
 188         pin_vh  p0_booster_userfault
 189         mov_lw  b'00000110'
 190         goto    serial_addbyte
 191
 192 ;----------
 193 power_stop_doflash
 194         pin_vhl p0_booster_userfault
 195         mov_lw  stopflash_timeout / tick_us
 196         mov_wf  retry_wait
 197         return
 198
 199 ;--------------------
 200 power_fault_tickdiv
 201         tst_f_ifnz stop_wait
 202         dec_f_ifnz stop_wait
 203         return
 204         ; stop_wait was running but has just reached zero;
 205         ; we were in Stopping, now we can Retry:
 206 power_retry
 207         mov_lw  retry_timeout / tickdiv_us
 208         mov_wf  retry_wait
 209         pin_vl  p0_booster_shutdown
 210         pin_vh  p0_booster_userfault
 211         return
 212
 213 ;--------------------
 214 power_panichook
 215         pin_vh  p0_booster_shutdown
 216         pin_vl  p0_booster_pwm
 217         pin_vh  p0_booster_userfault
 218         return
 219
 220 ;======================================================================
 221   include final.inc