// -*- C -*-

include <funcs.scad>
include <commitid.scad>

ply_th = 18;
ply_hole_dia = 15;
ply_edge_min = 10;

tile_th = 3;
post_dia = 8;

post_shorter = 1;

screw_dia = 2.2;
screw_big_dia = 3.6;
screw_big_len = 4.0;

round_edge_rad = 2.0;

interlock_dia = 10;

// calculated

ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;

echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));

hole_slop = (ply_hole_dia - post_dia)/2;
tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;

echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
	 tile_hard_edge_hole_dist));

echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
	 tile_hard_edge_hole_dist + round_edge_rad));

thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
thehd_tr = thehd;
thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
thehd_bl = -thehd_tr;
thehd_br = -thehd_tl;

interlock_rad = interlock_dia/2;
interlock_negative_rad = interlock_rad + 0.125;

module Post(){
  mirror([0,0,1]) {
    difference(){
      cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
      translate([0,0, tile_th]) {
	cylinder(r= screw_big_dia/2, h= screw_big_len);
	cylinder(r= screw_dia/2, h= ply_th, $fn=20);
      }
    }
  }
}

module Posts(posts) {
  for (p= posts) {
    translate(concat(p, [0]))
      Post();
  }
}

module TileBase(botleft, topright){
  size = topright - botleft;
  botleft_post = botleft + thehd_tr;
  topright_post = topright - thehd_bl;
  echo(botleft_post, topright_post);
  difference(){
    mirror([0,0,1])
      translate(concat(botleft, [0]))
      cube(concat(size, [tile_th]));
    translate( concat(botleft_post, [-tile_th])
	       + 0.5 * [ post_dia, post_dia, 0 ] )
      Commitid_BestCount_M( topright_post-botleft_post
			    + [0, thehd[1] ]
			    + [-post_dia,-post_dia] );
  }
}

m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
m4_define(`INREFFRAME',`
  length_vec = ($2) - ($1);
  length = dist2d([0,0], length_vec);
  length_uvec = length_vec / length;
  ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
  m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
	[ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
	[ 0,              0,              1,            0, ],
	[ 0,              0,              0,            1, ] ];
  $3
  multmatrix(m)
')

m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
m4_dnl    INREFFRAME_EDGE { body; }
m4_define(`INREFFRAME_EDGE',`
  translate([0,0, -round_edge_rad])
')

module RoundEdge(left_cnr, right_cnr) {
  INREFFRAME(left_cnr, right_cnr)
    INREFFRAME_EDGE {
    difference(){
      rotate([0,90,0])
	cylinder(r= round_edge_rad, h= length, $fn=50);
      translate([-1, 0, -20])
	cube([length+2, 20, 20]);
    }
  }
}

module RoundLeftCorner(this_cnr, right_cnr) {
  INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
    difference(){
      sphere(r= round_edge_rad, $fn=60);
      translate([0,0, -20])
	cube([20,20,20]);
    }
  }
}

module InterlockCore(r, plusth, ymir) {
  dx = sqrt(3) * r;
  $fn= 80;
  translate([thehd[0], 0, plusth]){
    mirror([0,ymir,0]){
      mirror([0,0,1]){
	linear_extrude(height=tile_th+plusth*2, convexity=10){
	  circle(r=r);
	  difference(){
	    translate([-dx, -0.1])
	      square([ dx*2, r/2 + 0.1 ]);
	    for (xi = [-1, 1]) {
	      translate([ xi*dx, r ])
		circle(r=r);
	    }
	  }
	}
      }
    }
  }
}

module InterlockNegative(this_cnr, right_cnr) {
  INREFFRAME(this_cnr, right_cnr)
    InterlockCore(interlock_negative_rad, 1, 0);
}

module Interlock(this_cnr, right_cnr) {
  INREFFRAME(this_cnr, right_cnr)
    InterlockCore(interlock_rad, 0, 1);
}

function TestPiece_holes2corners(holes) =
  [ holes[0] + thehd_bl,
    holes[1] + thehd_br,
    holes[0] + thehd_tl,
    holes[1] + thehd_tr ];

module TestPiece1(){ ////toplevel
  holes = [ [-100, 0],
	    [   0, 0]
	    ];
  corners = TestPiece_holes2corners(holes);
  difference(){
    TileBase(corners[0], corners[3]);
    InterlockNegative(corners[1], corners[3]);
  }
  Posts(holes);
  RoundEdge(corners[0], corners[1]);
  RoundEdge(corners[2], corners[0]);
  RoundLeftCorner(corners[0], corners[1]);
}

module TestPiece2(){ ////toplevel
  holes = [ [   0, 0],
	    [  50, 0]
	    ];
  corners = TestPiece_holes2corners(holes);
  TileBase(corners[0], corners[3]);
  Posts(holes);
  RoundEdge(corners[0], corners[1]);
  Interlock(corners[2], corners[0]);
}

module Demo(){ ////toplevel
  translate([ -thehd[0], 0 ])
    color("blue")
    TestPiece1();
  translate([ +thehd[0], 0 ])
    TestPiece2();
}
  
//TestPiece1();
//TestPiece2();
//Demo();