// -*- C -*-

spoolwidth = 80; // fixme needs to be measured

include <doveclip.scad>

spoolwidthgap = 2;
barrady = 5;
barradz = 7;
guidewidth = 3;
guiderad = 20;

plugl = 12;
plugwmin = 4;
plugh = 10;
plugslope = 0.5;
plugwmax = plugwmin + plugh * plugslope;

module Plug(d=0){
  a = atan(plugslope);
  tdx = d * cos(a);
  tdy = d * sin(a);
  bdx = d / cos(a);
  rotate([90,0,90]) linear_extrude(height=plugl+0.1){
    polygon([[-(plugwmax + bdx),  0],
	     [-(plugwmin + tdx),  plugh + tdy],
	     [+(plugwmin + tdx),  plugh + tdy],
	     [+(plugwmax + bdx),  0]]);
  }
  translate([plugl + DoveClip_depth()*0.7, 0, 0])
    DoveClipPairSane(count=1, h=plugh);
}

module Bar(){
  spoolw = spoolwidth + spoolwidthgap*2;
  barz = barradz * 0.5;
  biggestw = spoolw + 50;

  intersection(){
    for (mir=[0,1]) {
      mirror([mir,0,0]) {
	translate([0,0,barz]) {
	  scale([1,barrady,barradz]) translate([-1,0,0])
	    rotate([0,90,0]) cylinder(r=1, h=spoolw/2+2, $fn=30);
	  translate([spoolw/2,0,0])
	    rotate([0,90,0]) cylinder(r=guiderad, h=guidewidth, $fn=60);
	}
	translate([spoolw/2 + guidewidth, 0, 0])
	  Plug();
      }
    }
    translate([-biggestw/2, -50, 0])
      cube([biggestw, 100, 100]);
  }
}

Bar();
//Plug(d=1);