// -*- C -*-

phone_height = 146.5;
phone_width = 76.75;

phone_cnr_rad = 4.0;

phone_edge_thick = 9.0;
phone_total_thick = 12.0;
phone_backside_slope = 1.0; // larger means shallower

case_th_bottom = 2;
case_th_lid = 2;
case_th_side = 2;
case_th_lip = 1.2;

case_lip = 2;

$fa = 5;
$fs = 0.1;

// calculated

phone_backside_slope_thick = phone_total_thick - phone_edge_thick;

//lid_lip_overlap_width xxx bad name = ;
//lid_lip_inner_slope = [ 5, 5 ]; // xxx

epp0 = [0,0];
epp1 = [0, -phone_edge_thick];
epp2 = epp1 + phone_backside_slope_thick * [ phone_backside_slope, -1 ];
epp3 = epp2 + [10, 0];
epp4 = epp0 - [1,0] * (case_th_side - case_th_lip);
epp5 = epp0 + [1,0] * case_lip;
epp6 = epp5 + [0,1] * case_th_lip;

module rectfromto(a,b) { translate(a) square(b - a); }
module circleat(c,r) { translate(c) circle(r); }

module EdgeProfile(){
  difference(){
    hull(){
      circleat(epp3, r=case_th_bottom);
      circleat(epp2, r=case_th_bottom);
      circleat(epp1, r=case_th_side);
      circleat(epp4, r=case_th_lip);
      rectfromto(epp0, epp6);
    }
    polygon([ epp6 + [10,10],
	      epp6 + [0,10],
	      epp5,
	      epp0,
	      epp1,
	      epp2,
	      epp3 + [10,0] ]);
  }
}

module CaseBase_rhsflip() {
  for (rhs=[0,1]) {
    translate([phone_width/2, 0, 0])
      mirror([rhs,0,0])
      translate([-phone_width/2, 0, 0])
      children();
  }
}

module CaseBase_botflip() {
  for (bot=[0,1]) {
    translate([0, -phone_height/2, 0])
      mirror([0, bot, 0])
      translate([0, phone_height/2, 0])
      children();
  }
}  

module CaseBase(){
  CaseBase_rhsflip(){
    translate([0, -phone_cnr_rad, 0])
      rotate([90,0,0])
      linear_extrude(height = phone_height - phone_cnr_rad*2)
      EdgeProfile();
  }
  CaseBase_rhsflip() CaseBase_botflip() {
    translate([+1,-1] * phone_cnr_rad)
      intersection(){
	rotate_extrude()
	  intersection(){
	    mirror([1,0,0])
	      translate([-1,0] * phone_cnr_rad)
	      EdgeProfile();
	    rectfromto([0,-20],[10,20]);
	  }
	translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
	  cube([10,10,40]);
      }
  }
  CaseBase_botflip(){
    translate([ phone_width - phone_cnr_rad, 0,0 ])
      rotate([90,0,-90])
      linear_extrude(height = phone_width - phone_cnr_rad*2)
      EdgeProfile();
  }
}

//EdgeProfile();
CaseBase();