// -*- C -*-

include <utils.scad>

nook_th = 12.41 + 0.50;
nook_w = 127.12 + 0.75;
nook_h = 123.44 + 21.88 + 21.05 + 0.75;

nook_cnr_rad = 10;

case_th = 2.5;
ledge_w = 4;
tape_th = 1.75;
tape_inside = 2.0;

gap = 0.5 * [1,1];

tape_w = 15;

test_pillar = 4;

engage_l0 = 10;
engage_l1 = 10;
engage_l2 = 3;

tooth_inward = gap[0] * 1.0;
tooth_x = nook_w * 1/6;
tooth_w = 15;

$test = false;

// calculated

tooth_height = nook_th;
ledge_h = case_th;
lid_th = case_th;
tooth_th = case_th;

spp0 = [0,0];
spp1 = spp0 + case_th * [-1,0];
spp9 = spp0 + ledge_h * [0,-1];
spp8 = spp9 + nook_th * [0,-1];
spp7 = spp8 + case_th * [-1,-1];

spp11y = spp1[1] - tape_th;
spp4y  = 0.5 * (spp0[1] + spp7[1]);
spp3y = spp4y + tape_inside/2;  spp5y = spp4y - tape_inside/2;
spp2y = spp3y + tape_th;        spp6y = spp5y - tape_th;

spp20 = spp8 + nook_cnr_rad * [1,0];
spp20x = spp20[0];

tppA = spp0 + gap;
tppB = spp1 + [0, gap[1]];
tppC = tppB + lid_th * [0,1];
tppD = [ spp20x, tppC[1] ];
tppE = [ spp20x, tppB[1] ];
tppF = tppA + ledge_w * [1,0];
tppG = tppF + ledge_h * [0,-1];
tppH = [ tppA[0], tppG[1] ];

tppJx = tppA[0] + tape_th;

tppK = [ tppC[0], tppG[1] ];
spp31 = tppK - [0, gap[1]];
spp30 = [ spp8[0], spp31[1] ];

nom_cnr = 0.5 * [nook_w, nook_h, 0] - nook_cnr_rad * [1,1,0];

etxa = nom_cnr[0] - engage_l2;
etxb = etxa - engage_l1;
etxc = -(nom_cnr[0] - engage_l2);

tppS = tppB + [-gap[0], 0];
tppP = [ tppS[0] - tooth_th, tppC[1] ];
tppQ = tppP + tooth_height * [0,-1] + tooth_inward * [1,0];
tppR = [ tppS[0] + tooth_inward, tppQ[1] ];
tppM = (tppQ + tppR) * 0.5 + tooth_th * 0.5 * [0,1];

module RightSideMainProfile() {
  rectfromto(spp7, spp0);
  rectfromto(spp7, spp20);
}

module LeftSideMainProfile() {
  rectfromto(spp7, spp30);
  rectfromto(spp7, spp20);
}

module TopTapeCutout() {
  polygon([ tppA,
	    tppA + [-40, 0],
	    tppG + [-40,-1],
	    [ tppJx, tppH[1]-1 ],
	    [ tppJx, tppC[1]+1 ],
	    [ tppA[0], tppC[1]+1 ]]);
}

module RightTopMainProfile() {
  l = [ tppA, tppB, tppC, tppD, tppE, tppF, tppG, tppH ];
  polygon(l);
}

module LeftTopMainProfile() {
  l = [ tppC, tppD, tppE, tppF, tppG, tppK ];
  polygon(l);
}

module SideTapeCutout1(y0,y1) {
  rectfromto([ spp7[0]-1, y0 ],
	     [ spp8[0]+1, y1 ]);
}

module SideTapeCutout() {
  SideTapeCutout1(spp6y, spp5y);
  SideTapeCutout1(spp3y, spp2y);
  SideTapeCutout1(spp3y, spp2y);
  SideTapeCutout1(spp11y, spp1[1] + 1);
}

module ToothProfile(){
  polygon([tppA,
	   tppB,
	   tppS + [-0.1,0],
	   tppP,
	   tppC]);
  hull(){
    polygon([tppP,
	     tppM,
	     tppS]);
    translate(tppM)
      circle(r= tooth_th/2, $fa=3, $fs=0.1);
  }
}

module Demo(){ ////toplevel
  translate([0,0,-2]) LeftSideMainProfile(); 
  translate([0,0,-2]) color("yellow") LeftTopMainProfile();
  color("red") difference(){
    LeftSideMainProfile();
    SideTapeCutout();
  }
  translate([0,0,0]) color("purple") difference(){
    LeftTopMainProfile();
    TopTapeCutout();
  }
  translate([nook_cnr_rad*2 + 5, 0,0]) mirror([1,0,0]) {
    color("red") RightSideMainProfile();
    color("purple") RightTopMainProfile();
    color("grey") translate([0,0,-2]) ToothProfile();
  }
  //%SideTapeCutout();
}

module FaceCore(z0,z1, extra_left, extra_right){
  for (mx=[0,1]) mirror([mx,0,0]) {
      for (my=[0,1]) mirror([0,my,0]) {
	  translate(-nom_cnr) {
	    rotate_extrude(angle=90, convexity=10)
	      translate(-[1,0,0] * nook_cnr_rad)
	      children(mx);
	  }
	}
      translate([nook_w/2, 0,0])
	linextr_y_xz(-nom_cnr[1]-0.1, nom_cnr[1]+0.1)
	children(1-mx);
    }
  for (my=[0,1]) mirror([0,my,0]) {
      translate([0, -nook_h/2, 0]) {
	linextr_x_yz(-nom_cnr[0]-0.1,    etxc + extra_left)  children(0);
	linextr_x_yz(etxc - extra_right, etxb + extra_right) children(1);
	linextr_x_yz(etxb - extra_left,  etxa + extra_left)  children(0);
	linextr_x_yz(etxa - extra_right, nom_cnr[0]+0.1)     children(1);
      }
    }
  if (!$test) {
    linextr(z0,z1)
      rectfromto(-nom_cnr, nom_cnr);
  }
}

module Base(){ ////toplevel
  FaceCore(spp7[1],spp8[1], 0.3, 0) {
    LeftSideMainProfile();
    RightSideMainProfile();
  }
}

module Top(){ ////toplevel
  FaceCore(tppE[1],tppD[1], -gap[0], gap[0] + 0.3) {
    LeftTopMainProfile();
    RightTopMainProfile();
  }
  translate([tooth_x, nook_h/2, 0])
    linextr_x_yz(-tooth_w/2, +tooth_w/2)
    mirror([1,0])
    ToothProfile();
}

module TestExtrude(){
  difference(){
    linextr_y_xz(-test_pillar, tape_w+test_pillar) children(0);
    linextr_y_xz(           0, tape_w            ) children(1);
  }
}

module TestSide(){ ////toplevel
  TestExtrude() { LeftSideMainProfile(); SideTapeCutout(); }
}

module TestTop(){ ////toplevel
  TestExtrude() { LeftTopMainProfile(); TopTapeCutout(); }
}
module TestTopPrint(){ ////toplevel
  rotate([180,0,0]) TestTop();
}