// -*- C -*-

phone_height = 146.5 - .80;
phone_width = 76.75 - .50;

phone_cnr_rad = 6.0;

button_cutout_depth = 9;

phone_edge_thick = 9.0;
phone_total_thick = 12.0;
phone_backside_slope_inner = 1.5; // larger means shallower
phone_backside_slope_outer = 1.0; // larger means shallower

camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
camera_pos_br = [ 22.85,37.85]; // tl/br as seen from back

case_th_bottom = 2.5;
case_th_lid = 2.5;
case_th_side = 2;
case_th_lip = 1.2;

case_struts_count = 6;
case_struts_solid_below = 0.75;
case_struts_solid_above = 1.00;
case_struts_width = 0.10;

keeper_th_z = 0.75;
keeper_th_x = 0.75;
keeper_inner_width = 2.75;
keeper_inner_height = 2.75;
keeper_slant_slope = 2; // larger means steeper

keeper_gap_z_top = 0.25;
keeper_gap_z_bot = 0.75;
keeper_gap_x     = 0.25;
keeper_gap_x_holes = 0.75;

case_lip = 1.25;

lid_gap_x = 0.25;
lid_gap_z = 0.25;
lid_lip = 1.75;

$fa = 5;
$fs = 0.1;

button_l_fudge = 4.5;

// ---------- calculated ----------

// ----- could be changed -----
lid_buttoncover_gap = lid_gap_x;
lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;

phone_backside_slope_thick = phone_total_thick - phone_edge_thick;

//lid_lip_overlap_width xxx bad name = ;
//lid_lip_inner_slope = [ 5, 5 ]; // xxx

epp0 = [0,0];
epp1 = [0, -phone_edge_thick];
epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
epp3 = epp2i + [10, 0];
epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
epp4 = epp5 + [-1,0] * case_th_side;

kppe = [0,0];
kppd = kppe + [1,0] * keeper_inner_width;
kppc = kppd + [0,1] * keeper_th_z;
kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
kppf = kppe - [0,1] * keeper_inner_height;
kppa = [ kppb[0], kppf[1] ];

lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
lpp12 = [ epp4[0] + lid_lip,   lpp11[1] ];
lpp13 = [ lpp12[0],            lpp12[1] + lid_lip ];

// button profile
bppM = epp4 + [0,5];
bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
bppS = [ epp1[0], bppR[1] ];
bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
bppP = bppQ + [0,1] * lid_buttoncover_gap;
bppO = [ bppN[0], bppP[1] ];
bppL = lpp10 + [5,0];
bppK = [ bppL[0], bppN[1] ];
bppJ = [ bppN[0], bppL[1] ];

module rectfromto(a,b) {
  ab = b - a;
  translate([min(a[0], b[0]), min(a[1], b[1])])
    square([abs(ab[0]), abs(ab[1])]);
}
module circleat(c,r) { translate(c) circle(r); }

module KeeperProfile(slant=0){
  use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
  polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
}

module EdgeProfile(){
  difference(){
    hull(){
      translate(epp3) square(case_th_bottom*2, center=true);
      circleat(epp2o, r=case_th_bottom);
      circleat(epp1, r=case_th_side);
      rectfromto(epp0, epp4);
    }
    polygon([ epp5 + [0,10],
	      epp1,
	      epp2i,
	      epp3 + [10,0] ]);
  }
}

module LidEdgeProfile(){
  polygon([ lpp10,
	    lpp11,
	    lpp12,
	    lpp13,
	    lpp13 + [10, 0],
	    lpp10 + [10, 0]
	    ]);
  intersection(){
    circleat(lpp12, r=lid_lip);
    rectfromto( lpp12 + [-10,   0],
		lpp12 + [+10, +10] );
  }
}

module ButtonCoverProfile(){
  intersection(){
    polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
    hull(){
      EdgeProfile();
      LidEdgeProfile();
    }
  }
}

module ButtonPlan(l, deep, cut){
  bigger =
    (deep ? lid_buttoncover_overlap : 0) +
    (cut  ? 0 : -lid_buttoncover_gap);

  d_D1_y =
    (cut  ? 0 : lid_buttoncover_gap);

  C = [0,0]; // by definition
  T = [ 0, epp4[1] ];
  G = T + [0,10];
  B0 = C + [0,-1] * button_cutout_depth;
  r0 = 0.5 * (T[1] - B0[1]);
  A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
  r1 = r0 + bigger;
  // | D1 - A | = r1 * 2
  // D1_y = T_y - r1 + d_D1_y
  // =>    4 * r1^2   =  (r1-r0 + d_D1_y)^2 + (D1_x - A_x)^2
  // =>    D1_x =  A_x + v/~ [  4 * r1^2   -   (r1-r0 + d_D1_y)^2 ]
  D1  = [ A[0] - sqrt( 4*r1*r1 - pow(bigger + d_D1_y, 2) ),
	  T[1] - r1 + d_D1_y ];
  E1  = 0.5 * (D1 + A);
  F1  = D1 + [0,10];

  hull(){
    for (m=[0,1]) mirror([m,0])
      circleat(A, r1);
  }
  for (m=[0,1]) mirror([m,0]) {
    difference(){
      polygon([ E1,
		A,
		B0,
		G,
		F1,
		D1
		]);
      circleat(D1, r1);
    }
  }
}

module CaseBase_rhsflip(yn=[0,1]) {
  for (rhs=yn) {
    translate([phone_width/2, 0, 0])
      mirror([rhs,0,0])
      translate([-phone_width/2, 0, 0])
      children();
  }
}

