sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 interlock_dia = 10;
  22
  23 // calculated
  24
  25 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
  26
  27 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
  28
  29 hole_slop = (ply_hole_dia - post_dia)/2;
  30 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
  31
  32 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
  33          tile_hard_edge_hole_dist));
  34
  35 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
  36          tile_hard_edge_hole_dist + round_edge_rad));
  37
  38 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
  39 thehd_tr = thehd;
  40 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
  41 thehd_bl = -thehd_tr;
  42 thehd_br = -thehd_tl;
  43
  44 interlock_rad = interlock_dia/2;
  45 interlock_negative_rad = interlock_rad + 0.125;
  46
  47 module Post(){
  48   mirror([0,0,1]) {
  49     difference(){
  50       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
  51       translate([0,0, tile_th]) {
  52         cylinder(r= screw_big_dia/2, h= screw_big_len);
  53         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
  54       }
  55     }
  56   }
  57 }
  58
  59 module Posts(posts) {
  60   for (p= posts) {
  61     translate(concat(p, [0]))
  62       Post();
  63   }
  64 }
  65
  66 module TileBase(botleft, topright){
  67   size = topright - botleft;
  68   botleft_post = botleft + thehd_tr;
  69   topright_post = topright + thehd_bl;
  70   difference(){
  71     mirror([0,0,1])
  72       translate(concat(botleft, [0]))
  73       cube(concat(size, [tile_th]));
  74     translate( concat(botleft_post, [-tile_th])
  75                + 0.5 * [ post_dia, post_dia, 0 ] )
  76       Commitid_BestCount_M( topright_post-botleft_post
  77                             + [-post_dia,-post_dia]
  78                             + [0, thehd[1]]);
  79   }
  80 }
  81
  82 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
  83 m4_define(`INREFFRAME',`
  84   length_vec = ($2) - ($1);
  85   length = dist2d([0,0], length_vec);
  86   length_uvec = length_vec / length;
  87   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
  88   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
  89         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
  90         [ 0,              0,              1,            0, ],
  91         [ 0,              0,              0,            1, ] ];
  92   $3
  93   multmatrix(m)
  94 ')
  95
  96 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
  97 m4_dnl    INREFFRAME_EDGE { body; }
  98 m4_define(`INREFFRAME_EDGE',`
  99   translate([0,0, -round_edge_rad])
 100 ')
 101
 102 module RoundEdge(left_cnr, right_cnr) {
 103   INREFFRAME(left_cnr, right_cnr)
 104     INREFFRAME_EDGE {
 105     difference(){
 106       rotate([0,90,0])
 107         cylinder(r= round_edge_rad, h= length, $fn=50);
 108       translate([-1, 0, -20])
 109         cube([length+2, 20, 20]);
 110     }
 111   }
 112 }
 113
 114 module RoundLeftCorner(this_cnr, right_cnr) {
 115   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 116     difference(){
 117       sphere(r= round_edge_rad, $fn=60);
 118       translate([0,0, -20])
 119         cube([20,20,20]);
 120     }
 121   }
 122 }
 123
 124 module InterlockLobePlan(r, ymir) {
 125   dx = sqrt(3) * r;
 126   $fn= 80;
 127   translate([thehd[0], 0]){
 128     mirror([0,ymir,0]){
 129       circle(r=r);
 130       difference(){
 131         translate([-dx, -0.1])
 132           square([ dx*2, r/2 + 0.1 ]);
 133         for (xi = [-1, 1]) {
 134           translate([ xi*dx, r ])
 135             circle(r=r);
 136         }
 137       }
 138     }
 139   }
 140 }
 141
 142 module InterlockLobeCore(negative=0) {
 143   r = negative ? interlock_negative_rad : interlock_rad;
 144   plusth = negative * 1.0;
 145   ymir = negative ? 0 : 1;
 146   translate([0, 0, plusth]){
 147     mirror([0,0,1]){
 148       linear_extrude(height=tile_th+plusth*2, convexity=10){
 149         InterlockLobePlan(r, ymir);
 150       }
 151     }
 152   }
 153 }
 154
 155 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 156   INREFFRAME(left_cnr, right_cnr) {
 157     for (lobei = [ 0 : nlobes-1 ]) {
 158       lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 159       translate([lobex, 0, 0])
 160         InterlockLobeCore(negative);
 161     }
 162   }
 163 }
 164
 165 function TestPiece_holes2corners(holes) =
 166   [ holes[0] + thehd_bl,
 167     holes[1] + thehd_br,
 168     holes[1] + thehd_tr,
 169     holes[0] + thehd_tl ];
 170
 171 module TestPiece1(){ ////toplevel
 172   holes = [ [-100, 0],
 173             [   0, 0]
 174             ];
 175   corners = TestPiece_holes2corners(holes);
 176   difference(){
 177     TileBase(corners[0], corners[2]);
 178     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 179   }
 180   Posts(holes);
 181   RoundEdge(corners[0], corners[1]);
 182   RoundEdge(corners[3], corners[0]);
 183   RoundLeftCorner(corners[0], corners[1]);
 184 }
 185
 186 module TestPiece2(){ ////toplevel
 187   holes = [ [   0, 0],
 188             [  50, 0]
 189             ];
 190   corners = TestPiece_holes2corners(holes);
 191   TileBase(corners[0], corners[2]);
 192   Posts(holes);
 193   RoundEdge(corners[0], corners[1]);
 194   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 195 }
 196
 197 module TestDemo(){ ////toplevel
 198   translate([ -thehd[0], 0 ])
 199     color("blue")
 200     TestPiece1();
 201   translate([ +thehd[0], 0 ])
 202     TestPiece2();
 203 }
 204
 205 function Rectangle_corners(c0, sz) =
 206   [ c0 + [ 0,     0     ],
 207     c0 + [ sz[0], 0     ],
 208     c0 + [ sz[0], sz[1] ],
 209     c0 + [ 0,     sz[1] ] ];
 210
 211 function Rectangle_corners2posts(c) =
 212   [ c[0] + thehd_tr,
 213     c[1] + thehd_tl,
 214     c[2] + thehd_bl,
 215     c[3] + thehd_br ];
 216
 217 module Tile02(){ ////toplevel
 218   sz = [100,170];
 219   c0 = -sz;
 220   c = Rectangle_corners(c0, sz);
 221   posts = Rectangle_corners2posts(c);
 222   difference(){
 223     TileBase(c[0], c[2]);
 224   }
 225   Posts(posts);
 226   RoundEdge(c[0], c[1]);
 227   RoundEdge(c[3], c[0]);
 228   RoundLeftCorner(c[0], c[1]);
 229   InterlockEdge(c[2], c[3], 0, 2);
 230 }
 231
 232 module Tile12(){ ////toplevel
 233   sz = [100,250];
 234   c0 = [-sz[0], 0];
 235   c = Rectangle_corners(c0, sz);
 236   posts = Rectangle_corners2posts(c);
 237   difference(){
 238     TileBase(c[0], c[2]);
 239   }
 240   Posts(posts);
 241   RoundEdge(c[2], c[3]);
 242   RoundEdge(c[3], c[0]);
 243   RoundLeftCorner(c[2], c[3]);
 244 }
 245
 246 module Demo(){ ////toplevel
 247   color("blue") Tile12();
 248   color("red")  Tile02();
 249 }
 250
 251 //TestPiece1();
 252 //TestPiece2();
 253 //Demo();