// -*- C -*-

include <funcs.scad>
include <commitid.scad>

ply_th = 18;
ply_hole_dia = 15;
ply_edge_min = 10;

tile_th = 3;
post_dia = 8;

post_shorter = 1;

screw_dia = 2.2;
screw_big_dia = 3.6;
screw_big_len = 4.0;

round_edge_rad = 2.0;

round_cnr_rad = 10;

interlock_dia = 10;
interlock_fine = 0.66;

interlock_fine_slope = 1.0;
interlock_fine_lenslop = 1.0;

demo_slop = 0.1;

// calculated

TEST = false;

ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;

echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));

hole_slop = (ply_hole_dia - post_dia)/2;
tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;

echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
	 tile_hard_edge_hole_dist));

echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
	 tile_hard_edge_hole_dist + round_edge_rad));

thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
thehd_tr = thehd;
thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
thehd_bl = -thehd_tr;
thehd_br = -thehd_tl;

interlock_rad = interlock_dia/2;
interlock_negative_rad = interlock_rad + 0.125;

interlock_sq_adj = 0.2; // arbitrary

module Post(){
  mirror([0,0,1]) {
    difference(){
      cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
      translate([0,0, tile_th]) {
	cylinder(r= screw_big_dia/2, h= screw_big_len);
	cylinder(r= screw_dia/2, h= ply_th, $fn=20);
      }
    }
    if (TEST) {
      tsz = tile_hard_edge_hole_dist - test_edge + 1;
      translate([0,0, tile_th/2]) {
	cube([post_dia, tsz*2, tile_th], center=true);
	cube([tsz*2, post_dia, tile_th], center=true);
      }
    }
  }
}

module Posts(posts) {
  for (p= posts) {
    translate(concat(p, [0]))
      Post();
  }
}

module TileBase(botleft, topright){
  size = topright - botleft;
  botleft_post = botleft + thehd_tr;
  topright_post = topright + thehd_bl;
  difference(){
    mirror([0,0,1])
      translate(concat(botleft, [0]))
      cube(concat(size, [tile_th]));
    if (!TEST) {
      translate( concat(botleft_post, [ -tile_th ])
		 + 0.5 * [ post_dia, post_dia, 0 ] )
	Commitid_BestCount_M( topright_post-botleft_post
			      + [-post_dia,-post_dia]
			      + [0, thehd[1]]);
    }
    if (TEST) {
      translate( concat(botleft + [thehd[0], 0], [0]) )
	Commitid_BestCount([ size[0] - thehd[0]*2, thehd[1] ]);
      mirror([0,0,1]) {
	translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
	  cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
	translate(concat(botleft_post, [-1]))
	  cube(concat(topright_post-botleft_post, [tile_th+2]));
      }
    }
  }
}

m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
m4_define(`INREFFRAME',`
  length_vec = ($2) - ($1);
  length = dist2d([0,0], length_vec);
  length_uvec = length_vec / length;
  ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
  m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
	[ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
	[ 0,              0,              1,            0, ],
	[ 0,              0,              0,            1, ] ];
  $3
  multmatrix(m)
')

m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
m4_dnl    INREFFRAME_EDGE { body; }
m4_define(`INREFFRAME_EDGE',`
  translate([0,0, -round_edge_rad])
')

module RoundEdge(left_cnr, right_cnr) {
  INREFFRAME(left_cnr, right_cnr)
    INREFFRAME_EDGE {
    difference(){
      rotate([0,90,0])
	cylinder(r= round_edge_rad, h= length, $fn=50);
      translate([-1, 0, -20])
	cube([length+2, 20, 20]);
    }
  }
}

module RoundCornerCut(ci) {
  this_cnr = ci[0];
  right_cnr = ci[1];
  offr= round_cnr_rad - round_edge_rad;
  INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
    difference(){
      cube(offr*2 - 0.1, center=true);
      translate([offr, offr, 0])
	cylinder(center=true, h=20, r= offr);
    }
  }
}

module RoundCornerAdd(ci) {
  this_cnr = ci[0];
  right_cnr = ci[1];
  bigr = round_cnr_rad - round_edge_rad;
  INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
    intersection(){
      cube(bigr*2 + 0.1, center=true);
      translate([bigr, bigr, 0])
	rotate_extrude(convexity=10, $fn=50)
	translate([bigr, 0])
	difference(){
	  circle(r= round_edge_rad, $fn=50);
	  mirror([1,1])
	    square([20,20]);
        }
    }
  }
}

module InterlockLobePlan(negative) {
  r = negative ? interlock_negative_rad : interlock_rad;
  ymir = negative ? 0 : 1;

  dx = sqrt(3) * r;
  $fn= 80;
  translate([thehd[0], 0]){
    mirror([0,ymir]){
      circle(r=r);
      difference(){
	translate([-dx, -0.1])
	  square([ dx*2, r/2 + 0.1 ]);
	for (xi = [-1, 1]) {
	  translate([ xi*dx, r ])
	    circle(r=r);
	}
      }
    }
  }
}

