// -*- C -*-

include <utils.scad>

//tongue_w = 11.92 + 0.4;

usb_w = 12.01 + 0.19;
usb_wall_w = 0.51;
usb_tongue_d = 8.97 - 0.2;
usb_tongue_w_slop = +0.5;
usb_wall_h = 4.54 - 2.04;
usb_ceil_th = 0.425;

side_wall_th = 1.5; // XXXX rename wall_th

board_l = 17.56 + 0.2;
board_w = 19.14 + 0.2;
board_th = 1.92 + 0.1;

sw_to_edge = board_w/2 + 0.1;

front_wall_th = 0.75;
// egress_w = 8.0;

wall_y_min = -board_l - side_wall_th; // XXXX remove
ceil_y_min = wall_y_min - 5;;

small_walls = [
	       [ [0, 0], [-sw_to_edge, -1.0] ],
	       [ [sw_to_edge-4.5, -4.5], [sw_to_edge, -5.7] ],
//	       [ [3.0, -11.72],              [sw_to_edge, -13.38] ],
	       [ [-sw_to_edge+3.85, -14.90], [sw_to_edge, -13.38] ],
	       ];
chip_cutout = [[ -sw_to_edge + 4.20,    -3.75 ],
	       [ -sw_to_edge + 11.95,  -11.90 ]];

strain_w = 2.0 + 0.5;
strain_t = 1.0 + 0.5;
strain_pitch_across = 5;
strain_pitch_along = 10;
strain_groove_d = 2;
strain_groove_w = 3;

cable_space_z = 6;
cable_dia = 5;
bottom_floor_th = 1.5;

fit_gap_z = 0.5;
fit_gap_y = 0.25;
side_x_gap = 0.5;

cover_ceil_th = 0.9;

// calculated

top_top_z = usb_wall_h;
top_base_z = -board_th;
bottom_base_z = top_base_z - cable_space_z - bottom_floor_th;;

front_y_max = front_wall_th;
main_y_min = -board_l - side_wall_th;

strain_0_y_c = main_y_min - strain_w/2;
strain_1_y_c = strain_0_y_c - strain_pitch_along;
total_y_min = strain_1_y_c - strain_w/2 - side_wall_th;

bottom_wall_top_z = (top_top_z + top_base_z) * 0.5 - fit_gap_z/2;
cover_wall_bot_z  = (top_top_z + top_base_z) * 0.5 + fit_gap_z/2;
cover_top_z  = top_top_z + cover_ceil_th;

top_side_wall_x = +board_w/2 + side_wall_th;
total_side_wall_x = top_side_wall_x + side_wall_th + side_x_gap;

module BothSides(){
  for (m=[0,1]) {
    mirror([m,0]) {
      children();
    }
  }
}
module FrontWallsPlan(slop) {
  BothSides(){
    rectfromto([ -board_w/2 - side_wall_th,    0             ],
               [ -usb_w/2 - slop,              front_wall_th ]);
  }
}
module TopSmallWallsPlan() {
  for (m=[0,1]) {
    mirror([m,0]) {
      rectfromto([ -usb_w/2,              -0.01        ],
		 [ -usb_w/2 + usb_wall_w, usb_tongue_d ]);
    }
  }
  FrontWallsPlan(0);
  for (w=small_walls) {
    rectfromto(w[0], w[1]);
  }
}
module TopCeilPlan() {
  difference(){
    BothSides(){
      rectfromto([ -usb_w/2,              -0.01        ],
		 [ 0.1,                   usb_tongue_d ]);
      rectfromto([ -board_w/2 - side_wall_th, 0            ],
		 [ 0.1,                       ceil_y_min   ]);
    }
    rectfromto(chip_cutout[0], chip_cutout[1]);
  }
}
module TopMainWallsPlan() {
  BothSides(){
    rectfromto([ -board_w/2 - side_wall_th, 0          ],
	       [ -board_w/2,                wall_y_min ]);
  }
  FrontWallsPlan(usb_tongue_w_slop);
  rectfromto([ -board_w/2 - side_wall_th + 0, -      board_l   ],
	     [ +board_w/2 + side_wall_th,            total_y_min ]);
}

module Top(){ ////toplevel
  difference(){
    union(){
      linextr(0, usb_wall_h)
	TopSmallWallsPlan();
      linextr(usb_wall_h - usb_ceil_th, usb_wall_h)
	TopCeilPlan();
      linextr(-board_th, usb_wall_h)
	TopMainWallsPlan();
      BothSides()
	linextr(cover_wall_bot_z, top_top_z)
        rectfromto([ -(board_w/2 + 0.1),  total_y_min             ],
		   [ -total_side_wall_x,  main_y_min - fit_gap_y  ]);
    }

    for (y_c = [strain_0_y_c, strain_1_y_c]) {
      for (x_c = [-1,+1] * strain_pitch_across/2) {
	translate([x_c, y_c, 0])
	  linextr(-20, 20)
	  square([ strain_t, strain_w ], center=true);
      }
    }
    linextr_y_xz(total_y_min-1, main_y_min)
      translate([0, top_base_z])
      scale([1, strain_groove_d/strain_groove_w])
      circle(strain_groove_w/2, $fn = 8);
  }
}

module TopElevationForCutout(){
    rectfromto([ -(top_side_wall_x + side_x_gap), top_base_z ],
	       [ +(top_side_wall_x + side_x_gap), top_top_z  ]);
}
module BottomMainElevation(){
  difference(){
    rectfromto([ -total_side_wall_x, bottom_base_z        ],
	       [ +total_side_wall_x, bottom_wall_top_z    ]);

    TopElevationForCutout();
  }
}
module Bottom(){ ////toplevel
  difference(){
    union(){
      linextr_y_xz(total_y_min, front_y_max)
	BottomMainElevation();
    }

    linextr_y_xz(total_y_min + side_wall_th,
		 front_y_max - side_wall_th)
      rectfromto([ -board_w/2, bottom_base_z + bottom_floor_th ],
		 [ +board_w/2, 20         ]);

    linextr_y_xz(total_y_min - 1,
		 total_y_min + side_wall_th + 1){
      translate([ 0, top_base_z ]){
	hull(){
	  translate([ 0, -cable_dia/2 ])
	    circle(r = cable_dia/2, $fa = 10, $fs = 1);
	  square([ cable_dia, 0.1 ], center=true);
	}
      }
    }
  }
}

module CoverMainElevation(){
  difference(){
    rectfromto([ -total_side_wall_x, cover_wall_bot_z        ],
	       [ +total_side_wall_x, cover_top_z    ]);

    TopElevationForCutout();
  }
}
module Cover(){ ////toplevel
  linextr_y_xz(main_y_min, front_y_max)
    CoverMainElevation();
}

module BottomDemo(){ ////toplevel
  translate([0, 0, -0.25]) Bottom();
  %Top();
  translate([0, 0, +0.25]) Cover();
}