// -*- C -*-

include <commitid.scad>
include <utils.scad>
include <sealing-box.scad>

pxp6012_rad = 22.5 / 2 + 0.5; // make circular hole this size in outer wall
pxp6012_rad_outer = 32.0 / 2 - 0.5;

s1930_y = 30.2 + 0.2;
s1930_x =   22 + 0.2;
s1930_y_outer = 36.4 + 0.2;
s1930_x_outer = 27.6 + 0.2;

s1930_recess = 3;
s1930_around = 3;
s1930_behind = 3;

wallthick = 2.5;

// origin is at centre on outer face wall
// outside is towards positive x
// mounting is vertical
module S1930_Positive(){
  d = s1930_recess + s1930_behind;
  translate([-d/2, 0,0])
    cube([d,
	  s1930_x_outer + s1930_around,
	  s1930_y_outer + s1930_around], center=true);
}
module S1930_Negative(){
  cube([60, s1930_x, s1930_y],
       center=true);
  translate([1, 0,0])
    cube([s1930_recess*2+2, s1930_x_outer, s1930_y_outer],
	 center=true);
}

module TestWall(){ ////toplevel
  sw_ctr = [25, wallthick, 25];

  rotate([0,0,-90]){
    difference(){
      union(){
	cube([50, wallthick, 42]);
      }

      translate([30, -1, 20])
	rotate([-90,0,0])
	cylinder(r = pxp6012_rad, h=10, $fn=60);

      rotate([90,0,0])
	Commitid_BestCount([15,40]);
    }
  }

  difference(){
    union(){
      cube([50, wallthick, 50]);
      translate(sw_ctr)
	rotate([0,0,90])
	S1930_Positive();
    }

    translate(sw_ctr) {
      rotate([0,0,90])
	S1930_Negative();
    }
  }    
}

ts_totx = 30;
ts_toty = 25;
ts_totz_inner = 8;

$sealingbox_wallth = wallthick;
$sealingbox_floorth = wallthick;
$sealingbox_ceilth = wallthick;

module TestSealBox(){ ////toplevel
  $sealingbox_xbox = ts_totx;
  $sealingbox_ybox = ts_toty;
  $sealingbox_zbox = ts_totz_inner;

  SealingBox_RectBox();
  ts_cidoff = ($sealingbox_cnrrad * (1-.7) + wallthick * .8) * [1,1];
  translate(ts_cidoff)
    Commitid_BestCount([ts_totx,ts_toty] - 2*ts_cidoff);
}

module TestSealLid(){ ////toplevel
  $sealingbox_xbox = ts_totx;
  $sealingbox_ybox = ts_toty;
  $sealingbox_zbox = ts_totz_inner;

  difference(){
    SealingBox_RectLid();

    translate([ts_totx * .75, ts_toty/2, 0])
      cylinder(h=100, r=5);
    
    translate([-wallthick + $sealingbox_cnrrad*.5,
	       $sealingbox_cnrrad*.5 - wallthick,
	       ts_totz_inner + $sealingbox_ceilth])
      Commitid_BestCount([ts_totx * .75 - 2.5 - ($sealingbox_cnrrad*.5),
			  ts_toty - ($sealingbox_cnrrad*.5 - wallthick)*2]);
  }
}

module TestSealLidPrint(){ ////toplevel
  rotate([180,0,0]) TestSealLid();
}

module ProfileDemos(){ ////toplevel
  $sealingbox_xbox = ts_totx;
  $sealingbox_ybox = ts_toty;
  $sealingbox_zbox = ts_totz_inner;

  SealingBox_WallProfile();
  color("blue") SealingBox_FloorProfile();
  SealingBox_LidProfile();
  color("blue") SealingBox_CeilProfile();
  color("red") translate([-5,0]) square([1,ts_totz_inner]);
}
			  
//TestWall();
//ProfileDemos();
//TestSealBox();
//TestSealLid();
//FArcSegment_mask(350);