// -*- C -*-

spoolwidth = 80; // fixme needs to be measured
trestleheight = 80; // fixme needs to be checked
trestlebase = 80; // fixme needs to be checked

include <doveclip.scad>

spoolwidthgap = 2;
barrady = 5;
barradz = 7;
guidewidth = 3;
guiderad = 20;

plugl = 12;
plugwmin = 3;
plugh = 10;
plugslope = 0.5;
plugwmax = plugwmin + plugh * plugslope * 2;

trestlelegw = 10;
trestlebaseh = 10;
trestleplugd = 1;

topcylthick = 3;
topcylbasedepth = 4;

module Plug(d=0){
  a = -atan(plugslope);
  tdx = d * cos(a);
  tdy = d * sin(a);
  bdx = d / cos(a);
  translate([-d,0,0]) rotate([90,0,90]) linear_extrude(height=plugl+0.1+d*2){
    polygon([[-(plugwmin/2 + bdx),  0],
	     [-(plugwmax/2 + tdx),  plugh + tdy],
	     [+(plugwmax/2 + tdx),  plugh + tdy],
	     [+(plugwmin/2 + bdx),  0]]);
  }
}

module Bar(){
  spoolw = spoolwidth + spoolwidthgap*2;
  barz = barradz * 0.5;
  biggestw = spoolw + 50;

  intersection(){
    for (mir=[0,1]) {
      mirror([mir,0,0]) {
	translate([0,0,barz]) {
	  scale([1,barrady,barradz]) translate([-1,0,0])
	    rotate([0,90,0]) cylinder(r=1, h=spoolw/2+2, $fn=30);
	  translate([spoolw/2,0,0])
	    rotate([0,90,0]) cylinder(r=guiderad, h=guidewidth, $fn=60);
	}
	translate([spoolw/2 + guidewidth, 0, 0])
	  Plug();
      }
    }
    translate([-biggestw/2, -50, 0])
      cube([biggestw, 100, 100]);
  }
}

module Trestle(){
  legang = atan2(trestlebase/2, trestleheight);
  eplen = sqrt(trestleheight*trestleheight + trestlebase*trestlebase*0.25);
  topcylw = plugwmax + topcylthick*2;

  difference(){
    union(){
      for (mir=[0,1]) {
	mirror([mir,0,0]) {
	  rotate([0,0, -90-legang])
	    ExtenderPillars(length=eplen+trestlelegw,
			    width=trestlelegw,
			    height=plugl,
			    baseweb=true);

	  translate([-trestlebase/2, -trestleheight, 0])
	    cylinder(r=trestlelegw/2*1.2, h=plugl);
	}
      }
      translate([-topcylw/2, -topcylbasedepth, 0])
	cube([topcylw, topcylbasedepth + plugh + topcylthick, plugl]);

      translate([-trestlebase/2, -trestleheight, 0])
	ExtenderPillars(length=trestlebase, width=trestlebaseh*2, height=plugl);
    }
    translate([-300, -trestleheight-50, -1])
      cube([600, 50, plugl+2]);

    rotate([-90,-90,0])
      Plug(d=trestleplugd);
  }
}

//Bar();
Trestle();

//Plug(d=1);
//ExtenderPillars(80,12,8, baseweb=true);