chiark / gitweb /
sewing-table: FitTest_PairLink: fix cx to be cx (moves feet only)
[reprap-play.git] / sewing-table.scad.m4
1 // -*- C -*-
2
3 include <funcs.scad>
4 include <commitid.scad>
5
6 ply_th = 18;
7 ply_hole_dia = 15;
8 ply_edge_min = 10;
9
10 tile_th = 3;
11 post_dia = 8;
12
13 post_shorter = 1;
14
15 screw_dia = 2.2;
16 screw_big_dia = 3.6;
17 screw_big_len = 4.0;
18
19 round_edge_rad = 2.0;
20
21 round_cnr_rad = 10;
22
23 interlock_dia = 10;
24 interlock_fine = 0.66;
25
26 interlock_fine_slope = 1.0;
27 interlock_fine_lenslop = 1.0;
28
29 demo_slop = 0.1;
30
31 // cutout
32
33 machine_rear_to_front = 85;
34
35 machine_rear_profile = [
36                         [ -  0,  -0.00 ],
37                         [ -  2,  -0.10 ],
38                         [ -  4,  -0.20 ],
39                         [ -  5,  -0.30 ],
40                         [ -  6,  -0.40 ],
41                         [ -  7,  -0.50 ],
42                         [ -  8,  -0.75 ],
43                         [ - 10,  -1.50 ],
44                         [ - 12,  -2.25 ],
45                         [ - 14,  -3.25 ],
46                         [ - 16,  -4.25 ],
47                         [ - 18,  -5.75 ],
48                         [ - 20,  -8.00 ]
49                         ];
50
51 machine_front_profile =  [
52                           [  128,  -3.70,  ],
53                           [  124,  -2.90,  ],
54                           [  120,  -2.45,  ],
55                           [  116,  -2.10,  ],
56                           [  112,  -1.80,  ],
57                           [  108,  -1.55,  ],
58                           [  104,  -1.25,  ],
59                           [  100,  -1.00,  ],
60                           [   96,  -0.80,  ],
61                           [   92,  -0.65,  ],
62                           [   88,  -0.55,  ],
63                           [   84,  -0.50,  ]
64                           ];
65
66 cutout_l_end_y_front_slop = 0.5;
67 cutout_l_end_y_rear_slop = 0.5;
68 cutout_l_end_x_slop = 0.25;
69
70 cutout_l_end_x = 22;
71 cutout_l_end_y = machine_rear_to_front;
72 cutout_l_end_curve = 1;
73 cutout_l_end_y_total = cutout_l_end_y
74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
75
76 tile02_tr = [-250, 0];
77 tile01_tr = [  0, 0];
78
79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
82
83 // front and rear curves
84
85 rearedge_len = 170;
86
87 rearcurve_strt_len = 52;
88
89 rearcurve_z_slop = 0.75;
90
91 rearcurve_avoid_y = 35;
92
93 rearcurve_double_inrad = 26.10 + 8.04;
94
95 reartablet_z = 2.54;
96 reartablet_x = 5 + 1;
97 reartablet_y = 8;
98
99 frontcurve_side_skew = 3.5 / 72;
100 frontcurve_avoid_y = 70;
101 frontcurve_z_slop = 0.75;
102
103 frontcurve_strt_len = 60;
104 frontcurve_dualcurve_angle = 90 - 65;
105
106 // calculated
107
108 TEST = false;
109
110 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
111
112 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
113
114 hole_slop = (ply_hole_dia - post_dia)/2;
115 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
116
117 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
118          tile_hard_edge_hole_dist));
119
120 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
121          tile_hard_edge_hole_dist + round_edge_rad));
122
123 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
124 thehd_tr = thehd;
125 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
126 thehd_bl = -thehd_tr;
127 thehd_br = -thehd_tl;
128
129 tablet_z_slop = rearcurve_z_slop;
130
131 interlock_rad = interlock_dia/2;
132 interlock_negative_rad = interlock_rad + 0.125;
133
134 interlock_sq_adj = 0.2; // arbitrary
135
136 first_front = machine_front_profile[len(machine_front_profile)-1];
137
138 m4_define(`POST_TCROSSSZ',
139           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
140
141 module Post(){
142   mirror([0,0,1]) {
143     difference(){
144       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
145       translate([0,0, tile_th]) {
146         cylinder(r= screw_big_dia/2, h= screw_big_len);
147         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
148       }
149     }
150     if (TEST) {
151       translate([0,0, tile_th/2]) {
152         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
153         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
154       }
155     }
156   }
157 }
158
159 module Posts(posts) {
160   for (p= posts) {
161     translate(concat(p, [0]))
162       Post();
163   }
164 }
165
166 module TileBase(botleft, topright){
167   size = topright - botleft;
168   botleft_post = botleft + thehd_tr;
169   topright_post = topright + thehd_bl;
170   difference(){
171     mirror([0,0,1])
172       translate(concat(botleft, [0]))
173       cube(concat(size, [tile_th]));
174     if (!TEST) {
175       cidsz = topright_post-botleft_post
176         + [-post_dia,-post_dia]
177         + [0, thehd[1]];
178       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
179       echo("CID",cidsz,cidszr);
180       translate( concat(botleft_post, [ -tile_th ])
181                  + 0.5 * [ post_dia, post_dia, 0 ]
182                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
183         Commitid_BestCount_M(cidszr);
184     }
185     if (TEST) {
186       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
187       cidsz = [ thehd[0], size[1] - 2*crossoff ];
188       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
189       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
190         Commitid_BestCount(cidszr);
191       difference(){
192         mirror([0,0,1]) {
193           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
194             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
195           translate(concat(botleft_post, [-1]))
196             cube(concat(topright_post-botleft_post, [tile_th+2]));
197         }
198         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
199         minkowski(){
200           MachineEnvelope();
201           cube(shufflesz, center=true);
202         }
203       }
204     }
205   }
206 }
207
208 m4_dnl   R_EDGE(c,ix)
209 m4_dnl        c is from Rectangle_corners and
210 m4_dnl        ix is a corner number
211 m4_dnl    expands to two comma-separated corners:
212 m4_dnl    that denoted by ix, and the next one anticlockwise
213 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
214
215 m4_dnl   R_CNR(c,ix)
216 m4_dnl        c is from Rectangle_corners and
217 m4_dnl        ix is a corner number
218 m4_dnl    expands to an array of corners as for RoundCorner
219 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
220
221 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
222 m4_define(`INREFFRAME',`
223   length_vec = ($2) - ($1);
224   length = dist2d([0,0], length_vec);
225   length_uvec = length_vec / length;
226   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
227   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
228         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
229         [ 0,              0,              1,            0, ],
230         [ 0,              0,              0,            1, ] ];
231   $3
232   multmatrix(m)
233 ')
234
235 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
236 m4_dnl    INREFFRAME_EDGE { body; }
237 m4_define(`INREFFRAME_EDGE',`
238   translate([0,0, -round_edge_rad])
239 ')
240
241 module RoundEdge(left_cnr, right_cnr) {
242   INREFFRAME(left_cnr, right_cnr)
243     INREFFRAME_EDGE {
244     difference(){
245       rotate([0,90,0])
246         cylinder(r= round_edge_rad, h= length, $fn=50);
247       translate([-1, 0, -20])
248         cube([length+2, 20, 20]);
249     }
250   }
251 }
252
253 m4_define(`ROUNDCORNER_VARS',`
254   this_cnr = ci[0];
255   right_cnr = ci[1];
256   left_cnr = ci[2];
257   bigr= round_cnr_rad - round_edge_rad;
258   l_uvec = unitvector2d(left_cnr - this_cnr);
259   r_uvec = unitvector2d(right_cnr - this_cnr);
260   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
261   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
262   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
263   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
264   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
265   ctr3 = concat(ctr,[0])
266 ')
267
268 module RoundCorner_selector(ci, adj) {
269   ROUNDCORNER_VARS;
270   intersection(){
271     union(){
272       INREFFRAME(ctr3,concat(lp1,[4])){
273         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
274           translate([-bigr*2 + adj, -bigr])
275             square([bigr*2, bigr*3]);
276         }
277       }
278     }
279     union(){
280       INREFFRAME(ctr3,concat(lp4,[0])){
281         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
282           translate([-bigr*2, -bigr*2])
283             square([bigr*2 + adj, bigr*3]);
284         }
285       }
286     }
287   }
288 }
289
290 module RoundCornerCut(ci) {
291   // ci should be [this_cnr, right_cnr, left_cnr]
292   // where right_cnr is to the right (ie, anticlockwise)
293   ROUNDCORNER_VARS;
294   difference(){
295     RoundCorner_selector(ci, -0.1);
296     translate(ctr3)
297       cylinder(center=true, h=20, r= bigr);
298   }
299 }
300
301 module RoundCornerAdd(ci) {
302   ROUNDCORNER_VARS;
303   intersection(){
304     RoundCorner_selector(ci, +0.1);
305     INREFFRAME_EDGE {
306       translate(ctr3){
307         rotate_extrude(convexity=10, $fn=50)
308           translate([bigr, 0])
309           difference(){
310           circle(r= round_edge_rad, $fn=50);
311           mirror([1,1])
312             square([20,20]);
313         }
314       }
315     }
316   }
317 }
318
319 module InterlockLobePlan(negative) {
320   r = negative ? interlock_negative_rad : interlock_rad;
321   ymir = negative ? 0 : 1;
322
323   dx = sqrt(3) * r;
324   $fn= 80;
325   translate([thehd[0], 0]){
326     mirror([0,ymir]){
327       circle(r=r);
328       difference(){
329         translate([-dx, -0.1])
330           square([ dx*2, r/2 + 0.1 ]);
331         for (xi = [-1, 1]) {
332           translate([ xi*dx, r ])
333             circle(r=r);
334         }
335       }
336     }
337   }
338 }
339
340 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
341   for (lobei = [ 0 : nlobes-1 ]) {
342     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
343     translate([lobex, 0, 0]) {
344       InterlockLobePlan(negative);
345     }
346   }
347
348   if (dosquare) {
349     iadj = 0;
350     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
351     mirror([0, negative])
352       translate([slotshorter, iadj])
353       square([length - slotshorter*2, interlock_fine + iadj*2]);
354   }
355 }
356
357 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
358   plusth = negative * 1.0;
359   protr = interlock_fine + interlock_sq_adj;
360
361   z2 = -tile_th/2;
362   z1 = -tile_th/2 - protr / interlock_fine_slope;
363   z3 = -tile_th/2 + protr / interlock_fine_slope;
364
365   negsign = negative ? -1 : +1;
366   yprotr = negsign * protr;
367
368   INREFFRAME(left_cnr, right_cnr) {
369     for (vsect = [ // zs0            zs1      ys0,            ys1
370                   [ -tile_th-plusth, plusth,  0,              0],
371                   [ z1,              z2,      0, yprotr],
372                   [ z2,              z3,      yprotr, 0],
373                   ]) {
374       zs0 = vsect[0];
375       zs1 = vsect[1];
376       zsd = zs1-zs0;
377       ys0 = vsect[2];
378       ys1 = vsect[3];
379       ysd = ys1-ys0;
380       sl = ysd/zsd;
381       m = [ [ 1,0,   0,    0 ],
382             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
383             [ 0,0,   1,  zs0 ],
384             [ 0,0,   0,    1 ] ];
385       multmatrix(m)
386         linear_extrude(height=zsd, convexity=10)
387         InterlockEdgePlan(negative, nlobes, length, !!ysd);
388     }
389   }
390 }
391
392 function TestPiece_holes2corners(holes) =
393   [ holes[0] + thehd_bl,
394     holes[1] + thehd_br,
395     holes[1] + thehd_tr,
396     holes[0] + thehd_tl ];
397
398 module TestPiece1(){ ////toplevel
399   holes = [ [-100, 0],
400             [   0, 0]
401             ];
402   corners = TestPiece_holes2corners(holes);
403   rcs = R_CNR(corners,0);
404   difference(){
405     union(){
406       TileBase(corners[0], corners[2]);
407       Posts(holes);
408       RoundEdge(corners[0], corners[1]);
409       RoundEdge(corners[3], corners[0]);
410     }
411     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
412     RoundCornerCut(rcs);
413   }
414   RoundCornerAdd(rcs);
415 }
416
417 module TestPiece2(){ ////toplevel
418   holes = [ [   0, 0],
419             [  50, 0]
420             ];
421   corners = TestPiece_holes2corners(holes);
422   TileBase(corners[0], corners[2]);
423   Posts(holes);
424   RoundEdge(corners[0], corners[1]);
425   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
426 }
427
428 module TestDemo(){ ////toplevel
429   translate([ -thehd[0], 0 ])
430     color("blue")
431     TestPiece1();
432   translate([ +thehd[0] + demo_slop, 0 ])
433     TestPiece2();
434 }
435
436 module Machine_Arm(){
437   ysz = cutout_l_end_y_total;
438   // assume the round end is arc of a circle
439   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
440   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
441   
442   translate([0,0,-30]) linear_extrude(height=60) {
443     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
444       intersection(){
445         translate([-50, -ysz/2])
446           square([400, ysz]);
447         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
448           circle(r=endrad, $fa=0.01,$fd=5);
449       }
450     }
451   }
452 }
453
454 module Machine_Profile(){
455   first_rear = machine_rear_profile[0];
456   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
457   pol = concat( machine_rear_profile,
458                 [ below_point ],
459                 machine_front_profile);
460   skew_angle = atan2( first_front[1] - first_rear[1],
461                       first_front[0] - first_rear[0] );
462   //echo(below_point, pol, skew_angle);
463   hull(){
464     for (z=[0,-40]) {
465       translate([0,z]) {
466         //scale([1,5])
467         rotate([0,0, -skew_angle ]){
468           //translate( - first_front )
469           polygon(pol);
470         }
471       }
472     }
473   }
474 }
475
476 module Machine_NewRearProfile(){
477   // figures copied out of xfig edit boxes
478   // best not to edit the posbox size if poss - just move it
479   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
480   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
481   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
482   scaleline_mm = 12+5+10+5+3;
483   sh = -[abs(posbox[0]), abs(posbox[1])];
484   rot = atan2(-sideline[0], sideline[1]);
485   sc = scaleline_mm / scaleline;
486   //echo("SH",sh,rot,sc);
487   scale(sc) rotate(rot) translate(sh){
488     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
489   }
490 }
491
492 module Machine_NewFrontProfile(){
493   // figures copied out of xfig edit boxes
494   // best not to edit the posbox size if poss - just move it
495   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
496   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
497   refline_mm = (11-1)*10;
498   sh = -[abs(posbox[0]), abs(posbox[1])];
499   rot = atan2(-refline[0], refline[1]);
500   sc = refline_mm / vectorlen2d(refline);
501   //echo("SH",sh,rot,sc);
502   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
503     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
504   }
505 }
506
507 module Machine_NewRearCurve(){
508   slant = atan2(4,210-10);
509   //echo("SL",slant);
510   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
511     translate([ rearcurve_double_inrad,
512                 0,
513                 -rearcurve_double_inrad + 10 ]){
514       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
515         hull(){
516           Machine_NewRearProfile();
517           translate([0,-100]) Machine_NewRearProfile();
518         }
519       }
520     }
521     rotate([0,90,0]) rotate([90,0,0]) {
522       intersection(){
523         rotate_extrude(convexity=10, $fn=64)
524           rotate(90)
525           translate([ 0, -rearcurve_double_inrad ])
526           Machine_NewRearProfile();
527         translate([0,0,-500])
528           cube([500,500,1000]);
529       }
530     }
531     translate([1,0,-rearcurve_double_inrad])
532       rotate([0,-90,0]) rotate([0,0,-90])
533       linear_extrude(height= rearcurve_strt_len + 1)
534       Machine_NewRearProfile();
535   }
536 }
537
538 module Machine_RearProfile(){ ////toplevel
539   intersection(){
540     Machine_Profile();
541     translate([ -200 + machine_rear_to_front/2, -100 ]) {
542       square([200,200]);
543     }
544   }
545 }
546
547 module Machine_FrontProfile(){
548   intersection(){
549     Machine_Profile();
550     translate([ machine_rear_to_front/2, -100 ]) {
551       square([200,200]);
552     }
553   }
554 }
555
556 module Machine_Curves(){ ////toplevel
557   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
558               cutout_tile11_y,
559               0 ]){
560     //%cube([20,20,20]);
561     translate([ -reartablet_x,
562                 -1,
563                 -reartablet_z + tablet_z_slop])
564       mirror([0,0,1])
565       cube([ reartablet_x+1,
566              reartablet_y+1,
567              20 ]);
568   }
569   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
570               cutout_tile11_y,
571               frontcurve_z_slop ]){
572     translate([0, -machine_rear_to_front, 0])
573       multmatrix([[1, -frontcurve_side_skew, 0, 0],
574                   [0,  1,   0, 0],
575                   [0,  0,   1, 0],
576                   [0,  0,   0, 1]])
577       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
578       linear_extrude(height= 200)
579       Machine_NewFrontProfile();
580
581     translate([ rearcurve_strt_len,
582                 0,
583                 rearcurve_z_slop ]){
584       Machine_NewRearCurve();
585     }
586   }
587 }
588
589 module Machine(){ ////toplevel
590   Machine_Arm();
591   Machine_Curves();
592 }
593
594 module MachineEnvelope(){
595   // used for testing
596   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
597   y_arm_t  = cutout_tile11_y;
598   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
599   y_crv_b  = y_arm_t + rearcurve_avoid_y;
600
601   translate([0,0,-50]) linear_extrude(height= 100){
602     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
603     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
604   }
605 }
606
607 function Rectangle_corners(c0, sz) =
608   // returns the corners of a rectangle from c0 to c0+sz
609   // if sz is positive, the corners are anticlockwise starting with c0
610   [ c0 + [ 0,     0     ],
611     c0 + [ sz[0], 0     ],
612     c0 + [ sz[0], sz[1] ],
613     c0 + [ 0,     sz[1] ] ];
614
615 function Rectangle_corners2posts(c) =
616   [ c[0] + thehd_tr,
617     c[1] + thehd_tl,
618     c[2] + thehd_bl,
619     c[3] + thehd_br ];
620
621 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
622
623 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
624
625 module Tile02(){ ////toplevel
626   sz = [100,170];
627   c0 = tile02_tr + -sz;
628   c = Rectangle_corners(c0, sz);
629   posts = Rectangle_corners2posts(c);
630   rcs = R_CNR(c,0);
631   difference(){
632     union(){
633       Rectangle_TileBase(c);
634       Posts(posts);
635       RoundEdge(R_EDGE(c,0));
636       RoundEdge(R_EDGE(c,3));
637       InterlockEdge(R_EDGE(c,2), 0);
638     }
639     InterlockEdge(R_EDGE(c,1), 1);
640     RoundCornerCut(rcs);
641   }
642   RoundCornerAdd(rcs);
643 }
644
645 module Tile12(){ ////toplevel
646   sz = [100,250];
647   c0 = tile02_tr + [-sz[0], 0];
648   c = Rectangle_corners(c0, sz);
649   posts = Rectangle_corners2posts(c);
650   rcs = R_CNR(c,3);
651   difference(){
652     union(){
653       Rectangle_TileBase(c);
654       Posts(posts);
655       RoundEdge(R_EDGE(c,2));
656       RoundEdge(R_EDGE(c,3));
657     }
658     InterlockEdge(R_EDGE(c,0), 1);
659     InterlockEdge(R_EDGE(c,1), 1);
660     RoundCornerCut(rcs);
661   }
662   RoundCornerAdd(rcs);
663 }
664
665 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
666 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
667 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
668
669 module Tile11(){ ////toplevel
670   sz = [250,250];
671   c0 = tile01_tr + [-sz[0],0];
672   c = Rectangle_corners(c0, sz);
673   cnr_posts = Rectangle_corners2posts(c);
674   posts = concat(
675                  Posts_interpolate_one(cnr_posts[0],
676                                        cnr_posts[1] - [cutout_tile11_x, 0]),
677                  [ cnr_posts[1] + [0, cutout_tile11_y],
678                    cnr_posts[2],
679                    cnr_posts[3]
680                    ]);
681   difference(){
682     union(){
683       Rectangle_TileBase(c);
684       Posts(posts);
685       RoundEdge(R_EDGE(c,2));
686       InterlockEdge(R_EDGE(c,3));
687     }
688     InterlockEdge(c[0], tile_01_11_cnr, 1);
689     InterlockEdge(tile_11_10_cnr, c[2], 1);
690     Machine();
691   }
692 }    
693
694 module Tile01(){ ////toplevel
695   sz = [250,170];
696   c0 = tile01_tr + -sz;
697   c = Rectangle_corners(c0, sz);
698   cnr_posts = Rectangle_corners2posts(c);
699   posts = concat(
700                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
701                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
702                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
703                                        cnr_posts[3])
704                  );
705   difference(){
706     union(){
707       Rectangle_TileBase(c);
708       Posts(posts);
709       RoundEdge(R_EDGE(c,0));
710       InterlockEdge(tile_01_11_cnr, c[3]);
711       InterlockEdge(R_EDGE(c,3));
712     }
713     InterlockEdge(c[1], tile_01_00_cnr, 1);
714     Machine();
715   }
716 }    
717
718 module Tile10(){ ////toplevel
719   sz = [250,250];
720   c0 = tile01_tr + [0,0];
721   c = Rectangle_corners(c0, sz);
722   cnr_posts = Rectangle_corners2posts(c);
723   cty = cutout_tile11_y;
724   rcy = cty + rearcurve_avoid_y;
725   posts = [ cnr_posts[0] + [ 0,                             cty ],
726             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
727             cnr_posts[1] + [ 0,                             rcy ],
728             cnr_posts[2],
729             cnr_posts[3] ];
730   rcs = R_CNR(c,2);
731   difference(){
732     union(){
733       Rectangle_TileBase(c);
734       Posts(posts);
735       RoundEdge(R_EDGE(c,1));
736       RoundEdge(R_EDGE(c,2));
737       InterlockEdge(c[3], tile_11_10_cnr);
738     }
739     RoundCornerCut(rcs);
740     Machine();
741   }
742   RoundCornerAdd(rcs);
743 }
744
745 module Tile00(){ ////toplevel
746   sz = [250,170];
747   c0 = tile01_tr + [0,-sz[1]];
748   c = Rectangle_corners(c0, sz);
749
750   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
751   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
752   c1bis = [ c[1][0],
753             c[2][1] -
754             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
755
756   cnr_posts = Rectangle_corners2posts(c);
757   cty = cutout_tile01_y;
758   rcy = cty + frontcurve_avoid_y;
759   posts = [ cnr_posts[0],
760             cnr_posts[1],
761             cnr_posts[2] + [ 0,                             -rcy ],
762             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
763             cnr_posts[3] + [ 0,                             -cty ]
764             ];
765   rcs = R_CNR(c,1);
766   rc2 = [c1bis,c2bis,c[1]];
767   difference(){
768     union(){
769       difference(){
770         union(){
771           Rectangle_TileBase(c);
772           Posts(posts);
773           RoundEdge(R_EDGE(c,0));
774           RoundEdge(c[1], c1bis);
775           InterlockEdge(tile_01_00_cnr, c[0]);
776         }
777         RoundCornerCut(rcs);
778         translate([0,0,-20]) linear_extrude(height=40) {
779           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
780         }
781       }
782       RoundEdge(c1bis, c2bis);
783     }
784     Machine();
785     RoundCornerCut(rc2);
786   }
787   RoundCornerAdd(rcs);
788   RoundCornerAdd(rc2);
789 }
790
791 module FitTest_general(c0,sz, dobrace=false){
792   c = Rectangle_corners(c0, sz);
793   brace = [7,7,9];
794   difference(){
795     union(){
796       Rectangle_TileBase(c);
797       if (dobrace) {
798         translate(concat(c0, [-brace[2] + 0.1])){
799           difference(){
800             cube(concat(sz,[brace[2]]) - [5,0,0]);
801             translate(brace + [0,0, -25])
802               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
803           }
804         }
805       }
806       RoundEdge(R_EDGE(c,1));
807     }
808     Machine();
809   }
810 }
811
812 module FitTest_Entire(){ ////toplevel
813   FitTest_general([-40,-80], [275,180], dobrace=true);
814 }
815
816 module FitTest_RearCurve(){ ////toplevel
817   FitTest_general([110,0], [170,100]);
818 }
819
820 module FitTest_FrontCurve(){ ////toplevel
821   p0 = [110,-80];
822   sz = [170,80];
823   intersection() {
824     Tile00();
825     translate([0,0,-8]) linear_extrude(height=18) {
826       translate(p0) square(sz);
827     }
828   }
829 }
830
831 module FitTest_PairLink(adjust=0){ ////toplevel
832   cy0=-55; cy1=85; cx=130;
833   bar = [10,10];
834   legrad = 15;
835   footrad_min = 4; footrad_max = 6; footrad_depth = 3;
836
837   translate([cx - bar[0]/2, cy0, 0])
838     cube([bar[0], cy1-cy0, bar[1]]);
839   for (endy=[cy0,cy1]) {
840     translate([cx,endy,0]){
841       for (rot=[0:90:270]) {
842         rotate(rot){
843           translate([legrad,0,0]){
844             hull(){
845               cylinder(r= footrad_max, height=1);
846               translate([0,0,-footrad_depth])
847                 cylinder(r= footrad_min, height=1);
848             }
849           }
850         }
851       }
852     }
853   }
854 }
855
856 module FitTest_PairDemo(){ ////toplevel
857   %FitTest_FrontCurve();
858   %FitTest_RearCurve();
859   FitTest_PairLink();
860 }
861
862 module RoundCornerDemo_plat(cnr){
863   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
864 }
865
866 module RoundCornerDemo(){ ////toplevel
867   cnr = [ [-2,-3], [13,-3], [-12,9] ];
868   translate([0,25,0]) RoundCornerDemo_plat(cnr);
869   translate([25,0,0]) RoundCornerAdd(cnr);
870   translate([-25,0,0]) RoundCornerCut(cnr);
871   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
872   difference(){
873     RoundCornerDemo_plat(cnr);
874     RoundCornerCut(cnr);
875   }
876   RoundCornerAdd(cnr);
877 }
878
879 module Demo(){ ////toplevel
880   translate(demo_slop*[-2,1]) color("blue") Tile12();
881   translate(demo_slop*[-2,0]) color("red")  Tile02();
882   translate(demo_slop*[-2,1]) color("orange") Tile11();
883   translate(demo_slop*[-2,0]) color("purple") Tile01();
884   translate(demo_slop*[-3,1]) color("blue")   Tile10();
885   translate(demo_slop*[-3,0]) color("red")    Tile00();
886   %Machine();
887 }
888   
889 //TestPiece1();
890 //TestPiece2();
891 //Demo();
892
893 //Machine_Profile();
894 //Machine_NewRearProfile();
895 //Machine_NewRearCurve();
896 //Machine_NewFrontProfile();
897 //Machine_Curves();
898 //Machine();
899 //FitTest();
900 //MachineEnvelope();