// -*- C -*-

eclip_inner_rad = 2.5;
eclip_gap_rad = 0.5;
eclip_prong_th = 3;
eclip_outer_strt = 0.5;
eclip_inner_xstrt = 0.5;

eclip_ult_angle = 44;
eclip_base_epsilon = 0.5;

test_alpha = 10;
test_main_th = 1.5;

// calculated

include <utils.scad>

eclip_inner_strt = eclip_outer_strt + eclip_inner_xstrt;

r0 = eclip_inner_rad;
r1 = r0 + eclip_gap_rad;
r2 = r1 + eclip_prong_th;
r2e = r1 + eclip_base_epsilon;

ppxl = -(r0 / sqrt(2)) + (eclip_inner_strt / sqrt(2));

rgap = eclip_gap_rad;

$fn=70;

module EclipLPlanCore(alpha){
  FArcSegment(0,0, r1,r2,
	      180-eclip_ult_angle, eclip_ult_angle-alpha +1);

  difference(){
    hull(){
      intersection(){
	circle(r2);
	rotate(-alpha) mirror([1,1]) square([r2e, 50]);
     }
      rotate(-alpha) mirror([1,1]) square([r2e, r2]);
    }
    circle(r1);
  }
}

module EclipRPlan(alpha, main_th){
  rotate(alpha)
    translate([ppxl + main_th + rgap, -r2*2])
    square([eclip_prong_th, r2*(2 + 1/sqrt(2))]);
}

module EclipLPlan(alpha){
  rotate(alpha) EclipLPlanCore(alpha);
}

module EclipPPlan(main_th){
  intersection(){
    hull(){
      circle(r0);
      rotate(90-eclip_ult_angle) square([r0,r0]);
    }
    translate([-(r0+.1), -(r0+.1)])
      square([(r0+.1) + main_th + ppxl, r2*2]);
  }
  translate([ppxl, 0]) square([main_th, r2]);
}

rotate(-test_alpha){
color("red") EclipLPlan(test_alpha);
color("blue") rotate(test_alpha) EclipPPlan(test_main_th);
color("green") EclipRPlan(test_alpha, test_main_th);
}