sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 screw_dia = 2.2;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 leg_height = 50;
  34
  35 leg_hole_dia = 5 + 0.75;
  36 leg_big_dia = 37;
  37 leg_bot_dia = 15;
  38 leg_top_flat_z = 5;
  39
  40 leg_fin_top_w = 5;
  41 leg_fin_bot_w = 5;
  42 leg_fin_bot_rad = 30;
  43 leg_fin_bot_flat_z = 5;
  44
  45 // cutout
  46
  47 machine_rear_to_front = 84 + 0.25 - 1.4;
  48
  49 cutout_l_end_y_front_slop = 0.5;
  50 cutout_l_end_y_rear_slop = 0.5;
  51
  52 cutout_l_end_x = 22;
  53 cutout_l_end_y = machine_rear_to_front;
  54 cutout_l_end_new_x_slop = 1.4 - 1.95;
  55 cutout_l_end_y_total = cutout_l_end_y
  56   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  57
  58 tile02_tr = [-250, 0];
  59 tile01_tr = [  0, 0];
  60
  61 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  62 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  63
  64 // front and rear curves
  65
  66 rearedge_len = 170 + 0.70;
  67 frontedge_len = 170;
  68
  69 rearcurve_strt_len = 52;
  70
  71 rearcurve_z_slop = -0.50;
  72
  73 rearcurve_avoid_y = 35;
  74
  75 rearcurve_double_inrad = 26.10 + 8.04;
  76
  77 reartablet_z = 2.54;
  78 reartablet_x = 5 + 1;
  79 reartablet_y = 8;
  80
  81 frontcurve_side_skew = 3.5 / 72;
  82 frontcurve_avoid_y = 70;
  83 frontcurve_z_slop = 0.75;
  84
  85 frontcurve_strt_len = 50;
  86 frontcurve_dualcurve_angle = 30;
  87
  88 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  89                       [ 180, 90 ],
  90                       [ 190, -80 ], // do not change index of this one
  91                       [   0, 70 ],  [  0, -35 ],
  92                       ];
  93
  94 teststrap = [ 3, 5 ];
  95 teststrap_peg = [7.5, 3.5];
  96
  97 ply_edge_hole_dist_real = 14;
  98
  99 // calculated
 100
 101 TEST = false;
 102 JIG = false;
 103
 104 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 105
 106 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 107
 108 hole_slop = (ply_hole_dia - post_dia)/2;
 109 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 110
 111 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 112          tile_hard_edge_hole_dist));
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 115          tile_hard_edge_hole_dist + round_edge_rad));
 116
 117 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 118 thehd_tr = thehd;
 119 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 120 thehd_bl = -thehd_tr;
 121 thehd_br = -thehd_tl;
 122
 123 tablet_z_slop = 1.00;
 124
 125 interlock_rad = interlock_dia/2;
 126 interlock_negative_rad = interlock_rad + 0.125;
 127
 128 interlock_sq_adj = 0.2; // arbitrary
 129
 130 leg_fin_top_rad = sqrt( pow(leg_big_dia/2,2) -
 131                         pow(leg_fin_top_w/2,2) );
 132
 133 m4_define(`POST_TCROSSSZ',
 134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 135
 136 module Post(){
 137   mirror([0,0,1]) {
 138     if (!JIG) {
 139       difference(){
 140         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 141         translate([0,0, tile_th]) {
 142           cylinder(r= screw_big_dia/2, h= screw_big_len);
 143           cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 144         }
 145       }
 146     }
 147     if (TEST) {
 148       translate([0,0, tile_th/2]) {
 149         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 150         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 151       }
 152     }
 153     if (JIG) {
 154       translate([0,0, tile_th/2]) {
 155         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 156       }
 157     }
 158   }
 159 }
 160
 161 module PostHole(){
 162   if (JIG) {
 163     translate([0,0,-5])
 164       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 165     translate([0,0, -jig_min_th])
 166       cylinder(r= ply_hole_dia_real/2, h = 5);
 167     for (rot=[0:90:270]) rotate(rot) {
 168         translate([ ply_edge_hole_dist_real, 0, 0 ])
 169           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 170       }
 171   }
 172 }
 173
 174 module Posts(posts) {
 175   for (p= posts) {
 176     translate(concat(p, [0]))
 177       Post();
 178   }
 179 }
 180 module PostHoles(posts) {
 181   for (p= posts)  {
 182     translate(concat(p, [0]))
 183       PostHole();
 184   }
 185 }
 186
 187 module TileBase(botleft, topright){
 188   size = topright - botleft;
 189   botleft_post = botleft + thehd_tr;
 190   topright_post = topright + thehd_bl;
 191   difference(){
 192     mirror([0,0,1])
 193       translate(concat(botleft, [0]))
 194       cube(concat(size, [tile_th]));
 195     if (!(TEST || JIG)) {
 196       cidsz = topright_post-botleft_post
 197         + [-post_dia,-post_dia]
 198         + [0, thehd[1]];
 199       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 200       echo("CID",cidsz,cidszr);
 201       translate( concat(botleft_post, [ -tile_th ])
 202                  + 0.5 * [ post_dia, post_dia, 0 ]
 203                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 204         Commitid_BestCount_M(cidszr);
 205     }
 206     if ((TEST || JIG)) {
 207       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 208       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 209       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 210       if (TEST)
 211         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 212           Commitid_BestCount(cidszr);
 213       difference(){
 214         mirror([0,0,1]) {
 215           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 216             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 217           translate(concat(botleft_post, [-1]))
 218             cube(concat(topright_post-botleft_post, [tile_th+2]));
 219         }
 220         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 221         minkowski(){
 222           MachineEnvelope();
 223           cube(shufflesz, center=true);
 224         }
 225         if (JIG) {
 226           translate([0,0,-20]) linear_extrude(height=20) {
 227             for (diag=[[ +1, botleft                   ],
 228                        [ -1, [topright[0], botleft[1]] ]]) {
 229               translate(diag[1])
 230                 rotate(atan2(size[1], diag[0] * size[0]))
 231                 translate([0, -test_edge/2])
 232                 square([vectorlen2d(size), test_edge]);
 233             }
 234           }
 235         }
 236       }
 237     }
 238   }
 239 }
 240
 241 m4_dnl   R_EDGE(c,ix)
 242 m4_dnl        c is from Rectangle_corners and
 243 m4_dnl        ix is a corner number
 244 m4_dnl    expands to two comma-separated corners:
 245 m4_dnl    that denoted by ix, and the next one anticlockwise
 246 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 247
 248 m4_dnl   R_CNR(c,ix)
 249 m4_dnl        c is from Rectangle_corners and
 250 m4_dnl        ix is a corner number
 251 m4_dnl    expands to an array of corners as for RoundCorner
 252 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 253
 254 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 255 m4_define(`INREFFRAME',`
 256   length_vec = ($2) - ($1);
 257   length = dist2d([0,0], length_vec);
 258   length_uvec = length_vec / length;
 259   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 260   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 261         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 262         [ 0,              0,              1,            0, ],
 263         [ 0,              0,              0,            1, ] ];
 264   $3
 265   multmatrix(m)
 266 ')
 267
 268 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 269 m4_dnl    INREFFRAME_EDGE { body; }
 270 m4_define(`INREFFRAME_EDGE',`
 271   translate([0,0, -round_edge_rad])
 272 ')
 273
 274 module RoundEdge(left_cnr, right_cnr) {
 275   INREFFRAME(left_cnr, right_cnr)
 276     INREFFRAME_EDGE {
 277     difference(){
 278       rotate([0,90,0])
 279         cylinder(r= round_edge_rad, h= length, $fn=50);
 280       translate([-1, 0, -20])
 281         cube([length+2, 20, 20]);
 282     }
 283   }
 284 }
 285
 286 m4_define(`ROUNDCORNER_VARS',`
 287   this_cnr = ci[0];
 288   right_cnr = ci[1];
 289   left_cnr = ci[2];
 290   bigr= round_cnr_rad - round_edge_rad;
 291   l_uvec = unitvector2d(left_cnr - this_cnr);
 292   r_uvec = unitvector2d(right_cnr - this_cnr);
 293   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 294   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 295   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 296   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 297   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 298   ctr3 = concat(ctr,[0])
 299 ')
 300
 301 module RoundCorner_selector(ci, adj) {
 302   ROUNDCORNER_VARS;
 303   intersection(){
 304     union(){
 305       INREFFRAME(ctr3,concat(lp1,[4])){
 306         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 307           translate([-bigr*2 + adj, -bigr])
 308             square([bigr*2, bigr*3]);
 309         }
 310       }
 311     }
 312     union(){
 313       INREFFRAME(ctr3,concat(lp4,[0])){
 314         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 315           translate([-bigr*2, -bigr*2])
 316             square([bigr*2 + adj, bigr*3]);
 317         }
 318       }
 319     }
 320   }
 321 }
 322
 323 module RoundCornerCut(ci) {
 324   // ci should be [this_cnr, right_cnr, left_cnr]
 325   // where right_cnr is to the right (ie, anticlockwise)
 326   ROUNDCORNER_VARS;
 327   difference(){
 328     RoundCorner_selector(ci, -0.1);
 329     translate(ctr3)
 330       cylinder(center=true, h=20, r= bigr);
 331   }
 332 }
 333
 334 module RoundCornerAdd(ci) {
 335   ROUNDCORNER_VARS;
 336   intersection(){
 337     RoundCorner_selector(ci, +0.1);
 338     INREFFRAME_EDGE {
 339       translate(ctr3){
 340         rotate_extrude(convexity=10, $fn=50)
 341           translate([bigr, 0])
 342           difference(){
 343           circle(r= round_edge_rad, $fn=50);
 344           mirror([1,1])
 345             square([20,20]);
 346         }
 347       }
 348     }
 349   }
 350 }
 351
 352 module InterlockLobePlan(negative) {
 353   r = negative ? interlock_negative_rad : interlock_rad;
 354   ymir = negative ? 0 : 1;
 355
 356   dx = sqrt(3) * r;
 357   $fn= 80;
 358   translate([thehd[0], 0]){
 359     mirror([0,ymir]){
 360       circle(r=r);
 361       difference(){
 362         translate([-dx, -0.1])
 363           square([ dx*2, r/2 + 0.1 ]);
 364         for (xi = [-1, 1]) {
 365           translate([ xi*dx, r ])
 366             circle(r=r);
 367         }
 368       }
 369     }
 370   }
 371 }
 372
 373 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 374   for (lobei = [ 0 : nlobes-1 ]) {
 375     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 376     translate([lobex, 0, 0]) {
 377       InterlockLobePlan(negative);
 378     }
 379   }
 380
 381   if (dosquare) {
 382     iadj = 0;
 383     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 384     mirror([0, negative])
 385       translate([slotshorter, iadj])
 386       square([length - slotshorter*2, interlock_fine + iadj*2]);
 387   }
 388 }
 389
 390 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 391   plusth = negative * 1.0;
 392   protr = interlock_fine + interlock_sq_adj;
 393
 394   z2 = -tile_th/2;
 395   z1 = -tile_th/2 - protr / interlock_fine_slope;
 396   z3 = -tile_th/2 + protr / interlock_fine_slope;
 397
 398   negsign = negative ? -1 : +1;
 399   yprotr = negsign * protr;
 400
 401   INREFFRAME(left_cnr, right_cnr) {
 402     for (vsect = [ // zs0            zs1      ys0,            ys1
 403                   [ -tile_th-plusth, plusth,  0,              0],
 404                   [ z1,              z2,      0, yprotr],
 405                   [ z2,              z3,      yprotr, 0],
 406                   ]) {
 407       zs0 = vsect[0];
 408       zs1 = vsect[1];
 409       zsd = zs1-zs0;
 410       ys0 = vsect[2];
 411       ys1 = vsect[3];
 412       ysd = ys1-ys0;
 413       sl = ysd/zsd;
 414       m = [ [ 1,0,   0,    0 ],
 415             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 416             [ 0,0,   1,  zs0 ],
 417             [ 0,0,   0,    1 ] ];
 418       multmatrix(m)
 419         linear_extrude(height=zsd, convexity=10)
 420         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 421     }
 422   }
 423 }
 424
 425 function TestPiece_holes2corners(holes) =
 426   [ holes[0] + thehd_bl,
 427     holes[1] + thehd_br,
 428     holes[1] + thehd_tr,
 429     holes[0] + thehd_tl ];
 430
 431 module TestPiece1(){ ////toplevel
 432   holes = [ [-100, 0],
 433             [   0, 0]
 434             ];
 435   corners = TestPiece_holes2corners(holes);
 436   rcs = R_CNR(corners,0);
 437   difference(){
 438     union(){
 439       TileBase(corners[0], corners[2]);
 440       Posts(holes);
 441       RoundEdge(corners[0], corners[1]);
 442       RoundEdge(corners[3], corners[0]);
 443     }
 444     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 445     RoundCornerCut(rcs);
 446     PostHoles(holes);
 447   }
 448   RoundCornerAdd(rcs);
 449 }
 450
 451 module TestPiece2(){ ////toplevel
 452   holes = [ [   0, 0],
 453             [  50, 0]
 454             ];
 455   corners = TestPiece_holes2corners(holes);
 456   difference(){
 457     union(){
 458       TileBase(corners[0], corners[2]);
 459       Posts(holes);
 460       RoundEdge(corners[0], corners[1]);
 461       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 462     }
 463     PostHoles(holes);
 464   }
 465 }
 466
 467 module TestDemo(){ ////toplevel
 468   translate([ -thehd[0], 0 ])
 469     color("blue")
 470     TestPiece1();
 471   translate([ +thehd[0] + demo_slop, 0 ])
 472     TestPiece2();
 473 }
 474
 475 module Machine_NewRearProfile(){
 476   // figures copied out of xfig edit boxes
 477   // best not to edit the posbox size if poss - just move it
 478   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 479   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 480   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 481   scaleline_mm = 12+5+10+5+3;
 482   sh = -[abs(posbox[0]), abs(posbox[1])];
 483   rot = atan2(-sideline[0], sideline[1]);
 484   sc = scaleline_mm / scaleline;
 485   //echo("SH",sh,rot,sc);
 486   scale(sc) rotate(rot) translate(sh){
 487     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 488   }
 489 }
 490
 491 module Machine_NewFrontProfile(){
 492   // figures copied out of xfig edit boxes
 493   // best not to edit the posbox size if poss - just move it
 494   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 495   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 496   refline_mm = (11-1)*10;
 497   sh = -[abs(posbox[0]), abs(posbox[1])];
 498   rot = atan2(-refline[0], refline[1]);
 499   sc = refline_mm / vectorlen2d(refline);
 500   //echo("SH",sh,rot,sc);
 501   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 502     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 503   }
 504 }
 505
 506 module Machine_NewEndProfile(){
 507   // figures copied out of xfig edit boxes
 508   // NB that y coords are reversed - xfig origin is at bottom left
 509   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 510   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 511   refline_mm = 10 * (11 - 2.5);
 512   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 513                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 514   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 515
 516   rot_adj = -0.38;
 517
 518   posbox = [min(posboxs[0][0],posboxs[1][0]),
 519             max(posboxs[0][1],posboxs[1][1])];
 520
 521   m4_define(`MNEP_ELP',
 522      `line_intersection_2d(baseline[0],baseline[1],
 523                            sidelines[$1][0],sidelines[$1][1])')
 524   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 525
 526   rot = atan2(-refline[1], -refline[0]);
 527   sc = refline_mm / vectorlen2d(refline);
 528   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 529
 530   ellen = sc * dist2d(endline[0],endline[1]);
 531   scy = cutout_l_end_y_total / ellen;
 532
 533   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 534
 535     mirror([0,1]){
 536   //%translate(1 * (posboxs[0] - posbox)) square(50);
 537   //%translate(1 * (posboxs[1] - posbox)) square(50);
 538 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 539
 540 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 541 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 542
 543 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 544 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 545 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 546 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 547     }
 548
 549     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 550   }
 551 }
 552
 553 module Machine_NewEndProfileDemo(){ ////toplevel
 554     translate([0,5,0])                             Machine_NewEndProfile();
 555     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 556   mirror([0,1,0]){
 557     translate([0,5, 0])                             Machine_NewEndProfile();
 558     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 559   }
 560 }
 561
 562 module Machine_NewArm(){
 563   translate([0,0,-30]) linear_extrude(height=60) {
 564     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 565                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 566       rotate(-90){
 567         hull(){
 568           for (d=[0,400])
 569             translate([0,d]) Machine_NewEndProfile();
 570         }
 571       }
 572     }
 573   }
 574 }
 575
 576 module Machine_NewRearCurve(){
 577   slant = atan2(4,210-10);
 578   //echo("SL",slant);
 579   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 580     translate([ rearcurve_double_inrad,
 581                 0,
 582                 -rearcurve_double_inrad + 10 ]){
 583       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 584         hull(){
 585           Machine_NewRearProfile();
 586           translate([0,-100]) Machine_NewRearProfile();
 587         }
 588       }
 589     }
 590     rotate([0,90,0]) rotate([90,0,0]) {
 591       intersection(){
 592         rotate_extrude(convexity=10, $fn=64)
 593           rotate(90)
 594           translate([ 0, -rearcurve_double_inrad ])
 595           Machine_NewRearProfile();
 596         translate([0,0,-500])
 597           cube([500,500,1000]);
 598       }
 599     }
 600     translate([1,0,-rearcurve_double_inrad])
 601       rotate([0,-90,0]) rotate([0,0,-90])
 602       linear_extrude(height= rearcurve_strt_len + 1)
 603       Machine_NewRearProfile();
 604   }
 605 }
 606
 607 module Machine_Curves(){ ////toplevel
 608   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 609               cutout_tile11_y,
 610               0 ]){
 611     //%cube([20,20,20]);
 612     translate([ -reartablet_x,
 613                 -1,
 614                 -reartablet_z + tablet_z_slop])
 615       mirror([0,0,1])
 616       cube([ reartablet_x+1,
 617              reartablet_y+1,
 618              20 ]);
 619   }
 620   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 621               cutout_tile11_y,
 622               frontcurve_z_slop ]){
 623     translate([0, -machine_rear_to_front, 0])
 624       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 625                   [0,  1,   0, 0],
 626                   [0,  0,   1, 0],
 627                   [0,  0,   0, 1]])
 628       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 629       linear_extrude(height= 200)
 630       Machine_NewFrontProfile();
 631   }
 632   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 633               cutout_tile11_y,
 634               frontcurve_z_slop ]){
 635     translate([ rearcurve_strt_len,
 636                 0,
 637                 rearcurve_z_slop ]){
 638       Machine_NewRearCurve();
 639     }
 640   }
 641 }
 642
 643 module TestStrapSlots(){
 644   pegwidth = teststrap_peg[0];
 645   for (pos = teststrapslots_at) {
 646     echo("TSS",pos);
 647     translate(concat(pos,[0]))
 648       for (mx = [0,1]) mirror([mx,0,0]) {
 649           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 650             cube(concat(teststrap,[40]));
 651         }
 652   }
 653 }
 654
 655 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 656
 657 module TestStrapPeg_Short(){ ////toplevel
 658   TestStrapPeg_any(35);
 659 }
 660
 661 module TestStrapPeg_Long(){ ////toplevel
 662   TestStrapPeg_any(60);
 663 }
 664
 665 module Machine(){ ////toplevel
 666   Machine_NewArm();
 667   Machine_Curves();
 668   if (TEST)
 669     TestStrapSlots();
 670 }
 671
 672 module MachineEnvelope(){
 673   // used for testing
 674   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 675   y_arm_t  = cutout_tile11_y;
 676   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 677   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 678
 679   translate([0,0,-50]) linear_extrude(height= 100){
 680     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 681     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 682   }
 683 }
 684
 685 module Leg(){ ////toplevel
 686   difference(){
 687     union(){
 688       hull(){
 689         mirror([0,0,1])
 690           cylinder(r= leg_big_dia/2, height=leg_top_flat_z, $fn=100);
 691         translate([0,0, -leg_height])
 692           cylinder(r= leg_bot_dia/2, height=1, $fn=100);
 693       }
 694       for (rot=[0:90:270]) rotate(rot) {
 695           hull(){
 696             mirror([0,0,1]) translate([0, -leg_fin_top_w/2, 0])
 697               cube([ leg_fin_top_rad - 0.1,
 698                      leg_fin_top_w,
 699                      1 ])
 700               ;
 701             translate([0, -leg_fin_bot_w/2, -leg_height])
 702               cube([ leg_fin_bot_rad,
 703                      leg_fin_bot_w,
 704                      leg_fin_bot_flat_z ]);
 705           }
 706         }
 707     }
 708     mirror([0,0,1]) translate([0,0,-1])
 709       cylinder(r= leg_hole_dia/2, h=leg_height+2, $fn=30);
 710   }
 711 }
 712
 713 function Rectangle_corners(c0, sz) =
 714   // returns the corners of a rectangle from c0 to c0+sz
 715   // if sz is positive, the corners are anticlockwise starting with c0
 716   [ c0 + [ 0,     0     ],
 717     c0 + [ sz[0], 0     ],
 718     c0 + [ sz[0], sz[1] ],
 719     c0 + [ 0,     sz[1] ] ];
 720
 721 function Rectangle_corners2posts(c) =
 722   [ c[0] + thehd_tr,
 723     c[1] + thehd_tl,
 724     c[2] + thehd_bl,
 725     c[3] + thehd_br ];
 726
 727 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 728
 729 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 730
 731 module Tile02(){ ////toplevel
 732   sz = [100,170];
 733   c0 = tile02_tr + -sz;
 734   c = Rectangle_corners(c0, sz);
 735   posts = Rectangle_corners2posts(c);
 736   rcs = R_CNR(c,0);
 737   difference(){
 738     union(){
 739       Rectangle_TileBase(c);
 740       Posts(posts);
 741       RoundEdge(R_EDGE(c,0));
 742       RoundEdge(R_EDGE(c,3));
 743       InterlockEdge(R_EDGE(c,2), 0);
 744     }
 745     InterlockEdge(R_EDGE(c,1), 1);
 746     RoundCornerCut(rcs);
 747     PostHoles(posts);
 748   }
 749   RoundCornerAdd(rcs);
 750 }
 751
 752 module Tile12(){ ////toplevel
 753   sz = [100,250];
 754   c0 = tile02_tr + [-sz[0], 0];
 755   c = Rectangle_corners(c0, sz);
 756   posts = Rectangle_corners2posts(c);
 757   rcs = R_CNR(c,3);
 758   difference(){
 759     union(){
 760       Rectangle_TileBase(c);
 761       Posts(posts);
 762       RoundEdge(R_EDGE(c,2));
 763       RoundEdge(R_EDGE(c,3));
 764     }
 765     InterlockEdge(R_EDGE(c,0), 1);
 766     InterlockEdge(R_EDGE(c,1), 1);
 767     RoundCornerCut(rcs);
 768     PostHoles(posts);
 769   }
 770   RoundCornerAdd(rcs);
 771 }
 772
 773 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 774 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 775 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 776
 777 module Tile11(){ ////toplevel
 778   sz = [250,250];
 779   c0 = tile01_tr + [-sz[0],0];
 780   c = Rectangle_corners(c0, sz);
 781   cnr_posts = Rectangle_corners2posts(c);
 782   posts = concat(
 783                  Posts_interpolate_one(cnr_posts[0],
 784                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 785                  [ cnr_posts[1] + [0, cutout_tile11_y],
 786                    cnr_posts[2],
 787                    cnr_posts[3]
 788                    ]);
 789   difference(){
 790     union(){
 791       Rectangle_TileBase(c);
 792       Posts(posts);
 793       RoundEdge(R_EDGE(c,2));
 794       InterlockEdge(R_EDGE(c,3));
 795     }
 796     InterlockEdge(c[0], tile_01_11_cnr, 1);
 797     InterlockEdge(tile_11_10_cnr, c[2], 1);
 798     PostHoles(posts);
 799     Machine();
 800   }
 801 }
 802
 803 module Tile01(){ ////toplevel
 804   sz = [250,170];
 805   c0 = tile01_tr + -sz;
 806   c = Rectangle_corners(c0, sz);
 807   cnr_posts = Rectangle_corners2posts(c);
 808   posts = concat(
 809                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 810                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 811                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 812                                        cnr_posts[3])
 813                  );
 814   difference(){
 815     union(){
 816       Rectangle_TileBase(c);
 817       Posts(posts);
 818       RoundEdge(R_EDGE(c,0));
 819       InterlockEdge(tile_01_11_cnr, c[3]);
 820       InterlockEdge(R_EDGE(c,3));
 821     }
 822     PostHoles(posts);
 823     InterlockEdge(c[1], tile_01_00_cnr, 1);
 824     Machine();
 825   }
 826 }
 827
 828 module Tile10(){ ////toplevel
 829   sz = [250,250];
 830   c0 = tile01_tr + [0,0];
 831   c = Rectangle_corners(c0, sz);
 832   cnr_posts = Rectangle_corners2posts(c);
 833   cty = cutout_tile11_y;
 834   rcy = cty + rearcurve_avoid_y;
 835   posts = [ cnr_posts[0] + [ 0,                             cty ],
 836             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 837             cnr_posts[1] + [ 0,                             rcy ],
 838             cnr_posts[2],
 839             cnr_posts[3] ];
 840   rcs = R_CNR(c,2);
 841   difference(){
 842     union(){
 843       Rectangle_TileBase(c);
 844       Posts(posts);
 845       RoundEdge(R_EDGE(c,1));
 846       RoundEdge(R_EDGE(c,2));
 847       InterlockEdge(c[3], tile_11_10_cnr);
 848     }
 849     PostHoles(posts);
 850     RoundCornerCut(rcs);
 851     Machine();
 852   }
 853   RoundCornerAdd(rcs);
 854 }
 855
 856 module Tile00(){ ////toplevel
 857   sz = [250,170];
 858   c0 = tile01_tr + [0,-sz[1]];
 859   c = Rectangle_corners(c0, sz);
 860
 861   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 862   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 863   c1bis = [ c[1][0],
 864             c[2][1] -
 865             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 866
 867   cnr_posts = Rectangle_corners2posts(c);
 868   cty = cutout_tile01_y;
 869   rcy = cty + frontcurve_avoid_y;
 870   posts = [ cnr_posts[0],
 871             cnr_posts[1],
 872             0.5 * (cnr_posts[0] + cnr_posts[1]),
 873             cnr_posts[2] + [ 0,                             -rcy ],
 874             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 875             cnr_posts[3] + [ 0,                             -cty ]
 876             ];
 877   rcs = R_CNR(c,1);
 878   rc2 = [c1bis,c2bis,c[1]];
 879   difference(){
 880     union(){
 881       difference(){
 882         union(){
 883           Rectangle_TileBase(c);
 884           Posts(posts);
 885           RoundEdge(R_EDGE(c,0));
 886           RoundEdge(c[1], c1bis);
 887           InterlockEdge(tile_01_00_cnr, c[0]);
 888         }
 889         RoundCornerCut(rcs);
 890         translate([0,0,-20]) linear_extrude(height=40) {
 891           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 892         }
 893       }
 894       RoundEdge(c1bis, c2bis);
 895     }
 896     Machine();
 897     PostHoles(posts);
 898     RoundCornerCut(rc2);
 899   }
 900   RoundCornerAdd(rcs);
 901   RoundCornerAdd(rc2);
 902 }
 903
 904 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 905   c = Rectangle_corners(c0, sz);
 906   brace = [7,7,9];
 907   bsz = sz + [bracexx,0,0];
 908   difference(){
 909     union(){
 910       Rectangle_TileBase(c);
 911       if (dobrace) {
 912         translate(concat(c0, [-brace[2] + 0.1])){
 913           difference(){
 914             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 915             translate(brace + [0,0, -25])
 916               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 917           }
 918         }
 919       }
 920       RoundEdge(R_EDGE(c,1));
 921     }
 922     Machine();
 923   }
 924 }
 925
 926 module FitTest_PairLink(cut=false){ ////toplevel
 927   cy0=-55; cy1=85; cx=132;
 928   bar = [10,10];
 929   legrad = 12;
 930   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 931   strap = [3,5];
 932   adj_neg_slop = 1.0;
 933   bar_z_slop = 1.75;
 934
 935   // calculated
 936   straphole_x_max = legrad/sqrt(2) + footrad_max;
 937   dz = cut ? adj_neg_slop : 0;
 938
 939   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 940     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 941
 942   for (endy=[cy0,cy1]) {
 943     $fn=32;
 944     translate([cx,endy,dz]){
 945       // feet
 946       for (rot=[45:90:315]) rotate(rot) {
 947         translate([legrad,0,0]){
 948           hull(){
 949             cylinder(r= footrad_max, h=1);
 950             translate([0,0,-footrad_depth])
 951               cylinder(r= footrad_min, h=1);
 952           }
 953           if (cut)
 954             translate([0,0,-10])
 955             cylinder(r= footrad_min +
 956                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 957                      h=20);
 958         }
 959       }
 960       // legs
 961       for (rot=[45,135]) rotate(rot) {
 962         hull(){
 963           for (s=[-1,+1]){
 964             translate([s*legrad,0,0])
 965               cylinder(r= footrad_max, h=bar[1]);
 966           }
 967         }
 968       }
 969       // strap holes
 970       if (cut) {
 971         for (rot=[0,180]) rotate(rot) {
 972             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 973               cube(concat(strap,[20]), center=true);
 974           }
 975       }
 976     }
 977   }
 978 }
 979
 980 module FitTest_RearCurve(){ ////toplevel
 981   difference(){
 982     FitTest_general([100,0], [180,100]);
 983     FitTest_PairLink(true);
 984     TestStrapSlots();
 985   }
 986 }
 987
 988 module FitTest_FrontCurve(){ ////toplevel
 989   p0 = [100,-80];
 990   sz = [180,80];
 991   difference(){
 992     intersection() {
 993       Tile00();
 994       translate([0,0,-8]) linear_extrude(height=18) {
 995         translate(p0) square(sz);
 996         translate(teststrapslots_at[3])
 997           scale(2* [ teststrap_peg[0], teststrap[1] ])
 998           circle(r=1, $fn=20);
 999       }
1000     }
1001     FitTest_PairLink(true);
1002     TestStrapSlots();
1003   }
1004 }
1005
1006 module FitTest_Entire(){ ////toplevel
1007   p0 = [-33,-80];
1008   szrear = [263,180];
1009   szfront = [243,szrear[1]];
1010   difference(){
1011     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
1012     FitTest_PairLink(true);
1013     translate(concat(p0,[0]) + [szfront[0],-10,-40])
1014       cube([100, -p0[1], 80]);
1015     TestStrapSlots();
1016   }
1017   intersection(){
1018     FitTest_RearCurve();
1019     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
1020   }
1021   FitTest_FrontCurve();
1022 }
1023
1024 module FitTest_EntireDemo(){ ////toplevel
1025   FitTest_Entire();
1026   //%Tile00();
1027 }
1028
1029 module FitTest_EndEnd(){ ////toplevel
1030   p0 = [-30,-32];
1031   sz = [156,81] - p0;
1032   sz2 = [136,68] - p0;
1033   difference(){
1034     FitTest_general(p0, sz);
1035     translate([ p0[0] -1, p0[1]+sz2[1], -10])
1036       cube([ sz2[0] +1, 50, 20 ]);
1037   }
1038 }
1039
1040 module FitTest_PairDemo(){ ////toplevel
1041   sh=[-90,-15,0];
1042   translate(sh){
1043     FitTest_PairLink();
1044     %FitTest_FrontCurve();
1045     %FitTest_RearCurve();
1046   }
1047   rotate([0,0,180]){
1048     translate(sh){
1049       difference(){
1050         union(){
1051           FitTest_FrontCurve();
1052           FitTest_RearCurve();
1053         }
1054         #FitTest_PairLink(true);
1055       }
1056     }
1057   }
1058 }
1059
1060 module RoundCornerDemo_plat(cnr){
1061   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1062 }
1063
1064 module RoundCornerDemo(){ ////toplevel
1065   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1066   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1067   translate([25,0,0]) RoundCornerAdd(cnr);
1068   translate([-25,0,0]) RoundCornerCut(cnr);
1069   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1070   difference(){
1071     RoundCornerDemo_plat(cnr);
1072     RoundCornerCut(cnr);
1073   }
1074   RoundCornerAdd(cnr);
1075 }
1076
1077 module Demo(){ ////toplevel
1078   translate(demo_slop*[-2,1]) color("blue") Tile12();
1079   translate(demo_slop*[-2,0]) color("red")  Tile02();
1080   translate(demo_slop*[-2,1]) color("orange") Tile11();
1081   translate(demo_slop*[-2,0]) color("purple") Tile01();
1082   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1083   translate(demo_slop*[-3,0]) color("red")    Tile00();
1084   %Machine();
1085   // Can also do this, to print reference sheet:
1086   //  load this into openscad
1087   //  select Ctrl-4 view, view all, scale appropriately
1088   //  import sewing-table,Demo-flat.png
1089   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1090   //  lpr t.pnm
1091 }
1092
1093 //TestPiece1();
1094 //TestPiece2();
1095 //Demo();
1096
1097 //Machine_NewRearProfile();
1098 //Machine_NewRearCurve();
1099 //Machine_NewFrontProfile();
1100 //Machine_NewEndProfile();
1101 //Machine_NewEndProfileDemo();
1102 //Machine_Curves();
1103 //Machine();
1104 //FitTest();
1105 //MachineEnvelope();