// -*- C -*-

opening_height = 7.84 - 0.3 + 0.60;
opening_depth = 6.0; // 7.88;
openingcnr_dia = 2.75;
opening_topprotr = 1.54;

gap = 0.25;

retain_empir_angle = 20;
retain_empir_stalkw = 0.8;
retain_rad = 1.65;
retain_empir_inward = 0.65;

hgap_empir_adjust = -0.5 -2.50;

topprotr_rad = 0.35;

bot_overlap = 5;
bot_w = 3;

handle_w = 8;
handle_rh = 3;
handle_rcut = 3;

cutout_gap = 1.5;

total_len = 35;
retaining_len = 10;
overret_gaplen = 5;

overret_hch = 5;

// calculated

ins_irad = openingcnr_dia/2 + gap;
ins_orad = openingcnr_dia/2 + opening_height - gap;
ins_th = ins_orad - ins_irad;

handle_x0 = ins_irad + hgap_empir_adjust;
handle_h = bot_overlap + ins_th;
handle_y0 = -ins_orad-bot_overlap;
handle_y1 = handle_y0 + handle_h;

handle_x1 = handle_x0 + bot_w + handle_w;

topprotr_y = -ins_irad + opening_topprotr;

module InsertSection(){
  hull(){
    translate([-ins_irad, -ins_irad])
      mirror([1,0])
      square([opening_depth - ins_irad, 0.1]);
    translate([-ins_irad - topprotr_rad,
	       topprotr_y - topprotr_rad])
      circle(r=topprotr_rad, $fn=10);
  }
  translate([0, -ins_orad]) square([ins_irad+1, ins_th]);
  intersection(){
    translate([0.1, -ins_irad + 0.1])
      mirror([1,1])
      square([100, opening_depth]);
    difference(){
      circle(r= ins_orad);
      circle(r= ins_irad, $fn=20);
    }
  }
}

module HandleSection(){
  difference(){
    hull(){
      translate([handle_x0, handle_y0])
	square([bot_w, handle_h]);
      for (y= [handle_y1 - handle_rh/2,
	       handle_y1 - ins_th + handle_rh/2]) {
	translate([handle_x1 - handle_rh/2, y])
	  circle(r= handle_rh/2, $fn=20);
      }
    }
    hull(){
      for (x= [handle_x0 + bot_w + handle_rcut/2,
	       handle_x1 - handle_rh/2 - handle_rcut/2]) {
	translate([x, handle_y1])
	  circle(r = handle_rcut/2, $fn=20);
      }
    }
  }
  hull(){
    for (y= [handle_y1 -   handle_rh/2,
	     handle_y1 - 3*handle_rh/2])
      translate([handle_x1 - handle_rh/2, y])
	circle(r = handle_rh/2, $fn=20);
  }
}

module RetainSection(){
  rotate(180-retain_empir_angle)
    translate([0, ins_orad - retain_empir_inward])
    circle(r=retain_rad, $fn=20);
}

module RetainCutout(gapping=false){
  rotate(180-retain_empir_angle)
    translate([0, ins_orad - retain_empir_inward]) {
    difference(){
      circle(r=retain_rad + cutout_gap, $fn=20);
      if (!gapping)
	rotate(180 + retain_empir_angle/2)
	  translate([0, -retain_empir_stalkw])
	  square([100, retain_empir_stalkw*2]);
    }
  }
}  

module GappingSection(){
  difference(){
    InsertSection();
    RetainCutout(true);
  }
  HandleSection();
}

module WithRetainSection(){
  difference(){
    union(){
      InsertSection();
      HandleSection();
    }
    RetainCutout();
  }
  RetainSection();
}

module BasicSection(){
  InsertSection();
  HandleSection();
}

module Handle(){
  bs0 = retaining_len + overret_gaplen;
  bs1 = bs0 + overret_hch;
  linear_extrude(height=total_len, convexity=100) GappingSection();
  linear_extrude(height=retaining_len, convexity=100) WithRetainSection();
  translate([0,0, bs1]) linear_extrude(height= total_len - bs1)
    BasicSection();
  translate([0,0, bs1+0.1]) mirror([0,0,1]) {
    intersection_for (sl=[0,1]) {
      multmatrix([[1,0,0,0],
		  [0,1,sl*0.65,0],
		  [0,0,1,0],
		  [0,0,0,1]])
	linear_extrude(height= overret_gaplen+1, convexity=100)
	BasicSection();
    }
  }
}

module Demo(){
  color("red") translate([0,0,-3]) BasicSection();
  color("blue") translate([0,0,3]) WithRetainSection();
}

module Test(){
  linear_extrude(height=2) {
    WithRetainSection();
    translate([0, -handle_y0 + topprotr_y + 10])
      BasicSection();
  }
}

//Demo();
//HandleSection();
//InsertSection();
//WithRetainSection();
//BasicSection();
//GappingSection();
//Test();
Demo();
//Handle();