module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
  for (lobei = [ 0 : nlobes-1 ]) {
    lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
    translate([lobex, 0, 0]) {
      InterlockLobePlan(negative);
    }
  }

  if (dosquare) {
    iadj = 0;
    slotshorter = negative ? -0.1 : interlock_fine_lenslop;
    mirror([0, negative])
      translate([slotshorter, iadj])
      square([length - slotshorter*2, interlock_fine + iadj*2]);
  }
}

module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
  plusth = negative * 1.0;
  protr = interlock_fine + interlock_sq_adj;

  z2 = -tile_th/2;
  z1 = -tile_th/2 - protr / interlock_fine_slope;
  z3 = -tile_th/2 + protr / interlock_fine_slope;

  negsign = negative ? -1 : +1;
  yprotr = negsign * protr;

  INREFFRAME(left_cnr, right_cnr) {
    for (vsect = [ // zs0            zs1      ys0,            ys1
		  [ -tile_th-plusth, plusth,  0,              0],
		  [ z1,              z2,      0, yprotr],
		  [ z2,              z3,      yprotr, 0],
		  ]) {
      zs0 = vsect[0];
      zs1 = vsect[1];
      zsd = zs1-zs0;
      ys0 = vsect[2];
      ys1 = vsect[3];
      ysd = ys1-ys0;
      sl = ysd/zsd;
      m = [ [ 1,0,   0,    0 ],
	    [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
	    [ 0,0,   1,  zs0 ],
	    [ 0,0,   0,    1 ] ];
      multmatrix(m)
	linear_extrude(height=zsd, convexity=10)
	InterlockEdgePlan(negative, nlobes, length, !!ysd);
    }
  }
}

function TestPiece_holes2corners(holes) =
  [ holes[0] + thehd_bl,
    holes[1] + thehd_br,
    holes[1] + thehd_tr,
    holes[0] + thehd_tl ];

module TestPiece1(){ ////toplevel
  holes = [ [-100, 0],
	    [   0, 0]
	    ];
  corners = TestPiece_holes2corners(holes);
  rcs = [corners[0], corners[1]];
  difference(){
    union(){
      TileBase(corners[0], corners[2]);
      Posts(holes);
      RoundEdge(corners[0], corners[1]);
      RoundEdge(corners[3], corners[0]);
    }
    InterlockEdge(corners[1], corners[2], 1, nlobes=1);
    RoundCornerCut(rcs);
  }
  RoundCornerAdd(rcs);
}

module TestPiece2(){ ////toplevel
  holes = [ [   0, 0],
	    [  50, 0]
	    ];
  corners = TestPiece_holes2corners(holes);
  TileBase(corners[0], corners[2]);
  Posts(holes);
  RoundEdge(corners[0], corners[1]);
  InterlockEdge(corners[3], corners[0], 0, nlobes=1);
}

module TestDemo(){ ////toplevel
  translate([ -thehd[0], 0 ])
    color("blue")
    TestPiece1();
  translate([ +thehd[0] + demo_slop, 0 ])
    TestPiece2();
}
  
function Rectangle_corners(c0, sz) =
  [ c0 + [ 0,     0     ],
    c0 + [ sz[0], 0     ],
    c0 + [ sz[0], sz[1] ],
    c0 + [ 0,     sz[1] ] ];

function Rectangle_corners2posts(c) =
  [ c[0] + thehd_tr,
    c[1] + thehd_tl,
    c[2] + thehd_bl,
    c[3] + thehd_br ];

module Tile02(){ ////toplevel
  sz = [100,170];
  c0 = -sz;
  c = Rectangle_corners(c0, sz);
  posts = Rectangle_corners2posts(c);
  rcs = [c[0], c[1]];
  difference(){
    union(){
      TileBase(c[0], c[2]);
      Posts(posts);
      RoundEdge(c[0], c[1]);
      RoundEdge(c[3], c[0]);
      InterlockEdge(c[2], c[3], 0);
    }
    InterlockEdge(c[1], c[2], 1);
    RoundCornerCut(rcs);
  }
  RoundCornerAdd(rcs);
}

module Tile12(){ ////toplevel
  sz = [100,250];
  c0 = [-sz[0], 0];
  c = Rectangle_corners(c0, sz);
  posts = Rectangle_corners2posts(c);
  rcs = [c[2], c[3]];
  difference(){
    union(){
      TileBase(c[0], c[2]);
      RoundEdge(c[2], c[3]);
      RoundEdge(c[3], c[0]);
      Posts(posts);
    }
    InterlockEdge(c[0], c[1], 1);
    RoundCornerCut(rcs);
  }
  RoundCornerAdd(rcs);
}

module Demo(){ ////toplevel
  translate(demo_slop*[-2,1]) color("blue") Tile12();
  translate(demo_slop*[-2,0]) color("red")  Tile02();
}
  
//TestPiece1();
//TestPiece2();
//Demo();