sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 $screw_dia = 3.168;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 leg_height = 53.75 - 0.95;
  34
  35 leg_hole_dia = 5 + 0.75;
  36 leg_big_dia = 37;
  37 leg_bot_dia = 15;
  38 leg_top_flat_z = 2;
  39 leg_top_thick = 8;
  40
  41 leg_midspc_dia = 20;
  42 leg_bot_thick = 8;
  43 leg_bot_mid_dia = 12;
  44
  45 leg_fin_top_w = 3;
  46 leg_fin_bot_w = 5;
  47 leg_fin_bot_rad = 30;
  48 leg_fin_bot_flat_z = 5;
  49
  50 leg_n_fins = 4;
  51 leg_n_tubules = 4;
  52 leg_tubule_dia = 4;
  53
  54 // cutout
  55
  56 machine_rear_to_front = 84 + 0.25 - 1.4;
  57
  58 cutout_l_end_y_front_slop = 0.5;
  59 cutout_l_end_y_rear_slop = 0.5;
  60
  61 cutout_l_end_x = 22;
  62 cutout_l_end_y = machine_rear_to_front;
  63 cutout_l_end_new_x_slop = 1.4 - 1.95;
  64 cutout_l_end_y_total = cutout_l_end_y
  65   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  66
  67 tile02_tr = [-250, 0];
  68 tile01_tr = [  0, 0];
  69
  70 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  71 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  72
  73 // front and rear curves
  74
  75 rearedge_len = 170 + 0.70;
  76 frontedge_len = 170;
  77
  78 rearcurve_strt_len = 52;
  79
  80 rearcurve_z_slop = -0.50;
  81
  82 rearcurve_avoid_y = 35;
  83
  84 rearcurve_double_inrad = 26.10 + 8.04;
  85
  86 reartablet_z = 2.54;
  87 reartablet_x = 5 + 1;
  88 reartablet_y = 8;
  89
  90 frontcurve_side_skew = 3.5 / 72;
  91 frontcurve_avoid_y = 70;
  92 frontcurve_z_slop = 0.75;
  93
  94 frontcurve_strt_len = 50;
  95 frontcurve_dualcurve_angle = 30;
  96
  97 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  98                       [ 180, 90 ],
  99                       [ 190, -80 ], // do not change index of this one
 100                       [   0, 70 ],  [  0, -35 ],
 101                       ];
 102
 103 teststrap = [ 3, 5 ];
 104 teststrap_peg = [7.5, 3.5];
 105
 106 ply_edge_hole_dist_real = 14;
 107
 108 // calculated
 109
 110 TEST = false;
 111 JIG = false;
 112
 113 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 114
 115 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 116
 117 hole_slop = (ply_hole_dia - post_dia)/2;
 118 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 121          tile_hard_edge_hole_dist));
 122
 123 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 124          tile_hard_edge_hole_dist + round_edge_rad));
 125
 126 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 127 thehd_tr = thehd;
 128 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 129 thehd_bl = -thehd_tr;
 130 thehd_br = -thehd_tl;
 131
 132 tablet_z_slop = 1.00;
 133
 134 interlock_rad = interlock_dia/2;
 135 interlock_negative_rad = interlock_rad + 0.125;
 136
 137 interlock_sq_adj = 0.2; // arbitrary
 138
 139 leg_fin_top_rad = sqrt( pow(leg_big_dia/2,2) -
 140                         pow(leg_fin_top_w/2,2) );
 141
 142 leg_tubule_pos_rad = leg_big_dia/2 * 0.6;
 143
 144 m4_define(`POST_TCROSSSZ',
 145           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 146
 147 module Post(){
 148   mirror([0,0,1]) {
 149     if (!JIG) {
 150       difference(){
 151         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 152         translate([0,0, tile_th]) {
 153           cylinder(r= screw_big_dia/2, h= screw_big_len);
 154           cylinder(r= $screw_dia/2, h= ply_th, $fn=20);
 155         }
 156       }
 157     }
 158     if (TEST) {
 159       translate([0,0, tile_th/2]) {
 160         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 161         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 162       }
 163     }
 164     if (JIG) {
 165       translate([0,0, tile_th/2]) {
 166         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 167       }
 168     }
 169   }
 170 }
 171
 172 module PostHole(){
 173   if (JIG) {
 174     translate([0,0,-5])
 175       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 176     translate([0,0, -jig_min_th])
 177       cylinder(r= ply_hole_dia_real/2, h = 5);
 178     for (rot=[0:90:270]) rotate(rot) {
 179         translate([ ply_edge_hole_dist_real, 0, 0 ])
 180           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 181       }
 182   }
 183 }
 184
 185 module Posts(posts) {
 186   for (p= posts) {
 187     translate(concat(p, [0]))
 188       Post();
 189   }
 190 }
 191 module PostHoles(posts) {
 192   for (p= posts)  {
 193     translate(concat(p, [0]))
 194       PostHole();
 195   }
 196 }
 197
 198 module TileBase(botleft, topright){
 199   size = topright - botleft;
 200   botleft_post = botleft + thehd_tr;
 201   topright_post = topright + thehd_bl;
 202   difference(){
 203     mirror([0,0,1])
 204       translate(concat(botleft, [0]))
 205       cube(concat(size, [tile_th]));
 206     if (!(TEST || JIG)) {
 207       cidsz = topright_post-botleft_post
 208         + [-post_dia,-post_dia]
 209         + [0, thehd[1]];
 210       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 211       echo("CID",cidsz,cidszr);
 212       translate( concat(botleft_post, [ -tile_th ])
 213                  + 0.5 * [ post_dia, post_dia, 0 ]
 214                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 215         Commitid_BestCount_M(cidszr);
 216     }
 217     if ((TEST || JIG)) {
 218       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 219       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 220       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 221       if (TEST)
 222         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 223           Commitid_BestCount(cidszr);
 224       difference(){
 225         mirror([0,0,1]) {
 226           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 227             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 228           translate(concat(botleft_post, [-1]))
 229             cube(concat(topright_post-botleft_post, [tile_th+2]));
 230         }
 231         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 232         minkowski(){
 233           MachineEnvelope();
 234           cube(shufflesz, center=true);
 235         }
 236         if (JIG) {
 237           translate([0,0,-20]) linear_extrude(height=20) {
 238             for (diag=[[ +1, botleft                   ],
 239                        [ -1, [topright[0], botleft[1]] ]]) {
 240               translate(diag[1])
 241                 rotate(atan2(size[1], diag[0] * size[0]))
 242                 translate([0, -test_edge/2])
 243                 square([vectorlen2d(size), test_edge]);
 244             }
 245           }
 246         }
 247       }
 248     }
 249   }
 250 }
 251
 252 m4_dnl   R_EDGE(c,ix)
 253 m4_dnl        c is from Rectangle_corners and
 254 m4_dnl        ix is a corner number
 255 m4_dnl    expands to two comma-separated corners:
 256 m4_dnl    that denoted by ix, and the next one anticlockwise
 257 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 258
 259 m4_dnl   R_CNR(c,ix)
 260 m4_dnl        c is from Rectangle_corners and
 261 m4_dnl        ix is a corner number
 262 m4_dnl    expands to an array of corners as for RoundCorner
 263 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 264
 265 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 266 m4_define(`INREFFRAME',`
 267   length_vec = ($2) - ($1);
 268   length = dist2d([0,0], length_vec);
 269   length_uvec = length_vec / length;
 270   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 271   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 272         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 273         [ 0,              0,              1,            0, ],
 274         [ 0,              0,              0,            1, ] ];
 275   $3
 276   multmatrix(m)
 277 ')
 278
 279 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 280 m4_dnl    INREFFRAME_EDGE { body; }
 281 m4_define(`INREFFRAME_EDGE',`
 282   translate([0,0, -round_edge_rad])
 283 ')
 284
 285 module RoundEdge(left_cnr, right_cnr) {
 286   INREFFRAME(left_cnr, right_cnr)
 287     INREFFRAME_EDGE {
 288     difference(){
 289       rotate([0,90,0])
 290         cylinder(r= round_edge_rad, h= length, $fn=50);
 291       translate([-1, 0, -20])
 292         cube([length+2, 20, 20]);
 293     }
 294   }
 295 }
 296
 297 m4_define(`ROUNDCORNER_VARS',`
 298   this_cnr = ci[0];
 299   right_cnr = ci[1];
 300   left_cnr = ci[2];
 301   bigr= round_cnr_rad - round_edge_rad;
 302   l_uvec = unitvector2d(left_cnr - this_cnr);
 303   r_uvec = unitvector2d(right_cnr - this_cnr);
 304   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 305   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 306   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 307   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 308   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 309   ctr3 = concat(ctr,[0])
 310 ')
 311
 312 module RoundCorner_selector(ci, adj) {
 313   ROUNDCORNER_VARS;
 314   intersection(){
 315     union(){
 316       INREFFRAME(ctr3,concat(lp1,[4])){
 317         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 318           translate([-bigr*2 + adj, -bigr])
 319             square([bigr*2, bigr*3]);
 320         }
 321       }
 322     }
 323     union(){
 324       INREFFRAME(ctr3,concat(lp4,[0])){
 325         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 326           translate([-bigr*2, -bigr*2])
 327             square([bigr*2 + adj, bigr*3]);
 328         }
 329       }
 330     }
 331   }
 332 }
 333
 334 module RoundCornerCut(ci) {
 335   // ci should be [this_cnr, right_cnr, left_cnr]
 336   // where right_cnr is to the right (ie, anticlockwise)
 337   ROUNDCORNER_VARS;
 338   difference(){
 339     RoundCorner_selector(ci, -0.1);
 340     translate(ctr3)
 341       cylinder(center=true, h=20, r= bigr);
 342   }
 343 }
 344
 345 module RoundCornerAdd(ci) {
 346   ROUNDCORNER_VARS;
 347   intersection(){
 348     RoundCorner_selector(ci, +0.1);
 349     INREFFRAME_EDGE {
 350       translate(ctr3){
 351         rotate_extrude(convexity=10, $fn=50)
 352           translate([bigr, 0])
 353           difference(){
 354           circle(r= round_edge_rad, $fn=50);
 355           mirror([1,1])
 356             square([20,20]);
 357         }
 358       }
 359     }
 360   }
 361 }
 362
 363 module InterlockLobePlan(negative) {
 364   r = negative ? interlock_negative_rad : interlock_rad;
 365   ymir = negative ? 0 : 1;
 366
 367   dx = sqrt(3) * r;
 368   $fn= 80;
 369   translate([thehd[0], 0]){
 370     mirror([0,ymir]){
 371       circle(r=r);
 372       difference(){
 373         translate([-dx, -0.1])
 374           square([ dx*2, r/2 + 0.1 ]);
 375         for (xi = [-1, 1]) {
 376           translate([ xi*dx, r ])
 377             circle(r=r);
 378         }
 379       }
 380     }
 381   }
 382 }
 383
 384 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 385   for (lobei = [ 0 : nlobes-1 ]) {
 386     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 387     translate([lobex, 0, 0]) {
 388       InterlockLobePlan(negative);
 389     }
 390   }
 391
 392   if (dosquare) {
 393     iadj = 0;
 394     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 395     mirror([0, negative])
 396       translate([slotshorter, iadj])
 397       square([length - slotshorter*2, interlock_fine + iadj*2]);
 398   }
 399 }
 400
 401 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 402   plusth = negative * 1.0;
 403   protr = interlock_fine + interlock_sq_adj;
 404
 405   z2 = -tile_th/2;
 406   z1 = -tile_th/2 - protr / interlock_fine_slope;
 407   z3 = -tile_th/2 + protr / interlock_fine_slope;
 408
 409   negsign = negative ? -1 : +1;
 410   yprotr = negsign * protr;
 411
 412   INREFFRAME(left_cnr, right_cnr) {
 413     for (vsect = [ // zs0            zs1      ys0,            ys1
 414                   [ -tile_th-plusth, plusth,  0,              0],
 415                   [ z1,              z2,      0, yprotr],
 416                   [ z2,              z3,      yprotr, 0],
 417                   ]) {
 418       zs0 = vsect[0];
 419       zs1 = vsect[1];
 420       zsd = zs1-zs0;
 421       ys0 = vsect[2];
 422       ys1 = vsect[3];
 423       ysd = ys1-ys0;
 424       sl = ysd/zsd;
 425       m = [ [ 1,0,   0,    0 ],
 426             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 427             [ 0,0,   1,  zs0 ],
 428             [ 0,0,   0,    1 ] ];
 429       multmatrix(m)
 430         linear_extrude(height=zsd, convexity=10)
 431         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 432     }
 433   }
 434 }
 435
 436 function TestPiece_holes2corners(holes) =
 437   [ holes[0] + thehd_bl,
 438     holes[1] + thehd_br,
 439     holes[1] + thehd_tr,
 440     holes[0] + thehd_tl ];
 441
 442 module TestPiece1(){ ////toplevel
 443   holes = [ [-100, 0],
 444             [   0, 0]
 445             ];
 446   corners = TestPiece_holes2corners(holes);
 447   rcs = R_CNR(corners,0);
 448   difference(){
 449     union(){
 450       TileBase(corners[0], corners[2]);
 451       Posts(holes);
 452       RoundEdge(corners[0], corners[1]);
 453       RoundEdge(corners[3], corners[0]);
 454     }
 455     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 456     RoundCornerCut(rcs);
 457     PostHoles(holes);
 458   }
 459   RoundCornerAdd(rcs);
 460 }
 461
 462 module TestPiece2(){ ////toplevel
 463   holes = [ [   0, 0],
 464             [  50, 0]
 465             ];
 466   corners = TestPiece_holes2corners(holes);
 467   difference(){
 468     union(){
 469       TileBase(corners[0], corners[2]);
 470       Posts(holes);
 471       RoundEdge(corners[0], corners[1]);
 472       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 473     }
 474     PostHoles(holes);
 475   }
 476 }
 477
 478 module TestDemo(){ ////toplevel
 479   translate([ -thehd[0], 0 ])
 480     color("blue")
 481     TestPiece1();
 482   translate([ +thehd[0] + demo_slop, 0 ])
 483     TestPiece2();
 484 }
 485
 486 module PostTestPiece(){ ////toplevel
 487   hole_sizes = [2.8, 3.0, 3.1, 3.134, 3.168, 3.2, 3.3, 3.5];
 488   nholes = len(hole_sizes)*2;
 489   nrows = 4;
 490   stride = post_dia*1.5;
 491   rect_sz = stride * [ nrows,
 492                        ceil(nholes/nrows) ];
 493   corners = Rectangle_corners(-stride * 0.5 * [1,1], rect_sz);
 494   difference(){
 495     union(){
 496       TileBase(corners[0], corners[2]);
 497       RoundEdge(corners[0], corners[1]);
 498       for (i= [ 0: nholes-1 ]) {
 499         $screw_dia = hole_sizes[ floor(i/2) ];
 500         translate(stride * [ (nrows-1) - (i % nrows),
 501                              floor(i / nrows),
 502                              0
 503                              ]) {
 504           Posts([[0,0]]);
 505           color("blue")
 506             mirror([0,0,1])
 507             translate([post_dia/2, -post_dia/2, 1])
 508             cube([1, post_dia * (i / nholes), tile_th]);
 509         }
 510       }
 511     }
 512   }
 513 }
 514
 515 module Machine_NewRearProfile(){
 516   // figures copied out of xfig edit boxes
 517   // best not to edit the posbox size if poss - just move it
 518   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 519   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 520   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 521   scaleline_mm = 12+5+10+5+3;
 522   sh = -[abs(posbox[0]), abs(posbox[1])];
 523   rot = atan2(-sideline[0], sideline[1]);
 524   sc = scaleline_mm / scaleline;
 525   //echo("SH",sh,rot,sc);
 526   scale(sc) rotate(rot) translate(sh){
 527     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 528   }
 529 }
 530
 531 module Machine_NewFrontProfile(){
 532   // figures copied out of xfig edit boxes
 533   // best not to edit the posbox size if poss - just move it
 534   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 535   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 536   refline_mm = (11-1)*10;
 537   sh = -[abs(posbox[0]), abs(posbox[1])];
 538   rot = atan2(-refline[0], refline[1]);
 539   sc = refline_mm / vectorlen2d(refline);
 540   //echo("SH",sh,rot,sc);
 541   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 542     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 543   }
 544 }
 545
 546 module Machine_NewEndProfile(){
 547   // figures copied out of xfig edit boxes
 548   // NB that y coords are reversed - xfig origin is at bottom left
 549   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 550   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 551   refline_mm = 10 * (11 - 2.5);
 552   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 553                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 554   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 555
 556   rot_adj = -0.38;
 557
 558   posbox = [min(posboxs[0][0],posboxs[1][0]),
 559             max(posboxs[0][1],posboxs[1][1])];
 560
 561   m4_define(`MNEP_ELP',
 562      `line_intersection_2d(baseline[0],baseline[1],
 563                            sidelines[$1][0],sidelines[$1][1])')
 564   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 565
 566   rot = atan2(-refline[1], -refline[0]);
 567   sc = refline_mm / vectorlen2d(refline);
 568   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 569
 570   ellen = sc * dist2d(endline[0],endline[1]);
 571   scy = cutout_l_end_y_total / ellen;
 572
 573   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 574
 575     mirror([0,1]){
 576   //%translate(1 * (posboxs[0] - posbox)) square(50);
 577   //%translate(1 * (posboxs[1] - posbox)) square(50);
 578 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 579
 580 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 581 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 582
 583 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 584 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 585 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 586 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 587     }
 588
 589     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 590   }
 591 }
 592
 593 module Machine_NewEndProfileDemo(){ ////toplevel
 594     translate([0,5,0])                             Machine_NewEndProfile();
 595     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 596   mirror([0,1,0]){
 597     translate([0,5, 0])                             Machine_NewEndProfile();
 598     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 599   }
 600 }
 601
 602 module Machine_NewArm(){
 603   translate([0,0,-30]) linear_extrude(height=60) {
 604     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 605                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 606       rotate(-90){
 607         hull(){
 608           for (d=[0,400])
 609             translate([0,d]) Machine_NewEndProfile();
 610         }
 611       }
 612     }
 613   }
 614 }
 615
 616 module Machine_NewRearCurve(){
 617   slant = atan2(4,210-10);
 618   //echo("SL",slant);
 619   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 620     translate([ rearcurve_double_inrad,
 621                 0,
 622                 -rearcurve_double_inrad + 10 ]){
 623       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 624         hull(){
 625           Machine_NewRearProfile();
 626           translate([0,-100]) Machine_NewRearProfile();
 627         }
 628       }
 629     }
 630     rotate([0,90,0]) rotate([90,0,0]) {
 631       intersection(){
 632         rotate_extrude(convexity=10, $fn=64)
 633           rotate(90)
 634           translate([ 0, -rearcurve_double_inrad ])
 635           Machine_NewRearProfile();
 636         translate([0,0,-500])
 637           cube([500,500,1000]);
 638       }
 639     }
 640     translate([1,0,-rearcurve_double_inrad])
 641       rotate([0,-90,0]) rotate([0,0,-90])
 642       linear_extrude(height= rearcurve_strt_len + 1)
 643       Machine_NewRearProfile();
 644   }
 645 }
 646
 647 module Machine_Curves(){ ////toplevel
 648   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 649               cutout_tile11_y,
 650               0 ]){
 651     //%cube([20,20,20]);
 652     translate([ -reartablet_x,
 653                 -1,
 654                 -reartablet_z + tablet_z_slop])
 655       mirror([0,0,1])
 656       cube([ reartablet_x+1,
 657              reartablet_y+1,
 658              20 ]);
 659   }
 660   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 661               cutout_tile11_y,
 662               frontcurve_z_slop ]){
 663     translate([0, -machine_rear_to_front, 0])
 664       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 665                   [0,  1,   0, 0],
 666                   [0,  0,   1, 0],
 667                   [0,  0,   0, 1]])
 668       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 669       linear_extrude(height= 200)
 670       Machine_NewFrontProfile();
 671   }
 672   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 673               cutout_tile11_y,
 674               frontcurve_z_slop ]){
 675     translate([ rearcurve_strt_len,
 676                 0,
 677                 rearcurve_z_slop ]){
 678       Machine_NewRearCurve();
 679     }
 680   }
 681 }
 682
 683 module TestStrapSlots(){
 684   pegwidth = teststrap_peg[0];
 685   for (pos = teststrapslots_at) {
 686     echo("TSS",pos);
 687     translate(concat(pos,[0]))
 688       for (mx = [0,1]) mirror([mx,0,0]) {
 689           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 690             cube(concat(teststrap,[40]));
 691         }
 692   }
 693 }
 694
 695 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 696
 697 module TestStrapPeg_Short(){ ////toplevel
 698   TestStrapPeg_any(35);
 699 }
 700
 701 module TestStrapPeg_Long(){ ////toplevel
 702   TestStrapPeg_any(60);
 703 }
 704
 705 module Machine(){ ////toplevel
 706   Machine_NewArm();
 707   Machine_Curves();
 708   if (TEST)
 709     TestStrapSlots();
 710 }
 711
 712 module MachineEnvelope(){
 713   // used for testing
 714   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 715   y_arm_t  = cutout_tile11_y;
 716   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 717   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 718
 719   translate([0,0,-50]) linear_extrude(height= 100){
 720     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 721     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 722   }
 723 }
 724
 725 module Leg(){ ////toplevel
 726   difference(){
 727     union(){
 728       hull(){
 729         mirror([0,0,1])
 730           cylinder(r= leg_big_dia/2, h=leg_top_flat_z, $fn=100);
 731         translate([0,0, -leg_top_thick])
 732           cylinder(r= leg_bot_dia/2, height=1, $fn=100);
 733       }
 734       if (!TEST)
 735         translate([0,0,-leg_height])
 736           cylinder(r= leg_bot_mid_dia/2, h=leg_bot_thick);
 737       for (rot=[0: 360/leg_n_fins : 359]) rotate(rot) {
 738           hull(){
 739             mirror([0,0,1]) translate([0, -leg_fin_top_w/2, 0])
 740               cube([ leg_fin_top_rad - 0.1,
 741                      leg_fin_top_w,
 742                      1 ])
 743               ;
 744             translate([0, -leg_fin_bot_w/2, -leg_height])
 745               cube([ leg_fin_bot_rad,
 746                      leg_fin_bot_w,
 747                      leg_fin_bot_flat_z ]);
 748           }
 749         }
 750     }
 751     mirror([0,0,1]) translate([0,0,-1])
 752       cylinder(r= leg_hole_dia/2,
 753                h= (!TEST ? leg_height+2 : leg_height/2),
 754                $fn=30);
 755     mirror([0,0,1]) translate([0,0,leg_top_thick - 0.1])
 756       hull(){
 757         cylinder(r= (!TEST ? leg_midspc_dia/2 : 0.1),
 758                  h= leg_height - leg_top_thick - leg_bot_thick + 0.2,
 759                  $fn=30);
 760         if (TEST)
 761           cylinder(r= leg_midspc_dia/2,
 762                    h= leg_height - leg_top_thick - leg_bot_thick
 763                       + (!TEST ? 0.2 : -leg_midspc_dia/2),
 764                    $fn=30);
 765       }
 766     if (!TEST)
 767       for (rot=[45: 360/leg_n_tubules : 359]) rotate(rot) {
 768           mirror([0,0,1]) translate([ leg_tubule_pos_rad, 0, -1])
 769             cylinder(r= leg_tubule_dia/2, h=leg_height+2, $fn=20);
 770         }
 771   }
 772 }
 773
 774 function Rectangle_corners(c0, sz) =
 775   // returns the corners of a rectangle from c0 to c0+sz
 776   // if sz is positive, the corners are anticlockwise starting with c0
 777   [ c0 + [ 0,     0     ],
 778     c0 + [ sz[0], 0     ],
 779     c0 + [ sz[0], sz[1] ],
 780     c0 + [ 0,     sz[1] ] ];
 781
 782 function Rectangle_corners2posts(c) =
 783   [ c[0] + thehd_tr,
 784     c[1] + thehd_tl,
 785     c[2] + thehd_bl,
 786     c[3] + thehd_br ];
 787
 788 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 789
 790 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 791
 792 module Tile02(){ ////toplevel
 793   sz = [100,170];
 794   c0 = tile02_tr + -sz;
 795   c = Rectangle_corners(c0, sz);
 796   posts = Rectangle_corners2posts(c);
 797   rcs = R_CNR(c,0);
 798   difference(){
 799     union(){
 800       Rectangle_TileBase(c);
 801       Posts(posts);
 802       RoundEdge(R_EDGE(c,0));
 803       RoundEdge(R_EDGE(c,3));
 804       InterlockEdge(R_EDGE(c,2), 0);
 805     }
 806     InterlockEdge(R_EDGE(c,1), 1);
 807     RoundCornerCut(rcs);
 808     PostHoles(posts);
 809   }
 810   RoundCornerAdd(rcs);
 811 }
 812
 813 module Tile12(){ ////toplevel
 814   sz = [100,250];
 815   c0 = tile02_tr + [-sz[0], 0];
 816   c = Rectangle_corners(c0, sz);
 817   posts = Rectangle_corners2posts(c);
 818   rcs = R_CNR(c,3);
 819   difference(){
 820     union(){
 821       Rectangle_TileBase(c);
 822       Posts(posts);
 823       RoundEdge(R_EDGE(c,2));
 824       RoundEdge(R_EDGE(c,3));
 825     }
 826     InterlockEdge(R_EDGE(c,0), 1);
 827     InterlockEdge(R_EDGE(c,1), 1);
 828     RoundCornerCut(rcs);
 829     PostHoles(posts);
 830   }
 831   RoundCornerAdd(rcs);
 832 }
 833
 834 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 835 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 836 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 837
 838 module Tile11(){ ////toplevel
 839   sz = [250,250];
 840   c0 = tile01_tr + [-sz[0],0];
 841   c = Rectangle_corners(c0, sz);
 842   cnr_posts = Rectangle_corners2posts(c);
 843   posts = concat(
 844                  Posts_interpolate_one(cnr_posts[0],
 845                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 846                  [ cnr_posts[1] + [0, cutout_tile11_y],
 847                    cnr_posts[2],
 848                    cnr_posts[3]
 849                    ]);
 850   difference(){
 851     union(){
 852       Rectangle_TileBase(c);
 853       Posts(posts);
 854       RoundEdge(R_EDGE(c,2));
 855       InterlockEdge(R_EDGE(c,3));
 856     }
 857     InterlockEdge(c[0], tile_01_11_cnr, 1);
 858     InterlockEdge(tile_11_10_cnr, c[2], 1);
 859     PostHoles(posts);
 860     Machine();
 861   }
 862 }
 863
 864 module Tile01(){ ////toplevel
 865   sz = [250,170];
 866   c0 = tile01_tr + -sz;
 867   c = Rectangle_corners(c0, sz);
 868   cnr_posts = Rectangle_corners2posts(c);
 869   posts = concat(
 870                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 871                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 872                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 873                                        cnr_posts[3])
 874                  );
 875   difference(){
 876     union(){
 877       Rectangle_TileBase(c);
 878       Posts(posts);
 879       RoundEdge(R_EDGE(c,0));
 880       InterlockEdge(tile_01_11_cnr, c[3]);
 881       InterlockEdge(R_EDGE(c,3));
 882     }
 883     PostHoles(posts);
 884     InterlockEdge(c[1], tile_01_00_cnr, 1);
 885     Machine();
 886   }
 887 }
 888
 889 module Tile10(){ ////toplevel
 890   sz = [250,250];
 891   c0 = tile01_tr + [0,0];
 892   c = Rectangle_corners(c0, sz);
 893   cnr_posts = Rectangle_corners2posts(c);
 894   cty = cutout_tile11_y;
 895   rcy = cty + rearcurve_avoid_y;
 896   posts = [ cnr_posts[0] + [ 0,                             cty ],
 897             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 898             cnr_posts[1] + [ 0,                             rcy ],
 899             cnr_posts[2],
 900             cnr_posts[3] ];
 901   rcs = R_CNR(c,2);
 902   difference(){
 903     union(){
 904       Rectangle_TileBase(c);
 905       Posts(posts);
 906       RoundEdge(R_EDGE(c,1));
 907       RoundEdge(R_EDGE(c,2));
 908       InterlockEdge(c[3], tile_11_10_cnr);
 909     }
 910     PostHoles(posts);
 911     RoundCornerCut(rcs);
 912     Machine();
 913   }
 914   RoundCornerAdd(rcs);
 915 }
 916
 917 module Tile00(){ ////toplevel
 918   sz = [250,170];
 919   c0 = tile01_tr + [0,-sz[1]];
 920   c = Rectangle_corners(c0, sz);
 921
 922   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 923   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 924   c1bis = [ c[1][0],
 925             c[2][1] -
 926             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 927
 928   cnr_posts = Rectangle_corners2posts(c);
 929   cty = cutout_tile01_y;
 930   rcy = cty + frontcurve_avoid_y;
 931   posts = [ cnr_posts[0],
 932             cnr_posts[1],
 933             0.5 * (cnr_posts[0] + cnr_posts[1]),
 934             cnr_posts[2] + [ 0,                             -rcy ],
 935             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 936             cnr_posts[3] + [ 0,                             -cty ]
 937             ];
 938   rcs = R_CNR(c,1);
 939   rc2 = [c1bis,c2bis,c[1]];
 940   difference(){
 941     union(){
 942       difference(){
 943         union(){
 944           Rectangle_TileBase(c);
 945           Posts(posts);
 946           RoundEdge(R_EDGE(c,0));
 947           RoundEdge(c[1], c1bis);
 948           InterlockEdge(tile_01_00_cnr, c[0]);
 949         }
 950         RoundCornerCut(rcs);
 951         translate([0,0,-20]) linear_extrude(height=40) {
 952           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 953         }
 954       }
 955       RoundEdge(c1bis, c2bis);
 956     }
 957     Machine();
 958     PostHoles(posts);
 959     RoundCornerCut(rc2);
 960   }
 961   RoundCornerAdd(rcs);
 962   RoundCornerAdd(rc2);
 963 }
 964
 965 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 966   c = Rectangle_corners(c0, sz);
 967   brace = [7,7,9];
 968   bsz = sz + [bracexx,0,0];
 969   difference(){
 970     union(){
 971       Rectangle_TileBase(c);
 972       if (dobrace) {
 973         translate(concat(c0, [-brace[2] + 0.1])){
 974           difference(){
 975             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 976             translate(brace + [0,0, -25])
 977               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 978           }
 979         }
 980       }
 981       RoundEdge(R_EDGE(c,1));
 982     }
 983     Machine();
 984   }
 985 }
 986
 987 module FitTest_PairLink(cut=false){ ////toplevel
 988   cy0=-55; cy1=85; cx=132;
 989   bar = [10,10];
 990   legrad = 12;
 991   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 992   strap = [3,5];
 993   adj_neg_slop = 1.0;
 994   bar_z_slop = 1.75;
 995
 996   // calculated
 997   straphole_x_max = legrad/sqrt(2) + footrad_max;
 998   dz = cut ? adj_neg_slop : 0;
 999
1000   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
1001     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
1002
1003   for (endy=[cy0,cy1]) {
1004     $fn=32;
1005     translate([cx,endy,dz]){
1006       // feet
1007       for (rot=[45:90:315]) rotate(rot) {
1008         translate([legrad,0,0]){
1009           hull(){
1010             cylinder(r= footrad_max, h=1);
1011             translate([0,0,-footrad_depth])
1012               cylinder(r= footrad_min, h=1);
1013           }
1014           if (cut)
1015             translate([0,0,-10])
1016             cylinder(r= footrad_min +
1017                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
1018                      h=20);
1019         }
1020       }
1021       // legs
1022       for (rot=[45,135]) rotate(rot) {
1023         hull(){
1024           for (s=[-1,+1]){
1025             translate([s*legrad,0,0])
1026               cylinder(r= footrad_max, h=bar[1]);
1027           }
1028         }
1029       }
1030       // strap holes
1031       if (cut) {
1032         for (rot=[0,180]) rotate(rot) {
1033             translate([ straphole_x_max - strap[0]/2, 0,0 ])
1034               cube(concat(strap,[20]), center=true);
1035           }
1036       }
1037     }
1038   }
1039 }
1040
1041 module FitTest_RearCurve(){ ////toplevel
1042   difference(){
1043     FitTest_general([100,0], [180,100]);
1044     FitTest_PairLink(true);
1045     TestStrapSlots();
1046   }
1047 }
1048
1049 module FitTest_FrontCurve(){ ////toplevel
1050   p0 = [100,-80];
1051   sz = [180,80];
1052   difference(){
1053     intersection() {
1054       Tile00();
1055       translate([0,0,-8]) linear_extrude(height=18) {
1056         translate(p0) square(sz);
1057         translate(teststrapslots_at[3])
1058           scale(2* [ teststrap_peg[0], teststrap[1] ])
1059           circle(r=1, $fn=20);
1060       }
1061     }
1062     FitTest_PairLink(true);
1063     TestStrapSlots();
1064   }
1065 }
1066
1067 module FitTest_Entire(){ ////toplevel
1068   p0 = [-33,-80];
1069   szrear = [263,180];
1070   szfront = [243,szrear[1]];
1071   difference(){
1072     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
1073     FitTest_PairLink(true);
1074     translate(concat(p0,[0]) + [szfront[0],-10,-40])
1075       cube([100, -p0[1], 80]);
1076     TestStrapSlots();
1077   }
1078   intersection(){
1079     FitTest_RearCurve();
1080     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
1081   }
1082   FitTest_FrontCurve();
1083 }
1084
1085 module FitTest_EntireDemo(){ ////toplevel
1086   FitTest_Entire();
1087   //%Tile00();
1088 }
1089
1090 module FitTest_EndEnd(){ ////toplevel
1091   p0 = [-30,-32];
1092   sz = [156,81] - p0;
1093   sz2 = [136,68] - p0;
1094   difference(){
1095     FitTest_general(p0, sz);
1096     translate([ p0[0] -1, p0[1]+sz2[1], -10])
1097       cube([ sz2[0] +1, 50, 20 ]);
1098   }
1099 }
1100
1101 module FitTest_PairDemo(){ ////toplevel
1102   sh=[-90,-15,0];
1103   translate(sh){
1104     FitTest_PairLink();
1105     %FitTest_FrontCurve();
1106     %FitTest_RearCurve();
1107   }
1108   rotate([0,0,180]){
1109     translate(sh){
1110       difference(){
1111         union(){
1112           FitTest_FrontCurve();
1113           FitTest_RearCurve();
1114         }
1115         #FitTest_PairLink(true);
1116       }
1117     }
1118   }
1119 }
1120
1121 module RoundCornerDemo_plat(cnr){
1122   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1123 }
1124
1125 module RoundCornerDemo(){ ////toplevel
1126   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1127   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1128   translate([25,0,0]) RoundCornerAdd(cnr);
1129   translate([-25,0,0]) RoundCornerCut(cnr);
1130   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1131   difference(){
1132     RoundCornerDemo_plat(cnr);
1133     RoundCornerCut(cnr);
1134   }
1135   RoundCornerAdd(cnr);
1136 }
1137
1138 module Demo(){ ////toplevel
1139   translate(demo_slop*[-2,1]) color("blue") Tile12();
1140   translate(demo_slop*[-2,0]) color("red")  Tile02();
1141   translate(demo_slop*[-2,1]) color("orange") Tile11();
1142   translate(demo_slop*[-2,0]) color("purple") Tile01();
1143   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1144   translate(demo_slop*[-3,0]) color("red")    Tile00();
1145   %Machine();
1146   // Can also do this, to print reference sheet:
1147   //  load this into openscad
1148   //  select Ctrl-4 view, view all, scale appropriately
1149   //  import sewing-table,Demo-flat.png
1150   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1151   //  lpr t.pnm
1152 }
1153
1154 //TestPiece1();
1155 //TestPiece2();
1156 //Demo();
1157
1158 //Machine_NewRearProfile();
1159 //Machine_NewRearCurve();
1160 //Machine_NewFrontProfile();
1161 //Machine_NewEndProfile();
1162 //Machine_NewEndProfileDemo();
1163 //Machine_Curves();
1164 //Machine();
1165 //FitTest();
1166 //MachineEnvelope();