chiark / gitweb /
sewing-table: FitTest_Entire: shrink somewhat
[reprap-play.git] / sewing-table.scad.m4
1 // -*- C -*-
2
3 include <funcs.scad>
4 include <commitid.scad>
5
6 ply_th = 18;
7 ply_hole_dia = 15;
8 ply_edge_min = 10;
9
10 tile_th = 3;
11 post_dia = 8;
12
13 post_shorter = 1;
14
15 screw_dia = 2.2;
16 screw_big_dia = 3.6;
17 screw_big_len = 4.0;
18
19 round_edge_rad = 2.0;
20
21 round_cnr_rad = 10;
22
23 interlock_dia = 10;
24 interlock_fine = 0.66;
25
26 interlock_fine_slope = 1.0;
27 interlock_fine_lenslop = 1.0;
28
29 demo_slop = 0.1;
30
31 // cutout
32
33 machine_rear_to_front = 84 + 0.25 - 1.4;
34
35 cutout_l_end_y_front_slop = 0.5;
36 cutout_l_end_y_rear_slop = 0.5;
37 cutout_l_end_x_slop = 0.25;
38
39 cutout_l_end_x = 22;
40 cutout_l_end_y = machine_rear_to_front;
41 cutout_l_end_curve = 1;
42 cutout_l_end_y_total = cutout_l_end_y
43   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
44
45 tile02_tr = [-250, 0];
46 tile01_tr = [  0, 0];
47
48 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
49 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
50 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
51
52 // front and rear curves
53
54 rearedge_len = 170;
55
56 rearcurve_strt_len = 52;
57
58 rearcurve_z_slop = -0.50;
59
60 rearcurve_avoid_y = 35;
61
62 rearcurve_double_inrad = 26.10 + 8.04;
63
64 reartablet_z = 2.54;
65 reartablet_x = 5 + 1;
66 reartablet_y = 8;
67
68 frontcurve_side_skew = 3.5 / 72;
69 frontcurve_avoid_y = 70;
70 frontcurve_z_slop = 0.75;
71
72 frontcurve_strt_len = 50;
73 frontcurve_dualcurve_angle = 30;
74
75 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
76                       [ 180, 90 ],
77                       [ 190, -80 ], // do not change index of this one
78                       [   0, 70 ],  [  0, -35 ],
79                       ];
80
81 teststrap = [ 3, 5 ];
82 teststrap_peg = [7.5, 3.5];
83
84 // calculated
85
86 TEST = false;
87
88 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
89
90 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
91
92 hole_slop = (ply_hole_dia - post_dia)/2;
93 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
94
95 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
96          tile_hard_edge_hole_dist));
97
98 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
99          tile_hard_edge_hole_dist + round_edge_rad));
100
101 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
102 thehd_tr = thehd;
103 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
104 thehd_bl = -thehd_tr;
105 thehd_br = -thehd_tl;
106
107 tablet_z_slop = 0.25;
108
109 interlock_rad = interlock_dia/2;
110 interlock_negative_rad = interlock_rad + 0.125;
111
112 interlock_sq_adj = 0.2; // arbitrary
113
114 m4_define(`POST_TCROSSSZ',
115           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
116
117 module Post(){
118   mirror([0,0,1]) {
119     difference(){
120       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
121       translate([0,0, tile_th]) {
122         cylinder(r= screw_big_dia/2, h= screw_big_len);
123         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
124       }
125     }
126     if (TEST) {
127       translate([0,0, tile_th/2]) {
128         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
129         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
130       }
131     }
132   }
133 }
134
135 module Posts(posts) {
136   for (p= posts) {
137     translate(concat(p, [0]))
138       Post();
139   }
140 }
141
142 module TileBase(botleft, topright){
143   size = topright - botleft;
144   botleft_post = botleft + thehd_tr;
145   topright_post = topright + thehd_bl;
146   difference(){
147     mirror([0,0,1])
148       translate(concat(botleft, [0]))
149       cube(concat(size, [tile_th]));
150     if (!TEST) {
151       cidsz = topright_post-botleft_post
152         + [-post_dia,-post_dia]
153         + [0, thehd[1]];
154       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
155       echo("CID",cidsz,cidszr);
156       translate( concat(botleft_post, [ -tile_th ])
157                  + 0.5 * [ post_dia, post_dia, 0 ]
158                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
159         Commitid_BestCount_M(cidszr);
160     }
161     if (TEST) {
162       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
163       cidsz = [ thehd[0], size[1] - 2*crossoff ];
164       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
165       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
166         Commitid_BestCount(cidszr);
167       difference(){
168         mirror([0,0,1]) {
169           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
170             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
171           translate(concat(botleft_post, [-1]))
172             cube(concat(topright_post-botleft_post, [tile_th+2]));
173         }
174         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
175         minkowski(){
176           MachineEnvelope();
177           cube(shufflesz, center=true);
178         }
179       }
180     }
181   }
182 }
183
184 m4_dnl   R_EDGE(c,ix)
185 m4_dnl        c is from Rectangle_corners and
186 m4_dnl        ix is a corner number
187 m4_dnl    expands to two comma-separated corners:
188 m4_dnl    that denoted by ix, and the next one anticlockwise
189 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
190
191 m4_dnl   R_CNR(c,ix)
192 m4_dnl        c is from Rectangle_corners and
193 m4_dnl        ix is a corner number
194 m4_dnl    expands to an array of corners as for RoundCorner
195 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
196
197 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
198 m4_define(`INREFFRAME',`
199   length_vec = ($2) - ($1);
200   length = dist2d([0,0], length_vec);
201   length_uvec = length_vec / length;
202   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
203   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
204         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
205         [ 0,              0,              1,            0, ],
206         [ 0,              0,              0,            1, ] ];
207   $3
208   multmatrix(m)
209 ')
210
211 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
212 m4_dnl    INREFFRAME_EDGE { body; }
213 m4_define(`INREFFRAME_EDGE',`
214   translate([0,0, -round_edge_rad])
215 ')
216
217 module RoundEdge(left_cnr, right_cnr) {
218   INREFFRAME(left_cnr, right_cnr)
219     INREFFRAME_EDGE {
220     difference(){
221       rotate([0,90,0])
222         cylinder(r= round_edge_rad, h= length, $fn=50);
223       translate([-1, 0, -20])
224         cube([length+2, 20, 20]);
225     }
226   }
227 }
228
229 m4_define(`ROUNDCORNER_VARS',`
230   this_cnr = ci[0];
231   right_cnr = ci[1];
232   left_cnr = ci[2];
233   bigr= round_cnr_rad - round_edge_rad;
234   l_uvec = unitvector2d(left_cnr - this_cnr);
235   r_uvec = unitvector2d(right_cnr - this_cnr);
236   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
237   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
238   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
239   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
240   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
241   ctr3 = concat(ctr,[0])
242 ')
243
244 module RoundCorner_selector(ci, adj) {
245   ROUNDCORNER_VARS;
246   intersection(){
247     union(){
248       INREFFRAME(ctr3,concat(lp1,[4])){
249         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
250           translate([-bigr*2 + adj, -bigr])
251             square([bigr*2, bigr*3]);
252         }
253       }
254     }
255     union(){
256       INREFFRAME(ctr3,concat(lp4,[0])){
257         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
258           translate([-bigr*2, -bigr*2])
259             square([bigr*2 + adj, bigr*3]);
260         }
261       }
262     }
263   }
264 }
265
266 module RoundCornerCut(ci) {
267   // ci should be [this_cnr, right_cnr, left_cnr]
268   // where right_cnr is to the right (ie, anticlockwise)
269   ROUNDCORNER_VARS;
270   difference(){
271     RoundCorner_selector(ci, -0.1);
272     translate(ctr3)
273       cylinder(center=true, h=20, r= bigr);
274   }
275 }
276
277 module RoundCornerAdd(ci) {
278   ROUNDCORNER_VARS;
279   intersection(){
280     RoundCorner_selector(ci, +0.1);
281     INREFFRAME_EDGE {
282       translate(ctr3){
283         rotate_extrude(convexity=10, $fn=50)
284           translate([bigr, 0])
285           difference(){
286           circle(r= round_edge_rad, $fn=50);
287           mirror([1,1])
288             square([20,20]);
289         }
290       }
291     }
292   }
293 }
294
295 module InterlockLobePlan(negative) {
296   r = negative ? interlock_negative_rad : interlock_rad;
297   ymir = negative ? 0 : 1;
298
299   dx = sqrt(3) * r;
300   $fn= 80;
301   translate([thehd[0], 0]){
302     mirror([0,ymir]){
303       circle(r=r);
304       difference(){
305         translate([-dx, -0.1])
306           square([ dx*2, r/2 + 0.1 ]);
307         for (xi = [-1, 1]) {
308           translate([ xi*dx, r ])
309             circle(r=r);
310         }
311       }
312     }
313   }
314 }
315
316 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
317   for (lobei = [ 0 : nlobes-1 ]) {
318     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
319     translate([lobex, 0, 0]) {
320       InterlockLobePlan(negative);
321     }
322   }
323
324   if (dosquare) {
325     iadj = 0;
326     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
327     mirror([0, negative])
328       translate([slotshorter, iadj])
329       square([length - slotshorter*2, interlock_fine + iadj*2]);
330   }
331 }
332
333 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
334   plusth = negative * 1.0;
335   protr = interlock_fine + interlock_sq_adj;
336
337   z2 = -tile_th/2;
338   z1 = -tile_th/2 - protr / interlock_fine_slope;
339   z3 = -tile_th/2 + protr / interlock_fine_slope;
340
341   negsign = negative ? -1 : +1;
342   yprotr = negsign * protr;
343
344   INREFFRAME(left_cnr, right_cnr) {
345     for (vsect = [ // zs0            zs1      ys0,            ys1
346                   [ -tile_th-plusth, plusth,  0,              0],
347                   [ z1,              z2,      0, yprotr],
348                   [ z2,              z3,      yprotr, 0],
349                   ]) {
350       zs0 = vsect[0];
351       zs1 = vsect[1];
352       zsd = zs1-zs0;
353       ys0 = vsect[2];
354       ys1 = vsect[3];
355       ysd = ys1-ys0;
356       sl = ysd/zsd;
357       m = [ [ 1,0,   0,    0 ],
358             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
359             [ 0,0,   1,  zs0 ],
360             [ 0,0,   0,    1 ] ];
361       multmatrix(m)
362         linear_extrude(height=zsd, convexity=10)
363         InterlockEdgePlan(negative, nlobes, length, !!ysd);
364     }
365   }
366 }
367
368 function TestPiece_holes2corners(holes) =
369   [ holes[0] + thehd_bl,
370     holes[1] + thehd_br,
371     holes[1] + thehd_tr,
372     holes[0] + thehd_tl ];
373
374 module TestPiece1(){ ////toplevel
375   holes = [ [-100, 0],
376             [   0, 0]
377             ];
378   corners = TestPiece_holes2corners(holes);
379   rcs = R_CNR(corners,0);
380   difference(){
381     union(){
382       TileBase(corners[0], corners[2]);
383       Posts(holes);
384       RoundEdge(corners[0], corners[1]);
385       RoundEdge(corners[3], corners[0]);
386     }
387     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
388     RoundCornerCut(rcs);
389   }
390   RoundCornerAdd(rcs);
391 }
392
393 module TestPiece2(){ ////toplevel
394   holes = [ [   0, 0],
395             [  50, 0]
396             ];
397   corners = TestPiece_holes2corners(holes);
398   TileBase(corners[0], corners[2]);
399   Posts(holes);
400   RoundEdge(corners[0], corners[1]);
401   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
402 }
403
404 module TestDemo(){ ////toplevel
405   translate([ -thehd[0], 0 ])
406     color("blue")
407     TestPiece1();
408   translate([ +thehd[0] + demo_slop, 0 ])
409     TestPiece2();
410 }
411
412 module Machine_Arm(){
413   ysz = cutout_l_end_y_total;
414   // assume the round end is arc of a circle
415   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
416   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
417   
418   translate([0,0,-30]) linear_extrude(height=60) {
419     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
420       intersection(){
421         translate([-50, -ysz/2])
422           square([400, ysz]);
423         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
424           circle(r=endrad, $fa=0.01,$fd=5);
425       }
426     }
427   }
428 }
429
430 module Machine_NewRearProfile(){
431   // figures copied out of xfig edit boxes
432   // best not to edit the posbox size if poss - just move it
433   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
434   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
435   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
436   scaleline_mm = 12+5+10+5+3;
437   sh = -[abs(posbox[0]), abs(posbox[1])];
438   rot = atan2(-sideline[0], sideline[1]);
439   sc = scaleline_mm / scaleline;
440   //echo("SH",sh,rot,sc);
441   scale(sc) rotate(rot) translate(sh){
442     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
443   }
444 }
445
446 module Machine_NewFrontProfile(){
447   // figures copied out of xfig edit boxes
448   // best not to edit the posbox size if poss - just move it
449   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
450   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
451   refline_mm = (11-1)*10;
452   sh = -[abs(posbox[0]), abs(posbox[1])];
453   rot = atan2(-refline[0], refline[1]);
454   sc = refline_mm / vectorlen2d(refline);
455   //echo("SH",sh,rot,sc);
456   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
457     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
458   }
459 }
460
461 module Machine_NewRearCurve(){
462   slant = atan2(4,210-10);
463   //echo("SL",slant);
464   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
465     translate([ rearcurve_double_inrad,
466                 0,
467                 -rearcurve_double_inrad + 10 ]){
468       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
469         hull(){
470           Machine_NewRearProfile();
471           translate([0,-100]) Machine_NewRearProfile();
472         }
473       }
474     }
475     rotate([0,90,0]) rotate([90,0,0]) {
476       intersection(){
477         rotate_extrude(convexity=10, $fn=64)
478           rotate(90)
479           translate([ 0, -rearcurve_double_inrad ])
480           Machine_NewRearProfile();
481         translate([0,0,-500])
482           cube([500,500,1000]);
483       }
484     }
485     translate([1,0,-rearcurve_double_inrad])
486       rotate([0,-90,0]) rotate([0,0,-90])
487       linear_extrude(height= rearcurve_strt_len + 1)
488       Machine_NewRearProfile();
489   }
490 }
491
492 module Machine_Curves(){ ////toplevel
493   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
494               cutout_tile11_y,
495               0 ]){
496     //%cube([20,20,20]);
497     translate([ -reartablet_x,
498                 -1,
499                 -reartablet_z + tablet_z_slop])
500       mirror([0,0,1])
501       cube([ reartablet_x+1,
502              reartablet_y+1,
503              20 ]);
504   }
505   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
506               cutout_tile11_y,
507               frontcurve_z_slop ]){
508     translate([0, -machine_rear_to_front, 0])
509       multmatrix([[1, -frontcurve_side_skew, 0, 0],
510                   [0,  1,   0, 0],
511                   [0,  0,   1, 0],
512                   [0,  0,   0, 1]])
513       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
514       linear_extrude(height= 200)
515       Machine_NewFrontProfile();
516
517     translate([ rearcurve_strt_len,
518                 0,
519                 rearcurve_z_slop ]){
520       Machine_NewRearCurve();
521     }
522   }
523 }
524
525 module TestStrapSlots(){
526   pegwidth = teststrap_peg[0];
527   for (pos = teststrapslots_at) {
528     echo("TSS",pos);
529     translate(concat(pos,[0]))
530       for (mx = [0,1]) mirror([mx,0,0]) {
531           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
532             cube(concat(teststrap,[40]));
533         }
534   }
535 }
536
537 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
538
539 module TestStrapPeg_Short(){ ////toplevel
540   TestStrapPeg_any(35);
541 }
542
543 module TestStrapPeg_Long(){ ////toplevel
544   TestStrapPeg_any(60);
545 }
546
547 module Machine(){ ////toplevel
548   Machine_Arm();
549   Machine_Curves();
550   if (TEST)
551     TestStrapSlots();
552 }
553
554 module MachineEnvelope(){
555   // used for testing
556   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
557   y_arm_t  = cutout_tile11_y;
558   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
559   y_crv_b  = y_arm_t + rearcurve_avoid_y;
560
561   translate([0,0,-50]) linear_extrude(height= 100){
562     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
563     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
564   }
565 }
566
567 function Rectangle_corners(c0, sz) =
568   // returns the corners of a rectangle from c0 to c0+sz
569   // if sz is positive, the corners are anticlockwise starting with c0
570   [ c0 + [ 0,     0     ],
571     c0 + [ sz[0], 0     ],
572     c0 + [ sz[0], sz[1] ],
573     c0 + [ 0,     sz[1] ] ];
574
575 function Rectangle_corners2posts(c) =
576   [ c[0] + thehd_tr,
577     c[1] + thehd_tl,
578     c[2] + thehd_bl,
579     c[3] + thehd_br ];
580
581 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
582
583 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
584
585 module Tile02(){ ////toplevel
586   sz = [100,170];
587   c0 = tile02_tr + -sz;
588   c = Rectangle_corners(c0, sz);
589   posts = Rectangle_corners2posts(c);
590   rcs = R_CNR(c,0);
591   difference(){
592     union(){
593       Rectangle_TileBase(c);
594       Posts(posts);
595       RoundEdge(R_EDGE(c,0));
596       RoundEdge(R_EDGE(c,3));
597       InterlockEdge(R_EDGE(c,2), 0);
598     }
599     InterlockEdge(R_EDGE(c,1), 1);
600     RoundCornerCut(rcs);
601   }
602   RoundCornerAdd(rcs);
603 }
604
605 module Tile12(){ ////toplevel
606   sz = [100,250];
607   c0 = tile02_tr + [-sz[0], 0];
608   c = Rectangle_corners(c0, sz);
609   posts = Rectangle_corners2posts(c);
610   rcs = R_CNR(c,3);
611   difference(){
612     union(){
613       Rectangle_TileBase(c);
614       Posts(posts);
615       RoundEdge(R_EDGE(c,2));
616       RoundEdge(R_EDGE(c,3));
617     }
618     InterlockEdge(R_EDGE(c,0), 1);
619     InterlockEdge(R_EDGE(c,1), 1);
620     RoundCornerCut(rcs);
621   }
622   RoundCornerAdd(rcs);
623 }
624
625 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
626 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
627 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
628
629 module Tile11(){ ////toplevel
630   sz = [250,250];
631   c0 = tile01_tr + [-sz[0],0];
632   c = Rectangle_corners(c0, sz);
633   cnr_posts = Rectangle_corners2posts(c);
634   posts = concat(
635                  Posts_interpolate_one(cnr_posts[0],
636                                        cnr_posts[1] - [cutout_tile11_x, 0]),
637                  [ cnr_posts[1] + [0, cutout_tile11_y],
638                    cnr_posts[2],
639                    cnr_posts[3]
640                    ]);
641   difference(){
642     union(){
643       Rectangle_TileBase(c);
644       Posts(posts);
645       RoundEdge(R_EDGE(c,2));
646       InterlockEdge(R_EDGE(c,3));
647     }
648     InterlockEdge(c[0], tile_01_11_cnr, 1);
649     InterlockEdge(tile_11_10_cnr, c[2], 1);
650     Machine();
651   }
652 }    
653
654 module Tile01(){ ////toplevel
655   sz = [250,170];
656   c0 = tile01_tr + -sz;
657   c = Rectangle_corners(c0, sz);
658   cnr_posts = Rectangle_corners2posts(c);
659   posts = concat(
660                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
661                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
662                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
663                                        cnr_posts[3])
664                  );
665   difference(){
666     union(){
667       Rectangle_TileBase(c);
668       Posts(posts);
669       RoundEdge(R_EDGE(c,0));
670       InterlockEdge(tile_01_11_cnr, c[3]);
671       InterlockEdge(R_EDGE(c,3));
672     }
673     InterlockEdge(c[1], tile_01_00_cnr, 1);
674     Machine();
675   }
676 }    
677
678 module Tile10(){ ////toplevel
679   sz = [250,250];
680   c0 = tile01_tr + [0,0];
681   c = Rectangle_corners(c0, sz);
682   cnr_posts = Rectangle_corners2posts(c);
683   cty = cutout_tile11_y;
684   rcy = cty + rearcurve_avoid_y;
685   posts = [ cnr_posts[0] + [ 0,                             cty ],
686             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
687             cnr_posts[1] + [ 0,                             rcy ],
688             cnr_posts[2],
689             cnr_posts[3] ];
690   rcs = R_CNR(c,2);
691   difference(){
692     union(){
693       Rectangle_TileBase(c);
694       Posts(posts);
695       RoundEdge(R_EDGE(c,1));
696       RoundEdge(R_EDGE(c,2));
697       InterlockEdge(c[3], tile_11_10_cnr);
698     }
699     RoundCornerCut(rcs);
700     Machine();
701   }
702   RoundCornerAdd(rcs);
703 }
704
705 module Tile00(){ ////toplevel
706   sz = [250,170];
707   c0 = tile01_tr + [0,-sz[1]];
708   c = Rectangle_corners(c0, sz);
709
710   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
711   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
712   c1bis = [ c[1][0],
713             c[2][1] -
714             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
715
716   cnr_posts = Rectangle_corners2posts(c);
717   cty = cutout_tile01_y;
718   rcy = cty + frontcurve_avoid_y;
719   posts = [ cnr_posts[0],
720             cnr_posts[1],
721             cnr_posts[2] + [ 0,                             -rcy ],
722             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
723             cnr_posts[3] + [ 0,                             -cty ]
724             ];
725   rcs = R_CNR(c,1);
726   rc2 = [c1bis,c2bis,c[1]];
727   difference(){
728     union(){
729       difference(){
730         union(){
731           Rectangle_TileBase(c);
732           Posts(posts);
733           RoundEdge(R_EDGE(c,0));
734           RoundEdge(c[1], c1bis);
735           InterlockEdge(tile_01_00_cnr, c[0]);
736         }
737         RoundCornerCut(rcs);
738         translate([0,0,-20]) linear_extrude(height=40) {
739           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
740         }
741       }
742       RoundEdge(c1bis, c2bis);
743     }
744     Machine();
745     RoundCornerCut(rc2);
746   }
747   RoundCornerAdd(rcs);
748   RoundCornerAdd(rc2);
749 }
750
751 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
752   c = Rectangle_corners(c0, sz);
753   brace = [7,7,9];
754   bsz = sz + [bracexx,0,0];
755   difference(){
756     union(){
757       Rectangle_TileBase(c);
758       if (dobrace) {
759         translate(concat(c0, [-brace[2] + 0.1])){
760           difference(){
761             cube(concat(bsz, [brace[2]]) - [5,0,0]);
762             translate(brace + [0,0, -25])
763               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
764           }
765         }
766       }
767       RoundEdge(R_EDGE(c,1));
768     }
769     Machine();
770   }
771 }
772
773 module FitTest_PairLink(cut=false){ ////toplevel
774   cy0=-55; cy1=85; cx=132;
775   bar = [10,10];
776   legrad = 12;
777   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
778   strap = [3,5];
779   adj_neg_slop = 1.0;
780   bar_z_slop = 1.75;
781
782   // calculated
783   straphole_x_max = legrad/sqrt(2) + footrad_max;
784   dz = cut ? adj_neg_slop : 0;
785
786   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
787     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
788
789   for (endy=[cy0,cy1]) {
790     $fn=32;
791     translate([cx,endy,dz]){
792       // feet
793       for (rot=[45:90:315]) rotate(rot) {
794         translate([legrad,0,0]){
795           hull(){
796             cylinder(r= footrad_max, h=1);
797             translate([0,0,-footrad_depth])
798               cylinder(r= footrad_min, h=1);
799           }
800           if (cut)
801             translate([0,0,-10])
802             cylinder(r= footrad_min +
803                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
804                      h=20);
805         }
806       }
807       // legs
808       for (rot=[45,135]) rotate(rot) {
809         hull(){
810           for (s=[-1,+1]){
811             translate([s*legrad,0,0])
812               cylinder(r= footrad_max, h=bar[1]);
813           }
814         }
815       }
816       // strap holes
817       if (cut) {
818         for (rot=[0,180]) rotate(rot) {
819             translate([ straphole_x_max - strap[0]/2, 0,0 ])
820               cube(concat(strap,[20]), center=true);
821           }
822       }
823     }
824   }
825 }
826
827 module FitTest_RearCurve(){ ////toplevel
828   difference(){
829     FitTest_general([100,0], [180,100]);
830     FitTest_PairLink(true);
831     TestStrapSlots();
832   }
833 }
834
835 module FitTest_FrontCurve(){ ////toplevel
836   p0 = [100,-80];
837   sz = [180,80];
838   difference(){
839     intersection() {
840       Tile00();
841       translate([0,0,-8]) linear_extrude(height=18) {
842         translate(p0) square(sz);
843         translate(teststrapslots_at[3])
844           scale(2* [ teststrap_peg[0], teststrap[1] ])
845           circle(r=1, $fn=20);
846       }
847     }
848     FitTest_PairLink(true);
849     TestStrapSlots();
850   }
851 }
852
853 module FitTest_Entire(){ ////toplevel
854   p0 = [-33,-80];
855   szrear = [263,180];
856   szfront = [243,szrear[1]];
857   difference(){
858     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
859     FitTest_PairLink(true);
860     translate(concat(p0,[0]) + [szfront[0],-10,-40])
861       cube([100, -p0[1], 80]);
862     TestStrapSlots();
863   }
864   intersection(){
865     FitTest_RearCurve();
866     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
867   }
868   FitTest_FrontCurve();
869 }
870
871 module FitTest_EntireDemo(){ ////toplevel
872   FitTest_Entire();
873   //%Tile00();
874 }
875
876 module FitTest_PairDemo(){ ////toplevel
877   sh=[-90,-15,0];
878   translate(sh){
879     FitTest_PairLink();
880     %FitTest_FrontCurve();
881     %FitTest_RearCurve();
882   }
883   rotate([0,0,180]){
884     translate(sh){
885       difference(){
886         union(){
887           FitTest_FrontCurve();
888           FitTest_RearCurve();
889         }
890         #FitTest_PairLink(true);
891       }
892     }
893   }
894 }
895
896 module RoundCornerDemo_plat(cnr){
897   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
898 }
899
900 module RoundCornerDemo(){ ////toplevel
901   cnr = [ [-2,-3], [13,-3], [-12,9] ];
902   translate([0,25,0]) RoundCornerDemo_plat(cnr);
903   translate([25,0,0]) RoundCornerAdd(cnr);
904   translate([-25,0,0]) RoundCornerCut(cnr);
905   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
906   difference(){
907     RoundCornerDemo_plat(cnr);
908     RoundCornerCut(cnr);
909   }
910   RoundCornerAdd(cnr);
911 }
912
913 module Demo(){ ////toplevel
914   translate(demo_slop*[-2,1]) color("blue") Tile12();
915   translate(demo_slop*[-2,0]) color("red")  Tile02();
916   translate(demo_slop*[-2,1]) color("orange") Tile11();
917   translate(demo_slop*[-2,0]) color("purple") Tile01();
918   translate(demo_slop*[-3,1]) color("blue")   Tile10();
919   translate(demo_slop*[-3,0]) color("red")    Tile00();
920   %Machine();
921 }
922   
923 //TestPiece1();
924 //TestPiece2();
925 //Demo();
926
927 //Machine_NewRearProfile();
928 //Machine_NewRearCurve();
929 //Machine_NewFrontProfile();
930 //Machine_Curves();
931 //Machine();
932 //FitTest();
933 //MachineEnvelope();