chiark / gitweb /
6c4467651985fd663cfb853253c4548bc0f9411a
[reprap-play.git] / sewing-table.scad.m4
1 // -*- C -*-
2
3 include <funcs.scad>
4 include <commitid.scad>
5
6 ply_th = 18;
7 ply_hole_dia = 15;
8 ply_edge_min = 10;
9
10 tile_th = 3;
11 post_dia = 8;
12
13 post_shorter = 1;
14
15 screw_dia = 2.2;
16 screw_big_dia = 3.6;
17 screw_big_len = 4.0;
18
19 round_edge_rad = 2.0;
20
21 interlock_dia = 10;
22
23 // calculated
24
25 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
26
27 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
28
29 hole_slop = (ply_hole_dia - post_dia)/2;
30 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
31
32 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
33          tile_hard_edge_hole_dist));
34
35 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
36          tile_hard_edge_hole_dist + round_edge_rad));
37
38 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
39 thehd_tr = thehd;
40 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
41 thehd_bl = -thehd_tr;
42 thehd_br = -thehd_tl;
43
44 interlock_rad = interlock_dia/2;
45 interlock_negative_rad = interlock_rad + 0.125;
46
47 module Post(){
48   mirror([0,0,1]) {
49     difference(){
50       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
51       translate([0,0, tile_th]) {
52         cylinder(r= screw_big_dia/2, h= screw_big_len);
53         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
54       }
55     }
56   }
57 }
58
59 module Posts(posts) {
60   for (p= posts) {
61     translate(concat(p, [0]))
62       Post();
63   }
64 }
65
66 module TileBase(botleft, topright){
67   size = topright - botleft;
68   botleft_post = botleft + thehd_tr;
69   topright_post = topright + thehd_bl;
70   difference(){
71     mirror([0,0,1])
72       translate(concat(botleft, [0]))
73       cube(concat(size, [tile_th]));
74     translate( concat(botleft_post, [-tile_th])
75                + 0.5 * [ post_dia, post_dia, 0 ] )
76       Commitid_BestCount_M( topright_post-botleft_post
77                             + [-post_dia,-post_dia]
78                             + [0, thehd[1]]);
79   }
80 }
81
82 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
83 m4_define(`INREFFRAME',`
84   length_vec = ($2) - ($1);
85   length = dist2d([0,0], length_vec);
86   length_uvec = length_vec / length;
87   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
88   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
89         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
90         [ 0,              0,              1,            0, ],
91         [ 0,              0,              0,            1, ] ];
92   $3
93   multmatrix(m)
94 ')
95
96 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
97 m4_dnl    INREFFRAME_EDGE { body; }
98 m4_define(`INREFFRAME_EDGE',`
99   translate([0,0, -round_edge_rad])
100 ')
101
102 module RoundEdge(left_cnr, right_cnr) {
103   INREFFRAME(left_cnr, right_cnr)
104     INREFFRAME_EDGE {
105     difference(){
106       rotate([0,90,0])
107         cylinder(r= round_edge_rad, h= length, $fn=50);
108       translate([-1, 0, -20])
109         cube([length+2, 20, 20]);
110     }
111   }
112 }
113
114 module RoundLeftCorner(this_cnr, right_cnr) {
115   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
116     difference(){
117       sphere(r= round_edge_rad, $fn=60);
118       translate([0,0, -20])
119         cube([20,20,20]);
120     }
121   }
122 }
123
124 module InterlockLobePlan(negative) {
125   r = negative ? interlock_negative_rad : interlock_rad;
126   ymir = negative ? 0 : 1;
127
128   dx = sqrt(3) * r;
129   $fn= 80;
130   translate([thehd[0], 0]){
131     mirror([0,ymir,0]){
132       circle(r=r);
133       difference(){
134         translate([-dx, -0.1])
135           square([ dx*2, r/2 + 0.1 ]);
136         for (xi = [-1, 1]) {
137           translate([ xi*dx, r ])
138             circle(r=r);
139         }
140       }
141     }
142   }
143 }
144
145 module InterlockEdgePlan(negative, nlobes, length) {
146   for (lobei = [ 0 : nlobes-1 ]) {
147     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
148     translate([lobex, 0, 0]) {
149       InterlockLobePlan(negative);
150     }
151   }
152 }
153
154 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
155   plusth = negative * 1.0;
156
157   INREFFRAME(left_cnr, right_cnr) {
158     translate([0, 0, plusth]){
159       mirror([0,0,1]){
160         linear_extrude(height=tile_th+plusth*2, convexity=10){
161           InterlockEdgePlan(negative, nlobes, length);
162         }
163       }
164     }
165   }
166 }
167
168 function TestPiece_holes2corners(holes) =
169   [ holes[0] + thehd_bl,
170     holes[1] + thehd_br,
171     holes[1] + thehd_tr,
172     holes[0] + thehd_tl ];
173
174 module TestPiece1(){ ////toplevel
175   holes = [ [-100, 0],
176             [   0, 0]
177             ];
178   corners = TestPiece_holes2corners(holes);
179   difference(){
180     TileBase(corners[0], corners[2]);
181     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
182   }
183   Posts(holes);
184   RoundEdge(corners[0], corners[1]);
185   RoundEdge(corners[3], corners[0]);
186   RoundLeftCorner(corners[0], corners[1]);
187 }
188
189 module TestPiece2(){ ////toplevel
190   holes = [ [   0, 0],
191             [  50, 0]
192             ];
193   corners = TestPiece_holes2corners(holes);
194   TileBase(corners[0], corners[2]);
195   Posts(holes);
196   RoundEdge(corners[0], corners[1]);
197   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
198 }
199
200 module TestDemo(){ ////toplevel
201   translate([ -thehd[0], 0 ])
202     color("blue")
203     TestPiece1();
204   translate([ +thehd[0], 0 ])
205     TestPiece2();
206 }
207   
208 function Rectangle_corners(c0, sz) =
209   [ c0 + [ 0,     0     ],
210     c0 + [ sz[0], 0     ],
211     c0 + [ sz[0], sz[1] ],
212     c0 + [ 0,     sz[1] ] ];
213
214 function Rectangle_corners2posts(c) =
215   [ c[0] + thehd_tr,
216     c[1] + thehd_tl,
217     c[2] + thehd_bl,
218     c[3] + thehd_br ];
219
220 module Tile02(){ ////toplevel
221   sz = [100,170];
222   c0 = -sz;
223   c = Rectangle_corners(c0, sz);
224   posts = Rectangle_corners2posts(c);
225   difference(){
226     TileBase(c[0], c[2]);
227   }
228   Posts(posts);
229   RoundEdge(c[0], c[1]);
230   RoundEdge(c[3], c[0]);
231   RoundLeftCorner(c[0], c[1]);
232   InterlockEdge(c[2], c[3], 0, 2);
233 }
234
235 module Tile12(){ ////toplevel
236   sz = [100,250];
237   c0 = [-sz[0], 0];
238   c = Rectangle_corners(c0, sz);
239   posts = Rectangle_corners2posts(c);
240   difference(){
241     TileBase(c[0], c[2]);
242   }
243   Posts(posts);
244   RoundEdge(c[2], c[3]);
245   RoundEdge(c[3], c[0]);
246   RoundLeftCorner(c[2], c[3]);
247 }
248
249 module Demo(){ ////toplevel
250   color("blue") Tile12();
251   color("red")  Tile02();
252 }
253   
254 //TestPiece1();
255 //TestPiece2();
256 //Demo();