// -*- C -*-

eclip_inner_rad = 2.5;
eclip_gap_rad = 0.5;
eclip_prong_th = 3;
eclip_outer_strt = 0.5;
eclip_inner_xstrt = 0.5;

eclip_ult_angle = 44;
eclip_base_epsilon = 0.5;

eclip_each_len = 6;
eclip_each_every = 15;

test_alpha = 10;
test_main_th = 1.5;
test_eclips = 5;
test_base_th = 2.5;
test_len = eclip_each_len + eclip_each_every*(test_eclips-1);

// calculated

include <utils.scad>

eclip_inner_strt = eclip_outer_strt + eclip_inner_xstrt;

r0 = eclip_inner_rad;
r1 = r0 + eclip_gap_rad;
r2 = r1 + eclip_prong_th;
r2e = r1 + eclip_base_epsilon;

ppxl = -(r0 / sqrt(2)) + (eclip_inner_strt / sqrt(2));

rgap = eclip_gap_rad;

eclip_base_offset = r1;
eclip_wall_offset = -ppxl;

$fn=70;

module EclipLPlanCore(alpha){
  FArcSegment(0,0, r1,r2,
	      180-eclip_ult_angle, eclip_ult_angle-alpha +1);

  difference(){
    hull(){
      intersection(){
	circle(r2);
	rotate(-alpha) mirror([1,1]) square([r2e, 50]);
     }
      rotate(-alpha) mirror([1,1]) square([r2e, r2]);
    }
    circle(r1);
  }
}

module EclipRPlan(alpha, main_th){
  intersection(){
    rotate(alpha)
      translate([ppxl + main_th + rgap, -r2*2])
      square([eclip_prong_th, r2*(2 + 1/sqrt(2))]);
    translate([-r2, -r2e])
      square([r2*3, eclip_base_epsilon + r2*4]);
  }
}

module EclipLPlan(alpha){
  rotate(alpha) EclipLPlanCore(alpha);
}

module EclipPPlan(main_th){
  intersection(){
    hull(){
      circle(r0);
      rotate(90-eclip_ult_angle) square([r0,r0]);
    }
    translate([-(r0+.1), -(r0+.1)])
      square([(r0+.1) + main_th + ppxl, r2*2]);
  }
  translate([ppxl, 0]) square([main_th, r2]);
}

module TestBase(){
  translate([0,0, eclip_base_offset]){
    for (i=[0 : 2: test_eclips-1]) {
      translate([0, i*eclip_each_every])
	rotate([90,0,0])
	linear_extrude(height=eclip_each_len)
	EclipLPlan(test_alpha);
    }
    for (j=[1 : 2: test_eclips-2]) {
      translate([0, j*eclip_each_every])
	rotate([90,0,0])
	linear_extrude(height=eclip_each_len)
	EclipRPlan(test_alpha, test_main_th);
    }
  }
  translate([-r2, -eclip_each_len, -test_base_th])
    cube([r2*2,
	  test_len,
	  test_base_th]);
}

module TestProtr(){
  translate([0,0, test_main_th - eclip_wall_offset])
    rotate([0,90,0])
    linear_extrude(height=test_len)
    EclipPPlan(test_main_th);
}

module PlanDemo(){
  color("red") EclipLPlan(test_alpha);
  color("blue") rotate(test_alpha) EclipPPlan(test_main_th);
  color("green") EclipRPlan(test_alpha, test_main_th);
}

//PlanDemo();
//TestBase();
TestProtr();