sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 tablet_z_slop = rearcurve_z_slop;
 127
 128 interlock_rad = interlock_dia/2;
 129 interlock_negative_rad = interlock_rad + 0.125;
 130
 131 interlock_sq_adj = 0.2; // arbitrary
 132
 133 first_front = machine_front_profile[len(machine_front_profile)-1];
 134
 135 m4_define(`POST_TCROSSSZ',
 136           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 137
 138 module Post(){
 139   mirror([0,0,1]) {
 140     difference(){
 141       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 142       translate([0,0, tile_th]) {
 143         cylinder(r= screw_big_dia/2, h= screw_big_len);
 144         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 145       }
 146     }
 147     if (TEST) {
 148       translate([0,0, tile_th/2]) {
 149         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 150         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 151       }
 152     }
 153   }
 154 }
 155
 156 module Posts(posts) {
 157   for (p= posts) {
 158     translate(concat(p, [0]))
 159       Post();
 160   }
 161 }
 162
 163 module TileBase(botleft, topright){
 164   size = topright - botleft;
 165   botleft_post = botleft + thehd_tr;
 166   topright_post = topright + thehd_bl;
 167   difference(){
 168     mirror([0,0,1])
 169       translate(concat(botleft, [0]))
 170       cube(concat(size, [tile_th]));
 171     if (!TEST) {
 172       cidsz = topright_post-botleft_post
 173         + [-post_dia,-post_dia]
 174         + [0, thehd[1]];
 175       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 176       echo("CID",cidsz,cidszr);
 177       translate( concat(botleft_post, [ -tile_th ])
 178                  + 0.5 * [ post_dia, post_dia, 0 ]
 179                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 180         Commitid_BestCount_M(cidszr);
 181     }
 182     if (TEST) {
 183       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 184       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 185       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 186       difference(){
 187         mirror([0,0,1]) {
 188           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 189             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 190           translate(concat(botleft_post, [-1]))
 191             cube(concat(topright_post-botleft_post, [tile_th+2]));
 192         }
 193         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 194         hull(){ // poor man's minkowski
 195           for (xs=[-1,1]) for (ys=[-1,1]) for (zs=[-1,1]) {
 196             translate([xs,ys,zs] * shufflesz)
 197               Machine();
 198           }
 199         }
 200       }
 201     }
 202   }
 203 }
 204
 205 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 206 m4_define(`INREFFRAME',`
 207   length_vec = ($2) - ($1);
 208   length = dist2d([0,0], length_vec);
 209   length_uvec = length_vec / length;
 210   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 211   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 212         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 213         [ 0,              0,              1,            0, ],
 214         [ 0,              0,              0,            1, ] ];
 215   $3
 216   multmatrix(m)
 217 ')
 218
 219 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 220 m4_dnl    INREFFRAME_EDGE { body; }
 221 m4_define(`INREFFRAME_EDGE',`
 222   translate([0,0, -round_edge_rad])
 223 ')
 224
 225 module RoundEdge(left_cnr, right_cnr) {
 226   INREFFRAME(left_cnr, right_cnr)
 227     INREFFRAME_EDGE {
 228     difference(){
 229       rotate([0,90,0])
 230         cylinder(r= round_edge_rad, h= length, $fn=50);
 231       translate([-1, 0, -20])
 232         cube([length+2, 20, 20]);
 233     }
 234   }
 235 }
 236
 237 module RoundCornerCut(ci) {
 238   // ci should be [this_cnr, right_cnr]
 239   // where right_cnr is to the right (ie, anticlockwise)
 240   this_cnr = ci[0];
 241   right_cnr = ci[1];
 242   offr= round_cnr_rad - round_edge_rad;
 243   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 244     difference(){
 245       cube(offr*2 - 0.1, center=true);
 246       translate([offr, offr, 0])
 247         cylinder(center=true, h=20, r= offr);
 248     }
 249   }
 250 }
 251
 252 module RoundCornerAdd(ci) {
 253   this_cnr = ci[0];
 254   right_cnr = ci[1];
 255   bigr = round_cnr_rad - round_edge_rad;
 256   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 257     intersection(){
 258       cube(bigr*2 + 0.1, center=true);
 259       translate([bigr, bigr, 0])
 260         rotate_extrude(convexity=10, $fn=50)
 261         translate([bigr, 0])
 262         difference(){
 263           circle(r= round_edge_rad, $fn=50);
 264           mirror([1,1])
 265             square([20,20]);
 266         }
 267     }
 268   }
 269 }
 270
 271 module InterlockLobePlan(negative) {
 272   r = negative ? interlock_negative_rad : interlock_rad;
 273   ymir = negative ? 0 : 1;
 274
 275   dx = sqrt(3) * r;
 276   $fn= 80;
 277   translate([thehd[0], 0]){
 278     mirror([0,ymir]){
 279       circle(r=r);
 280       difference(){
 281         translate([-dx, -0.1])
 282           square([ dx*2, r/2 + 0.1 ]);
 283         for (xi = [-1, 1]) {
 284           translate([ xi*dx, r ])
 285             circle(r=r);
 286         }
 287       }
 288     }
 289   }
 290 }
 291
 292 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 293   for (lobei = [ 0 : nlobes-1 ]) {
 294     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 295     translate([lobex, 0, 0]) {
 296       InterlockLobePlan(negative);
 297     }
 298   }
 299
 300   if (dosquare) {
 301     iadj = 0;
 302     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 303     mirror([0, negative])
 304       translate([slotshorter, iadj])
 305       square([length - slotshorter*2, interlock_fine + iadj*2]);
 306   }
 307 }
 308
 309 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 310   plusth = negative * 1.0;
 311   protr = interlock_fine + interlock_sq_adj;
 312
 313   z2 = -tile_th/2;
 314   z1 = -tile_th/2 - protr / interlock_fine_slope;
 315   z3 = -tile_th/2 + protr / interlock_fine_slope;
 316
 317   negsign = negative ? -1 : +1;
 318   yprotr = negsign * protr;
 319
 320   INREFFRAME(left_cnr, right_cnr) {
 321     for (vsect = [ // zs0            zs1      ys0,            ys1
 322                   [ -tile_th-plusth, plusth,  0,              0],
 323                   [ z1,              z2,      0, yprotr],
 324                   [ z2,              z3,      yprotr, 0],
 325                   ]) {
 326       zs0 = vsect[0];
 327       zs1 = vsect[1];
 328       zsd = zs1-zs0;
 329       ys0 = vsect[2];
 330       ys1 = vsect[3];
 331       ysd = ys1-ys0;
 332       sl = ysd/zsd;
 333       m = [ [ 1,0,   0,    0 ],
 334             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 335             [ 0,0,   1,  zs0 ],
 336             [ 0,0,   0,    1 ] ];
 337       multmatrix(m)
 338         linear_extrude(height=zsd, convexity=10)
 339         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 340     }
 341   }
 342 }
 343
 344 function TestPiece_holes2corners(holes) =
 345   [ holes[0] + thehd_bl,
 346     holes[1] + thehd_br,
 347     holes[1] + thehd_tr,
 348     holes[0] + thehd_tl ];
 349
 350 module TestPiece1(){ ////toplevel
 351   holes = [ [-100, 0],
 352             [   0, 0]
 353             ];
 354   corners = TestPiece_holes2corners(holes);
 355   rcs = [corners[0], corners[1]];
 356   difference(){
 357     union(){
 358       TileBase(corners[0], corners[2]);
 359       Posts(holes);
 360       RoundEdge(corners[0], corners[1]);
 361       RoundEdge(corners[3], corners[0]);
 362     }
 363     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 364     RoundCornerCut(rcs);
 365   }
 366   RoundCornerAdd(rcs);
 367 }
 368
 369 module TestPiece2(){ ////toplevel
 370   holes = [ [   0, 0],
 371             [  50, 0]
 372             ];
 373   corners = TestPiece_holes2corners(holes);
 374   TileBase(corners[0], corners[2]);
 375   Posts(holes);
 376   RoundEdge(corners[0], corners[1]);
 377   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 378 }
 379
 380 module TestDemo(){ ////toplevel
 381   translate([ -thehd[0], 0 ])
 382     color("blue")
 383     TestPiece1();
 384   translate([ +thehd[0] + demo_slop, 0 ])
 385     TestPiece2();
 386 }
 387
 388 module Machine_Arm(){
 389   ysz = cutout_l_end_y_total;
 390   // assume the round end is arc of a circle
 391   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 392   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 393
 394   translate([0,0,-30]) linear_extrude(height=60) {
 395     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 396       intersection(){
 397         translate([-50, -ysz/2])
 398           square([400, ysz]);
 399         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 400           circle(r=endrad, $fa=0.01,$fd=5);
 401       }
 402     }
 403   }
 404 }
 405
 406 module Machine_Profile(){
 407   first_rear = machine_rear_profile[0];
 408   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 409   pol = concat( machine_rear_profile,
 410                 [ below_point ],
 411                 machine_front_profile);
 412   skew_angle = atan2( first_front[1] - first_rear[1],
 413                       first_front[0] - first_rear[0] );
 414   echo(below_point, pol, skew_angle);
 415   hull(){
 416     for (z=[0,-40]) {
 417       translate([0,z]) {
 418         //scale([1,5])
 419         rotate([0,0, -skew_angle ]){
 420           //translate( - first_front )
 421           polygon(pol);
 422         }
 423       }
 424     }
 425   }
 426 }
 427
 428 module Machine_NewRearProfile(){
 429   // figures copied out of xfig edit boxes
 430   // best not to edit the posbox size if poss - just move it
 431   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 432   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 433   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 434   scaleline_mm = 12+5+10+5+3;
 435   sh = -[abs(posbox[0]), abs(posbox[1])];
 436   rot = atan2(-sideline[0], sideline[1]);
 437   sc = scaleline_mm / scaleline;
 438   echo("SH",sh,rot,sc);
 439   scale(sc) rotate(rot) translate(sh){
 440     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 441   }
 442 }
 443
 444 module Machine_NewRearCurve(){
 445   slant = atan2(4,210-10);
 446   echo("SL",slant);
 447   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 448     translate([ rearcurve_double_inrad,
 449                 0,
 450                 -rearcurve_double_inrad + 10 ]){
 451       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 452         hull(){
 453           Machine_NewRearProfile();
 454           translate([0,-100]) Machine_NewRearProfile();
 455         }
 456       }
 457     }
 458     rotate([0,90,0]) rotate([90,0,0]) {
 459       intersection(){
 460         rotate_extrude(convexity=10, $fn=64)
 461           rotate(90)
 462           translate([ 0, -rearcurve_double_inrad ])
 463           Machine_NewRearProfile();
 464         translate([0,0,-500])
 465           cube([500,500,1000]);
 466       }
 467     }
 468     translate([1,0,-rearcurve_double_inrad])
 469       rotate([0,-90,0]) rotate([0,0,-90])
 470       linear_extrude(height= rearcurve_strt_len + 1)
 471       Machine_NewRearProfile();
 472   }
 473 }
 474
 475 module Machine_RearProfile(){ ////toplevel
 476   intersection(){
 477     Machine_Profile();
 478     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 479       square([200,200]);
 480     }
 481   }
 482 }
 483
 484 module Machine_FrontProfile(){
 485   intersection(){
 486     Machine_Profile();
 487     translate([ machine_rear_to_front/2, -100 ]) {
 488       square([200,200]);
 489     }
 490   }
 491 }
 492
 493 module Machine_Curves(){ ////toplevel
 494   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 495               cutout_tile11_y,
 496               0 ]){
 497     //%cube([20,20,20]);
 498     translate([ -reartablet_x,
 499                 -1,
 500                 -reartablet_z + tablet_z_slop])
 501       mirror([0,0,1])
 502       cube([ reartablet_x+1,
 503              reartablet_y+1,
 504              20 ]);
 505   }
 506   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 507               cutout_tile11_y,
 508               frontcurve_z_slop ]){
 509     translate([ 0, -first_front[0] , 0 ])
 510       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 511                   [0,  1,   0, 0],
 512                   [0,  0,   1, 0],
 513                   [0,  0,   0, 1]])
 514       translate([ 0, first_front[0] , 0 ])
 515       mirror([1,0,0]){
 516       rotate([0,-90,0])rotate([0,0,-90]){
 517         linear_extrude(height= 200)
 518           Machine_FrontProfile();
 519       }
 520     }
 521     translate([ rearcurve_strt_len,
 522                 0,
 523                 rearcurve_z_slop ]){
 524       Machine_NewRearCurve();
 525     }
 526   }
 527 }
 528
 529 module Machine(){ ////toplevel
 530   Machine_Arm();
 531   Machine_Curves();
 532 }
 533
 534 function Rectangle_corners(c0, sz) =
 535   // returns the corners of a rectangle from c0 to c0+sz
 536   // if sz is positive, the corners are anticlockwise starting with c0
 537   [ c0 + [ 0,     0     ],
 538     c0 + [ sz[0], 0     ],
 539     c0 + [ sz[0], sz[1] ],
 540     c0 + [ 0,     sz[1] ] ];
 541
 542 function Rectangle_corners2posts(c) =
 543   [ c[0] + thehd_tr,
 544     c[1] + thehd_tl,
 545     c[2] + thehd_bl,
 546     c[3] + thehd_br ];
 547
 548 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 549
 550 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 551
 552 m4_dnl   R_EDGE(c,ix)
 553 m4_dnl        c is from Rectangle_corners and
 554 m4_dnl        ix is a corner number
 555 m4_dnl    expands to two comma-separated corners:
 556 m4_dnl    that denoted by ix, and the next one anticlockwise
 557 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 558
 559 module FitTest_general(c0,sz, dobrace=false){
 560   c = Rectangle_corners(c0, sz);
 561   brace = [7,7,9];
 562   difference(){
 563     union(){
 564       Rectangle_TileBase(c);
 565       if (dobrace) {
 566         translate(concat(c0, [-brace[2] + 0.1])){
 567           difference(){
 568             cube(concat(sz,[brace[2]]) - [5,0,0]);
 569             translate(brace + [0,0, -25])
 570               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 571           }
 572         }
 573       }
 574       RoundEdge(R_EDGE(c,1));
 575     }
 576     Machine();
 577   }
 578 }
 579
 580 module FitTest_Entire(){ ////toplevel
 581   FitTest_general([-40,-80], [275,180], dobrace=true);
 582 }
 583
 584 module FitTest_RearCurve(){ ////toplevel
 585   FitTest_general([110,0], [170,100]);
 586 }
 587
 588 module FitTest_FrontCurve(){ ////toplevel
 589   FitTest_general([110,-80], [170,80]);
 590 }
 591
 592 module Tile02(){ ////toplevel
 593   sz = [100,170];
 594   c0 = tile02_tr + -sz;
 595   c = Rectangle_corners(c0, sz);
 596   posts = Rectangle_corners2posts(c);
 597   rcs = [R_EDGE(c,0)];
 598   difference(){
 599     union(){
 600       Rectangle_TileBase(c);
 601       Posts(posts);
 602       RoundEdge(R_EDGE(c,0));
 603       RoundEdge(R_EDGE(c,3));
 604       InterlockEdge(R_EDGE(c,2), 0);
 605     }
 606     InterlockEdge(R_EDGE(c,1), 1);
 607     RoundCornerCut(rcs);
 608   }
 609   RoundCornerAdd(rcs);
 610 }
 611
 612 module Tile12(){ ////toplevel
 613   sz = [100,250];
 614   c0 = tile02_tr + [-sz[0], 0];
 615   c = Rectangle_corners(c0, sz);
 616   posts = Rectangle_corners2posts(c);
 617   rcs = [R_EDGE(c,3)];
 618   difference(){
 619     union(){
 620       Rectangle_TileBase(c);
 621       Posts(posts);
 622       RoundEdge(R_EDGE(c,2));
 623       RoundEdge(R_EDGE(c,3));
 624     }
 625     InterlockEdge(R_EDGE(c,0), 1);
 626     InterlockEdge(R_EDGE(c,1), 1);
 627     RoundCornerCut(rcs);
 628   }
 629   RoundCornerAdd(rcs);
 630 }
 631
 632 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 633 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 634 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 635
 636 module Tile11(){ ////toplevel
 637   sz = [250,250];
 638   c0 = tile01_tr + [-sz[0],0];
 639   c = Rectangle_corners(c0, sz);
 640   cnr_posts = Rectangle_corners2posts(c);
 641   posts = concat(
 642                  Posts_interpolate_one(cnr_posts[0],
 643                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 644                  [ cnr_posts[1] + [0, cutout_tile11_y],
 645                    cnr_posts[2],
 646                    cnr_posts[3]
 647                    ]);
 648   difference(){
 649     union(){
 650       Rectangle_TileBase(c);
 651       Posts(posts);
 652       RoundEdge(R_EDGE(c,2));
 653       InterlockEdge(R_EDGE(c,3));
 654     }
 655     InterlockEdge(c[0], tile_01_11_cnr, 1);
 656     InterlockEdge(tile_11_10_cnr, c[2], 1);
 657     Machine();
 658   }
 659 }
 660
 661 module Tile01(){ ////toplevel
 662   sz = [250,170];
 663   c0 = tile01_tr + -sz;
 664   c = Rectangle_corners(c0, sz);
 665   cnr_posts = Rectangle_corners2posts(c);
 666   posts = concat(
 667                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 668                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 669                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 670                                        cnr_posts[3])
 671                  );
 672   difference(){
 673     union(){
 674       Rectangle_TileBase(c);
 675       Posts(posts);
 676       RoundEdge(R_EDGE(c,0));
 677       InterlockEdge(tile_01_11_cnr, c[3]);
 678       InterlockEdge(R_EDGE(c,3));
 679     }
 680     InterlockEdge(c[1], tile_01_00_cnr, 1);
 681     Machine();
 682   }
 683 }
 684
 685 module Tile10(){ ////toplevel
 686   sz = [250,250];
 687   c0 = tile01_tr + [0,0];
 688   c = Rectangle_corners(c0, sz);
 689   cnr_posts = Rectangle_corners2posts(c);
 690   cty = cutout_tile11_y;
 691   rcy = cty + rearcurve_avoid_y;
 692   posts = [ cnr_posts[0] + [ 0,                             cty ],
 693             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 694             cnr_posts[1] + [ 0,                             rcy ],
 695             cnr_posts[2],
 696             cnr_posts[3] ];
 697   rcs = [R_EDGE(c,2)];
 698   difference(){
 699     union(){
 700       Rectangle_TileBase(c);
 701       Posts(posts);
 702       RoundEdge(R_EDGE(c,1));
 703       RoundEdge(R_EDGE(c,2));
 704       InterlockEdge(c[3], tile_11_10_cnr);
 705     }
 706     RoundCornerCut(rcs);
 707     Machine();
 708   }
 709   RoundCornerAdd(rcs);
 710 }
 711
 712 module Tile00(){ ////toplevel
 713   sz = [250,170];
 714   c0 = tile01_tr + [0,-sz[1]];
 715   c = Rectangle_corners(c0, sz);
 716   cnr_posts = Rectangle_corners2posts(c);
 717   cty = cutout_tile01_y;
 718   rcy = cty + frontcurve_avoid_y;
 719   posts = [ cnr_posts[0],
 720             cnr_posts[1],
 721             cnr_posts[2] + [ 0,                             -rcy ],
 722             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 723             cnr_posts[3] + [ 0,                             -cty ]
 724             ];
 725   rcs = [R_EDGE(c,1)];
 726   difference(){
 727     union(){
 728       Rectangle_TileBase(c);
 729       Posts(posts);
 730       RoundEdge(R_EDGE(c,0));
 731       RoundEdge(R_EDGE(c,1));
 732       InterlockEdge(tile_01_00_cnr, c[0]);
 733     }
 734     RoundCornerCut(rcs);
 735     Machine();
 736   }
 737   RoundCornerAdd(rcs);
 738 }
 739
 740 module Demo(){ ////toplevel
 741   translate(demo_slop*[-2,1]) color("blue") Tile12();
 742   translate(demo_slop*[-2,0]) color("red")  Tile02();
 743   translate(demo_slop*[-2,1]) color("orange") Tile11();
 744   translate(demo_slop*[-2,0]) color("purple") Tile01();
 745   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 746   translate(demo_slop*[-3,0]) color("red")    Tile00();
 747   %Machine();
 748 }
 749
 750 //TestPiece1();
 751 //TestPiece2();
 752 //Demo();
 753
 754 //Machine_Profile();
 755 //Machine_NewRearProfile();
 756 //Machine_NewRearCurve();
 757 //Machine_Curves();
 758 //Machine();
 759 //FitTest();