module CaseBase_botflip() {
  for (bot=[0,1]) {
    translate([0, -phone_height/2, 0])
      mirror([0, bot, 0])
      translate([0, phone_height/2, 0])
      children();
  }
}  

module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
  // sides
  CaseBase_rhsflip(){
    translate([0, -phone_cnr_rad, 0])
      rotate([90,0,0])
      linear_extrude(height = phone_height - phone_cnr_rad*2)
      children(0);
  }
  // corners
  CaseBase_rhsflip() CaseBase_botflip() {
    translate([+1,-1] * phone_cnr_rad)
      intersection(){
	rotate_extrude()
	  intersection(){
	    mirror([1,0,0])
	      translate([-1,0] * phone_cnr_rad)
	      children(0);
	    rectfromto([0,-20],[10,20]);
	  }
	translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
	  cube([10,10,40]);
      }
  }
  // top and bottom
  CaseBase_botflip(){
    translate([ phone_width - phone_cnr_rad, 0,0 ])
      rotate([90,0,-90])
      linear_extrude(height = phone_width - phone_cnr_rad*2)
      children(0);
  }
  // fill
  translate([0,0, fill_zstart])
    mirror([0,0, fill_downwards])
    linear_extrude(height = fill_th)
    rectfromto([+1,-1] * phone_cnr_rad,
	       [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
}

module CaseBase(){
  AroundEdges(epp3[1], case_th_bottom, 1)
    EdgeProfile();
}

module Case(){ ////toplevel
  difference(){
    union(){
      CaseBase();

      // ledge (fixed keeper)
      intersection(){
	rotate([90, 0, 0])
	  linear_extrude(height = phone_height + phone_cnr_rad * 2)
	  KeeperProfile(1);

	// outline of the whole case, to stop it protruding
	translate([0,0, -25])
	  linear_extrude(height = 50)
	  hull()
	  // CaseBase_rhsflip() // actually, we only care about the LH
	  CaseBase_botflip()
	  circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
      }
    }

    // slot for keeper
    CaseBase_rhsflip(1)
      translate([0, -phone_cnr_rad, 0])
      rotate([90, 0, 0])
      linear_extrude(height = phone_height + phone_cnr_rad * 2)
      minkowski(){
        KeeperProfile();
	rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
		   [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
      }

    // front camera
    CaseBase_rhsflip([1])
      mirror([0, 0, 1])
      linear_extrude(height = 20)
      mirror([0, 1, 0])
      rectfromto(camera_pos_tl, camera_pos_br);

    // struts (invisible, because they're buried in the case)
    for (i= [1 : 1 : case_struts_count]) {
      translate([0,
		 -phone_height * i / (case_struts_count+1),
		 epp2i[1] - case_th_bottom + case_struts_solid_below])
	linear_extrude(height= case_th_bottom
		       -(case_struts_solid_below+case_struts_solid_above))
	rectfromto([               epp2i[0], -0.5 * case_struts_width ],
		   [ phone_width - epp2i[0], +0.5 * case_struts_width ]);
    }
  }
}

module Lid(){ ////toplevel
  AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
    LidEdgeProfile();
}

module TestLength(){ ////toplevel
  intersection(){
    Case();
    translate([-30, -200, -20])
    cube([30 + 15, 250, 40]);
  }
}

module TestWidth(){ ////toplevel
  intersection(){
    Case();
    translate([-30, -(phone_height - 25), -20])
      mirror([0, 1, 0])
      cube([200, 50, 40]);
  }
}

module TestLidWidthPrint(){ ////toplevel
  rotate([0,180.0])
    intersection(){
      Lid();
      translate([-30, -(phone_height - 25), -20])
	mirror([0, 1, 0])
	cube([200, 50, 40]);
    }
}

module TestCamera(){ ////toplevel
  intersection(){
    Case();
    CaseBase_rhsflip(1)
      translate([0,0,-25])
      linear_extrude(height = 50)
      mirror([0, 1, 0])
      rectfromto([-20, -20],
		 camera_pos_br + [ 5, 5 ]);
  }
}

module OneKeeper(){ ////toplevel
  translate([0, -phone_cnr_rad, 0])
    rotate([90, 0, 0])
    linear_extrude(height = phone_height - phone_cnr_rad * 2)
    KeeperProfile();
}

module OneKeeperPrint(){ ////toplevel
  rotate([0,180,0])
    OneKeeper();
}

module Keeper(){ ////toplevel
  CaseBase_rhsflip()
    OneKeeper();
}

module ButtonPlanForDemo(colour, z, deep, cut){
  color(colour)
    translate([0,0,z])
    ButtonPlan(8, deep, cut);
}

module DemoProfiles(){ ////toplevel
  LidEdgeProfile();
  %EdgeProfile();
  KeeperProfile();
  translate([0,0,-1]) color("black") KeeperProfile(1);

  translate([20,0]) {
    LidEdgeProfile();
    %EdgeProfile();

    demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
  
    color("blue") ButtonCoverProfile();
    color("red") {
      rectfromto(bppQ, demopoint_QR);
      rectfromto(bppR, demopoint_QR);
    }
  }

  translate([-20,0]) {
    ButtonPlanForDemo("grey", -1, 0,1);
    ButtonPlanForDemo("blue", -2, 1,0);
    ButtonPlanForDemo("red",  -3, 1,1);
  }
}

//EdgeProfile();
//KeeperProfile();
//CaseBase();
//%Case();
//Keeper();
//LidEdgeProfile();
//KeeperProfile();
//DemoProfiles();