chiark / gitweb /
80d86c84e3dc2d2c09aec5b2201c1b1c0c354642
[reprap-play.git] / sewing-table.scad.m4
1 // -*- C -*-
2
3 include <funcs.scad>
4 include <commitid.scad>
5
6 ply_th = 18;
7 ply_hole_dia = 15;
8 ply_edge_min = 10;
9
10 tile_th = 3;
11 post_dia = 8;
12
13 post_shorter = 1;
14
15 screw_dia = 2.2;
16 screw_big_dia = 3.6;
17 screw_big_len = 4.0;
18
19 round_edge_rad = 2.0;
20
21 round_cnr_rad = 10;
22
23 interlock_dia = 10;
24 interlock_fine = 0.66;
25
26 interlock_fine_slope = 1.0;
27 interlock_fine_lenslop = 1.0;
28
29 demo_slop = 0.1;
30
31 // cutout
32
33 machine_rear_to_front = 85;
34
35 machine_rear_profile = [
36                         [ -  0,  -0.00 ],
37                         [ -  2,  -0.10 ],
38                         [ -  4,  -0.20 ],
39                         [ -  5,  -0.30 ],
40                         [ -  6,  -0.40 ],
41                         [ -  7,  -0.50 ],
42                         [ -  8,  -0.75 ],
43                         [ - 10,  -1.50 ],
44                         [ - 12,  -2.25 ],
45                         [ - 14,  -3.25 ],
46                         [ - 16,  -4.25 ],
47                         [ - 18,  -5.75 ],
48                         [ - 20,  -8.00 ]
49                         ];
50
51 machine_front_profile =  [
52                           [  128,  -3.70,  ],
53                           [  124,  -2.90,  ],
54                           [  120,  -2.45,  ],
55                           [  116,  -2.10,  ],
56                           [  112,  -1.80,  ],
57                           [  108,  -1.55,  ],
58                           [  104,  -1.25,  ],
59                           [  100,  -1.00,  ],
60                           [   96,  -0.80,  ],
61                           [   92,  -0.65,  ],
62                           [   88,  -0.55,  ],
63                           [   84,  -0.50,  ]
64                           ];
65
66 cutout_l_end_y_front_slop = 0.5;
67 cutout_l_end_y_rear_slop = 0.5;
68 cutout_l_end_x_slop = 0.25;
69
70 cutout_l_end_x = 22;
71 cutout_l_end_y = machine_rear_to_front;
72 cutout_l_end_curve = 1;
73 cutout_l_end_y_total = cutout_l_end_y
74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
75
76 tile02_tr = [-250, 0];
77 tile01_tr = [  0, 0];
78
79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
82
83 // front and rear curves
84
85 rearedge_len = 170;
86
87 rearcurve_strt_len = 52;
88
89 rearcurve_z_slop = 0.75;
90
91 rearcurve_avoid_y = 35;
92
93 rearcurve_double_inrad = 26.10 + 8.04;
94
95 reartablet_z = 2.54;
96 reartablet_x = 5 + 1;
97 reartablet_y = 5;
98
99 frontcurve_side_skew = 3.5 / 72;
100 frontcurve_avoid_y = 70;
101 frontcurve_z_slop = 0.75;
102
103 // calculated
104
105 TEST = false;
106
107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
108
109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
110
111 hole_slop = (ply_hole_dia - post_dia)/2;
112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
113
114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
115          tile_hard_edge_hole_dist));
116
117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
118          tile_hard_edge_hole_dist + round_edge_rad));
119
120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
121 thehd_tr = thehd;
122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
123 thehd_bl = -thehd_tr;
124 thehd_br = -thehd_tl;
125
126 interlock_rad = interlock_dia/2;
127 interlock_negative_rad = interlock_rad + 0.125;
128
129 interlock_sq_adj = 0.2; // arbitrary
130
131 first_front = machine_front_profile[len(machine_front_profile)-1];
132
133 m4_define(`POST_TCROSSSZ',
134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
135
136 module Post(){
137   mirror([0,0,1]) {
138     difference(){
139       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
140       translate([0,0, tile_th]) {
141         cylinder(r= screw_big_dia/2, h= screw_big_len);
142         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
143       }
144     }
145     if (TEST) {
146       translate([0,0, tile_th/2]) {
147         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
148         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
149       }
150     }
151   }
152 }
153
154 module Posts(posts) {
155   for (p= posts) {
156     translate(concat(p, [0]))
157       Post();
158   }
159 }
160
161 module TileBase(botleft, topright){
162   size = topright - botleft;
163   botleft_post = botleft + thehd_tr;
164   topright_post = topright + thehd_bl;
165   difference(){
166     mirror([0,0,1])
167       translate(concat(botleft, [0]))
168       cube(concat(size, [tile_th]));
169     if (!TEST) {
170       translate( concat(botleft_post, [ -tile_th ])
171                  + 0.5 * [ post_dia, post_dia, 0 ] )
172         Commitid_BestCount_M( topright_post-botleft_post
173                               + [-post_dia,-post_dia]
174                               + [0, thehd[1]]);
175     }
176     if (TEST) {
177       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
178       cidsz = [ size[0] - 2*crossoff, thehd[1] ];
179       translate( concat(botleft + [crossoff, 0] + cidsz, [0]) )
180         rotate([0,0,180])
181         Commitid_BestCount(cidsz);
182       difference(){
183         mirror([0,0,1]) {
184           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
185             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
186           translate(concat(botleft_post, [-1]))
187             cube(concat(topright_post-botleft_post, [tile_th+2]));
188         }
189         minkowski(){
190           Machine();
191           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
192         }
193       }
194     }
195   }
196 }
197
198 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
199 m4_define(`INREFFRAME',`
200   length_vec = ($2) - ($1);
201   length = dist2d([0,0], length_vec);
202   length_uvec = length_vec / length;
203   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
204   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
205         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
206         [ 0,              0,              1,            0, ],
207         [ 0,              0,              0,            1, ] ];
208   $3
209   multmatrix(m)
210 ')
211
212 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
213 m4_dnl    INREFFRAME_EDGE { body; }
214 m4_define(`INREFFRAME_EDGE',`
215   translate([0,0, -round_edge_rad])
216 ')
217
218 module RoundEdge(left_cnr, right_cnr) {
219   INREFFRAME(left_cnr, right_cnr)
220     INREFFRAME_EDGE {
221     difference(){
222       rotate([0,90,0])
223         cylinder(r= round_edge_rad, h= length, $fn=50);
224       translate([-1, 0, -20])
225         cube([length+2, 20, 20]);
226     }
227   }
228 }
229
230 module RoundCornerCut(ci) {
231   // ci should be [this_cnr, right_cnr]
232   // where right_cnr is to the right (ie, anticlockwise)
233   this_cnr = ci[0];
234   right_cnr = ci[1];
235   offr= round_cnr_rad - round_edge_rad;
236   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
237     difference(){
238       cube(offr*2 - 0.1, center=true);
239       translate([offr, offr, 0])
240         cylinder(center=true, h=20, r= offr);
241     }
242   }
243 }
244
245 module RoundCornerAdd(ci) {
246   this_cnr = ci[0];
247   right_cnr = ci[1];
248   bigr = round_cnr_rad - round_edge_rad;
249   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
250     intersection(){
251       cube(bigr*2 + 0.1, center=true);
252       translate([bigr, bigr, 0])
253         rotate_extrude(convexity=10, $fn=50)
254         translate([bigr, 0])
255         difference(){
256           circle(r= round_edge_rad, $fn=50);
257           mirror([1,1])
258             square([20,20]);
259         }
260     }
261   }
262 }
263
264 module InterlockLobePlan(negative) {
265   r = negative ? interlock_negative_rad : interlock_rad;
266   ymir = negative ? 0 : 1;
267
268   dx = sqrt(3) * r;
269   $fn= 80;
270   translate([thehd[0], 0]){
271     mirror([0,ymir]){
272       circle(r=r);
273       difference(){
274         translate([-dx, -0.1])
275           square([ dx*2, r/2 + 0.1 ]);
276         for (xi = [-1, 1]) {
277           translate([ xi*dx, r ])
278             circle(r=r);
279         }
280       }
281     }
282   }
283 }
284
285 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
286   for (lobei = [ 0 : nlobes-1 ]) {
287     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
288     translate([lobex, 0, 0]) {
289       InterlockLobePlan(negative);
290     }
291   }
292
293   if (dosquare) {
294     iadj = 0;
295     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
296     mirror([0, negative])
297       translate([slotshorter, iadj])
298       square([length - slotshorter*2, interlock_fine + iadj*2]);
299   }
300 }
301
302 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
303   plusth = negative * 1.0;
304   protr = interlock_fine + interlock_sq_adj;
305
306   z2 = -tile_th/2;
307   z1 = -tile_th/2 - protr / interlock_fine_slope;
308   z3 = -tile_th/2 + protr / interlock_fine_slope;
309
310   negsign = negative ? -1 : +1;
311   yprotr = negsign * protr;
312
313   INREFFRAME(left_cnr, right_cnr) {
314     for (vsect = [ // zs0            zs1      ys0,            ys1
315                   [ -tile_th-plusth, plusth,  0,              0],
316                   [ z1,              z2,      0, yprotr],
317                   [ z2,              z3,      yprotr, 0],
318                   ]) {
319       zs0 = vsect[0];
320       zs1 = vsect[1];
321       zsd = zs1-zs0;
322       ys0 = vsect[2];
323       ys1 = vsect[3];
324       ysd = ys1-ys0;
325       sl = ysd/zsd;
326       m = [ [ 1,0,   0,    0 ],
327             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
328             [ 0,0,   1,  zs0 ],
329             [ 0,0,   0,    1 ] ];
330       multmatrix(m)
331         linear_extrude(height=zsd, convexity=10)
332         InterlockEdgePlan(negative, nlobes, length, !!ysd);
333     }
334   }
335 }
336
337 function TestPiece_holes2corners(holes) =
338   [ holes[0] + thehd_bl,
339     holes[1] + thehd_br,
340     holes[1] + thehd_tr,
341     holes[0] + thehd_tl ];
342
343 module TestPiece1(){ ////toplevel
344   holes = [ [-100, 0],
345             [   0, 0]
346             ];
347   corners = TestPiece_holes2corners(holes);
348   rcs = [corners[0], corners[1]];
349   difference(){
350     union(){
351       TileBase(corners[0], corners[2]);
352       Posts(holes);
353       RoundEdge(corners[0], corners[1]);
354       RoundEdge(corners[3], corners[0]);
355     }
356     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
357     RoundCornerCut(rcs);
358   }
359   RoundCornerAdd(rcs);
360 }
361
362 module TestPiece2(){ ////toplevel
363   holes = [ [   0, 0],
364             [  50, 0]
365             ];
366   corners = TestPiece_holes2corners(holes);
367   TileBase(corners[0], corners[2]);
368   Posts(holes);
369   RoundEdge(corners[0], corners[1]);
370   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
371 }
372
373 module TestDemo(){ ////toplevel
374   translate([ -thehd[0], 0 ])
375     color("blue")
376     TestPiece1();
377   translate([ +thehd[0] + demo_slop, 0 ])
378     TestPiece2();
379 }
380
381 module Machine_Arm(){
382   ysz = cutout_l_end_y_total;
383   // assume the round end is arc of a circle
384   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
385   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
386   
387   translate([0,0,-30]) linear_extrude(height=60) {
388     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
389       intersection(){
390         translate([-100, -ysz/2])
391           square([400, ysz]);
392         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
393           circle(r=endrad, $fa=0.01,$fd=5);
394       }
395     }
396   }
397 }
398
399 module Machine_Profile(){
400   first_rear = machine_rear_profile[0];
401   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
402   pol = concat( machine_rear_profile,
403                 [ below_point ],
404                 machine_front_profile);
405   skew_angle = atan2( first_front[1] - first_rear[1],
406                       first_front[0] - first_rear[0] );
407   echo(below_point, pol, skew_angle);
408   hull(){
409     for (z=[0,-40]) {
410       translate([0,z]) {
411         //scale([1,5])
412         rotate([0,0, -skew_angle ]){
413           //translate( - first_front )
414           polygon(pol);
415         }
416       }
417     }
418   }
419 }
420
421 module Machine_RearProfile(){
422   intersection(){
423     Machine_Profile();
424     translate([ -200 + machine_rear_to_front/2, -100 ]) {
425       square([200,200]);
426     }
427   }
428 }
429
430 module Machine_FrontProfile(){
431   intersection(){
432     Machine_Profile();
433     translate([ machine_rear_to_front/2, -100 ]) {
434       square([200,200]);
435     }
436   }
437 }
438
439 module Machine_Curves(){ ////toplevel
440   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
441               cutout_tile11_y,
442               0 ]){
443     //%cube([20,20,20]);
444     translate([ -reartablet_x,
445                 -1,
446                 -reartablet_z])
447       mirror([0,0,1])
448       cube([ reartablet_x+1,
449              reartablet_y+1,
450              20 ]);
451   }
452   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
453               cutout_tile11_y,
454               frontcurve_z_slop ]){
455     translate([ 0, -first_front[0] , 0 ])
456       multmatrix([[1, -frontcurve_side_skew, 0, 0],
457                   [0,  1,   0, 0],
458                   [0,  0,   1, 0],
459                   [0,  0,   0, 1]])
460       translate([ 0, first_front[0] , 0 ])
461       mirror([1,0,0]){
462       rotate([0,-90,0])rotate([0,0,-90]){
463         linear_extrude(height= 200)
464           Machine_FrontProfile();
465       }
466     }
467     translate([ rearcurve_strt_len,
468                 0,
469                 rearcurve_z_slop ]){
470       translate([ 1,
471                   0,
472                   0
473                   ]){
474         rotate([0,-90,0])rotate([0,0,-90]){
475           linear_extrude(height= rearcurve_strt_len + 1)
476           Machine_RearProfile();
477         }
478       }
479       translate([ 0,
480                   0,
481                   rearcurve_double_inrad ]) {
482         intersection(){
483           rotate([90,0,0]){
484             rotate_extrude(convexity=10, $fn=32) {
485               rotate([0,0,90]) translate([ 0,
486                           -rearcurve_double_inrad ]) {
487                 Machine_RearProfile();
488               }
489             }
490           }
491           mirror([0,0,1])
492             translate([0,-75,0]) cube([150,150,150]);
493         }
494       }
495     }
496   }
497 }
498
499 module Machine(){ ////toplevel
500   Machine_Arm();
501   Machine_Curves();
502 }
503   
504 function Rectangle_corners(c0, sz) =
505   // returns the corners of a rectangle from c0 to c0+sz
506   // if sz is positive, the corners are anticlockwise starting with c0
507   [ c0 + [ 0,     0     ],
508     c0 + [ sz[0], 0     ],
509     c0 + [ sz[0], sz[1] ],
510     c0 + [ 0,     sz[1] ] ];
511
512 function Rectangle_corners2posts(c) =
513   [ c[0] + thehd_tr,
514     c[1] + thehd_tl,
515     c[2] + thehd_bl,
516     c[3] + thehd_br ];
517
518 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
519
520 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
521
522 m4_dnl   R_EDGE(c,ix)
523 m4_dnl        c is from Rectangle_corners and
524 m4_dnl        ix is a corner number
525 m4_dnl    expands to two comma-separated corners:
526 m4_dnl    that denoted by ix, and the next one anticlockwise
527 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
528
529 module Tile02(){ ////toplevel
530   sz = [100,170];
531   c0 = tile02_tr + -sz;
532   c = Rectangle_corners(c0, sz);
533   posts = Rectangle_corners2posts(c);
534   rcs = [R_EDGE(c,0)];
535   difference(){
536     union(){
537       Rectangle_TileBase(c);
538       Posts(posts);
539       RoundEdge(R_EDGE(c,0));
540       RoundEdge(R_EDGE(c,3));
541       InterlockEdge(R_EDGE(c,2), 0);
542     }
543     InterlockEdge(R_EDGE(c,1), 1);
544     RoundCornerCut(rcs);
545   }
546   RoundCornerAdd(rcs);
547 }
548
549 module Tile12(){ ////toplevel
550   sz = [100,250];
551   c0 = tile02_tr + [-sz[0], 0];
552   c = Rectangle_corners(c0, sz);
553   posts = Rectangle_corners2posts(c);
554   rcs = [R_EDGE(c,3)];
555   difference(){
556     union(){
557       Rectangle_TileBase(c);
558       Posts(posts);
559       RoundEdge(R_EDGE(c,2));
560       RoundEdge(R_EDGE(c,3));
561     }
562     InterlockEdge(R_EDGE(c,0), 1);
563     InterlockEdge(R_EDGE(c,1), 1);
564     RoundCornerCut(rcs);
565   }
566   RoundCornerAdd(rcs);
567 }
568
569 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
570 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
571 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
572
573 module Tile11(){ ////toplevel
574   sz = [250,250];
575   c0 = tile01_tr + [-sz[0],0];
576   c = Rectangle_corners(c0, sz);
577   cnr_posts = Rectangle_corners2posts(c);
578   posts = concat(
579                  Posts_interpolate_one(cnr_posts[0],
580                                        cnr_posts[1] - [cutout_tile11_x, 0]),
581                  [ cnr_posts[1] + [0, cutout_tile11_y],
582                    cnr_posts[2],
583                    cnr_posts[3]
584                    ]);
585   difference(){
586     union(){
587       Rectangle_TileBase(c);
588       Posts(posts);
589       RoundEdge(R_EDGE(c,2));
590       InterlockEdge(R_EDGE(c,3));
591     }
592     InterlockEdge(c[0], tile_01_11_cnr, 1);
593     InterlockEdge(tile_11_10_cnr, c[2], 1);
594     Machine();
595   }
596 }    
597
598 module Tile01(){ ////toplevel
599   sz = [250,170];
600   c0 = tile01_tr + -sz;
601   c = Rectangle_corners(c0, sz);
602   cnr_posts = Rectangle_corners2posts(c);
603   posts = concat(
604                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
605                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
606                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
607                                        cnr_posts[3])
608                  );
609   difference(){
610     union(){
611       Rectangle_TileBase(c);
612       Posts(posts);
613       RoundEdge(R_EDGE(c,0));
614       InterlockEdge(tile_01_11_cnr, c[3]);
615       InterlockEdge(R_EDGE(c,3));
616     }
617     InterlockEdge(c[1], tile_01_00_cnr, 1);
618     Machine();
619   }
620 }    
621
622 module Tile10(){ ////toplevel
623   sz = [250,250];
624   c0 = tile01_tr + [0,0];
625   c = Rectangle_corners(c0, sz);
626   cnr_posts = Rectangle_corners2posts(c);
627   cty = cutout_tile11_y;
628   rcy = cty + rearcurve_avoid_y;
629   posts = [ cnr_posts[0] + [ 0,                             cty ],
630             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
631             cnr_posts[1] + [ 0,                             rcy ],
632             cnr_posts[2],
633             cnr_posts[3] ];
634   rcs = [R_EDGE(c,2)];
635   difference(){
636     union(){
637       Rectangle_TileBase(c);
638       Posts(posts);
639       RoundEdge(R_EDGE(c,1));
640       RoundEdge(R_EDGE(c,2));
641       InterlockEdge(c[3], tile_11_10_cnr);
642     }
643     RoundCornerCut(rcs);
644     Machine();
645   }
646   RoundCornerAdd(rcs);
647 }
648
649 module Tile00(){ ////toplevel
650   sz = [250,170];
651   c0 = tile01_tr + [0,-sz[1]];
652   c = Rectangle_corners(c0, sz);
653   cnr_posts = Rectangle_corners2posts(c);
654   cty = cutout_tile01_y;
655   rcy = cty + frontcurve_avoid_y;
656   posts = [ cnr_posts[0],
657             cnr_posts[1],
658             cnr_posts[2] + [ 0,                             -rcy ],
659             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
660             cnr_posts[3] + [ 0,                             -cty ]
661             ];
662   rcs = [R_EDGE(c,1)];
663   difference(){
664     union(){
665       Rectangle_TileBase(c);
666       Posts(posts);
667       RoundEdge(R_EDGE(c,0));
668       RoundEdge(R_EDGE(c,1));
669       InterlockEdge(tile_01_00_cnr, c[0]);
670     }
671     RoundCornerCut(rcs);
672     Machine();
673   }
674   RoundCornerAdd(rcs);
675 }
676
677 module Demo(){ ////toplevel
678   translate(demo_slop*[-2,1]) color("blue") Tile12();
679   translate(demo_slop*[-2,0]) color("red")  Tile02();
680   translate(demo_slop*[-2,1]) color("orange") Tile11();
681   translate(demo_slop*[-2,0]) color("purple") Tile01();
682   translate(demo_slop*[-3,1]) color("blue")   Tile10();
683   translate(demo_slop*[-3,0]) color("red")    Tile00();
684   %Machine();
685 }
686   
687 //TestPiece1();
688 //TestPiece2();
689 //Demo();
690
691 //Machine_Profile();
692 //Machine_RearProfile();