// -*- C -*-

include <funcs.scad>

wall = 0.75 * [1,1,1];
phone = [ 76.40, 30.96, 6.00 ]; // includes socket
phone_button_z = 6.58;
minwall = 0.50;

button_dz = 1.35;

button_dy_outer = 28.42;
button_dy_inner = 19.05;
button_dy_centre = 5.65;

phone_slop = 0.5 * [1,1,0]
           + 0.5 * [0,0,1];

led = [25.9, 9.44]; // y is from edge
led_dia = 4.4;

// next values include slop
plug_maxw = 10.95 + 0.35;
plug_minw=   6.53 + 0.35;
plug_sllen=  6.50;
plug_totlen = 84.90; // to maxw, including phone

plug_h = 6.5;
plug_tooth_h = 0.5;
plug_tooth_dy = 0.5;

keeper_prong = 2;
keeper_stalk_basewidth = 4;
keeper_stalk_len = 70;
keeper_stalk_gap = 2;

// calculated

top_z = max( phone[2] + wall[2],
	     phone_button_z + minwall )
  + phone_slop[2];

plugkeeper_x_maxw = phone[0] - plug_totlen;

plugkeeper_p_max = [ 0, plug_maxw/2 ];
plugkeeper_p_min = [ -plug_sllen, plug_minw/2 ];;
plugkeeper_d_u = unitvector2d(
                 clockwise2d(
                 vecdiff2d( plugkeeper_p_max, plugkeeper_p_min )
			     )
			     );

module MainProfileInnerHalf(){
  p = phone + phone_slop;
  pb = p[2] + button_dz;
  polygon([[ -2,                 0    ],
	   [ p[1]/2,             0    ],
	   [ p[1]/2,             p[2] ],
	   [ button_dy_outer/2,  p[2] ],
	   [ button_dy_outer/2,  pb   ],
	   [ button_dy_inner/2,  pb   ],
	   [ button_dy_inner/2,  p[2] ],
	   [ button_dy_centre/2, p[2] ],
	   [ button_dy_centre/2, pb   ],
	   [ -2,                 pb   ]]);
}

module MainProfile(){
  p = phone + phone_slop;
  difference(){
    for (m=[0,1]) mirror([m,0]) {
	minkowski(){
	  square(2 * [wall[1], wall[2]], center=true);
	  MainProfileInnerHalf();
	}
      }
    for (m=[0,1]) mirror([m,0]) {
	MainProfileInnerHalf();
      }
  }
}

module BoxMain(){
  rotate([0,0,90]) rotate([90,0,0]) {
    linear_extrude(height = phone[0] + wall[0], convexity=20)
      MainProfile();
    translate([0,0, phone[0]])
      linear_extrude(height = wall[0], convexity=20)
      hull() MainProfile();
  }
}

module PlugKeeperProfileHalf(){
  p_max = plugkeeper_p_max;
  p_min = plugkeeper_p_min;
  d = plugkeeper_d_u * keeper_prong;
  
  translate([ plugkeeper_x_maxw, 0 ]) {
    polygon([ p_min,
	      p_max,
	      p_max + d,
	      p_min + d ]);
  }
}

module PlugKeeperStalkProfile(){
  hull(){
    for (m=[0,1]) mirror([0,m,0]) PlugKeeperProfileHalf();
    translate([ plugkeeper_x_maxw + keeper_stalk_len, 0,0 ])
      square([ 0.1, keeper_stalk_basewidth/2 ], center=true);
  }
}

module PlugKeeper(){
  for (m=[0,1]) mirror([0,m,0]) {
      translate([0,0, -wall[2]])
	linear_extrude(height=plug_h + wall[2])
	PlugKeeperProfileHalf();

      translate([0, 0, plug_h - plug_tooth_h])
	linear_extrude(height= plug_tooth_h)
	translate(plugkeeper_d_u * -plug_tooth_dy)
	PlugKeeperProfileHalf();

    }

  translate([0,0, -wall[2]])
    linear_extrude(height = wall[2])
    PlugKeeperStalkProfile();
}

module Box(){
  difference(){
    BoxMain();

    translate([ led[0], phone[1]/2 - led[1], 1 ])
      cylinder(r = led_dia/2, h= phone[2]*2, $fn=20);

    for (ys=[-1,+1])
      translate([ -0.1, ys * keeper_stalk_gap, -wall[2]*2])
	linear_extrude(height = wall[2]*3)
	PlugKeeperStalkProfile();
  }

  PlugKeeper();
}

//MainProfileInner();
Box();