// -*- C -*-

opening_height = 7.84;
opening_depth = 7.88;
openingedge_dia = 1.34;
opening_protrh = 1.8;

pivot_x = 6;
inside_len = 4;

pivoting_gap = 0.1;

outside_gap = 3;
outside_len = 16;
outend_height = 3;

outside_pushh = 4;
outside_pushslope = 1.4;
outside_push_inadj = 0.82;

ourcirc_r = 0.5 / 2;

opening_protr_slop = 0.1;

intooth_top_slop = 0.1;
inside_h_xgap = 1;

pivot_r = 2;
pivot_slop = 0.25;

width = 5;

// calculated

inside_h = opening_height/2 - opening_protrh - inside_h_xgap/2;

edge_or = openingedge_dia/2 + opening_protr_slop;

Q0 = [ openingedge_dia/2,
       openingedge_dia/2 + opening_height/2 ];

p4p5d = [edge_or + ourcirc_r, 0];

P0 = [ pivot_x, pivoting_gap ];
P4 = Q0 - p4p5d;
P3t = [ P4[0], Q0[1] - openingedge_dia/2 + opening_protrh
	- intooth_top_slop - ourcirc_r ];
P2 = P4 + [ -(inside_len - ourcirc_r*2), 0 ];
P1 = [ P2[0], P3t[1] - (inside_h + ourcirc_r*2) ];

P5 = Q0 + p4p5d;

P9mid = [ outside_len - ourcirc_r, outside_gap/2 + ourcirc_r ];
P8mid = P9mid + [ 0, outend_height - ourcirc_r*2 ];

P89adj = [ 0, P5[1] - P8mid[1] ];

P6t = P5 + [ 0, outside_pushh - ourcirc_r*2 ];
P7 = [ P6t[0] + (P6t[1] - P1[1]) / outside_pushslope,
       P1[1] ];

P3a = P3t + [ -outside_push_inadj, 0 ];
P6a = P6t + [ -outside_push_inadj, 0 ];

outside_push_inadj_slope = (P3t[1]-P4[1]) / (P6a[1]-P5[1]);

module ExtrusionSect(){
  cr = openingedge_dia/2;
  toph = opening_height/2 + opening_protrh;

  for (my=[0,1]) {
    mirror([0,my]) {
      translate(Q0) {
	hull(){
	  circle(r=cr, $fn=20);
	  translate([-cr,10]) square([cr*2, 1]);
	}
      }
    }
  }
  translate([-opening_depth, -toph]) {
    difference(){
      translate([-5,-5])
	square([opening_depth+6, toph*2+10]);
      square([opening_depth+2, toph*2]);
    }
  }
}

module PsHull(ps) {
  hull(){
    for (p = ps) {
      translate(p)
	circle(r = ourcirc_r, $fn=10);
    }
  }
}

module LeverSect(P89adjsense, inadj=false){
  P3 = inadj ? P3a : P3t;
  P8 = P8mid + P89adjsense * P89adj;
  P9 = P9mid + P89adjsense * P89adj;
  diag = inadj ? 0 : atan(outside_push_inadj_slope);
  PsHull([P2,P3,P4]);
  difference(){
    PsHull([P0,P1,P2,P5,P8,P9]);
    translate(Q0) {
      rotate(diag){
	hull(){
	  circle(r=edge_or, $fn=20);
	  translate([0,10]) circle(r=edge_or, $fn=20);
	}
      }
    }
  }
}

module LeverSectTop(){
  difference(){
    LeverSect(+1, false);
    translate([pivot_x,0]) circle(r= pivot_r + pivot_slop, $fn=20);
  }
}

module LeverSectBot(inadj=false){
  P6 = inadj ? P6a : P6t;
  mirror([0,1]) {
    LeverSect(-1, inadj);
    PsHull([P5,P6,P7]);
    translate([pivot_x,0]) circle(r=pivot_r, $fn=20);
  }
}

module Demo(){
  translate([0,0,-5]) color("white") ExtrusionSect();
  LeverSectTop();
  LeverSectBot();
}

module LeverTop(){
  linear_extrude(height=width, convexity=100) LeverSectTop();
}

module LeverBot(inadj=false){
  linear_extrude(height=width, convexity=100) LeverSectBot(inadj);
}

module Test(){
  translate([0,2,0]) LeverTop();
  LeverBot();
  translate([0,-opening_height - 2,0]) LeverBot(true);
}

//Demo();
Test();